lib/AsmParser/Lexer.l.cvs

   1 /*===-- Lexer.l - Scanner for llvm assembly files --------------*- C++ -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //  This file implements the flex scanner for LLVM assembly languages files.
  11 //
  12 //===----------------------------------------------------------------------===*/
  13
  14 %option prefix="llvmAsm"
  15 %option yylineno
  16 %option nostdinit
  17 %option never-interactive
  18 %option batch
  19 %option noyywrap
  20 %option nodefault
  21 %option 8bit
  22 %option outfile="Lexer.cpp"
  23 %option ecs
  24 %option noreject
  25 %option noyymore
  26
  27 %{
  28 #include "ParserInternals.h"
  29 #include "llvm/Module.h"
  30 #include "llvm/Support/MathExtras.h"
  31 #include <list>
  32 #include "llvmAsmParser.h"
  33 #include <cctype>
  34 #include <cstdlib>
  35
  36 void set_scan_file(FILE * F){
  37   yy_switch_to_buffer(yy_create_buffer( F, YY_BUF_SIZE ) );
  38 }
  39 void set_scan_string (const char * str) {
  40   yy_scan_string (str);
  41 }
  42
  43 // Construct a token value for a non-obsolete token
  44 #define RET_TOK(type, Enum, sym) \
  45   llvmAsmlval.type = Instruction::Enum; \
  46   return sym
  47
  48 // Construct a token value for an obsolete token
  49 #define RET_TY(CTYPE, SYM) \
  50   llvmAsmlval.PrimType = CTYPE;\
  51   return SYM
  52
  53 namespace llvm {
  54
  55 // TODO: All of the static identifiers are figured out by the lexer,
  56 // these should be hashed to reduce the lexer size
  57
  58
  59 // atoull - Convert an ascii string of decimal digits into the unsigned long
  60 // long representation... this does not have to do input error checking,
  61 // because we know that the input will be matched by a suitable regex...
  62 //
  63 static uint64_t atoull(const char *Buffer) {
  64   uint64_t Result = 0;
  65   for (; *Buffer; Buffer++) {
  66     uint64_t OldRes = Result;
  67     Result *= 10;
  68     Result += *Buffer-'0';
  69     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  70       GenerateError("constant bigger than 64 bits detected!");
  71   }
  72   return Result;
  73 }
  74
  75 static uint64_t HexIntToVal(const char *Buffer) {
  76   uint64_t Result = 0;
  77   for (; *Buffer; ++Buffer) {
  78     uint64_t OldRes = Result;
  79     Result *= 16;
  80     char C = *Buffer;
  81     if (C >= '0' && C <= '9')
  82       Result += C-'0';
  83     else if (C >= 'A' && C <= 'F')
  84       Result += C-'A'+10;
  85     else if (C >= 'a' && C <= 'f')
  86       Result += C-'a'+10;
  87
  88     if (Result < OldRes)   // Uh, oh, overflow detected!!!
  89       GenerateError("constant bigger than 64 bits detected!");
  90   }
  91   return Result;
  92 }
  93
  94
  95 // HexToFP - Convert the ascii string in hexidecimal format to the floating
  96 // point representation of it.
  97 //
  98 static double HexToFP(const char *Buffer) {
  99   return BitsToDouble(HexIntToVal(Buffer));   // Cast Hex constant to double
 100 }
 101
 102
 103 // UnEscapeLexed - Run through the specified buffer and change \xx codes to the
 104 // appropriate character.
 105 char *UnEscapeLexed(char *Buffer, char* EndBuffer) {
 106   char *BOut = Buffer;
 107   for (char *BIn = Buffer; *BIn; ) {
 108     if (BIn[0] == '\\') {
 109       if (BIn < EndBuffer-1 && BIn[1] == '\\') {
 110         *BOut++ = '\\'; // Two \ becomes one
 111         BIn += 2;
 112       } else if (BIn < EndBuffer-2 && isxdigit(BIn[1]) && isxdigit(BIn[2])) {
 113         char Tmp = BIn[3]; BIn[3] = 0;      // Terminate string
 114         *BOut = (char)strtol(BIn+1, 0, 16); // Convert to number
 115         BIn[3] = Tmp;                       // Restore character
 116         BIn += 3;                           // Skip over handled chars
 117         ++BOut;
 118       } else {
 119         *BOut++ = *BIn++;
 120       }
 121     } else {
 122       *BOut++ = *BIn++;
 123     }
 124   }
 125   return BOut;
 126 }
 127
 128 } // End llvm namespace
 129
 130 using namespace llvm;
 131
 132 #define YY_NEVER_INTERACTIVE 1
 133 %}
 134
 135
 136
 137 /* Comments start with a ; and go till end of line */
 138 Comment    ;.*
 139
 140 /* Local Values and Type identifiers start with a % sign */
 141 LocalVarName       %[-a-zA-Z$._][-a-zA-Z$._0-9]*
 142
 143 /* Global Value identifiers start with an @ sign */
 144 GlobalVarName       @[-a-zA-Z$._][-a-zA-Z$._0-9]*
 145
 146 /* Label identifiers end with a colon */
 147 Label       [-a-zA-Z$._0-9]+:
 148 QuoteLabel \"[^\"]+\":
 149
 150 /* Quoted names can contain any character except " and \ */
 151 StringConstant \"[^\"]*\"
 152 AtStringConstant @\"[^\"]*\"
 153 PctStringConstant %\"[^\"]*\"
 154
 155 /* LocalVarID/GlobalVarID: match an unnamed local variable slot ID. */
 156 LocalVarID     %[0-9]+
 157 GlobalVarID    @[0-9]+
 158
 159 /* Integer types are specified with i and a bitwidth */
 160 IntegerType i[0-9]+
 161
 162 /* E[PN]Integer: match positive and negative literal integer values. */
 163 PInteger   [0-9]+
 164 NInteger  -[0-9]+
 165
 166 /* FPConstant - A Floating point constant.
 167  */
 168 FPConstant [-+]?[0-9]+[.][0-9]*([eE][-+]?[0-9]+)?
 169
 170 /* HexFPConstant - Floating point constant represented in IEEE format as a
 171  *  hexadecimal number for when exponential notation is not precise enough.
 172  */
 173 HexFPConstant 0x[0-9A-Fa-f]+
 174
 175 /* HexIntConstant - Hexadecimal constant generated by the CFE to avoid forcing
 176  * it to deal with 64 bit numbers.
 177  */
 178 HexIntConstant [us]0x[0-9A-Fa-f]+
 179
 180 %%
 181
 182 {Comment}       { /* Ignore comments for now */ }
 183
 184 begin           { return BEGINTOK; }
 185 end             { return ENDTOK; }
 186 true            { return TRUETOK;  }
 187 false           { return FALSETOK; }
 188 declare         { return DECLARE; }
 189 define          { return DEFINE; }
 190 global          { return GLOBAL; }
 191 constant        { return CONSTANT; }
 192 internal        { return INTERNAL; }
 193 linkonce        { return LINKONCE; }
 194 weak            { return WEAK; }
 195 appending       { return APPENDING; }
 196 dllimport       { return DLLIMPORT; }
 197 dllexport       { return DLLEXPORT; }
 198 hidden          { return HIDDEN; }
 199 protected       { return PROTECTED; }
 200 extern_weak     { return EXTERN_WEAK; }
 201 external        { return EXTERNAL; }
 202 thread_local    { return THREAD_LOCAL; }
 203 zeroinitializer { return ZEROINITIALIZER; }
 204 \.\.\.          { return DOTDOTDOT; }
 205 undef           { return UNDEF; }
 206 null            { return NULL_TOK; }
 207 to              { return TO; }
 208 tail            { return TAIL; }
 209 target          { return TARGET; }
 210 triple          { return TRIPLE; }
 211 deplibs         { return DEPLIBS; }
 212 datalayout      { return DATALAYOUT; }
 213 volatile        { return VOLATILE; }
 214 align           { return ALIGN;  }
 215 section         { return SECTION; }
 216 alias           { return ALIAS; }
 217 module          { return MODULE; }
 218 asm             { return ASM_TOK; }
 219 sideeffect      { return SIDEEFFECT; }
 220
 221 cc              { return CC_TOK; }
 222 ccc             { return CCC_TOK; }
 223 fastcc          { return FASTCC_TOK; }
 224 coldcc          { return COLDCC_TOK; }
 225 x86_stdcallcc   { return X86_STDCALLCC_TOK; }
 226 x86_fastcallcc  { return X86_FASTCALLCC_TOK; }
 227
 228 inreg           { return INREG; }
 229 sret            { return SRET;  }
 230 nounwind        { return NOUNWIND; }
 231 noreturn        { return NORETURN; }
 232
 233 void            { RET_TY(Type::VoidTy,  VOID);  }
 234 float           { RET_TY(Type::FloatTy, FLOAT); }
 235 double          { RET_TY(Type::DoubleTy,DOUBLE);}
 236 label           { RET_TY(Type::LabelTy, LABEL); }
 237 type            { return TYPE;   }
 238 opaque          { return OPAQUE; }
 239 {IntegerType}   { uint64_t NumBits = atoull(yytext+1);
 240                   if (NumBits < IntegerType::MIN_INT_BITS ||
 241                       NumBits > IntegerType::MAX_INT_BITS)
 242                     GenerateError("Bitwidth for integer type out of range!");
 243                   const Type* Ty = IntegerType::get(NumBits);
 244                   RET_TY(Ty, INTTYPE);
 245                 }
 246
 247 add             { RET_TOK(BinaryOpVal, Add, ADD); }
 248 sub             { RET_TOK(BinaryOpVal, Sub, SUB); }
 249 mul             { RET_TOK(BinaryOpVal, Mul, MUL); }
 250 udiv            { RET_TOK(BinaryOpVal, UDiv, UDIV); }
 251 sdiv            { RET_TOK(BinaryOpVal, SDiv, SDIV); }
 252 fdiv            { RET_TOK(BinaryOpVal, FDiv, FDIV); }
 253 urem            { RET_TOK(BinaryOpVal, URem, UREM); }
 254 srem            { RET_TOK(BinaryOpVal, SRem, SREM); }
 255 frem            { RET_TOK(BinaryOpVal, FRem, FREM); }
 256 shl             { RET_TOK(BinaryOpVal, Shl, SHL); }
 257 lshr            { RET_TOK(BinaryOpVal, LShr, LSHR); }
 258 ashr            { RET_TOK(BinaryOpVal, AShr, ASHR); }
 259 and             { RET_TOK(BinaryOpVal, And, AND); }
 260 or              { RET_TOK(BinaryOpVal, Or , OR ); }
 261 xor             { RET_TOK(BinaryOpVal, Xor, XOR); }
 262 icmp            { RET_TOK(OtherOpVal,  ICmp,  ICMP); }
 263 fcmp            { RET_TOK(OtherOpVal,  FCmp,  FCMP); }
 264
 265 eq              { return EQ;  }
 266 ne              { return NE;  }
 267 slt             { return SLT; }
 268 sgt             { return SGT; }
 269 sle             { return SLE; }
 270 sge             { return SGE; }
 271 ult             { return ULT; }
 272 ugt             { return UGT; }
 273 ule             { return ULE; }
 274 uge             { return UGE; }
 275 oeq             { return OEQ; }
 276 one             { return ONE; }
 277 olt             { return OLT; }
 278 ogt             { return OGT; }
 279 ole             { return OLE; }
 280 oge             { return OGE; }
 281 ord             { return ORD; }
 282 uno             { return UNO; }
 283 ueq             { return UEQ; }
 284 une             { return UNE; }
 285
 286 phi             { RET_TOK(OtherOpVal, PHI, PHI_TOK); }
 287 call            { RET_TOK(OtherOpVal, Call, CALL); }
 288 trunc           { RET_TOK(CastOpVal, Trunc, TRUNC); }
 289 zext            { RET_TOK(CastOpVal, ZExt, ZEXT); }
 290 sext            { RET_TOK(CastOpVal, SExt, SEXT); }
 291 fptrunc         { RET_TOK(CastOpVal, FPTrunc, FPTRUNC); }
 292 fpext           { RET_TOK(CastOpVal, FPExt, FPEXT); }
 293 uitofp          { RET_TOK(CastOpVal, UIToFP, UITOFP); }
 294 sitofp          { RET_TOK(CastOpVal, SIToFP, SITOFP); }
 295 fptoui          { RET_TOK(CastOpVal, FPToUI, FPTOUI); }
 296 fptosi          { RET_TOK(CastOpVal, FPToSI, FPTOSI); }
 297 inttoptr        { RET_TOK(CastOpVal, IntToPtr, INTTOPTR); }
 298 ptrtoint        { RET_TOK(CastOpVal, PtrToInt, PTRTOINT); }
 299 bitcast         { RET_TOK(CastOpVal, BitCast, BITCAST); }
 300 select          { RET_TOK(OtherOpVal, Select, SELECT); }
 301 va_arg          { RET_TOK(OtherOpVal, VAArg , VAARG); }
 302 ret             { RET_TOK(TermOpVal, Ret, RET); }
 303 br              { RET_TOK(TermOpVal, Br, BR); }
 304 switch          { RET_TOK(TermOpVal, Switch, SWITCH); }
 305 invoke          { RET_TOK(TermOpVal, Invoke, INVOKE); }
 306 unwind          { RET_TOK(TermOpVal, Unwind, UNWIND); }
 307 unreachable     { RET_TOK(TermOpVal, Unreachable, UNREACHABLE); }
 308
 309 malloc          { RET_TOK(MemOpVal, Malloc, MALLOC); }
 310 alloca          { RET_TOK(MemOpVal, Alloca, ALLOCA); }
 311 free            { RET_TOK(MemOpVal, Free, FREE); }
 312 load            { RET_TOK(MemOpVal, Load, LOAD); }
 313 store           { RET_TOK(MemOpVal, Store, STORE); }
 314 getelementptr   { RET_TOK(MemOpVal, GetElementPtr, GETELEMENTPTR); }
 315
 316 extractelement  { RET_TOK(OtherOpVal, ExtractElement, EXTRACTELEMENT); }
 317 insertelement   { RET_TOK(OtherOpVal, InsertElement, INSERTELEMENT); }
 318 shufflevector   { RET_TOK(OtherOpVal, ShuffleVector, SHUFFLEVECTOR); }
 319
 320
 321 {LocalVarName}  {
 322                   llvmAsmlval.StrVal = new std::string(yytext+1);   // Skip %
 323                   return LOCALVAR;
 324                 }
 325 {GlobalVarName} {
 326                   llvmAsmlval.StrVal = new std::string(yytext+1);   // Skip @
 327                   return GLOBALVAR;
 328                 }
 329 {Label}         {
 330                   yytext[yyleng-1] = 0;            // nuke colon
 331                   llvmAsmlval.StrVal = new std::string(yytext);
 332                   return LABELSTR;
 333                 }
 334 {QuoteLabel}    {
 335                   yytext[yyleng-2] = 0;  // nuke colon, end quote
 336                   const char* EndChar = UnEscapeLexed(yytext+1, yytext+yyleng);
 337                   llvmAsmlval.StrVal =
 338                     new std::string(yytext+1, EndChar - yytext - 1);
 339                   return LABELSTR;
 340                 }
 341
 342 {StringConstant} { yytext[yyleng-1] = 0;           // nuke end quote
 343                    const char* EndChar = UnEscapeLexed(yytext+1, yytext+yyleng);
 344                    llvmAsmlval.StrVal =
 345                      new std::string(yytext+1, EndChar - yytext - 1);
 346                    return STRINGCONSTANT;
 347                  }
 348 {AtStringConstant} {
 349                      yytext[yyleng-1] = 0;         // nuke end quote
 350                      const char* EndChar =
 351                        UnEscapeLexed(yytext+2, yytext+yyleng);
 352                      llvmAsmlval.StrVal =
 353                        new std::string(yytext+2, EndChar - yytext - 2);
 354                      return ATSTRINGCONSTANT;
 355                    }
 356 {PctStringConstant} {
 357                      yytext[yyleng-1] = 0;           // nuke end quote
 358                      const char* EndChar =
 359                        UnEscapeLexed(yytext+2, yytext+yyleng);
 360                      llvmAsmlval.StrVal =
 361                        new std::string(yytext+2, EndChar - yytext - 2);
 362                      return PCTSTRINGCONSTANT;
 363                    }
 364 {PInteger}      {
 365                   uint32_t numBits = ((yyleng * 64) / 19) + 1;
 366                   APInt Tmp(numBits, yytext, yyleng, 10);
 367                   uint32_t activeBits = Tmp.getActiveBits();
 368                   if (activeBits > 0 && activeBits < numBits)
 369                     Tmp.trunc(activeBits);
 370                   if (Tmp.getBitWidth() > 64) {
 371                     llvmAsmlval.APIntVal = new APInt(Tmp);
 372                     return EUAPINTVAL;
 373                   } else {
 374                     llvmAsmlval.UInt64Val = Tmp.getZExtValue();
 375                     return EUINT64VAL;
 376                   }
 377                 }
 378 {NInteger}      {
 379                   uint32_t numBits = (((yyleng-1) * 64) / 19) + 2;
 380                   APInt Tmp(numBits, yytext, yyleng, 10);
 381                   uint32_t minBits = Tmp.getMinSignedBits();
 382                   if (minBits > 0 && minBits < numBits)
 383                     Tmp.trunc(minBits);
 384                   if (Tmp.getBitWidth() > 64) {
 385                     llvmAsmlval.APIntVal = new APInt(Tmp);
 386                     return ESAPINTVAL;
 387                   } else {
 388                     llvmAsmlval.SInt64Val = Tmp.getSExtValue();
 389                     return ESINT64VAL;
 390                   }
 391                 }
 392
 393 {HexIntConstant} { int len = yyleng - 3;
 394                    uint32_t bits = len * 4;
 395                    APInt Tmp(bits, yytext+3, len, 16);
 396                    uint32_t activeBits = Tmp.getActiveBits();
 397                    if (activeBits > 0 && activeBits < bits)
 398                      Tmp.trunc(activeBits);
 399                    if (Tmp.getBitWidth() > 64) {
 400                      llvmAsmlval.APIntVal = new APInt(Tmp);
 401                      return yytext[0] == 's' ? ESAPINTVAL : EUAPINTVAL;
 402                    } else if (yytext[0] == 's') {
 403                      llvmAsmlval.SInt64Val = Tmp.getSExtValue();
 404                      return ESINT64VAL;
 405                    } else {
 406                      llvmAsmlval.UInt64Val = Tmp.getZExtValue();
 407                      return EUINT64VAL;
 408                    }
 409                  }
 410
 411 {LocalVarID}     {
 412                   uint64_t Val = atoull(yytext+1);
 413                   if ((unsigned)Val != Val)
 414                     GenerateError("Invalid value number (too large)!");
 415                   llvmAsmlval.UIntVal = unsigned(Val);
 416                   return LOCALVAL_ID;
 417                 }
 418 {GlobalVarID}   {
 419                   uint64_t Val = atoull(yytext+1);
 420                   if ((unsigned)Val != Val)
 421                     GenerateError("Invalid value number (too large)!");
 422                   llvmAsmlval.UIntVal = unsigned(Val);
 423                   return GLOBALVAL_ID;
 424                 }
 425
 426 {FPConstant}    { llvmAsmlval.FPVal = atof(yytext); return FPVAL; }
 427 {HexFPConstant} { llvmAsmlval.FPVal = HexToFP(yytext); return FPVAL; }
 428
 429 <<EOF>>         {
 430                   /* Make sure to free the internal buffers for flex when we are
 431                    * done reading our input!
 432                    */
 433                   yy_delete_buffer(YY_CURRENT_BUFFER);
 434                   return EOF;
 435                 }
 436
 437 [ \r\t\n]       { /* Ignore whitespace */ }
 438 .               { return yytext[0]; }
 439
 440 %%