lib/Target/ARM/ARMInstrFormats.td

   1 //===- ARMInstrFormats.td - ARM Instruction Formats --*- tablegen -*---------=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //
  12 // ARM Instruction Format Definitions.
  13 //
  14
  15 // Format specifies the encoding used by the instruction.  This is part of the
  16 // ad-hoc solution used to emit machine instruction encodings by our machine
  17 // code emitter.
  18 class Format<bits<5> val> {
  19   bits<5> Value = val;
  20 }
  21
  22 def Pseudo        : Format<0>;
  23 def MulFrm        : Format<1>;
  24 def BrFrm         : Format<2>;
  25 def BrMiscFrm     : Format<3>;
  26
  27 def DPFrm         : Format<4>;
  28 def DPSoRegFrm    : Format<5>;
  29
  30 def LdFrm         : Format<6>;
  31 def StFrm         : Format<7>;
  32 def LdMiscFrm     : Format<8>;
  33 def StMiscFrm     : Format<9>;
  34 def LdStMulFrm    : Format<10>;
  35
  36 def LdStExFrm     : Format<28>;
  37
  38 def ArithMiscFrm  : Format<11>;
  39 def ExtFrm        : Format<12>;
  40
  41 def VFPUnaryFrm   : Format<13>;
  42 def VFPBinaryFrm  : Format<14>;
  43 def VFPConv1Frm   : Format<15>;
  44 def VFPConv2Frm   : Format<16>;
  45 def VFPConv3Frm   : Format<17>;
  46 def VFPConv4Frm   : Format<18>;
  47 def VFPConv5Frm   : Format<19>;
  48 def VFPLdStFrm    : Format<20>;
  49 def VFPLdStMulFrm : Format<21>;
  50 def VFPMiscFrm    : Format<22>;
  51
  52 def ThumbFrm      : Format<23>;
  53
  54 def NEONFrm       : Format<24>;
  55 def NEONGetLnFrm  : Format<25>;
  56 def NEONSetLnFrm  : Format<26>;
  57 def NEONDupFrm    : Format<27>;
  58
  59 // Misc flags.
  60
  61 // the instruction has a Rn register operand.
  62 // UnaryDP - Indicates this is a unary data processing instruction, i.e.
  63 // it doesn't have a Rn operand.
  64 class UnaryDP    { bit isUnaryDataProc = 1; }
  65
  66 // Xform16Bit - Indicates this Thumb2 instruction may be transformed into
  67 // a 16-bit Thumb instruction if certain conditions are met.
  68 class Xform16Bit { bit canXformTo16Bit = 1; }
  69
  70 //===----------------------------------------------------------------------===//
  71 // ARM Instruction flags.  These need to match ARMInstrInfo.h.
  72 //
  73
  74 // Addressing mode.
  75 class AddrMode<bits<4> val> {
  76   bits<4> Value = val;
  77 }
  78 def AddrModeNone  : AddrMode<0>;
  79 def AddrMode1     : AddrMode<1>;
  80 def AddrMode2     : AddrMode<2>;
  81 def AddrMode3     : AddrMode<3>;
  82 def AddrMode4     : AddrMode<4>;
  83 def AddrMode5     : AddrMode<5>;
  84 def AddrMode6     : AddrMode<6>;
  85 def AddrModeT1_1  : AddrMode<7>;
  86 def AddrModeT1_2  : AddrMode<8>;
  87 def AddrModeT1_4  : AddrMode<9>;
  88 def AddrModeT1_s  : AddrMode<10>;
  89 def AddrModeT2_i12: AddrMode<11>;
  90 def AddrModeT2_i8 : AddrMode<12>;
  91 def AddrModeT2_so : AddrMode<13>;
  92 def AddrModeT2_pc : AddrMode<14>;
  93 def AddrModeT2_i8s4 : AddrMode<15>;
  94
  95 // Instruction size.
  96 class SizeFlagVal<bits<3> val> {
  97   bits<3> Value = val;
  98 }
  99 def SizeInvalid  : SizeFlagVal<0>;  // Unset.
 100 def SizeSpecial  : SizeFlagVal<1>;  // Pseudo or special.
 101 def Size8Bytes   : SizeFlagVal<2>;
 102 def Size4Bytes   : SizeFlagVal<3>;
 103 def Size2Bytes   : SizeFlagVal<4>;
 104
 105 // Load / store index mode.
 106 class IndexMode<bits<2> val> {
 107   bits<2> Value = val;
 108 }
 109 def IndexModeNone : IndexMode<0>;
 110 def IndexModePre  : IndexMode<1>;
 111 def IndexModePost : IndexMode<2>;
 112
 113 // Instruction execution domain.
 114 class Domain<bits<2> val> {
 115   bits<2> Value = val;
 116 }
 117 def GenericDomain : Domain<0>;
 118 def VFPDomain     : Domain<1>; // Instructions in VFP domain only
 119 def NeonDomain    : Domain<2>; // Instructions in Neon domain only
 120 def VFPNeonDomain : Domain<3>; // Instructions in both VFP & Neon domains
 121
 122 //===----------------------------------------------------------------------===//
 123
 124 // ARM special operands.
 125 //
 126
 127 // ARM Predicate operand. Default to 14 = always (AL). Second part is CC
 128 // register whose default is 0 (no register).
 129 def pred : PredicateOperand<OtherVT, (ops i32imm, CCR),
 130                                      (ops (i32 14), (i32 zero_reg))> {
 131   let PrintMethod = "printPredicateOperand";
 132 }
 133
 134 // Conditional code result for instructions whose 's' bit is set, e.g. subs.
 135 def cc_out : OptionalDefOperand<OtherVT, (ops CCR), (ops (i32 zero_reg))> {
 136   let PrintMethod = "printSBitModifierOperand";
 137 }
 138
 139 // Same as cc_out except it defaults to setting CPSR.
 140 def s_cc_out : OptionalDefOperand<OtherVT, (ops CCR), (ops (i32 CPSR))> {
 141   let PrintMethod = "printSBitModifierOperand";
 142 }
 143
 144 //===----------------------------------------------------------------------===//
 145
 146 // ARM Instruction templates.
 147 //
 148
 149 class InstTemplate<AddrMode am, SizeFlagVal sz, IndexMode im,
 150                    Format f, Domain d, string cstr, InstrItinClass itin>
 151   : Instruction {
 152   let Namespace = "ARM";
 153
 154   // TSFlagsFields
 155   AddrMode AM = am;
 156   bits<4> AddrModeBits = AM.Value;
 157
 158   SizeFlagVal SZ = sz;
 159   bits<3> SizeFlag = SZ.Value;
 160
 161   IndexMode IM = im;
 162   bits<2> IndexModeBits = IM.Value;
 163
 164   Format F = f;
 165   bits<5> Form = F.Value;
 166
 167   Domain D = d;
 168   bits<2> Dom = D.Value;
 169
 170   //
 171   // Attributes specific to ARM instructions...
 172   //
 173   bit isUnaryDataProc = 0;
 174   bit canXformTo16Bit = 0;
 175
 176   let Constraints = cstr;
 177   let Itinerary = itin;
 178 }
 179
 180 class Encoding {
 181   field bits<32> Inst;
 182 }
 183
 184 class InstARM<AddrMode am, SizeFlagVal sz, IndexMode im,
 185               Format f, Domain d, string cstr, InstrItinClass itin>
 186   : InstTemplate<am, sz, im, f, d, cstr, itin>, Encoding;
 187
 188 // This Encoding-less class is used by Thumb1 to specify the encoding bits later
 189 // on by adding flavors to specific instructions.
 190 class InstThumb<AddrMode am, SizeFlagVal sz, IndexMode im,
 191                 Format f, Domain d, string cstr, InstrItinClass itin>
 192   : InstTemplate<am, sz, im, f, d, cstr, itin>;
 193
 194 class PseudoInst<dag oops, dag iops, InstrItinClass itin,
 195                  string asm, list<dag> pattern>
 196   : InstARM<AddrModeNone, SizeSpecial, IndexModeNone, Pseudo, GenericDomain,
 197             "", itin> {
 198   let OutOperandList = oops;
 199   let InOperandList = iops;
 200   let AsmString   = asm;
 201   let Pattern = pattern;
 202 }
 203
 204 // Almost all ARM instructions are predicable.
 205 class I<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 206         IndexMode im, Format f, InstrItinClass itin,
 207         string opc, string asm, string cstr,
 208         list<dag> pattern>
 209   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 210   let OutOperandList = oops;
 211   let InOperandList = !con(iops, (ops pred:$p));
 212   let AsmString   = !strconcat(opc, !strconcat("${p}", asm));
 213   let Pattern = pattern;
 214   list<Predicate> Predicates = [IsARM];
 215 }
 216 // A few are not predicable
 217 class InoP<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 218         IndexMode im, Format f, InstrItinClass itin,
 219         string opc, string asm, string cstr,
 220         list<dag> pattern>
 221   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 222   let OutOperandList = oops;
 223   let InOperandList = iops;
 224   let AsmString   = !strconcat(opc, asm);
 225   let Pattern = pattern;
 226   let isPredicable = 0;
 227   list<Predicate> Predicates = [IsARM];
 228 }
 229
 230 // Same as I except it can optionally modify CPSR. Note it's modeled as
 231 // an input operand since by default it's a zero register. It will
 232 // become an implicit def once it's "flipped".
 233 class sI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 234          IndexMode im, Format f, InstrItinClass itin,
 235          string opc, string asm, string cstr,
 236          list<dag> pattern>
 237   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 238   let OutOperandList = oops;
 239   let InOperandList = !con(iops, (ops pred:$p, cc_out:$s));
 240   let AsmString   = !strconcat(opc, !strconcat("${p}${s}", asm));
 241   let Pattern = pattern;
 242   list<Predicate> Predicates = [IsARM];
 243 }
 244
 245 // Special cases
 246 class XI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 247          IndexMode im, Format f, InstrItinClass itin,
 248          string asm, string cstr, list<dag> pattern>
 249   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 250   let OutOperandList = oops;
 251   let InOperandList = iops;
 252   let AsmString   = asm;
 253   let Pattern = pattern;
 254   list<Predicate> Predicates = [IsARM];
 255 }
 256
 257 class AI<dag oops, dag iops, Format f, InstrItinClass itin,
 258          string opc, string asm, list<dag> pattern>
 259   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 260       opc, asm, "", pattern>;
 261 class AsI<dag oops, dag iops, Format f, InstrItinClass itin,
 262           string opc, string asm, list<dag> pattern>
 263   : sI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 264        opc, asm, "", pattern>;
 265 class AXI<dag oops, dag iops, Format f, InstrItinClass itin,
 266           string asm, list<dag> pattern>
 267   : XI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 268        asm, "", pattern>;
 269 class AInoP<dag oops, dag iops, Format f, InstrItinClass itin,
 270          string opc, string asm, list<dag> pattern>
 271   : InoP<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 272       opc, asm, "", pattern>;
 273
 274 // Ctrl flow instructions
 275 class ABI<bits<4> opcod, dag oops, dag iops, InstrItinClass itin,
 276           string opc, string asm, list<dag> pattern>
 277   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, BrFrm, itin,
 278       opc, asm, "", pattern> {
 279   let Inst{27-24} = opcod;
 280 }
 281 class ABXI<bits<4> opcod, dag oops, dag iops, InstrItinClass itin,
 282            string asm, list<dag> pattern>
 283   : XI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, BrFrm, itin,
 284        asm, "", pattern> {
 285   let Inst{27-24} = opcod;
 286 }
 287 class ABXIx2<dag oops, dag iops, InstrItinClass itin,
 288              string asm, list<dag> pattern>
 289   : XI<oops, iops, AddrModeNone, Size8Bytes, IndexModeNone, BrMiscFrm, itin,
 290        asm, "", pattern>;
 291
 292 // BR_JT instructions
 293 class JTI<dag oops, dag iops, InstrItinClass itin,
 294           string asm, list<dag> pattern>
 295   : XI<oops, iops, AddrModeNone, SizeSpecial, IndexModeNone, BrMiscFrm, itin,
 296        asm, "", pattern>;
 297
 298
 299 // Atomic load/store instructions
 300
 301 class AIldrex<bits<2> opcod, dag oops, dag iops, InstrItinClass itin,
 302               string opc, string asm, list<dag> pattern>
 303   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, LdStExFrm, itin,
 304       opc, asm, "", pattern> {
 305   let Inst{27-23} = 0b00011;
 306   let Inst{22-21} = opcod;
 307   let Inst{20} = 1;
 308   let Inst{11-0}  = 0b111110011111;
 309 }
 310 class AIstrex<bits<2> opcod, dag oops, dag iops, InstrItinClass itin,
 311               string opc, string asm, list<dag> pattern>
 312   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, LdStExFrm, itin,
 313       opc, asm, "", pattern> {
 314   let Inst{27-23} = 0b00011;
 315   let Inst{22-21} = opcod;
 316   let Inst{20} = 0;
 317   let Inst{11-4}  = 0b11111001;
 318 }
 319
 320 // addrmode1 instructions
 321 class AI1<bits<4> opcod, dag oops, dag iops, Format f, InstrItinClass itin,
 322           string opc, string asm, list<dag> pattern>
 323   : I<oops, iops, AddrMode1, Size4Bytes, IndexModeNone, f, itin,
 324       opc, asm, "", pattern> {
 325   let Inst{24-21} = opcod;
 326   let Inst{27-26} = {0,0};
 327 }
 328 class AsI1<bits<4> opcod, dag oops, dag iops, Format f, InstrItinClass itin,
 329            string opc, string asm, list<dag> pattern>
 330   : sI<oops, iops, AddrMode1, Size4Bytes, IndexModeNone, f, itin,
 331        opc, asm, "", pattern> {
 332   let Inst{24-21} = opcod;
 333   let Inst{27-26} = {0,0};
 334 }
 335 class AXI1<bits<4> opcod, dag oops, dag iops, Format f, InstrItinClass itin,
 336            string asm, list<dag> pattern>
 337   : XI<oops, iops, AddrMode1, Size4Bytes, IndexModeNone, f, itin,
 338        asm, "", pattern> {
 339   let Inst{24-21} = opcod;
 340   let Inst{27-26} = {0,0};
 341 }
 342 class AI1x2<dag oops, dag iops, Format f, InstrItinClass itin,
 343             string opc, string asm, list<dag> pattern>
 344   : I<oops, iops, AddrMode1, Size8Bytes, IndexModeNone, f, itin,
 345       opc, asm, "", pattern>;
 346
 347
 348 // addrmode2 loads and stores
 349 class AI2<dag oops, dag iops, Format f, InstrItinClass itin,
 350           string opc, string asm, list<dag> pattern>
 351   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 352       opc, asm, "", pattern> {
 353   let Inst{27-26} = {0,1};
 354 }
 355
 356 // loads
 357 class AI2ldw<dag oops, dag iops, Format f, InstrItinClass itin,
 358              string opc, string asm, list<dag> pattern>
 359   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 360       opc, asm, "", pattern> {
 361   let Inst{20}    = 1; // L bit
 362   let Inst{21}    = 0; // W bit
 363   let Inst{22}    = 0; // B bit
 364   let Inst{24}    = 1; // P bit
 365   let Inst{27-26} = {0,1};
 366 }
 367 class AXI2ldw<dag oops, dag iops, Format f, InstrItinClass itin,
 368               string asm, list<dag> pattern>
 369   : XI<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 370        asm, "", pattern> {
 371   let Inst{20}    = 1; // L bit
 372   let Inst{21}    = 0; // W bit
 373   let Inst{22}    = 0; // B bit
 374   let Inst{24}    = 1; // P bit
 375   let Inst{27-26} = {0,1};
 376 }
 377 class AI2ldb<dag oops, dag iops, Format f, InstrItinClass itin,
 378              string opc, string asm, list<dag> pattern>
 379   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 380       opc, asm, "", pattern> {
 381   let Inst{20}    = 1; // L bit
 382   let Inst{21}    = 0; // W bit
 383   let Inst{22}    = 1; // B bit
 384   let Inst{24}    = 1; // P bit
 385   let Inst{27-26} = {0,1};
 386 }
 387 class AXI2ldb<dag oops, dag iops, Format f, InstrItinClass itin,
 388               string asm, list<dag> pattern>
 389   : XI<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 390        asm, "", pattern> {
 391   let Inst{20}    = 1; // L bit
 392   let Inst{21}    = 0; // W bit
 393   let Inst{22}    = 1; // B bit
 394   let Inst{24}    = 1; // P bit
 395   let Inst{27-26} = {0,1};
 396 }
 397
 398 // stores
 399 class AI2stw<dag oops, dag iops, Format f, InstrItinClass itin,
 400              string opc, string asm, list<dag> pattern>
 401   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 402       opc, asm, "", pattern> {
 403   let Inst{20}    = 0; // L bit
 404   let Inst{21}    = 0; // W bit
 405   let Inst{22}    = 0; // B bit
 406   let Inst{24}    = 1; // P bit
 407   let Inst{27-26} = {0,1};
 408 }
 409 class AXI2stw<dag oops, dag iops, Format f, InstrItinClass itin,
 410               string asm, list<dag> pattern>
 411   : XI<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 412        asm, "", pattern> {
 413   let Inst{20}    = 0; // L bit
 414   let Inst{21}    = 0; // W bit
 415   let Inst{22}    = 0; // B bit
 416   let Inst{24}    = 1; // P bit
 417   let Inst{27-26} = {0,1};
 418 }
 419 class AI2stb<dag oops, dag iops, Format f, InstrItinClass itin,
 420              string opc, string asm, list<dag> pattern>
 421   : I<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 422       opc, asm, "", pattern> {
 423   let Inst{20}    = 0; // L bit
 424   let Inst{21}    = 0; // W bit
 425   let Inst{22}    = 1; // B bit
 426   let Inst{24}    = 1; // P bit
 427   let Inst{27-26} = {0,1};
 428 }
 429 class AXI2stb<dag oops, dag iops, Format f, InstrItinClass itin,
 430               string asm, list<dag> pattern>
 431   : XI<oops, iops, AddrMode2, Size4Bytes, IndexModeNone, f, itin,
 432        asm, "", pattern> {
 433   let Inst{20}    = 0; // L bit
 434   let Inst{21}    = 0; // W bit
 435   let Inst{22}    = 1; // B bit
 436   let Inst{24}    = 1; // P bit
 437   let Inst{27-26} = {0,1};
 438 }
 439
 440 // Pre-indexed loads
 441 class AI2ldwpr<dag oops, dag iops, Format f, InstrItinClass itin,
 442                string opc, string asm, string cstr, list<dag> pattern>
 443   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePre, f, itin,
 444       opc, asm, cstr, pattern> {
 445   let Inst{20}    = 1; // L bit
 446   let Inst{21}    = 1; // W bit
 447   let Inst{22}    = 0; // B bit
 448   let Inst{24}    = 1; // P bit
 449   let Inst{27-26} = {0,1};
 450 }
 451 class AI2ldbpr<dag oops, dag iops, Format f, InstrItinClass itin,
 452                string opc, string asm, string cstr, list<dag> pattern>
 453   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePre, f, itin,
 454       opc, asm, cstr, pattern> {
 455   let Inst{20}    = 1; // L bit
 456   let Inst{21}    = 1; // W bit
 457   let Inst{22}    = 1; // B bit
 458   let Inst{24}    = 1; // P bit
 459   let Inst{27-26} = {0,1};
 460 }
 461
 462 // Pre-indexed stores
 463 class AI2stwpr<dag oops, dag iops, Format f, InstrItinClass itin,
 464                string opc, string asm, string cstr, list<dag> pattern>
 465   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePre, f, itin,
 466       opc, asm, cstr, pattern> {
 467   let Inst{20}    = 0; // L bit
 468   let Inst{21}    = 1; // W bit
 469   let Inst{22}    = 0; // B bit
 470   let Inst{24}    = 1; // P bit
 471   let Inst{27-26} = {0,1};
 472 }
 473 class AI2stbpr<dag oops, dag iops, Format f, InstrItinClass itin,
 474                string opc, string asm, string cstr, list<dag> pattern>
 475   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePre, f, itin,
 476       opc, asm, cstr, pattern> {
 477   let Inst{20}    = 0; // L bit
 478   let Inst{21}    = 1; // W bit
 479   let Inst{22}    = 1; // B bit
 480   let Inst{24}    = 1; // P bit
 481   let Inst{27-26} = {0,1};
 482 }
 483
 484 // Post-indexed loads
 485 class AI2ldwpo<dag oops, dag iops, Format f, InstrItinClass itin,
 486                string opc, string asm, string cstr, list<dag> pattern>
 487   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePost, f, itin,
 488       opc, asm, cstr,pattern> {
 489   let Inst{20}    = 1; // L bit
 490   let Inst{21}    = 0; // W bit
 491   let Inst{22}    = 0; // B bit
 492   let Inst{24}    = 0; // P bit
 493   let Inst{27-26} = {0,1};
 494 }
 495 class AI2ldbpo<dag oops, dag iops, Format f, InstrItinClass itin,
 496                string opc, string asm, string cstr, list<dag> pattern>
 497   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePost, f, itin,
 498       opc, asm, cstr,pattern> {
 499   let Inst{20}    = 1; // L bit
 500   let Inst{21}    = 0; // W bit
 501   let Inst{22}    = 1; // B bit
 502   let Inst{24}    = 0; // P bit
 503   let Inst{27-26} = {0,1};
 504 }
 505
 506 // Post-indexed stores
 507 class AI2stwpo<dag oops, dag iops, Format f, InstrItinClass itin,
 508                string opc, string asm, string cstr, list<dag> pattern>
 509   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePost, f, itin,
 510       opc, asm, cstr,pattern> {
 511   let Inst{20}    = 0; // L bit
 512   let Inst{21}    = 0; // W bit
 513   let Inst{22}    = 0; // B bit
 514   let Inst{24}    = 0; // P bit
 515   let Inst{27-26} = {0,1};
 516 }
 517 class AI2stbpo<dag oops, dag iops, Format f, InstrItinClass itin,
 518                string opc, string asm, string cstr, list<dag> pattern>
 519   : I<oops, iops, AddrMode2, Size4Bytes, IndexModePost, f, itin,
 520       opc, asm, cstr,pattern> {
 521   let Inst{20}    = 0; // L bit
 522   let Inst{21}    = 0; // W bit
 523   let Inst{22}    = 1; // B bit
 524   let Inst{24}    = 0; // P bit
 525   let Inst{27-26} = {0,1};
 526 }
 527
 528 // addrmode3 instructions
 529 class AI3<dag oops, dag iops, Format f, InstrItinClass itin,
 530           string opc, string asm, list<dag> pattern>
 531   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 532       opc, asm, "", pattern>;
 533 class AXI3<dag oops, dag iops, Format f, InstrItinClass itin,
 534            string asm, list<dag> pattern>
 535   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 536        asm, "", pattern>;
 537
 538 // loads
 539 class AI3ldh<dag oops, dag iops, Format f, InstrItinClass itin,
 540              string opc, string asm, list<dag> pattern>
 541   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 542       opc, asm, "", pattern> {
 543   let Inst{4}     = 1;
 544   let Inst{5}     = 1; // H bit
 545   let Inst{6}     = 0; // S bit
 546   let Inst{7}     = 1;
 547   let Inst{20}    = 1; // L bit
 548   let Inst{21}    = 0; // W bit
 549   let Inst{24}    = 1; // P bit
 550   let Inst{27-25} = 0b000;
 551 }
 552 class AXI3ldh<dag oops, dag iops, Format f, InstrItinClass itin,
 553               string asm, list<dag> pattern>
 554   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 555        asm, "", pattern> {
 556   let Inst{4}     = 1;
 557   let Inst{5}     = 1; // H bit
 558   let Inst{6}     = 0; // S bit
 559   let Inst{7}     = 1;
 560   let Inst{20}    = 1; // L bit
 561   let Inst{21}    = 0; // W bit
 562   let Inst{24}    = 1; // P bit
 563 }
 564 class AI3ldsh<dag oops, dag iops, Format f, InstrItinClass itin,
 565               string opc, string asm, list<dag> pattern>
 566   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 567       opc, asm, "", pattern> {
 568   let Inst{4}     = 1;
 569   let Inst{5}     = 1; // H bit
 570   let Inst{6}     = 1; // S bit
 571   let Inst{7}     = 1;
 572   let Inst{20}    = 1; // L bit
 573   let Inst{21}    = 0; // W bit
 574   let Inst{24}    = 1; // P bit
 575   let Inst{27-25} = 0b000;
 576 }
 577 class AXI3ldsh<dag oops, dag iops, Format f, InstrItinClass itin,
 578                string asm, list<dag> pattern>
 579   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 580        asm, "", pattern> {
 581   let Inst{4}     = 1;
 582   let Inst{5}     = 1; // H bit
 583   let Inst{6}     = 1; // S bit
 584   let Inst{7}     = 1;
 585   let Inst{20}    = 1; // L bit
 586   let Inst{21}    = 0; // W bit
 587   let Inst{24}    = 1; // P bit
 588 }
 589 class AI3ldsb<dag oops, dag iops, Format f, InstrItinClass itin,
 590               string opc, string asm, list<dag> pattern>
 591   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 592       opc, asm, "", pattern> {
 593   let Inst{4}     = 1;
 594   let Inst{5}     = 0; // H bit
 595   let Inst{6}     = 1; // S bit
 596   let Inst{7}     = 1;
 597   let Inst{20}    = 1; // L bit
 598   let Inst{21}    = 0; // W bit
 599   let Inst{24}    = 1; // P bit
 600   let Inst{27-25} = 0b000;
 601 }
 602 class AXI3ldsb<dag oops, dag iops, Format f, InstrItinClass itin,
 603                string asm, list<dag> pattern>
 604   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 605        asm, "", pattern> {
 606   let Inst{4}     = 1;
 607   let Inst{5}     = 0; // H bit
 608   let Inst{6}     = 1; // S bit
 609   let Inst{7}     = 1;
 610   let Inst{20}    = 1; // L bit
 611   let Inst{21}    = 0; // W bit
 612   let Inst{24}    = 1; // P bit
 613 }
 614 class AI3ldd<dag oops, dag iops, Format f, InstrItinClass itin,
 615              string opc, string asm, list<dag> pattern>
 616   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 617       opc, asm, "", pattern> {
 618   let Inst{4}     = 1;
 619   let Inst{5}     = 0; // H bit
 620   let Inst{6}     = 1; // S bit
 621   let Inst{7}     = 1;
 622   let Inst{20}    = 0; // L bit
 623   let Inst{21}    = 0; // W bit
 624   let Inst{24}    = 1; // P bit
 625   let Inst{27-25} = 0b000;
 626 }
 627
 628 // stores
 629 class AI3sth<dag oops, dag iops, Format f, InstrItinClass itin,
 630              string opc, string asm, list<dag> pattern>
 631   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 632       opc, asm, "", pattern> {
 633   let Inst{4}     = 1;
 634   let Inst{5}     = 1; // H bit
 635   let Inst{6}     = 0; // S bit
 636   let Inst{7}     = 1;
 637   let Inst{20}    = 0; // L bit
 638   let Inst{21}    = 0; // W bit
 639   let Inst{24}    = 1; // P bit
 640   let Inst{27-25} = 0b000;
 641 }
 642 class AXI3sth<dag oops, dag iops, Format f, InstrItinClass itin,
 643               string asm, list<dag> pattern>
 644   : XI<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 645        asm, "", pattern> {
 646   let Inst{4}     = 1;
 647   let Inst{5}     = 1; // H bit
 648   let Inst{6}     = 0; // S bit
 649   let Inst{7}     = 1;
 650   let Inst{20}    = 0; // L bit
 651   let Inst{21}    = 0; // W bit
 652   let Inst{24}    = 1; // P bit
 653 }
 654 class AI3std<dag oops, dag iops, Format f, InstrItinClass itin,
 655              string opc, string asm, list<dag> pattern>
 656   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 657       opc, asm, "", pattern> {
 658   let Inst{4}     = 1;
 659   let Inst{5}     = 1; // H bit
 660   let Inst{6}     = 1; // S bit
 661   let Inst{7}     = 1;
 662   let Inst{20}    = 0; // L bit
 663   let Inst{21}    = 0; // W bit
 664   let Inst{24}    = 1; // P bit
 665   let Inst{27-25} = 0b000;
 666 }
 667
 668 // Pre-indexed loads
 669 class AI3ldhpr<dag oops, dag iops, Format f, InstrItinClass itin,
 670                string opc, string asm, string cstr, list<dag> pattern>
 671   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 672       opc, asm, cstr, pattern> {
 673   let Inst{4}     = 1;
 674   let Inst{5}     = 1; // H bit
 675   let Inst{6}     = 0; // S bit
 676   let Inst{7}     = 1;
 677   let Inst{20}    = 1; // L bit
 678   let Inst{21}    = 1; // W bit
 679   let Inst{24}    = 1; // P bit
 680   let Inst{27-25} = 0b000;
 681 }
 682 class AI3ldshpr<dag oops, dag iops, Format f, InstrItinClass itin,
 683                 string opc, string asm, string cstr, list<dag> pattern>
 684   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 685       opc, asm, cstr, pattern> {
 686   let Inst{4}     = 1;
 687   let Inst{5}     = 1; // H bit
 688   let Inst{6}     = 1; // S bit
 689   let Inst{7}     = 1;
 690   let Inst{20}    = 1; // L bit
 691   let Inst{21}    = 1; // W bit
 692   let Inst{24}    = 1; // P bit
 693   let Inst{27-25} = 0b000;
 694 }
 695 class AI3ldsbpr<dag oops, dag iops, Format f, InstrItinClass itin,
 696                 string opc, string asm, string cstr, list<dag> pattern>
 697   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 698       opc, asm, cstr, pattern> {
 699   let Inst{4}     = 1;
 700   let Inst{5}     = 0; // H bit
 701   let Inst{6}     = 1; // S bit
 702   let Inst{7}     = 1;
 703   let Inst{20}    = 1; // L bit
 704   let Inst{21}    = 1; // W bit
 705   let Inst{24}    = 1; // P bit
 706   let Inst{27-25} = 0b000;
 707 }
 708
 709 // Pre-indexed stores
 710 class AI3sthpr<dag oops, dag iops, Format f, InstrItinClass itin,
 711                string opc, string asm, string cstr, list<dag> pattern>
 712   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 713       opc, asm, cstr, pattern> {
 714   let Inst{4}     = 1;
 715   let Inst{5}     = 1; // H bit
 716   let Inst{6}     = 0; // S bit
 717   let Inst{7}     = 1;
 718   let Inst{20}    = 0; // L bit
 719   let Inst{21}    = 1; // W bit
 720   let Inst{24}    = 1; // P bit
 721   let Inst{27-25} = 0b000;
 722 }
 723
 724 // Post-indexed loads
 725 class AI3ldhpo<dag oops, dag iops, Format f, InstrItinClass itin,
 726                string opc, string asm, string cstr, list<dag> pattern>
 727   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 728       opc, asm, cstr,pattern> {
 729   let Inst{4}     = 1;
 730   let Inst{5}     = 1; // H bit
 731   let Inst{6}     = 0; // S bit
 732   let Inst{7}     = 1;
 733   let Inst{20}    = 1; // L bit
 734   let Inst{21}    = 1; // W bit
 735   let Inst{24}    = 0; // P bit
 736   let Inst{27-25} = 0b000;
 737 }
 738 class AI3ldshpo<dag oops, dag iops, Format f, InstrItinClass itin,
 739                 string opc, string asm, string cstr, list<dag> pattern>
 740   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 741       opc, asm, cstr,pattern> {
 742   let Inst{4}     = 1;
 743   let Inst{5}     = 1; // H bit
 744   let Inst{6}     = 1; // S bit
 745   let Inst{7}     = 1;
 746   let Inst{20}    = 1; // L bit
 747   let Inst{21}    = 1; // W bit
 748   let Inst{24}    = 0; // P bit
 749   let Inst{27-25} = 0b000;
 750 }
 751 class AI3ldsbpo<dag oops, dag iops, Format f, InstrItinClass itin,
 752                 string opc, string asm, string cstr, list<dag> pattern>
 753   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 754       opc, asm, cstr,pattern> {
 755   let Inst{4}     = 1;
 756   let Inst{5}     = 0; // H bit
 757   let Inst{6}     = 1; // S bit
 758   let Inst{7}     = 1;
 759   let Inst{20}    = 1; // L bit
 760   let Inst{21}    = 1; // W bit
 761   let Inst{24}    = 0; // P bit
 762   let Inst{27-25} = 0b000;
 763 }
 764
 765 // Post-indexed stores
 766 class AI3sthpo<dag oops, dag iops, Format f, InstrItinClass itin,
 767                string opc, string asm, string cstr, list<dag> pattern>
 768   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 769       opc, asm, cstr,pattern> {
 770   let Inst{4}     = 1;
 771   let Inst{5}     = 1; // H bit
 772   let Inst{6}     = 0; // S bit
 773   let Inst{7}     = 1;
 774   let Inst{20}    = 0; // L bit
 775   let Inst{21}    = 1; // W bit
 776   let Inst{24}    = 0; // P bit
 777   let Inst{27-25} = 0b000;
 778 }
 779
 780
 781 // addrmode4 instructions
 782 class AXI4ld<dag oops, dag iops, Format f, InstrItinClass itin,
 783              string asm, list<dag> pattern>
 784   : XI<oops, iops, AddrMode4, Size4Bytes, IndexModeNone, f, itin,
 785        asm, "", pattern> {
 786   let Inst{20}    = 1; // L bit
 787   let Inst{22}    = 0; // S bit
 788   let Inst{27-25} = 0b100;
 789 }
 790 class AXI4st<dag oops, dag iops, Format f, InstrItinClass itin,
 791              string asm, list<dag> pattern>
 792   : XI<oops, iops, AddrMode4, Size4Bytes, IndexModeNone, f, itin,
 793        asm, "", pattern> {
 794   let Inst{20}    = 0; // L bit
 795   let Inst{22}    = 0; // S bit
 796   let Inst{27-25} = 0b100;
 797 }
 798
 799 // Unsigned multiply, multiply-accumulate instructions.
 800 class AMul1I<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 801              string opc, string asm, list<dag> pattern>
 802   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 803       opc, asm, "", pattern> {
 804   let Inst{7-4}   = 0b1001;
 805   let Inst{20}    = 0; // S bit
 806   let Inst{27-21} = opcod;
 807 }
 808 class AsMul1I<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 809               string opc, string asm, list<dag> pattern>
 810   : sI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 811        opc, asm, "", pattern> {
 812   let Inst{7-4}   = 0b1001;
 813   let Inst{27-21} = opcod;
 814 }
 815
 816 // Most significant word multiply
 817 class AMul2I<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 818              string opc, string asm, list<dag> pattern>
 819   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 820       opc, asm, "", pattern> {
 821   let Inst{7-4}   = 0b1001;
 822   let Inst{20}    = 1;
 823   let Inst{27-21} = opcod;
 824 }
 825
 826 // SMUL<x><y> / SMULW<y> / SMLA<x><y> / SMLAW<x><y>
 827 class AMulxyI<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 828               string opc, string asm, list<dag> pattern>
 829   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 830       opc, asm, "", pattern> {
 831   let Inst{4}     = 0;
 832   let Inst{7}     = 1;
 833   let Inst{20}    = 0;
 834   let Inst{27-21} = opcod;
 835 }
 836
 837 // Extend instructions.
 838 class AExtI<bits<8> opcod, dag oops, dag iops, InstrItinClass itin,
 839             string opc, string asm, list<dag> pattern>
 840   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, ExtFrm, itin,
 841       opc, asm, "", pattern> {
 842   let Inst{7-4}   = 0b0111;
 843   let Inst{27-20} = opcod;
 844 }
 845
 846 // Misc Arithmetic instructions.
 847 class AMiscA1I<bits<8> opcod, dag oops, dag iops, InstrItinClass itin,
 848                string opc, string asm, list<dag> pattern>
 849   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, ArithMiscFrm, itin,
 850       opc, asm, "", pattern> {
 851   let Inst{27-20} = opcod;
 852 }
 853
 854 //===----------------------------------------------------------------------===//
 855
 856 // ARMPat - Same as Pat<>, but requires that the compiler be in ARM mode.
 857 class ARMPat<dag pattern, dag result> : Pat<pattern, result> {
 858   list<Predicate> Predicates = [IsARM];
 859 }
 860 class ARMV5TEPat<dag pattern, dag result> : Pat<pattern, result> {
 861   list<Predicate> Predicates = [IsARM, HasV5TE];
 862 }
 863 class ARMV6Pat<dag pattern, dag result> : Pat<pattern, result> {
 864   list<Predicate> Predicates = [IsARM, HasV6];
 865 }
 866
 867 //===----------------------------------------------------------------------===//
 868 //
 869 // Thumb Instruction Format Definitions.
 870 //
 871
 872 // TI - Thumb instruction.
 873
 874 class ThumbI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 875              InstrItinClass itin, string asm, string cstr, list<dag> pattern>
 876   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
 877   let OutOperandList = oops;
 878   let InOperandList = iops;
 879   let AsmString   = asm;
 880   let Pattern = pattern;
 881   list<Predicate> Predicates = [IsThumb];
 882 }
 883
 884 class TI<dag oops, dag iops, InstrItinClass itin, string asm, list<dag> pattern>
 885   : ThumbI<oops, iops, AddrModeNone, Size2Bytes, itin, asm, "", pattern>;
 886
 887 // Two-address instructions
 888 class TIt<dag oops, dag iops, InstrItinClass itin, string asm, list<dag> pattern>
 889   : ThumbI<oops, iops, AddrModeNone, Size2Bytes, itin, asm, "$lhs = $dst", pattern>;
 890
 891 // tBL, tBX 32-bit instructions
 892 class TIx2<bits<5> opcod1, bits<2> opcod2, bit opcod3,
 893     dag oops, dag iops, InstrItinClass itin, string asm, list<dag> pattern>
 894     : ThumbI<oops, iops, AddrModeNone, Size4Bytes, itin, asm, "", pattern>, Encoding {
 895   let Inst{31-27} = opcod1;
 896   let Inst{15-14} = opcod2;
 897   let Inst{12} = opcod3;
 898 }
 899
 900 // BR_JT instructions
 901 class TJTI<dag oops, dag iops, InstrItinClass itin, string asm, list<dag> pattern>
 902   : ThumbI<oops, iops, AddrModeNone, SizeSpecial, itin, asm, "", pattern>;
 903
 904 // Thumb1 only
 905 class Thumb1I<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 906               InstrItinClass itin, string asm, string cstr, list<dag> pattern>
 907   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
 908   let OutOperandList = oops;
 909   let InOperandList = iops;
 910   let AsmString   = asm;
 911   let Pattern = pattern;
 912   list<Predicate> Predicates = [IsThumb1Only];
 913 }
 914
 915 class T1I<dag oops, dag iops, InstrItinClass itin,
 916           string asm, list<dag> pattern>
 917   : Thumb1I<oops, iops, AddrModeNone, Size2Bytes, itin, asm, "", pattern>;
 918 class T1Ix2<dag oops, dag iops, InstrItinClass itin,
 919             string asm, list<dag> pattern>
 920   : Thumb1I<oops, iops, AddrModeNone, Size4Bytes, itin, asm, "", pattern>;
 921 class T1JTI<dag oops, dag iops, InstrItinClass itin,
 922             string asm, list<dag> pattern>
 923   : Thumb1I<oops, iops, AddrModeNone, SizeSpecial, itin, asm, "", pattern>,
 924     Encoding;
 925
 926 // Two-address instructions
 927 class T1It<dag oops, dag iops, InstrItinClass itin,
 928            string asm, list<dag> pattern>
 929   : Thumb1I<oops, iops, AddrModeNone, Size2Bytes, itin,
 930             asm, "$lhs = $dst", pattern>;
 931
 932 // Thumb1 instruction that can either be predicated or set CPSR.
 933 class Thumb1sI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 934                InstrItinClass itin,
 935                string opc, string asm, string cstr, list<dag> pattern>
 936   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
 937   let OutOperandList = !con(oops, (ops s_cc_out:$s));
 938   let InOperandList = !con(iops, (ops pred:$p));
 939   let AsmString = !strconcat(opc, !strconcat("${s}${p}", asm));
 940   let Pattern = pattern;
 941   list<Predicate> Predicates = [IsThumb1Only];
 942 }
 943
 944 class T1sI<dag oops, dag iops, InstrItinClass itin,
 945            string opc, string asm, list<dag> pattern>
 946   : Thumb1sI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm, "", pattern>;
 947
 948 // Two-address instructions
 949 class T1sIt<dag oops, dag iops, InstrItinClass itin,
 950             string opc, string asm, list<dag> pattern>
 951   : Thumb1sI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm,
 952             "$lhs = $dst", pattern>;
 953
 954 // Thumb1 instruction that can be predicated.
 955 class Thumb1pI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 956                InstrItinClass itin,
 957                string opc, string asm, string cstr, list<dag> pattern>
 958   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
 959   let OutOperandList = oops;
 960   let InOperandList = !con(iops, (ops pred:$p));
 961   let AsmString = !strconcat(opc, !strconcat("${p}", asm));
 962   let Pattern = pattern;
 963   list<Predicate> Predicates = [IsThumb1Only];
 964 }
 965
 966 class T1pI<dag oops, dag iops, InstrItinClass itin,
 967            string opc, string asm, list<dag> pattern>
 968   : Thumb1pI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm, "", pattern>;
 969
 970 // Two-address instructions
 971 class T1pIt<dag oops, dag iops, InstrItinClass itin,
 972             string opc, string asm, list<dag> pattern>
 973   : Thumb1pI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm,
 974             "$lhs = $dst", pattern>;
 975
 976 class T1pI1<dag oops, dag iops, InstrItinClass itin,
 977             string opc, string asm, list<dag> pattern>
 978   : Thumb1pI<oops, iops, AddrModeT1_1, Size2Bytes, itin, opc, asm, "", pattern>;
 979 class T1pI2<dag oops, dag iops, InstrItinClass itin,
 980             string opc, string asm, list<dag> pattern>
 981   : Thumb1pI<oops, iops, AddrModeT1_2, Size2Bytes, itin, opc, asm, "", pattern>;
 982 class T1pI4<dag oops, dag iops, InstrItinClass itin,
 983             string opc, string asm, list<dag> pattern>
 984   : Thumb1pI<oops, iops, AddrModeT1_4, Size2Bytes, itin, opc, asm, "", pattern>;
 985 class T1pIs<dag oops, dag iops,
 986             InstrItinClass itin, string opc, string asm, list<dag> pattern>
 987   : Thumb1pI<oops, iops, AddrModeT1_s, Size2Bytes, itin, opc, asm, "", pattern>;
 988
 989 // A6.2 16-bit Thumb instruction encoding
 990 class T1Encoding<bits<6> opcode> : Encoding {
 991   let Inst{15-10} = opcode;
 992 }
 993
 994 // A6.2.1 Shift (immediate), add, subtract, move, and compare encoding.
 995 class T1General<bits<5> opcode> : Encoding {
 996   let Inst{15-14} = 0b00;
 997   let Inst{13-9} = opcode;
 998 }
 999
1000 // A6.2.2 Data-processing encoding.
1001 class T1DataProcessing<bits<4> opcode> : Encoding {
1002   let Inst{15-10} = 0b010000;
1003   let Inst{9-6} = opcode;
1004 }
1005
1006 // A6.2.3 Special data instructions and branch and exchange encoding.
1007 class T1Special<bits<4> opcode> : Encoding {
1008   let Inst{15-10} = 0b010001;
1009   let Inst{9-6} = opcode;
1010 }
1011
1012 // A6.2.4 Load/store single data item encoding.
1013 class T1LoadStore<bits<4> opA, bits<3> opB> : Encoding {
1014   let Inst{15-12} = opA;
1015   let Inst{11-9} = opB;
1016 }
1017 class T1LdSt<bits<3> opB> : T1LoadStore<0b0101, opB>;
1018 class T1LdSt4Imm<bits<3> opB> : T1LoadStore<0b0110, opB>; // Immediate, 4 bytes
1019 class T1LdSt1Imm<bits<3> opB> : T1LoadStore<0b0111, opB>; // Immediate, 1 byte
1020 class T1LdSt2Imm<bits<3> opB> : T1LoadStore<0b1000, opB>; // Immediate, 2 bytes
1021 class T1LdStSP<bits<3> opB> : T1LoadStore<0b1001, opB>;   // SP relative
1022
1023 // A6.2.5 Miscellaneous 16-bit instructions encoding.
1024 class T1Misc<bits<7> opcode> : Encoding {
1025   let Inst{15-12} = 0b1011;
1026   let Inst{11-5} = opcode;
1027 }
1028
1029 // Thumb2I - Thumb2 instruction. Almost all Thumb2 instructions are predicable.
1030 class Thumb2I<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1031               InstrItinClass itin,
1032               string opc, string asm, string cstr, list<dag> pattern>
1033   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1034   let OutOperandList = oops;
1035   let InOperandList = !con(iops, (ops pred:$p));
1036   let AsmString = !strconcat(opc, !strconcat("${p}", asm));
1037   let Pattern = pattern;
1038   list<Predicate> Predicates = [IsThumb2];
1039 }
1040
1041 // Same as Thumb2I except it can optionally modify CPSR. Note it's modeled as
1042 // an input operand since by default it's a zero register. It will
1043 // become an implicit def once it's "flipped".
1044 // FIXME: This uses unified syntax so {s} comes before {p}. We should make it
1045 // more consistent.
1046 class Thumb2sI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1047                InstrItinClass itin,
1048                string opc, string asm, string cstr, list<dag> pattern>
1049   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1050   let OutOperandList = oops;
1051   let InOperandList = !con(iops, (ops pred:$p, cc_out:$s));
1052   let AsmString   = !strconcat(opc, !strconcat("${s}${p}", asm));
1053   let Pattern = pattern;
1054   list<Predicate> Predicates = [IsThumb2];
1055 }
1056
1057 // Special cases
1058 class Thumb2XI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1059                InstrItinClass itin,
1060                string asm, string cstr, list<dag> pattern>
1061   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1062   let OutOperandList = oops;
1063   let InOperandList = iops;
1064   let AsmString   = asm;
1065   let Pattern = pattern;
1066   list<Predicate> Predicates = [IsThumb2];
1067 }
1068
1069 class ThumbXI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1070                InstrItinClass itin,
1071                string asm, string cstr, list<dag> pattern>
1072   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1073   let OutOperandList = oops;
1074   let InOperandList = iops;
1075   let AsmString   = asm;
1076   let Pattern = pattern;
1077   list<Predicate> Predicates = [IsThumb1Only];
1078 }
1079
1080 class T2I<dag oops, dag iops, InstrItinClass itin,
1081           string opc, string asm, list<dag> pattern>
1082   : Thumb2I<oops, iops, AddrModeNone, Size4Bytes, itin, opc, asm, "", pattern>;
1083 class T2Ii12<dag oops, dag iops, InstrItinClass itin,
1084              string opc, string asm, list<dag> pattern>
1085   : Thumb2I<oops, iops, AddrModeT2_i12, Size4Bytes, itin, opc, asm, "", pattern>;
1086 class T2Ii8<dag oops, dag iops, InstrItinClass itin,
1087             string opc, string asm, list<dag> pattern>
1088   : Thumb2I<oops, iops, AddrModeT2_i8, Size4Bytes, itin, opc, asm, "", pattern>;
1089 class T2Iso<dag oops, dag iops, InstrItinClass itin,
1090             string opc, string asm, list<dag> pattern>
1091   : Thumb2I<oops, iops, AddrModeT2_so, Size4Bytes, itin, opc, asm, "", pattern>;
1092 class T2Ipc<dag oops, dag iops, InstrItinClass itin,
1093             string opc, string asm, list<dag> pattern>
1094   : Thumb2I<oops, iops, AddrModeT2_pc, Size4Bytes, itin, opc, asm, "", pattern>;
1095 class T2Ii8s4<bit P, bit W, bit load, dag oops, dag iops, InstrItinClass itin,
1096               string opc, string asm, list<dag> pattern>
1097   : Thumb2I<oops, iops, AddrModeT2_i8s4, Size4Bytes, itin, opc, asm, "",
1098             pattern> {
1099   let Inst{31-27} = 0b11101;
1100   let Inst{26-25} = 0b00;
1101   let Inst{24} = P;
1102   let Inst{23} = ?; // The U bit.
1103   let Inst{22} = 1;
1104   let Inst{21} = W;
1105   let Inst{20} = load;
1106 }
1107
1108 class T2sI<dag oops, dag iops, InstrItinClass itin,
1109            string opc, string asm, list<dag> pattern>
1110   : Thumb2sI<oops, iops, AddrModeNone, Size4Bytes, itin, opc, asm, "", pattern>;
1111
1112 class T2XI<dag oops, dag iops, InstrItinClass itin,
1113            string asm, list<dag> pattern>
1114   : Thumb2XI<oops, iops, AddrModeNone, Size4Bytes, itin, asm, "", pattern>;
1115 class T2JTI<dag oops, dag iops, InstrItinClass itin,
1116             string asm, list<dag> pattern>
1117   : Thumb2XI<oops, iops, AddrModeNone, SizeSpecial, itin, asm, "", pattern>;
1118
1119 class T2Ix2<dag oops, dag iops, InstrItinClass itin,
1120           string opc, string asm, list<dag> pattern>
1121   : Thumb2I<oops, iops, AddrModeNone, Size8Bytes, itin, opc, asm, "", pattern>;
1122
1123
1124 // T2Iidxldst - Thumb2 indexed load / store instructions.
1125 class T2Iidxldst<bit signed, bits<2> opcod, bit load, bit pre,
1126                  dag oops, dag iops,
1127                  AddrMode am, IndexMode im, InstrItinClass itin,
1128                  string opc, string asm, string cstr, list<dag> pattern>
1129   : InstARM<am, Size4Bytes, im, ThumbFrm, GenericDomain, cstr, itin> {
1130   let OutOperandList = oops;
1131   let InOperandList = !con(iops, (ops pred:$p));
1132   let AsmString = !strconcat(opc, !strconcat("${p}", asm));
1133   let Pattern = pattern;
1134   list<Predicate> Predicates = [IsThumb2];
1135   let Inst{31-27} = 0b11111;
1136   let Inst{26-25} = 0b00;
1137   let Inst{24} = signed;
1138   let Inst{23} = 0;
1139   let Inst{22-21} = opcod;
1140   let Inst{20} = load;
1141   let Inst{11} = 1;
1142   // (P, W) = (1, 1) Pre-indexed or (0, 1) Post-indexed
1143   let Inst{10} = pre; // The P bit.
1144   let Inst{8} = 1; // The W bit.
1145 }
1146
1147 // Tv5Pat - Same as Pat<>, but requires V5T Thumb mode.
1148 class Tv5Pat<dag pattern, dag result> : Pat<pattern, result> {
1149   list<Predicate> Predicates = [IsThumb1Only, HasV5T];
1150 }
1151
1152 // T1Pat - Same as Pat<>, but requires that the compiler be in Thumb1 mode.
1153 class T1Pat<dag pattern, dag result> : Pat<pattern, result> {
1154   list<Predicate> Predicates = [IsThumb1Only];
1155 }
1156
1157 // T2Pat - Same as Pat<>, but requires that the compiler be in Thumb2 mode.
1158 class T2Pat<dag pattern, dag result> : Pat<pattern, result> {
1159   list<Predicate> Predicates = [IsThumb2];
1160 }
1161
1162 //===----------------------------------------------------------------------===//
1163
1164 //===----------------------------------------------------------------------===//
1165 // ARM VFP Instruction templates.
1166 //
1167
1168 // Almost all VFP instructions are predicable.
1169 class VFPI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1170            IndexMode im, Format f, InstrItinClass itin,
1171            string opc, string asm, string cstr, list<dag> pattern>
1172   : InstARM<am, sz, im, f, VFPDomain, cstr, itin> {
1173   let OutOperandList = oops;
1174   let InOperandList = !con(iops, (ops pred:$p));
1175   let AsmString   = !strconcat(opc, !strconcat("${p}", asm));
1176   let Pattern = pattern;
1177   list<Predicate> Predicates = [HasVFP2];
1178 }
1179
1180 // Special cases
1181 class VFPXI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1182             IndexMode im, Format f, InstrItinClass itin,
1183             string asm, string cstr, list<dag> pattern>
1184   : InstARM<am, sz, im, f, VFPDomain, cstr, itin> {
1185   let OutOperandList = oops;
1186   let InOperandList = iops;
1187   let AsmString   = asm;
1188   let Pattern = pattern;
1189   list<Predicate> Predicates = [HasVFP2];
1190 }
1191
1192 class VFPAI<dag oops, dag iops, Format f, InstrItinClass itin,
1193             string opc, string asm, list<dag> pattern>
1194   : VFPI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
1195          opc, asm, "", pattern>;
1196
1197 // ARM VFP addrmode5 loads and stores
1198 class ADI5<bits<4> opcod1, bits<2> opcod2, dag oops, dag iops,
1199            InstrItinClass itin,
1200            string opc, string asm, list<dag> pattern>
1201   : VFPI<oops, iops, AddrMode5, Size4Bytes, IndexModeNone,
1202       VFPLdStFrm, itin, opc, asm, "", pattern> {
1203   // TODO: Mark the instructions with the appropriate subtarget info.
1204   let Inst{27-24} = opcod1;
1205   let Inst{21-20} = opcod2;
1206   let Inst{11-8}  = 0b1011;
1207
1208   // 64-bit loads & stores operate on both NEON and VFP pipelines.
1209   let Dom = VFPNeonDomain.Value;
1210 }
1211
1212 class ASI5<bits<4> opcod1, bits<2> opcod2, dag oops, dag iops,
1213            InstrItinClass itin,
1214            string opc, string asm, list<dag> pattern>
1215   : VFPI<oops, iops, AddrMode5, Size4Bytes, IndexModeNone,
1216       VFPLdStFrm, itin, opc, asm, "", pattern> {
1217   // TODO: Mark the instructions with the appropriate subtarget info.
1218   let Inst{27-24} = opcod1;
1219   let Inst{21-20} = opcod2;
1220   let Inst{11-8}  = 0b1010;
1221 }
1222
1223 // Load / store multiple
1224 class AXDI5<dag oops, dag iops, InstrItinClass itin,
1225             string asm, list<dag> pattern>
1226   : VFPXI<oops, iops, AddrMode5, Size4Bytes, IndexModeNone,
1227        VFPLdStMulFrm, itin, asm, "", pattern> {
1228   // TODO: Mark the instructions with the appropriate subtarget info.
1229   let Inst{27-25} = 0b110;
1230   let Inst{11-8}  = 0b1011;
1231
1232   // 64-bit loads & stores operate on both NEON and VFP pipelines.
1233   let Dom = VFPNeonDomain.Value;
1234 }
1235
1236 class AXSI5<dag oops, dag iops, InstrItinClass itin,
1237             string asm, list<dag> pattern>
1238   : VFPXI<oops, iops, AddrMode5, Size4Bytes, IndexModeNone,
1239        VFPLdStMulFrm, itin, asm, "", pattern> {
1240   // TODO: Mark the instructions with the appropriate subtarget info.
1241   let Inst{27-25} = 0b110;
1242   let Inst{11-8}  = 0b1010;
1243 }
1244
1245 // Double precision, unary
1246 class ADuI<bits<8> opcod1, bits<4> opcod2, bits<4> opcod3, dag oops, dag iops,
1247            InstrItinClass itin, string opc, string asm, list<dag> pattern>
1248   : VFPAI<oops, iops, VFPUnaryFrm, itin, opc, asm, pattern> {
1249   let Inst{27-20} = opcod1;
1250   let Inst{19-16} = opcod2;
1251   let Inst{11-8}  = 0b1011;
1252   let Inst{7-4}   = opcod3;
1253 }
1254
1255 // Double precision, binary
1256 class ADbI<bits<8> opcod, dag oops, dag iops, InstrItinClass itin,
1257            string opc, string asm, list<dag> pattern>
1258   : VFPAI<oops, iops, VFPBinaryFrm, itin, opc, asm, pattern> {
1259   let Inst{27-20} = opcod;
1260   let Inst{11-8}  = 0b1011;
1261 }
1262
1263 // Single precision, unary
1264 class ASuI<bits<8> opcod1, bits<4> opcod2, bits<4> opcod3, dag oops, dag iops,
1265            InstrItinClass itin, string opc, string asm, list<dag> pattern>
1266   : VFPAI<oops, iops, VFPUnaryFrm, itin, opc, asm, pattern> {
1267   // Bits 22 (D bit) and 5 (M bit) will be changed during instruction encoding.
1268   let Inst{27-20} = opcod1;
1269   let Inst{19-16} = opcod2;
1270   let Inst{11-8}  = 0b1010;
1271   let Inst{7-4}   = opcod3;
1272 }
1273
1274 // Single precision unary, if no NEON
1275 // Same as ASuI except not available if NEON is enabled
1276 class ASuIn<bits<8> opcod1, bits<4> opcod2, bits<4> opcod3, dag oops, dag iops,
1277             InstrItinClass itin, string opc, string asm, list<dag> pattern>
1278   : ASuI<opcod1, opcod2, opcod3, oops, iops, itin, opc, asm, pattern> {
1279   list<Predicate> Predicates = [HasVFP2,DontUseNEONForFP];
1280 }
1281
1282 // Single precision, binary
1283 class ASbI<bits<8> opcod, dag oops, dag iops, InstrItinClass itin,
1284            string opc, string asm, list<dag> pattern>
1285   : VFPAI<oops, iops, VFPBinaryFrm, itin, opc, asm, pattern> {
1286   // Bit 22 (D bit) can be changed during instruction encoding.
1287   let Inst{27-20} = opcod;
1288   let Inst{11-8}  = 0b1010;
1289 }
1290
1291 // Single precision binary, if no NEON
1292 // Same as ASbI except not available if NEON is enabled
1293 class ASbIn<bits<8> opcod, dag oops, dag iops, InstrItinClass itin,
1294             string opc, string asm, list<dag> pattern>
1295   : ASbI<opcod, oops, iops, itin, opc, asm, pattern> {
1296   list<Predicate> Predicates = [HasVFP2,DontUseNEONForFP];
1297 }
1298
1299 // VFP conversion instructions
1300 class AVConv1I<bits<8> opcod1, bits<4> opcod2, bits<4> opcod3,
1301                dag oops, dag iops, InstrItinClass itin,
1302                string opc, string asm, list<dag> pattern>
1303   : VFPAI<oops, iops, VFPConv1Frm, itin, opc, asm, pattern> {
1304   let Inst{27-20} = opcod1;
1305   let Inst{19-16} = opcod2;
1306   let Inst{11-8}  = opcod3;
1307   let Inst{6}     = 1;
1308 }
1309
1310 // VFP conversion instructions, if no NEON
1311 class AVConv1In<bits<8> opcod1, bits<4> opcod2, bits<4> opcod3,
1312                 dag oops, dag iops, InstrItinClass itin,
1313                 string opc, string asm, list<dag> pattern>
1314   : AVConv1I<opcod1, opcod2, opcod3, oops, iops, itin, opc, asm, pattern> {
1315   list<Predicate> Predicates = [HasVFP2,DontUseNEONForFP];
1316 }
1317
1318 class AVConvXI<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops, Format f,
1319                InstrItinClass itin,
1320                string opc, string asm, list<dag> pattern>
1321   : VFPAI<oops, iops, f, itin, opc, asm, pattern> {
1322   let Inst{27-20} = opcod1;
1323   let Inst{11-8}  = opcod2;
1324   let Inst{4}     = 1;
1325 }
1326
1327 class AVConv2I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1328                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1329   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv2Frm, itin, opc, asm, pattern>;
1330
1331 class AVConv3I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1332                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1333   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv3Frm, itin, opc, asm, pattern>;
1334
1335 class AVConv4I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1336                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1337   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv4Frm, itin, opc, asm, pattern>;
1338
1339 class AVConv5I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1340                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1341   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv5Frm, itin, opc, asm, pattern>;
1342
1343 //===----------------------------------------------------------------------===//
1344
1345 //===----------------------------------------------------------------------===//
1346 // ARM NEON Instruction templates.
1347 //
1348
1349 class NeonI<dag oops, dag iops, AddrMode am, IndexMode im, InstrItinClass itin,
1350             string opc, string dt, string asm, string cstr, list<dag> pattern>
1351   : InstARM<am, Size4Bytes, im, NEONFrm, NeonDomain, cstr, itin> {
1352   let OutOperandList = oops;
1353   let InOperandList = !con(iops, (ops pred:$p));
1354   let AsmString = !strconcat(
1355                      !strconcat(!strconcat(opc, "${p}"), !strconcat(".", dt)),
1356                      !strconcat("\t", asm));
1357   let Pattern = pattern;
1358   list<Predicate> Predicates = [HasNEON];
1359 }
1360
1361 // Same as NeonI except it does not have a "data type" specifier.
1362 class NeonXI<dag oops, dag iops, AddrMode am, IndexMode im, InstrItinClass itin,
1363             string opc, string asm, string cstr, list<dag> pattern>
1364   : InstARM<am, Size4Bytes, im, NEONFrm, NeonDomain, cstr, itin> {
1365   let OutOperandList = oops;
1366   let InOperandList = !con(iops, (ops pred:$p));
1367   let AsmString = !strconcat(!strconcat(opc, "${p}"), !strconcat("\t", asm));
1368   let Pattern = pattern;
1369   list<Predicate> Predicates = [HasNEON];
1370 }
1371
1372 class NI<dag oops, dag iops, InstrItinClass itin, string opc, string asm,
1373          list<dag> pattern>
1374   : NeonXI<oops, iops, AddrModeNone, IndexModeNone, itin, opc, asm, "",
1375           pattern> {
1376 }
1377
1378 class NI4<dag oops, dag iops, InstrItinClass itin, string opc,
1379           string asm, list<dag> pattern>
1380   : NeonXI<oops, iops, AddrMode4, IndexModeNone, itin, opc, asm, "",
1381           pattern> {
1382 }
1383
1384 class NLdSt<bit op23, bits<2> op21_20, bits<4> op11_8, bits<4> op7_4,
1385             dag oops, dag iops, InstrItinClass itin,
1386             string opc, string dt, string asm, string cstr, list<dag> pattern>
1387   : NeonI<oops, iops, AddrMode6, IndexModeNone, itin, opc, dt, asm, cstr,
1388           pattern> {
1389   let Inst{31-24} = 0b11110100;
1390   let Inst{23} = op23;
1391   let Inst{21-20} = op21_20;
1392   let Inst{11-8} = op11_8;
1393   let Inst{7-4} = op7_4;
1394 }
1395
1396 class NDataI<dag oops, dag iops, InstrItinClass itin,
1397              string opc, string dt, string asm, string cstr, list<dag> pattern>
1398   : NeonI<oops, iops, AddrModeNone, IndexModeNone, itin, opc, dt, asm,
1399          cstr, pattern> {
1400   let Inst{31-25} = 0b1111001;
1401 }
1402
1403 class NDataXI<dag oops, dag iops, InstrItinClass itin,
1404              string opc, string asm, string cstr, list<dag> pattern>
1405   : NeonXI<oops, iops, AddrModeNone, IndexModeNone, itin, opc, asm,
1406          cstr, pattern> {
1407   let Inst{31-25} = 0b1111001;
1408 }
1409
1410 // NEON "one register and a modified immediate" format.
1411 class N1ModImm<bit op23, bits<3> op21_19, bits<4> op11_8, bit op7, bit op6,
1412                bit op5, bit op4,
1413                dag oops, dag iops, InstrItinClass itin,
1414                string opc, string dt, string asm, string cstr, list<dag> pattern>
1415   : NDataI<oops, iops, itin, opc, dt, asm, cstr, pattern> {
1416   let Inst{23} = op23;
1417   let Inst{21-19} = op21_19;
1418   let Inst{11-8} = op11_8;
1419   let Inst{7} = op7;
1420   let Inst{6} = op6;
1421   let Inst{5} = op5;
1422   let Inst{4} = op4;
1423 }
1424
1425 // NEON 2 vector register format.
1426 class N2V<bits<2> op24_23, bits<2> op21_20, bits<2> op19_18, bits<2> op17_16,
1427           bits<5> op11_7, bit op6, bit op4,
1428           dag oops, dag iops, InstrItinClass itin,
1429           string opc, string dt, string asm, string cstr, list<dag> pattern>
1430   : NDataI<oops, iops, itin, opc, dt, asm, cstr, pattern> {
1431   let Inst{24-23} = op24_23;
1432   let Inst{21-20} = op21_20;
1433   let Inst{19-18} = op19_18;
1434   let Inst{17-16} = op17_16;
1435   let Inst{11-7} = op11_7;
1436   let Inst{6} = op6;
1437   let Inst{4} = op4;
1438 }
1439
1440 // Same as N2V except it doesn't have a datatype suffix.
1441 class N2VX<bits<2> op24_23, bits<2> op21_20, bits<2> op19_18, bits<2> op17_16,
1442           bits<5> op11_7, bit op6, bit op4,
1443           dag oops, dag iops, InstrItinClass itin,
1444           string opc, string asm, string cstr, list<dag> pattern>
1445   : NDataXI<oops, iops, itin, opc, asm, cstr, pattern> {
1446   let Inst{24-23} = op24_23;
1447   let Inst{21-20} = op21_20;
1448   let Inst{19-18} = op19_18;
1449   let Inst{17-16} = op17_16;
1450   let Inst{11-7} = op11_7;
1451   let Inst{6} = op6;
1452   let Inst{4} = op4;
1453 }
1454
1455 // NEON 2 vector register with immediate.
1456 class N2VImm<bit op24, bit op23, bits<4> op11_8, bit op7, bit op6, bit op4,
1457              dag oops, dag iops, InstrItinClass itin,
1458              string opc, string dt, string asm, string cstr, list<dag> pattern>
1459   : NDataI<oops, iops, itin, opc, dt, asm, cstr, pattern> {
1460   let Inst{24} = op24;
1461   let Inst{23} = op23;
1462   let Inst{11-8} = op11_8;
1463   let Inst{7} = op7;
1464   let Inst{6} = op6;
1465   let Inst{4} = op4;
1466 }
1467
1468 // NEON 3 vector register format.
1469 class N3V<bit op24, bit op23, bits<2> op21_20, bits<4> op11_8, bit op6, bit op4,
1470           dag oops, dag iops, InstrItinClass itin,
1471           string opc, string dt, string asm, string cstr, list<dag> pattern>
1472   : NDataI<oops, iops, itin, opc, dt, asm, cstr, pattern> {
1473   let Inst{24} = op24;
1474   let Inst{23} = op23;
1475   let Inst{21-20} = op21_20;
1476   let Inst{11-8} = op11_8;
1477   let Inst{6} = op6;
1478   let Inst{4} = op4;
1479 }
1480
1481 // Same as N3VX except it doesn't have a data type suffix.
1482 class N3VX<bit op24, bit op23, bits<2> op21_20, bits<4> op11_8, bit op6, bit op4,
1483           dag oops, dag iops, InstrItinClass itin,
1484           string opc, string asm, string cstr, list<dag> pattern>
1485   : NDataXI<oops, iops, itin, opc, asm, cstr, pattern> {
1486   let Inst{24} = op24;
1487   let Inst{23} = op23;
1488   let Inst{21-20} = op21_20;
1489   let Inst{11-8} = op11_8;
1490   let Inst{6} = op6;
1491   let Inst{4} = op4;
1492 }
1493
1494 // NEON VMOVs between scalar and core registers.
1495 class NVLaneOp<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1496                dag oops, dag iops, Format f, InstrItinClass itin,
1497                string opc, string dt, string asm, list<dag> pattern>
1498   : InstARM<AddrModeNone, Size4Bytes, IndexModeNone, f, GenericDomain,
1499     "", itin> {
1500   let Inst{27-20} = opcod1;
1501   let Inst{11-8} = opcod2;
1502   let Inst{6-5} = opcod3;
1503   let Inst{4} = 1;
1504
1505   let OutOperandList = oops;
1506   let InOperandList = !con(iops, (ops pred:$p));
1507   let AsmString = !strconcat(
1508                      !strconcat(!strconcat(opc, "${p}"), !strconcat(".", dt)),
1509                      !strconcat("\t", asm));
1510   let Pattern = pattern;
1511   list<Predicate> Predicates = [HasNEON];
1512 }
1513 class NVGetLane<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1514                 dag oops, dag iops, InstrItinClass itin,
1515                 string opc, string dt, string asm, list<dag> pattern>
1516   : NVLaneOp<opcod1, opcod2, opcod3, oops, iops, NEONGetLnFrm, itin,
1517              opc, dt, asm, pattern>;
1518 class NVSetLane<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1519                 dag oops, dag iops, InstrItinClass itin,
1520                 string opc, string dt, string asm, list<dag> pattern>
1521   : NVLaneOp<opcod1, opcod2, opcod3, oops, iops, NEONSetLnFrm, itin,
1522              opc, dt, asm, pattern>;
1523 class NVDup<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1524             dag oops, dag iops, InstrItinClass itin,
1525             string opc, string dt, string asm, list<dag> pattern>
1526   : NVLaneOp<opcod1, opcod2, opcod3, oops, iops, NEONDupFrm, itin,
1527              opc, dt, asm, pattern>;
1528
1529 // NEONFPPat - Same as Pat<>, but requires that the compiler be using NEON
1530 // for single-precision FP.
1531 class NEONFPPat<dag pattern, dag result> : Pat<pattern, result> {
1532   list<Predicate> Predicates = [HasNEON,UseNEONForFP];
1533 }