lib/Target/ARM/ARMInstrFormats.td

   1 //===- ARMInstrFormats.td - ARM Instruction Formats ----------*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //
  12 // ARM Instruction Format Definitions.
  13 //
  14
  15 // Format specifies the encoding used by the instruction.  This is part of the
  16 // ad-hoc solution used to emit machine instruction encodings by our machine
  17 // code emitter.
  18 class Format<bits<6> val> {
  19   bits<6> Value = val;
  20 }
  21
  22 def Pseudo        : Format<0>;
  23 def MulFrm        : Format<1>;
  24 def BrFrm         : Format<2>;
  25 def BrMiscFrm     : Format<3>;
  26
  27 def DPFrm         : Format<4>;
  28 def DPSoRegFrm    : Format<5>;
  29
  30 def LdFrm         : Format<6>;
  31 def StFrm         : Format<7>;
  32 def LdMiscFrm     : Format<8>;
  33 def StMiscFrm     : Format<9>;
  34 def LdStMulFrm    : Format<10>;
  35
  36 def LdStExFrm     : Format<11>;
  37
  38 def ArithMiscFrm  : Format<12>;
  39 def SatFrm        : Format<13>;
  40 def ExtFrm        : Format<14>;
  41
  42 def VFPUnaryFrm   : Format<15>;
  43 def VFPBinaryFrm  : Format<16>;
  44 def VFPConv1Frm   : Format<17>;
  45 def VFPConv2Frm   : Format<18>;
  46 def VFPConv3Frm   : Format<19>;
  47 def VFPConv4Frm   : Format<20>;
  48 def VFPConv5Frm   : Format<21>;
  49 def VFPLdStFrm    : Format<22>;
  50 def VFPLdStMulFrm : Format<23>;
  51 def VFPMiscFrm    : Format<24>;
  52
  53 def ThumbFrm      : Format<25>;
  54 def MiscFrm       : Format<26>;
  55
  56 def NGetLnFrm     : Format<27>;
  57 def NSetLnFrm     : Format<28>;
  58 def NDupFrm       : Format<29>;
  59 def NLdStFrm      : Format<30>;
  60 def N1RegModImmFrm: Format<31>;
  61 def N2RegFrm      : Format<32>;
  62 def NVCVTFrm      : Format<33>;
  63 def NVDupLnFrm    : Format<34>;
  64 def N2RegVShLFrm  : Format<35>;
  65 def N2RegVShRFrm  : Format<36>;
  66 def N3RegFrm      : Format<37>;
  67 def N3RegVShFrm   : Format<38>;
  68 def NVExtFrm      : Format<39>;
  69 def NVMulSLFrm    : Format<40>;
  70 def NVTBLFrm      : Format<41>;
  71
  72 // Misc flags.
  73
  74 // The instruction has an Rn register operand.
  75 // UnaryDP - Indicates this is a unary data processing instruction, i.e.
  76 // it doesn't have a Rn operand.
  77 class UnaryDP    { bit isUnaryDataProc = 1; }
  78
  79 // Xform16Bit - Indicates this Thumb2 instruction may be transformed into
  80 // a 16-bit Thumb instruction if certain conditions are met.
  81 class Xform16Bit { bit canXformTo16Bit = 1; }
  82
  83 //===----------------------------------------------------------------------===//
  84 // ARM Instruction flags.  These need to match ARMBaseInstrInfo.h.
  85 //
  86
  87 // FIXME: Once the JIT is MC-ized, these can go away.
  88 // Addressing mode.
  89 class AddrMode<bits<5> val> {
  90   bits<5> Value = val;
  91 }
  92 def AddrModeNone    : AddrMode<0>;
  93 def AddrMode1       : AddrMode<1>;
  94 def AddrMode2       : AddrMode<2>;
  95 def AddrMode3       : AddrMode<3>;
  96 def AddrMode4       : AddrMode<4>;
  97 def AddrMode5       : AddrMode<5>;
  98 def AddrMode6       : AddrMode<6>;
  99 def AddrModeT1_1    : AddrMode<7>;
 100 def AddrModeT1_2    : AddrMode<8>;
 101 def AddrModeT1_4    : AddrMode<9>;
 102 def AddrModeT1_s    : AddrMode<10>;
 103 def AddrModeT2_i12  : AddrMode<11>;
 104 def AddrModeT2_i8   : AddrMode<12>;
 105 def AddrModeT2_so   : AddrMode<13>;
 106 def AddrModeT2_pc   : AddrMode<14>;
 107 def AddrModeT2_i8s4 : AddrMode<15>;
 108 def AddrMode_i12    : AddrMode<16>;
 109
 110 // Instruction size.
 111 class SizeFlagVal<bits<3> val> {
 112   bits<3> Value = val;
 113 }
 114 def SizeInvalid  : SizeFlagVal<0>;  // Unset.
 115 def SizeSpecial  : SizeFlagVal<1>;  // Pseudo or special.
 116 def Size8Bytes   : SizeFlagVal<2>;
 117 def Size4Bytes   : SizeFlagVal<3>;
 118 def Size2Bytes   : SizeFlagVal<4>;
 119
 120 // Load / store index mode.
 121 class IndexMode<bits<2> val> {
 122   bits<2> Value = val;
 123 }
 124 def IndexModeNone : IndexMode<0>;
 125 def IndexModePre  : IndexMode<1>;
 126 def IndexModePost : IndexMode<2>;
 127 def IndexModeUpd  : IndexMode<3>;
 128
 129 // Instruction execution domain.
 130 class Domain<bits<3> val> {
 131   bits<3> Value = val;
 132 }
 133 def GenericDomain : Domain<0>;
 134 def VFPDomain     : Domain<1>; // Instructions in VFP domain only
 135 def NeonDomain    : Domain<2>; // Instructions in Neon domain only
 136 def VFPNeonDomain : Domain<3>; // Instructions in both VFP & Neon domains
 137 def VFPNeonA8Domain : Domain<5>; // Instructions in VFP & Neon under A8
 138
 139 //===----------------------------------------------------------------------===//
 140 // ARM special operands.
 141 //
 142
 143 def CondCodeOperand : AsmOperandClass {
 144   let Name = "CondCode";
 145   let SuperClasses = [];
 146 }
 147
 148 def CCOutOperand : AsmOperandClass {
 149   let Name = "CCOut";
 150   let SuperClasses = [];
 151 }
 152
 153 def MemBarrierOptOperand : AsmOperandClass {
 154   let Name = "MemBarrierOpt";
 155   let SuperClasses = [];
 156   let ParserMethod = "tryParseMemBarrierOptOperand";
 157 }
 158
 159 def ProcIFlagsOperand : AsmOperandClass {
 160   let Name = "ProcIFlags";
 161   let SuperClasses = [];
 162   let ParserMethod = "tryParseProcIFlagsOperand";
 163 }
 164
 165 def MSRMaskOperand : AsmOperandClass {
 166   let Name = "MSRMask";
 167   let SuperClasses = [];
 168   let ParserMethod = "tryParseMSRMaskOperand";
 169 }
 170
 171 // ARM imod and iflag operands, used only by the CPS instruction.
 172 def imod_op : Operand<i32> {
 173   let PrintMethod = "printCPSIMod";
 174 }
 175
 176 def iflags_op : Operand<i32> {
 177   let PrintMethod = "printCPSIFlag";
 178   let ParserMatchClass = ProcIFlagsOperand;
 179 }
 180
 181 // ARM Predicate operand. Default to 14 = always (AL). Second part is CC
 182 // register whose default is 0 (no register).
 183 def pred : PredicateOperand<OtherVT, (ops i32imm, CCR),
 184                                      (ops (i32 14), (i32 zero_reg))> {
 185   let PrintMethod = "printPredicateOperand";
 186   let ParserMatchClass = CondCodeOperand;
 187 }
 188
 189 // Conditional code result for instructions whose 's' bit is set, e.g. subs.
 190 def cc_out : OptionalDefOperand<OtherVT, (ops CCR), (ops (i32 zero_reg))> {
 191   let EncoderMethod = "getCCOutOpValue";
 192   let PrintMethod = "printSBitModifierOperand";
 193   let ParserMatchClass = CCOutOperand;
 194 }
 195
 196 // Same as cc_out except it defaults to setting CPSR.
 197 def s_cc_out : OptionalDefOperand<OtherVT, (ops CCR), (ops (i32 CPSR))> {
 198   let EncoderMethod = "getCCOutOpValue";
 199   let PrintMethod = "printSBitModifierOperand";
 200   let ParserMatchClass = CCOutOperand;
 201 }
 202
 203 // ARM special operands for disassembly only.
 204 //
 205 def setend_op : Operand<i32> {
 206   let PrintMethod = "printSetendOperand";
 207 }
 208
 209 def msr_mask : Operand<i32> {
 210   let PrintMethod = "printMSRMaskOperand";
 211   let ParserMatchClass = MSRMaskOperand;
 212 }
 213
 214 // Shift Right Immediate - A shift right immediate is encoded differently from
 215 // other shift immediates. The imm6 field is encoded like so:
 216 //
 217 //    Offset    Encoding
 218 //     8        imm6<5:3> = '001', 8 - <imm> is encoded in imm6<2:0>
 219 //     16       imm6<5:4> = '01', 16 - <imm> is encoded in imm6<3:0>
 220 //     32       imm6<5> = '1', 32 - <imm> is encoded in imm6<4:0>
 221 //     64       64 - <imm> is encoded in imm6<5:0>
 222 def shr_imm8  : Operand<i32> {
 223   let EncoderMethod = "getShiftRight8Imm";
 224 }
 225 def shr_imm16 : Operand<i32> {
 226   let EncoderMethod = "getShiftRight16Imm";
 227 }
 228 def shr_imm32 : Operand<i32> {
 229   let EncoderMethod = "getShiftRight32Imm";
 230 }
 231 def shr_imm64 : Operand<i32> {
 232   let EncoderMethod = "getShiftRight64Imm";
 233 }
 234
 235 //===----------------------------------------------------------------------===//
 236 // ARM Instruction templates.
 237 //
 238
 239 class InstTemplate<AddrMode am, SizeFlagVal sz, IndexMode im,
 240                    Format f, Domain d, string cstr, InstrItinClass itin>
 241   : Instruction {
 242   let Namespace = "ARM";
 243
 244   AddrMode AM = am;
 245   SizeFlagVal SZ = sz;
 246   IndexMode IM = im;
 247   bits<2> IndexModeBits = IM.Value;
 248   Format F = f;
 249   bits<6> Form = F.Value;
 250   Domain D = d;
 251   bit isUnaryDataProc = 0;
 252   bit canXformTo16Bit = 0;
 253
 254   // If this is a pseudo instruction, mark it isCodeGenOnly.
 255   let isCodeGenOnly = !eq(!cast<string>(f), "Pseudo");
 256
 257   // The layout of TSFlags should be kept in sync with ARMBaseInstrInfo.h.
 258   let TSFlags{4-0}   = AM.Value;
 259   let TSFlags{7-5}   = SZ.Value;
 260   let TSFlags{9-8}   = IndexModeBits;
 261   let TSFlags{15-10} = Form;
 262   let TSFlags{16}    = isUnaryDataProc;
 263   let TSFlags{17}    = canXformTo16Bit;
 264   let TSFlags{20-18} = D.Value;
 265
 266   let Constraints = cstr;
 267   let Itinerary = itin;
 268 }
 269
 270 class Encoding {
 271   field bits<32> Inst;
 272 }
 273
 274 class InstARM<AddrMode am, SizeFlagVal sz, IndexMode im,
 275               Format f, Domain d, string cstr, InstrItinClass itin>
 276   : InstTemplate<am, sz, im, f, d, cstr, itin>, Encoding;
 277
 278 // This Encoding-less class is used by Thumb1 to specify the encoding bits later
 279 // on by adding flavors to specific instructions.
 280 class InstThumb<AddrMode am, SizeFlagVal sz, IndexMode im,
 281                 Format f, Domain d, string cstr, InstrItinClass itin>
 282   : InstTemplate<am, sz, im, f, d, cstr, itin>;
 283
 284 class PseudoInst<dag oops, dag iops, InstrItinClass itin, list<dag> pattern>
 285   // FIXME: This really should derive from InstTemplate instead, as pseudos
 286   //        don't need encoding information. TableGen doesn't like that
 287   //        currently. Need to figure out why and fix it.
 288   : InstARM<AddrModeNone, SizeSpecial, IndexModeNone, Pseudo, GenericDomain,
 289             "", itin> {
 290   let OutOperandList = oops;
 291   let InOperandList = iops;
 292   let Pattern = pattern;
 293   let isCodeGenOnly = 1;
 294 }
 295
 296 // PseudoInst that's ARM-mode only.
 297 class ARMPseudoInst<dag oops, dag iops, SizeFlagVal sz, InstrItinClass itin,
 298                     list<dag> pattern>
 299   : PseudoInst<oops, iops, itin, pattern> {
 300   let SZ = sz;
 301   list<Predicate> Predicates = [IsARM];
 302 }
 303
 304 // PseudoInst that's Thumb-mode only.
 305 class tPseudoInst<dag oops, dag iops, SizeFlagVal sz, InstrItinClass itin,
 306                     list<dag> pattern>
 307   : PseudoInst<oops, iops, itin, pattern> {
 308   let SZ = sz;
 309   list<Predicate> Predicates = [IsThumb];
 310 }
 311
 312 // PseudoInst that's Thumb2-mode only.
 313 class t2PseudoInst<dag oops, dag iops, SizeFlagVal sz, InstrItinClass itin,
 314                     list<dag> pattern>
 315   : PseudoInst<oops, iops, itin, pattern> {
 316   let SZ = sz;
 317   list<Predicate> Predicates = [IsThumb2];
 318 }
 319 // Almost all ARM instructions are predicable.
 320 class I<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 321         IndexMode im, Format f, InstrItinClass itin,
 322         string opc, string asm, string cstr,
 323         list<dag> pattern>
 324   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 325   bits<4> p;
 326   let Inst{31-28} = p;
 327   let OutOperandList = oops;
 328   let InOperandList = !con(iops, (ins pred:$p));
 329   let AsmString = !strconcat(opc, "${p}", asm);
 330   let Pattern = pattern;
 331   list<Predicate> Predicates = [IsARM];
 332 }
 333
 334 // A few are not predicable
 335 class InoP<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 336            IndexMode im, Format f, InstrItinClass itin,
 337            string opc, string asm, string cstr,
 338            list<dag> pattern>
 339   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 340   let OutOperandList = oops;
 341   let InOperandList = iops;
 342   let AsmString = !strconcat(opc, asm);
 343   let Pattern = pattern;
 344   let isPredicable = 0;
 345   list<Predicate> Predicates = [IsARM];
 346 }
 347
 348 // Same as I except it can optionally modify CPSR. Note it's modeled as an input
 349 // operand since by default it's a zero register. It will become an implicit def
 350 // once it's "flipped".
 351 class sI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 352          IndexMode im, Format f, InstrItinClass itin,
 353          string opc, string asm, string cstr,
 354          list<dag> pattern>
 355   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 356   bits<4> p; // Predicate operand
 357   bits<1> s; // condition-code set flag ('1' if the insn should set the flags)
 358   let Inst{31-28} = p;
 359   let Inst{20} = s;
 360
 361   let OutOperandList = oops;
 362   let InOperandList = !con(iops, (ins pred:$p, cc_out:$s));
 363   let AsmString = !strconcat(opc, "${s}${p}", asm);
 364   let Pattern = pattern;
 365   list<Predicate> Predicates = [IsARM];
 366 }
 367
 368 // Special cases
 369 class XI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 370          IndexMode im, Format f, InstrItinClass itin,
 371          string asm, string cstr, list<dag> pattern>
 372   : InstARM<am, sz, im, f, GenericDomain, cstr, itin> {
 373   let OutOperandList = oops;
 374   let InOperandList = iops;
 375   let AsmString = asm;
 376   let Pattern = pattern;
 377   list<Predicate> Predicates = [IsARM];
 378 }
 379
 380 class AI<dag oops, dag iops, Format f, InstrItinClass itin,
 381          string opc, string asm, list<dag> pattern>
 382   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 383       opc, asm, "", pattern>;
 384 class AsI<dag oops, dag iops, Format f, InstrItinClass itin,
 385           string opc, string asm, list<dag> pattern>
 386   : sI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 387        opc, asm, "", pattern>;
 388 class AXI<dag oops, dag iops, Format f, InstrItinClass itin,
 389           string asm, list<dag> pattern>
 390   : XI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 391        asm, "", pattern>;
 392 class AInoP<dag oops, dag iops, Format f, InstrItinClass itin,
 393             string opc, string asm, list<dag> pattern>
 394   : InoP<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
 395          opc, asm, "", pattern>;
 396
 397 // Ctrl flow instructions
 398 class ABI<bits<4> opcod, dag oops, dag iops, InstrItinClass itin,
 399           string opc, string asm, list<dag> pattern>
 400   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, BrFrm, itin,
 401       opc, asm, "", pattern> {
 402   let Inst{27-24} = opcod;
 403 }
 404 class ABXI<bits<4> opcod, dag oops, dag iops, InstrItinClass itin,
 405            string asm, list<dag> pattern>
 406   : XI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, BrFrm, itin,
 407        asm, "", pattern> {
 408   let Inst{27-24} = opcod;
 409 }
 410
 411 // BR_JT instructions
 412 class JTI<dag oops, dag iops, InstrItinClass itin,
 413           string asm, list<dag> pattern>
 414   : XI<oops, iops, AddrModeNone, SizeSpecial, IndexModeNone, BrMiscFrm, itin,
 415        asm, "", pattern>;
 416
 417 // Atomic load/store instructions
 418 class AIldrex<bits<2> opcod, dag oops, dag iops, InstrItinClass itin,
 419               string opc, string asm, list<dag> pattern>
 420   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, LdStExFrm, itin,
 421       opc, asm, "", pattern> {
 422   bits<4> Rt;
 423   bits<4> Rn;
 424   let Inst{27-23} = 0b00011;
 425   let Inst{22-21} = opcod;
 426   let Inst{20}    = 1;
 427   let Inst{19-16} = Rn;
 428   let Inst{15-12} = Rt;
 429   let Inst{11-0}  = 0b111110011111;
 430 }
 431 class AIstrex<bits<2> opcod, dag oops, dag iops, InstrItinClass itin,
 432               string opc, string asm, list<dag> pattern>
 433   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, LdStExFrm, itin,
 434       opc, asm, "", pattern> {
 435   bits<4> Rd;
 436   bits<4> Rt;
 437   bits<4> addr;
 438   let Inst{27-23} = 0b00011;
 439   let Inst{22-21} = opcod;
 440   let Inst{20}    = 0;
 441   let Inst{19-16} = addr;
 442   let Inst{15-12} = Rd;
 443   let Inst{11-4}  = 0b11111001;
 444   let Inst{3-0}   = Rt;
 445 }
 446 class AIswp<bit b, dag oops, dag iops, string opc, list<dag> pattern>
 447   : AI<oops, iops, MiscFrm, NoItinerary, opc, "\t$Rt, $Rt2, [$Rn]", pattern> {
 448   bits<4> Rt;
 449   bits<4> Rt2;
 450   bits<4> Rn;
 451   let Inst{27-23} = 0b00010;
 452   let Inst{22} = b;
 453   let Inst{21-20} = 0b00;
 454   let Inst{19-16} = Rn;
 455   let Inst{15-12} = Rt;
 456   let Inst{11-4} = 0b00001001;
 457   let Inst{3-0} = Rt2;
 458 }
 459
 460 // addrmode1 instructions
 461 class AI1<bits<4> opcod, dag oops, dag iops, Format f, InstrItinClass itin,
 462           string opc, string asm, list<dag> pattern>
 463   : I<oops, iops, AddrMode1, Size4Bytes, IndexModeNone, f, itin,
 464       opc, asm, "", pattern> {
 465   let Inst{24-21} = opcod;
 466   let Inst{27-26} = 0b00;
 467 }
 468 class AsI1<bits<4> opcod, dag oops, dag iops, Format f, InstrItinClass itin,
 469            string opc, string asm, list<dag> pattern>
 470   : sI<oops, iops, AddrMode1, Size4Bytes, IndexModeNone, f, itin,
 471        opc, asm, "", pattern> {
 472   let Inst{24-21} = opcod;
 473   let Inst{27-26} = 0b00;
 474 }
 475 class AXI1<bits<4> opcod, dag oops, dag iops, Format f, InstrItinClass itin,
 476            string asm, list<dag> pattern>
 477   : XI<oops, iops, AddrMode1, Size4Bytes, IndexModeNone, f, itin,
 478        asm, "", pattern> {
 479   let Inst{24-21} = opcod;
 480   let Inst{27-26} = 0b00;
 481 }
 482
 483 // loads
 484
 485 // LDR/LDRB/STR/STRB/...
 486 class AI2ldst<bits<3> op, bit isLd, bit isByte, dag oops, dag iops, AddrMode am,
 487              Format f, InstrItinClass itin, string opc, string asm,
 488              list<dag> pattern>
 489   : I<oops, iops, am, Size4Bytes, IndexModeNone, f, itin, opc, asm,
 490       "", pattern> {
 491   let Inst{27-25} = op;
 492   let Inst{24} = 1;  // 24 == P
 493   // 23 == U
 494   let Inst{22} = isByte;
 495   let Inst{21} = 0;  // 21 == W
 496   let Inst{20} = isLd;
 497 }
 498 // Indexed load/stores
 499 class AI2ldstidx<bit isLd, bit isByte, bit isPre, dag oops, dag iops,
 500                 IndexMode im, Format f, InstrItinClass itin, string opc,
 501                 string asm, string cstr, list<dag> pattern>
 502   : I<oops, iops, AddrMode2, Size4Bytes, im, f, itin,
 503       opc, asm, cstr, pattern> {
 504   bits<4> Rt;
 505   let Inst{27-26} = 0b01;
 506   let Inst{24}    = isPre; // P bit
 507   let Inst{22}    = isByte; // B bit
 508   let Inst{21}    = isPre; // W bit
 509   let Inst{20}    = isLd; // L bit
 510   let Inst{15-12} = Rt;
 511 }
 512 class AI2stridx<bit isByte, bit isPre, dag oops, dag iops,
 513                 IndexMode im, Format f, InstrItinClass itin, string opc,
 514                 string asm, string cstr, list<dag> pattern>
 515   : AI2ldstidx<0, isByte, isPre, oops, iops, im, f, itin, opc, asm, cstr,
 516                pattern> {
 517   // AM2 store w/ two operands: (GPR, am2offset)
 518   // {13}     1 == Rm, 0 == imm12
 519   // {12}     isAdd
 520   // {11-0}   imm12/Rm
 521   bits<14> offset;
 522   bits<4> Rn;
 523   let Inst{25} = offset{13};
 524   let Inst{23} = offset{12};
 525   let Inst{19-16} = Rn;
 526   let Inst{11-0} = offset{11-0};
 527 }
 528 // FIXME: Merge with the above class when addrmode2 gets used for STR, STRB
 529 // but for now use this class for STRT and STRBT.
 530 class AI2stridxT<bit isByte, bit isPre, dag oops, dag iops,
 531                 IndexMode im, Format f, InstrItinClass itin, string opc,
 532                 string asm, string cstr, list<dag> pattern>
 533   : AI2ldstidx<0, isByte, isPre, oops, iops, im, f, itin, opc, asm, cstr,
 534                pattern> {
 535   // AM2 store w/ two operands: (GPR, am2offset)
 536   // {17-14}  Rn
 537   // {13}     1 == Rm, 0 == imm12
 538   // {12}     isAdd
 539   // {11-0}   imm12/Rm
 540   bits<18> addr;
 541   let Inst{25} = addr{13};
 542   let Inst{23} = addr{12};
 543   let Inst{19-16} = addr{17-14};
 544   let Inst{11-0} = addr{11-0};
 545 }
 546
 547 // addrmode3 instructions
 548 class AI3ld<bits<4> op, bit op20, dag oops, dag iops, Format f,
 549             InstrItinClass itin, string opc, string asm, list<dag> pattern>
 550   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 551       opc, asm, "", pattern> {
 552   bits<14> addr;
 553   bits<4> Rt;
 554   let Inst{27-25} = 0b000;
 555   let Inst{24}    = 1;            // P bit
 556   let Inst{23}    = addr{8};      // U bit
 557   let Inst{22}    = addr{13};     // 1 == imm8, 0 == Rm
 558   let Inst{21}    = 0;            // W bit
 559   let Inst{20}    = op20;         // L bit
 560   let Inst{19-16} = addr{12-9};   // Rn
 561   let Inst{15-12} = Rt;           // Rt
 562   let Inst{11-8}  = addr{7-4};    // imm7_4/zero
 563   let Inst{7-4}   = op;
 564   let Inst{3-0}   = addr{3-0};    // imm3_0/Rm
 565 }
 566
 567 class AI3ldstidx<bits<4> op, bit op20, bit isLd, bit isPre, dag oops, dag iops,
 568                 IndexMode im, Format f, InstrItinClass itin, string opc,
 569                 string asm, string cstr, list<dag> pattern>
 570   : I<oops, iops, AddrMode3, Size4Bytes, im, f, itin,
 571       opc, asm, cstr, pattern> {
 572   bits<4> Rt;
 573   let Inst{27-25} = 0b000;
 574   let Inst{24}    = isPre;        // P bit
 575   let Inst{21}    = isPre;        // W bit
 576   let Inst{20}    = op20;         // L bit
 577   let Inst{15-12} = Rt;           // Rt
 578   let Inst{7-4}   = op;
 579 }
 580
 581 // FIXME: Merge with the above class when addrmode2 gets used for LDR, LDRB
 582 // but for now use this class for LDRSBT, LDRHT, LDSHT.
 583 class AI3ldstidxT<bits<4> op, bit op20, bit isLd, bit isPre, dag oops, dag iops,
 584                   IndexMode im, Format f, InstrItinClass itin, string opc,
 585                   string asm, string cstr, list<dag> pattern>
 586   : I<oops, iops, AddrMode3, Size4Bytes, im, f, itin,
 587       opc, asm, cstr, pattern> {
 588   // {13}     1 == imm8, 0 == Rm
 589   // {12-9}   Rn
 590   // {8}      isAdd
 591   // {7-4}    imm7_4/zero
 592   // {3-0}    imm3_0/Rm
 593   bits<14> addr;
 594   bits<4> Rt;
 595   let Inst{27-25} = 0b000;
 596   let Inst{24}    = isPre;        // P bit
 597   let Inst{23}    = addr{8};      // U bit
 598   let Inst{22}    = addr{13};     // 1 == imm8, 0 == Rm
 599   let Inst{20}    = op20;         // L bit
 600   let Inst{19-16} = addr{12-9};   // Rn
 601   let Inst{15-12} = Rt;           // Rt
 602   let Inst{11-8}  = addr{7-4};    // imm7_4/zero
 603   let Inst{7-4}   = op;
 604   let Inst{3-0}   = addr{3-0};    // imm3_0/Rm
 605   let AsmMatchConverter = "CvtLdWriteBackRegAddrMode3";
 606 }
 607
 608 class AI3stridx<bits<4> op, bit isByte, bit isPre, dag oops, dag iops,
 609                 IndexMode im, Format f, InstrItinClass itin, string opc,
 610                 string asm, string cstr, list<dag> pattern>
 611   : AI2ldstidx<0, isByte, isPre, oops, iops, im, f, itin, opc, asm, cstr,
 612                pattern> {
 613   // AM3 store w/ two operands: (GPR, am3offset)
 614   bits<14> offset;
 615   bits<4> Rt;
 616   bits<4> Rn;
 617   let Inst{27-25} = 0b000;
 618   let Inst{23}    = offset{8};
 619   let Inst{22}    = offset{9};
 620   let Inst{19-16} = Rn;
 621   let Inst{15-12} = Rt;           // Rt
 622   let Inst{11-8}  = offset{7-4};  // imm7_4/zero
 623   let Inst{7-4}   = op;
 624   let Inst{3-0}   = offset{3-0};  // imm3_0/Rm
 625 }
 626
 627 // stores
 628 class AI3str<bits<4> op, dag oops, dag iops, Format f, InstrItinClass itin,
 629              string opc, string asm, list<dag> pattern>
 630   : I<oops, iops, AddrMode3, Size4Bytes, IndexModeNone, f, itin,
 631       opc, asm, "", pattern> {
 632   bits<14> addr;
 633   bits<4> Rt;
 634   let Inst{27-25} = 0b000;
 635   let Inst{24}    = 1;            // P bit
 636   let Inst{23}    = addr{8};      // U bit
 637   let Inst{22}    = addr{13};     // 1 == imm8, 0 == Rm
 638   let Inst{21}    = 0;            // W bit
 639   let Inst{20}    = 0;            // L bit
 640   let Inst{19-16} = addr{12-9};   // Rn
 641   let Inst{15-12} = Rt;           // Rt
 642   let Inst{11-8}  = addr{7-4};    // imm7_4/zero
 643   let Inst{7-4}   = op;
 644   let Inst{3-0}   = addr{3-0};    // imm3_0/Rm
 645 }
 646
 647 // Pre-indexed stores
 648 class AI3sthpr<dag oops, dag iops, Format f, InstrItinClass itin,
 649                string opc, string asm, string cstr, list<dag> pattern>
 650   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 651       opc, asm, cstr, pattern> {
 652   let Inst{4}     = 1;
 653   let Inst{5}     = 1; // H bit
 654   let Inst{6}     = 0; // S bit
 655   let Inst{7}     = 1;
 656   let Inst{20}    = 0; // L bit
 657   let Inst{21}    = 1; // W bit
 658   let Inst{24}    = 1; // P bit
 659   let Inst{27-25} = 0b000;
 660 }
 661 class AI3stdpr<dag oops, dag iops, Format f, InstrItinClass itin,
 662              string opc, string asm, string cstr, list<dag> pattern>
 663   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePre, f, itin,
 664       opc, asm, cstr, pattern> {
 665   let Inst{4}     = 1;
 666   let Inst{5}     = 1; // H bit
 667   let Inst{6}     = 1; // S bit
 668   let Inst{7}     = 1;
 669   let Inst{20}    = 0; // L bit
 670   let Inst{21}    = 1; // W bit
 671   let Inst{24}    = 1; // P bit
 672   let Inst{27-25} = 0b000;
 673 }
 674
 675 // Post-indexed stores
 676 class AI3sthpo<dag oops, dag iops, Format f, InstrItinClass itin,
 677                string opc, string asm, string cstr, list<dag> pattern>
 678   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 679       opc, asm, cstr,pattern> {
 680   // {13}     1 == imm8, 0 == Rm
 681   // {12-9}   Rn
 682   // {8}      isAdd
 683   // {7-4}    imm7_4/zero
 684   // {3-0}    imm3_0/Rm
 685   bits<14> addr;
 686   bits<4> Rt;
 687   let Inst{3-0}   = addr{3-0};    // imm3_0/Rm
 688   let Inst{4}     = 1;
 689   let Inst{5}     = 1; // H bit
 690   let Inst{6}     = 0; // S bit
 691   let Inst{7}     = 1;
 692   let Inst{11-8}  = addr{7-4};    // imm7_4/zero
 693   let Inst{15-12} = Rt;           // Rt
 694   let Inst{19-16} = addr{12-9};   // Rn
 695   let Inst{20}    = 0; // L bit
 696   let Inst{21}    = 0; // W bit
 697   let Inst{22}    = addr{13};     // 1 == imm8, 0 == Rm
 698   let Inst{23}    = addr{8};      // U bit
 699   let Inst{24}    = 0; // P bit
 700   let Inst{27-25} = 0b000;
 701 }
 702 class AI3stdpo<dag oops, dag iops, Format f, InstrItinClass itin,
 703              string opc, string asm, string cstr, list<dag> pattern>
 704   : I<oops, iops, AddrMode3, Size4Bytes, IndexModePost, f, itin,
 705       opc, asm, cstr, pattern> {
 706   let Inst{4}     = 1;
 707   let Inst{5}     = 1; // H bit
 708   let Inst{6}     = 1; // S bit
 709   let Inst{7}     = 1;
 710   let Inst{20}    = 0; // L bit
 711   let Inst{21}    = 0; // W bit
 712   let Inst{24}    = 0; // P bit
 713   let Inst{27-25} = 0b000;
 714 }
 715
 716 // addrmode4 instructions
 717 class AXI4<dag oops, dag iops, IndexMode im, Format f, InstrItinClass itin,
 718            string asm, string cstr, list<dag> pattern>
 719   : XI<oops, iops, AddrMode4, Size4Bytes, im, f, itin, asm, cstr, pattern> {
 720   bits<4>  p;
 721   bits<16> regs;
 722   bits<4>  Rn;
 723   let Inst{31-28} = p;
 724   let Inst{27-25} = 0b100;
 725   let Inst{22}    = 0; // S bit
 726   let Inst{19-16} = Rn;
 727   let Inst{15-0}  = regs;
 728 }
 729
 730 // Unsigned multiply, multiply-accumulate instructions.
 731 class AMul1I<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 732              string opc, string asm, list<dag> pattern>
 733   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 734       opc, asm, "", pattern> {
 735   let Inst{7-4}   = 0b1001;
 736   let Inst{20}    = 0; // S bit
 737   let Inst{27-21} = opcod;
 738 }
 739 class AsMul1I<bits<7> opcod, dag oops, dag iops, InstrItinClass itin,
 740               string opc, string asm, list<dag> pattern>
 741   : sI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 742        opc, asm, "", pattern> {
 743   let Inst{7-4}   = 0b1001;
 744   let Inst{27-21} = opcod;
 745 }
 746
 747 // Most significant word multiply
 748 class AMul2I<bits<7> opcod, bits<4> opc7_4, dag oops, dag iops,
 749              InstrItinClass itin, string opc, string asm, list<dag> pattern>
 750   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 751       opc, asm, "", pattern> {
 752   bits<4> Rd;
 753   bits<4> Rn;
 754   bits<4> Rm;
 755   let Inst{7-4}   = opc7_4;
 756   let Inst{20}    = 1;
 757   let Inst{27-21} = opcod;
 758   let Inst{19-16} = Rd;
 759   let Inst{11-8}  = Rm;
 760   let Inst{3-0}   = Rn;
 761 }
 762 // MSW multiple w/ Ra operand
 763 class AMul2Ia<bits<7> opcod, bits<4> opc7_4, dag oops, dag iops,
 764               InstrItinClass itin, string opc, string asm, list<dag> pattern>
 765   : AMul2I<opcod, opc7_4, oops, iops, itin, opc, asm, pattern> {
 766   bits<4> Ra;
 767   let Inst{15-12} = Ra;
 768 }
 769
 770 // SMUL<x><y> / SMULW<y> / SMLA<x><y> / SMLAW<x><y>
 771 class AMulxyIbase<bits<7> opcod, bits<2> bit6_5, dag oops, dag iops,
 772               InstrItinClass itin, string opc, string asm, list<dag> pattern>
 773   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, MulFrm, itin,
 774       opc, asm, "", pattern> {
 775   bits<4> Rn;
 776   bits<4> Rm;
 777   let Inst{4}     = 0;
 778   let Inst{7}     = 1;
 779   let Inst{20}    = 0;
 780   let Inst{27-21} = opcod;
 781   let Inst{6-5}   = bit6_5;
 782   let Inst{11-8}  = Rm;
 783   let Inst{3-0}   = Rn;
 784 }
 785 class AMulxyI<bits<7> opcod, bits<2> bit6_5, dag oops, dag iops,
 786               InstrItinClass itin, string opc, string asm, list<dag> pattern>
 787   : AMulxyIbase<opcod, bit6_5, oops, iops, itin, opc, asm, pattern> {
 788   bits<4> Rd;
 789   let Inst{19-16} = Rd;
 790 }
 791
 792 // AMulxyI with Ra operand
 793 class AMulxyIa<bits<7> opcod, bits<2> bit6_5, dag oops, dag iops,
 794               InstrItinClass itin, string opc, string asm, list<dag> pattern>
 795   : AMulxyI<opcod, bit6_5, oops, iops, itin, opc, asm, pattern> {
 796   bits<4> Ra;
 797   let Inst{15-12} = Ra;
 798 }
 799 // SMLAL*
 800 class AMulxyI64<bits<7> opcod, bits<2> bit6_5, dag oops, dag iops,
 801               InstrItinClass itin, string opc, string asm, list<dag> pattern>
 802   : AMulxyIbase<opcod, bit6_5, oops, iops, itin, opc, asm, pattern> {
 803   bits<4> RdLo;
 804   bits<4> RdHi;
 805   let Inst{19-16} = RdHi;
 806   let Inst{15-12} = RdLo;
 807 }
 808
 809 // Extend instructions.
 810 class AExtI<bits<8> opcod, dag oops, dag iops, InstrItinClass itin,
 811             string opc, string asm, list<dag> pattern>
 812   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, ExtFrm, itin,
 813       opc, asm, "", pattern> {
 814   // All AExtI instructions have Rd and Rm register operands.
 815   bits<4> Rd;
 816   bits<4> Rm;
 817   let Inst{15-12} = Rd;
 818   let Inst{3-0}   = Rm;
 819   let Inst{7-4}   = 0b0111;
 820   let Inst{9-8}   = 0b00;
 821   let Inst{27-20} = opcod;
 822 }
 823
 824 // Misc Arithmetic instructions.
 825 class AMiscA1I<bits<8> opcod, bits<4> opc7_4, dag oops, dag iops,
 826                InstrItinClass itin, string opc, string asm, list<dag> pattern>
 827   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, ArithMiscFrm, itin,
 828       opc, asm, "", pattern> {
 829   bits<4> Rd;
 830   bits<4> Rm;
 831   let Inst{27-20} = opcod;
 832   let Inst{19-16} = 0b1111;
 833   let Inst{15-12} = Rd;
 834   let Inst{11-8}  = 0b1111;
 835   let Inst{7-4}   = opc7_4;
 836   let Inst{3-0}   = Rm;
 837 }
 838
 839 // PKH instructions
 840 class APKHI<bits<8> opcod, bit tb, dag oops, dag iops, InstrItinClass itin,
 841             string opc, string asm, list<dag> pattern>
 842   : I<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, ArithMiscFrm, itin,
 843       opc, asm, "", pattern> {
 844   bits<4> Rd;
 845   bits<4> Rn;
 846   bits<4> Rm;
 847   bits<8> sh;
 848   let Inst{27-20} = opcod;
 849   let Inst{19-16} = Rn;
 850   let Inst{15-12} = Rd;
 851   let Inst{11-7}  = sh{7-3};
 852   let Inst{6}     = tb;
 853   let Inst{5-4}   = 0b01;
 854   let Inst{3-0}   = Rm;
 855 }
 856
 857 //===----------------------------------------------------------------------===//
 858
 859 // ARMPat - Same as Pat<>, but requires that the compiler be in ARM mode.
 860 class ARMPat<dag pattern, dag result> : Pat<pattern, result> {
 861   list<Predicate> Predicates = [IsARM];
 862 }
 863 class ARMV5TPat<dag pattern, dag result> : Pat<pattern, result> {
 864   list<Predicate> Predicates = [IsARM, HasV5T];
 865 }
 866 class ARMV5TEPat<dag pattern, dag result> : Pat<pattern, result> {
 867   list<Predicate> Predicates = [IsARM, HasV5TE];
 868 }
 869 class ARMV6Pat<dag pattern, dag result> : Pat<pattern, result> {
 870   list<Predicate> Predicates = [IsARM, HasV6];
 871 }
 872
 873 //===----------------------------------------------------------------------===//
 874 // Thumb Instruction Format Definitions.
 875 //
 876
 877 class ThumbI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 878              InstrItinClass itin, string asm, string cstr, list<dag> pattern>
 879   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
 880   let OutOperandList = oops;
 881   let InOperandList = iops;
 882   let AsmString = asm;
 883   let Pattern = pattern;
 884   list<Predicate> Predicates = [IsThumb];
 885 }
 886
 887 // TI - Thumb instruction.
 888 class TI<dag oops, dag iops, InstrItinClass itin, string asm, list<dag> pattern>
 889   : ThumbI<oops, iops, AddrModeNone, Size2Bytes, itin, asm, "", pattern>;
 890
 891 // Two-address instructions
 892 class TIt<dag oops, dag iops, InstrItinClass itin, string asm,
 893           list<dag> pattern>
 894   : ThumbI<oops, iops, AddrModeNone, Size2Bytes, itin, asm, "$lhs = $dst",
 895            pattern>;
 896
 897 // tBL, tBX 32-bit instructions
 898 class TIx2<bits<5> opcod1, bits<2> opcod2, bit opcod3,
 899            dag oops, dag iops, InstrItinClass itin, string asm,
 900            list<dag> pattern>
 901     : ThumbI<oops, iops, AddrModeNone, Size4Bytes, itin, asm, "", pattern>,
 902       Encoding {
 903   let Inst{31-27} = opcod1;
 904   let Inst{15-14} = opcod2;
 905   let Inst{12}    = opcod3;
 906 }
 907
 908 // Move to/from coprocessor instructions
 909 class T1Cop<dag oops, dag iops, string asm, list<dag> pattern>
 910   : ThumbI<oops, iops, AddrModeNone, Size4Bytes, NoItinerary, asm, "", pattern>,
 911     Encoding, Requires<[IsThumb, HasV6]> {
 912   let Inst{31-28} = 0b1110;
 913 }
 914
 915 // BR_JT instructions
 916 class TJTI<dag oops, dag iops, InstrItinClass itin, string asm,
 917            list<dag> pattern>
 918   : ThumbI<oops, iops, AddrModeNone, SizeSpecial, itin, asm, "", pattern>;
 919
 920 // Thumb1 only
 921 class Thumb1I<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 922               InstrItinClass itin, string asm, string cstr, list<dag> pattern>
 923   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
 924   let OutOperandList = oops;
 925   let InOperandList = iops;
 926   let AsmString = asm;
 927   let Pattern = pattern;
 928   list<Predicate> Predicates = [IsThumb, IsThumb1Only];
 929 }
 930
 931 class T1I<dag oops, dag iops, InstrItinClass itin,
 932           string asm, list<dag> pattern>
 933   : Thumb1I<oops, iops, AddrModeNone, Size2Bytes, itin, asm, "", pattern>;
 934 class T1Ix2<dag oops, dag iops, InstrItinClass itin,
 935             string asm, list<dag> pattern>
 936   : Thumb1I<oops, iops, AddrModeNone, Size4Bytes, itin, asm, "", pattern>;
 937
 938 // Two-address instructions
 939 class T1It<dag oops, dag iops, InstrItinClass itin,
 940            string asm, string cstr, list<dag> pattern>
 941   : Thumb1I<oops, iops, AddrModeNone, Size2Bytes, itin,
 942             asm, cstr, pattern>;
 943
 944 // Thumb1 instruction that can either be predicated or set CPSR.
 945 class Thumb1sI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 946                InstrItinClass itin,
 947                string opc, string asm, string cstr, list<dag> pattern>
 948   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
 949   let OutOperandList = !con(oops, (outs s_cc_out:$s));
 950   let InOperandList = !con(iops, (ins pred:$p));
 951   let AsmString = !strconcat(opc, "${s}${p}", asm);
 952   let Pattern = pattern;
 953   list<Predicate> Predicates = [IsThumb, IsThumb1Only];
 954 }
 955
 956 class T1sI<dag oops, dag iops, InstrItinClass itin,
 957            string opc, string asm, list<dag> pattern>
 958   : Thumb1sI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm, "", pattern>;
 959
 960 // Two-address instructions
 961 class T1sIt<dag oops, dag iops, InstrItinClass itin,
 962             string opc, string asm, list<dag> pattern>
 963   : Thumb1sI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm,
 964              "$Rn = $Rdn", pattern>;
 965
 966 // Thumb1 instruction that can be predicated.
 967 class Thumb1pI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
 968                InstrItinClass itin,
 969                string opc, string asm, string cstr, list<dag> pattern>
 970   : InstThumb<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
 971   let OutOperandList = oops;
 972   let InOperandList = !con(iops, (ins pred:$p));
 973   let AsmString = !strconcat(opc, "${p}", asm);
 974   let Pattern = pattern;
 975   list<Predicate> Predicates = [IsThumb, IsThumb1Only];
 976 }
 977
 978 class T1pI<dag oops, dag iops, InstrItinClass itin,
 979            string opc, string asm, list<dag> pattern>
 980   : Thumb1pI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm, "", pattern>;
 981
 982 // Two-address instructions
 983 class T1pIt<dag oops, dag iops, InstrItinClass itin,
 984             string opc, string asm, list<dag> pattern>
 985   : Thumb1pI<oops, iops, AddrModeNone, Size2Bytes, itin, opc, asm,
 986              "$Rn = $Rdn", pattern>;
 987
 988 class T1pIs<dag oops, dag iops,
 989             InstrItinClass itin, string opc, string asm, list<dag> pattern>
 990   : Thumb1pI<oops, iops, AddrModeT1_s, Size2Bytes, itin, opc, asm, "", pattern>;
 991
 992 class Encoding16 : Encoding {
 993   let Inst{31-16} = 0x0000;
 994 }
 995
 996 // A6.2 16-bit Thumb instruction encoding
 997 class T1Encoding<bits<6> opcode> : Encoding16 {
 998   let Inst{15-10} = opcode;
 999 }
1000
1001 // A6.2.1 Shift (immediate), add, subtract, move, and compare encoding.
1002 class T1General<bits<5> opcode> : Encoding16 {
1003   let Inst{15-14} = 0b00;
1004   let Inst{13-9} = opcode;
1005 }
1006
1007 // A6.2.2 Data-processing encoding.
1008 class T1DataProcessing<bits<4> opcode> : Encoding16 {
1009   let Inst{15-10} = 0b010000;
1010   let Inst{9-6} = opcode;
1011 }
1012
1013 // A6.2.3 Special data instructions and branch and exchange encoding.
1014 class T1Special<bits<4> opcode> : Encoding16 {
1015   let Inst{15-10} = 0b010001;
1016   let Inst{9-6}   = opcode;
1017 }
1018
1019 // A6.2.4 Load/store single data item encoding.
1020 class T1LoadStore<bits<4> opA, bits<3> opB> : Encoding16 {
1021   let Inst{15-12} = opA;
1022   let Inst{11-9}  = opB;
1023 }
1024 class T1LdStSP<bits<3> opB>   : T1LoadStore<0b1001, opB>; // SP relative
1025
1026 // Helper classes to encode Thumb1 loads and stores. For immediates, the
1027 // following bits are used for "opA" (see A6.2.4):
1028 //
1029 //   0b0110 => Immediate, 4 bytes
1030 //   0b1000 => Immediate, 2 bytes
1031 //   0b0111 => Immediate, 1 byte
1032 class T1pILdStEncode<bits<3> opcode, dag oops, dag iops, AddrMode am,
1033                      InstrItinClass itin, string opc, string asm,
1034                      list<dag> pattern>
1035   : Thumb1pI<oops, iops, am, Size2Bytes, itin, opc, asm, "", pattern>,
1036     T1LoadStore<0b0101, opcode> {
1037   bits<3> Rt;
1038   bits<8> addr;
1039   let Inst{8-6} = addr{5-3};    // Rm
1040   let Inst{5-3} = addr{2-0};    // Rn
1041   let Inst{2-0} = Rt;
1042 }
1043 class T1pILdStEncodeImm<bits<4> opA, bit opB, dag oops, dag iops, AddrMode am,
1044                         InstrItinClass itin, string opc, string asm,
1045                         list<dag> pattern>
1046   : Thumb1pI<oops, iops, am, Size2Bytes, itin, opc, asm, "", pattern>,
1047     T1LoadStore<opA, {opB,?,?}> {
1048   bits<3> Rt;
1049   bits<8> addr;
1050   let Inst{10-6} = addr{7-3};   // imm5
1051   let Inst{5-3}  = addr{2-0};   // Rn
1052   let Inst{2-0}  = Rt;
1053 }
1054
1055 // A6.2.5 Miscellaneous 16-bit instructions encoding.
1056 class T1Misc<bits<7> opcode> : Encoding16 {
1057   let Inst{15-12} = 0b1011;
1058   let Inst{11-5} = opcode;
1059 }
1060
1061 // Thumb2I - Thumb2 instruction. Almost all Thumb2 instructions are predicable.
1062 class Thumb2I<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1063               InstrItinClass itin,
1064               string opc, string asm, string cstr, list<dag> pattern>
1065   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1066   let OutOperandList = oops;
1067   let InOperandList = !con(iops, (ins pred:$p));
1068   let AsmString = !strconcat(opc, "${p}", asm);
1069   let Pattern = pattern;
1070   list<Predicate> Predicates = [IsThumb2];
1071 }
1072
1073 // Same as Thumb2I except it can optionally modify CPSR. Note it's modeled as an
1074 // input operand since by default it's a zero register. It will become an
1075 // implicit def once it's "flipped".
1076 //
1077 // FIXME: This uses unified syntax so {s} comes before {p}. We should make it
1078 // more consistent.
1079 class Thumb2sI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1080                InstrItinClass itin,
1081                string opc, string asm, string cstr, list<dag> pattern>
1082   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1083   bits<1> s; // condition-code set flag ('1' if the insn should set the flags)
1084   let Inst{20} = s;
1085
1086   let OutOperandList = oops;
1087   let InOperandList = !con(iops, (ins pred:$p, cc_out:$s));
1088   let AsmString = !strconcat(opc, "${s}${p}", asm);
1089   let Pattern = pattern;
1090   list<Predicate> Predicates = [IsThumb2];
1091 }
1092
1093 // Special cases
1094 class Thumb2XI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1095                InstrItinClass itin,
1096                string asm, string cstr, list<dag> pattern>
1097   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1098   let OutOperandList = oops;
1099   let InOperandList = iops;
1100   let AsmString = asm;
1101   let Pattern = pattern;
1102   list<Predicate> Predicates = [IsThumb2];
1103 }
1104
1105 class ThumbXI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1106               InstrItinClass itin,
1107               string asm, string cstr, list<dag> pattern>
1108   : InstARM<am, sz, IndexModeNone, ThumbFrm, GenericDomain, cstr, itin> {
1109   let OutOperandList = oops;
1110   let InOperandList = iops;
1111   let AsmString = asm;
1112   let Pattern = pattern;
1113   list<Predicate> Predicates = [IsThumb, IsThumb1Only];
1114 }
1115
1116 class T2I<dag oops, dag iops, InstrItinClass itin,
1117           string opc, string asm, list<dag> pattern>
1118   : Thumb2I<oops, iops, AddrModeNone, Size4Bytes, itin, opc, asm, "", pattern>;
1119 class T2Ii12<dag oops, dag iops, InstrItinClass itin,
1120              string opc, string asm, list<dag> pattern>
1121   : Thumb2I<oops, iops, AddrModeT2_i12, Size4Bytes, itin, opc, asm, "",pattern>;
1122 class T2Ii8<dag oops, dag iops, InstrItinClass itin,
1123             string opc, string asm, list<dag> pattern>
1124   : Thumb2I<oops, iops, AddrModeT2_i8, Size4Bytes, itin, opc, asm, "", pattern>;
1125 class T2Iso<dag oops, dag iops, InstrItinClass itin,
1126             string opc, string asm, list<dag> pattern>
1127   : Thumb2I<oops, iops, AddrModeT2_so, Size4Bytes, itin, opc, asm, "", pattern>;
1128 class T2Ipc<dag oops, dag iops, InstrItinClass itin,
1129             string opc, string asm, list<dag> pattern>
1130   : Thumb2I<oops, iops, AddrModeT2_pc, Size4Bytes, itin, opc, asm, "", pattern>;
1131 class T2Ii8s4<bit P, bit W, bit isLoad, dag oops, dag iops, InstrItinClass itin,
1132               string opc, string asm, list<dag> pattern>
1133   : Thumb2I<oops, iops, AddrModeT2_i8s4, Size4Bytes, itin, opc, asm, "",
1134             pattern> {
1135   bits<4> Rt;
1136   bits<4> Rt2;
1137   bits<13> addr;
1138   let Inst{31-25} = 0b1110100;
1139   let Inst{24}    = P;
1140   let Inst{23}    = addr{8};
1141   let Inst{22}    = 1;
1142   let Inst{21}    = W;
1143   let Inst{20}    = isLoad;
1144   let Inst{19-16} = addr{12-9};
1145   let Inst{15-12} = Rt{3-0};
1146   let Inst{11-8}  = Rt2{3-0};
1147   let Inst{7-0}   = addr{7-0};
1148 }
1149
1150 class T2sI<dag oops, dag iops, InstrItinClass itin,
1151            string opc, string asm, list<dag> pattern>
1152   : Thumb2sI<oops, iops, AddrModeNone, Size4Bytes, itin, opc, asm, "", pattern>;
1153
1154 class T2XI<dag oops, dag iops, InstrItinClass itin,
1155            string asm, list<dag> pattern>
1156   : Thumb2XI<oops, iops, AddrModeNone, Size4Bytes, itin, asm, "", pattern>;
1157 class T2JTI<dag oops, dag iops, InstrItinClass itin,
1158             string asm, list<dag> pattern>
1159   : Thumb2XI<oops, iops, AddrModeNone, SizeSpecial, itin, asm, "", pattern>;
1160
1161 // Move to/from coprocessor instructions
1162 class T2Cop<dag oops, dag iops, string asm, list<dag> pattern>
1163   : T2XI<oops, iops, NoItinerary, asm, pattern>, Requires<[IsThumb2, HasV6]> {
1164   let Inst{31-28} = 0b1111;
1165 }
1166
1167 // Two-address instructions
1168 class T2XIt<dag oops, dag iops, InstrItinClass itin,
1169             string asm, string cstr, list<dag> pattern>
1170   : Thumb2XI<oops, iops, AddrModeNone, Size4Bytes, itin, asm, cstr, pattern>;
1171
1172 // T2Iidxldst - Thumb2 indexed load / store instructions.
1173 class T2Iidxldst<bit signed, bits<2> opcod, bit load, bit pre,
1174                  dag oops, dag iops,
1175                  AddrMode am, IndexMode im, InstrItinClass itin,
1176                  string opc, string asm, string cstr, list<dag> pattern>
1177   : InstARM<am, Size4Bytes, im, ThumbFrm, GenericDomain, cstr, itin> {
1178   let OutOperandList = oops;
1179   let InOperandList = !con(iops, (ins pred:$p));
1180   let AsmString = !strconcat(opc, "${p}", asm);
1181   let Pattern = pattern;
1182   list<Predicate> Predicates = [IsThumb2];
1183   let Inst{31-27} = 0b11111;
1184   let Inst{26-25} = 0b00;
1185   let Inst{24}    = signed;
1186   let Inst{23}    = 0;
1187   let Inst{22-21} = opcod;
1188   let Inst{20}    = load;
1189   let Inst{11}    = 1;
1190   // (P, W) = (1, 1) Pre-indexed or (0, 1) Post-indexed
1191   let Inst{10}    = pre; // The P bit.
1192   let Inst{8}     = 1; // The W bit.
1193
1194   bits<9> addr;
1195   let Inst{7-0} = addr{7-0};
1196   let Inst{9}   = addr{8}; // Sign bit
1197
1198   bits<4> Rt;
1199   bits<4> Rn;
1200   let Inst{15-12} = Rt{3-0};
1201   let Inst{19-16} = Rn{3-0};
1202 }
1203
1204 // Tv5Pat - Same as Pat<>, but requires V5T Thumb mode.
1205 class Tv5Pat<dag pattern, dag result> : Pat<pattern, result> {
1206   list<Predicate> Predicates = [IsThumb, IsThumb1Only, HasV5T];
1207 }
1208
1209 // T1Pat - Same as Pat<>, but requires that the compiler be in Thumb1 mode.
1210 class T1Pat<dag pattern, dag result> : Pat<pattern, result> {
1211   list<Predicate> Predicates = [IsThumb, IsThumb1Only];
1212 }
1213
1214 // T2v6Pat - Same as Pat<>, but requires V6T2 Thumb2 mode.
1215 class T2v6Pat<dag pattern, dag result> : Pat<pattern, result> {
1216   list<Predicate> Predicates = [IsThumb2, HasV6T2];
1217 }
1218
1219 // T2Pat - Same as Pat<>, but requires that the compiler be in Thumb2 mode.
1220 class T2Pat<dag pattern, dag result> : Pat<pattern, result> {
1221   list<Predicate> Predicates = [IsThumb2];
1222 }
1223
1224 //===----------------------------------------------------------------------===//
1225
1226 //===----------------------------------------------------------------------===//
1227 // ARM VFP Instruction templates.
1228 //
1229
1230 // Almost all VFP instructions are predicable.
1231 class VFPI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1232            IndexMode im, Format f, InstrItinClass itin,
1233            string opc, string asm, string cstr, list<dag> pattern>
1234   : InstARM<am, sz, im, f, VFPDomain, cstr, itin> {
1235   bits<4> p;
1236   let Inst{31-28} = p;
1237   let OutOperandList = oops;
1238   let InOperandList = !con(iops, (ins pred:$p));
1239   let AsmString = !strconcat(opc, "${p}", asm);
1240   let Pattern = pattern;
1241   let PostEncoderMethod = "VFPThumb2PostEncoder";
1242   list<Predicate> Predicates = [HasVFP2];
1243 }
1244
1245 // Special cases
1246 class VFPXI<dag oops, dag iops, AddrMode am, SizeFlagVal sz,
1247             IndexMode im, Format f, InstrItinClass itin,
1248             string asm, string cstr, list<dag> pattern>
1249   : InstARM<am, sz, im, f, VFPDomain, cstr, itin> {
1250   bits<4> p;
1251   let Inst{31-28} = p;
1252   let OutOperandList = oops;
1253   let InOperandList = iops;
1254   let AsmString = asm;
1255   let Pattern = pattern;
1256   let PostEncoderMethod = "VFPThumb2PostEncoder";
1257   list<Predicate> Predicates = [HasVFP2];
1258 }
1259
1260 class VFPAI<dag oops, dag iops, Format f, InstrItinClass itin,
1261             string opc, string asm, list<dag> pattern>
1262   : VFPI<oops, iops, AddrModeNone, Size4Bytes, IndexModeNone, f, itin,
1263          opc, asm, "", pattern> {
1264   let PostEncoderMethod = "VFPThumb2PostEncoder";
1265 }
1266
1267 // ARM VFP addrmode5 loads and stores
1268 class ADI5<bits<4> opcod1, bits<2> opcod2, dag oops, dag iops,
1269            InstrItinClass itin,
1270            string opc, string asm, list<dag> pattern>
1271   : VFPI<oops, iops, AddrMode5, Size4Bytes, IndexModeNone,
1272          VFPLdStFrm, itin, opc, asm, "", pattern> {
1273   // Instruction operands.
1274   bits<5>  Dd;
1275   bits<13> addr;
1276
1277   // Encode instruction operands.
1278   let Inst{23}    = addr{8};      // U (add = (U == '1'))
1279   let Inst{22}    = Dd{4};
1280   let Inst{19-16} = addr{12-9};   // Rn
1281   let Inst{15-12} = Dd{3-0};
1282   let Inst{7-0}   = addr{7-0};    // imm8
1283
1284   // TODO: Mark the instructions with the appropriate subtarget info.
1285   let Inst{27-24} = opcod1;
1286   let Inst{21-20} = opcod2;
1287   let Inst{11-9}  = 0b101;
1288   let Inst{8}     = 1;          // Double precision
1289
1290   // Loads & stores operate on both NEON and VFP pipelines.
1291   let D = VFPNeonDomain;
1292 }
1293
1294 class ASI5<bits<4> opcod1, bits<2> opcod2, dag oops, dag iops,
1295            InstrItinClass itin,
1296            string opc, string asm, list<dag> pattern>
1297   : VFPI<oops, iops, AddrMode5, Size4Bytes, IndexModeNone,
1298          VFPLdStFrm, itin, opc, asm, "", pattern> {
1299   // Instruction operands.
1300   bits<5>  Sd;
1301   bits<13> addr;
1302
1303   // Encode instruction operands.
1304   let Inst{23}    = addr{8};      // U (add = (U == '1'))
1305   let Inst{22}    = Sd{0};
1306   let Inst{19-16} = addr{12-9};   // Rn
1307   let Inst{15-12} = Sd{4-1};
1308   let Inst{7-0}   = addr{7-0};    // imm8
1309
1310   // TODO: Mark the instructions with the appropriate subtarget info.
1311   let Inst{27-24} = opcod1;
1312   let Inst{21-20} = opcod2;
1313   let Inst{11-9}  = 0b101;
1314   let Inst{8}     = 0;          // Single precision
1315
1316   // Loads & stores operate on both NEON and VFP pipelines.
1317   let D = VFPNeonDomain;
1318 }
1319
1320 // VFP Load / store multiple pseudo instructions.
1321 class PseudoVFPLdStM<dag oops, dag iops, InstrItinClass itin, string cstr,
1322                      list<dag> pattern>
1323   : InstARM<AddrMode4, Size4Bytes, IndexModeNone, Pseudo, VFPNeonDomain,
1324             cstr, itin> {
1325   let OutOperandList = oops;
1326   let InOperandList = !con(iops, (ins pred:$p));
1327   let Pattern = pattern;
1328   list<Predicate> Predicates = [HasVFP2];
1329 }
1330
1331 // Load / store multiple
1332 class AXDI4<dag oops, dag iops, IndexMode im, InstrItinClass itin,
1333             string asm, string cstr, list<dag> pattern>
1334   : VFPXI<oops, iops, AddrMode4, Size4Bytes, im,
1335           VFPLdStMulFrm, itin, asm, cstr, pattern> {
1336   // Instruction operands.
1337   bits<4>  Rn;
1338   bits<13> regs;
1339
1340   // Encode instruction operands.
1341   let Inst{19-16} = Rn;
1342   let Inst{22}    = regs{12};
1343   let Inst{15-12} = regs{11-8};
1344   let Inst{7-0}   = regs{7-0};
1345
1346   // TODO: Mark the instructions with the appropriate subtarget info.
1347   let Inst{27-25} = 0b110;
1348   let Inst{11-9}  = 0b101;
1349   let Inst{8}     = 1;          // Double precision
1350 }
1351
1352 class AXSI4<dag oops, dag iops, IndexMode im, InstrItinClass itin,
1353             string asm, string cstr, list<dag> pattern>
1354   : VFPXI<oops, iops, AddrMode4, Size4Bytes, im,
1355           VFPLdStMulFrm, itin, asm, cstr, pattern> {
1356   // Instruction operands.
1357   bits<4> Rn;
1358   bits<13> regs;
1359
1360   // Encode instruction operands.
1361   let Inst{19-16} = Rn;
1362   let Inst{22}    = regs{8};
1363   let Inst{15-12} = regs{12-9};
1364   let Inst{7-0}   = regs{7-0};
1365
1366   // TODO: Mark the instructions with the appropriate subtarget info.
1367   let Inst{27-25} = 0b110;
1368   let Inst{11-9}  = 0b101;
1369   let Inst{8}     = 0;          // Single precision
1370 }
1371
1372 // Double precision, unary
1373 class ADuI<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<2> opcod4,
1374            bit opcod5, dag oops, dag iops, InstrItinClass itin, string opc,
1375            string asm, list<dag> pattern>
1376   : VFPAI<oops, iops, VFPUnaryFrm, itin, opc, asm, pattern> {
1377   // Instruction operands.
1378   bits<5> Dd;
1379   bits<5> Dm;
1380
1381   // Encode instruction operands.
1382   let Inst{3-0}   = Dm{3-0};
1383   let Inst{5}     = Dm{4};
1384   let Inst{15-12} = Dd{3-0};
1385   let Inst{22}    = Dd{4};
1386
1387   let Inst{27-23} = opcod1;
1388   let Inst{21-20} = opcod2;
1389   let Inst{19-16} = opcod3;
1390   let Inst{11-9}  = 0b101;
1391   let Inst{8}     = 1;          // Double precision
1392   let Inst{7-6}   = opcod4;
1393   let Inst{4}     = opcod5;
1394 }
1395
1396 // Double precision, binary
1397 class ADbI<bits<5> opcod1, bits<2> opcod2, bit op6, bit op4, dag oops,
1398            dag iops, InstrItinClass itin, string opc, string asm,
1399            list<dag> pattern>
1400   : VFPAI<oops, iops, VFPBinaryFrm, itin, opc, asm, pattern> {
1401   // Instruction operands.
1402   bits<5> Dd;
1403   bits<5> Dn;
1404   bits<5> Dm;
1405
1406   // Encode instruction operands.
1407   let Inst{3-0}   = Dm{3-0};
1408   let Inst{5}     = Dm{4};
1409   let Inst{19-16} = Dn{3-0};
1410   let Inst{7}     = Dn{4};
1411   let Inst{15-12} = Dd{3-0};
1412   let Inst{22}    = Dd{4};
1413
1414   let Inst{27-23} = opcod1;
1415   let Inst{21-20} = opcod2;
1416   let Inst{11-9}  = 0b101;
1417   let Inst{8}     = 1;          // Double precision
1418   let Inst{6}     = op6;
1419   let Inst{4}     = op4;
1420 }
1421
1422 // Single precision, unary
1423 class ASuI<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<2> opcod4,
1424            bit opcod5, dag oops, dag iops, InstrItinClass itin, string opc,
1425            string asm, list<dag> pattern>
1426   : VFPAI<oops, iops, VFPUnaryFrm, itin, opc, asm, pattern> {
1427   // Instruction operands.
1428   bits<5> Sd;
1429   bits<5> Sm;
1430
1431   // Encode instruction operands.
1432   let Inst{3-0}   = Sm{4-1};
1433   let Inst{5}     = Sm{0};
1434   let Inst{15-12} = Sd{4-1};
1435   let Inst{22}    = Sd{0};
1436
1437   let Inst{27-23} = opcod1;
1438   let Inst{21-20} = opcod2;
1439   let Inst{19-16} = opcod3;
1440   let Inst{11-9}  = 0b101;
1441   let Inst{8}     = 0;          // Single precision
1442   let Inst{7-6}   = opcod4;
1443   let Inst{4}     = opcod5;
1444 }
1445
1446 // Single precision unary, if no NEON. Same as ASuI except not available if
1447 // NEON is enabled.
1448 class ASuIn<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<2> opcod4,
1449             bit opcod5, dag oops, dag iops, InstrItinClass itin, string opc,
1450             string asm, list<dag> pattern>
1451   : ASuI<opcod1, opcod2, opcod3, opcod4, opcod5, oops, iops, itin, opc, asm,
1452          pattern> {
1453   list<Predicate> Predicates = [HasVFP2,DontUseNEONForFP];
1454 }
1455
1456 // Single precision, binary
1457 class ASbI<bits<5> opcod1, bits<2> opcod2, bit op6, bit op4, dag oops, dag iops,
1458            InstrItinClass itin, string opc, string asm, list<dag> pattern>
1459   : VFPAI<oops, iops, VFPBinaryFrm, itin, opc, asm, pattern> {
1460   // Instruction operands.
1461   bits<5> Sd;
1462   bits<5> Sn;
1463   bits<5> Sm;
1464
1465   // Encode instruction operands.
1466   let Inst{3-0}   = Sm{4-1};
1467   let Inst{5}     = Sm{0};
1468   let Inst{19-16} = Sn{4-1};
1469   let Inst{7}     = Sn{0};
1470   let Inst{15-12} = Sd{4-1};
1471   let Inst{22}    = Sd{0};
1472
1473   let Inst{27-23} = opcod1;
1474   let Inst{21-20} = opcod2;
1475   let Inst{11-9}  = 0b101;
1476   let Inst{8}     = 0;          // Single precision
1477   let Inst{6}     = op6;
1478   let Inst{4}     = op4;
1479 }
1480
1481 // Single precision binary, if no NEON. Same as ASbI except not available if
1482 // NEON is enabled.
1483 class ASbIn<bits<5> opcod1, bits<2> opcod2, bit op6, bit op4, dag oops,
1484             dag iops, InstrItinClass itin, string opc, string asm,
1485             list<dag> pattern>
1486   : ASbI<opcod1, opcod2, op6, op4, oops, iops, itin, opc, asm, pattern> {
1487   list<Predicate> Predicates = [HasVFP2,DontUseNEONForFP];
1488
1489   // Instruction operands.
1490   bits<5> Sd;
1491   bits<5> Sn;
1492   bits<5> Sm;
1493
1494   // Encode instruction operands.
1495   let Inst{3-0}   = Sm{4-1};
1496   let Inst{5}     = Sm{0};
1497   let Inst{19-16} = Sn{4-1};
1498   let Inst{7}     = Sn{0};
1499   let Inst{15-12} = Sd{4-1};
1500   let Inst{22}    = Sd{0};
1501 }
1502
1503 // VFP conversion instructions
1504 class AVConv1I<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<4> opcod4,
1505                dag oops, dag iops, InstrItinClass itin, string opc, string asm,
1506                list<dag> pattern>
1507   : VFPAI<oops, iops, VFPConv1Frm, itin, opc, asm, pattern> {
1508   let Inst{27-23} = opcod1;
1509   let Inst{21-20} = opcod2;
1510   let Inst{19-16} = opcod3;
1511   let Inst{11-8}  = opcod4;
1512   let Inst{6}     = 1;
1513   let Inst{4}     = 0;
1514 }
1515
1516 // VFP conversion between floating-point and fixed-point
1517 class AVConv1XI<bits<5> op1, bits<2> op2, bits<4> op3, bits<4> op4, bit op5,
1518                 dag oops, dag iops, InstrItinClass itin, string opc, string asm,
1519                 list<dag> pattern>
1520   : AVConv1I<op1, op2, op3, op4, oops, iops, itin, opc, asm, pattern> {
1521   // size (fixed-point number): sx == 0 ? 16 : 32
1522   let Inst{7} = op5; // sx
1523 }
1524
1525 // VFP conversion instructions, if no NEON
1526 class AVConv1In<bits<5> opcod1, bits<2> opcod2, bits<4> opcod3, bits<4> opcod4,
1527                 dag oops, dag iops, InstrItinClass itin,
1528                 string opc, string asm, list<dag> pattern>
1529   : AVConv1I<opcod1, opcod2, opcod3, opcod4, oops, iops, itin, opc, asm,
1530              pattern> {
1531   list<Predicate> Predicates = [HasVFP2,DontUseNEONForFP];
1532 }
1533
1534 class AVConvXI<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops, Format f,
1535                InstrItinClass itin,
1536                string opc, string asm, list<dag> pattern>
1537   : VFPAI<oops, iops, f, itin, opc, asm, pattern> {
1538   let Inst{27-20} = opcod1;
1539   let Inst{11-8}  = opcod2;
1540   let Inst{4}     = 1;
1541 }
1542
1543 class AVConv2I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1544                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1545   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv2Frm, itin, opc, asm, pattern>;
1546
1547 class AVConv3I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1548                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1549   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv3Frm, itin, opc, asm, pattern>;
1550
1551 class AVConv4I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1552                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1553   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv4Frm, itin, opc, asm, pattern>;
1554
1555 class AVConv5I<bits<8> opcod1, bits<4> opcod2, dag oops, dag iops,
1556                InstrItinClass itin, string opc, string asm, list<dag> pattern>
1557   : AVConvXI<opcod1, opcod2, oops, iops, VFPConv5Frm, itin, opc, asm, pattern>;
1558
1559 //===----------------------------------------------------------------------===//
1560
1561 //===----------------------------------------------------------------------===//
1562 // ARM NEON Instruction templates.
1563 //
1564
1565 class NeonI<dag oops, dag iops, AddrMode am, IndexMode im, Format f,
1566             InstrItinClass itin, string opc, string dt, string asm, string cstr,
1567             list<dag> pattern>
1568   : InstARM<am, Size4Bytes, im, f, NeonDomain, cstr, itin> {
1569   let OutOperandList = oops;
1570   let InOperandList = !con(iops, (ins pred:$p));
1571   let AsmString = !strconcat(opc, "${p}", ".", dt, "\t", asm);
1572   let Pattern = pattern;
1573   list<Predicate> Predicates = [HasNEON];
1574 }
1575
1576 // Same as NeonI except it does not have a "data type" specifier.
1577 class NeonXI<dag oops, dag iops, AddrMode am, IndexMode im, Format f,
1578              InstrItinClass itin, string opc, string asm, string cstr,
1579              list<dag> pattern>
1580   : InstARM<am, Size4Bytes, im, f, NeonDomain, cstr, itin> {
1581   let OutOperandList = oops;
1582   let InOperandList = !con(iops, (ins pred:$p));
1583   let AsmString = !strconcat(opc, "${p}", "\t", asm);
1584   let Pattern = pattern;
1585   list<Predicate> Predicates = [HasNEON];
1586 }
1587
1588 class NLdSt<bit op23, bits<2> op21_20, bits<4> op11_8, bits<4> op7_4,
1589             dag oops, dag iops, InstrItinClass itin,
1590             string opc, string dt, string asm, string cstr, list<dag> pattern>
1591   : NeonI<oops, iops, AddrMode6, IndexModeNone, NLdStFrm, itin, opc, dt, asm,
1592           cstr, pattern> {
1593   let Inst{31-24} = 0b11110100;
1594   let Inst{23}    = op23;
1595   let Inst{21-20} = op21_20;
1596   let Inst{11-8}  = op11_8;
1597   let Inst{7-4}   = op7_4;
1598
1599   let PostEncoderMethod = "NEONThumb2LoadStorePostEncoder";
1600
1601   bits<5> Vd;
1602   bits<6> Rn;
1603   bits<4> Rm;
1604
1605   let Inst{22}    = Vd{4};
1606   let Inst{15-12} = Vd{3-0};
1607   let Inst{19-16} = Rn{3-0};
1608   let Inst{3-0}   = Rm{3-0};
1609 }
1610
1611 class NLdStLn<bit op23, bits<2> op21_20, bits<4> op11_8, bits<4> op7_4,
1612             dag oops, dag iops, InstrItinClass itin,
1613             string opc, string dt, string asm, string cstr, list<dag> pattern>
1614   : NLdSt<op23, op21_20, op11_8, op7_4, oops, iops, itin, opc,
1615           dt, asm, cstr, pattern> {
1616   bits<3> lane;
1617 }
1618
1619 class PseudoNLdSt<dag oops, dag iops, InstrItinClass itin, string cstr>
1620   : InstARM<AddrMode6, Size4Bytes, IndexModeNone, Pseudo, NeonDomain, cstr,
1621             itin> {
1622   let OutOperandList = oops;
1623   let InOperandList = !con(iops, (ins pred:$p));
1624   list<Predicate> Predicates = [HasNEON];
1625 }
1626
1627 class PseudoNeonI<dag oops, dag iops, InstrItinClass itin, string cstr,
1628                   list<dag> pattern>
1629   : InstARM<AddrModeNone, Size4Bytes, IndexModeNone, Pseudo, NeonDomain, cstr,
1630             itin> {
1631   let OutOperandList = oops;
1632   let InOperandList = !con(iops, (ins pred:$p));
1633   let Pattern = pattern;
1634   list<Predicate> Predicates = [HasNEON];
1635 }
1636
1637 class NDataI<dag oops, dag iops, Format f, InstrItinClass itin,
1638              string opc, string dt, string asm, string cstr, list<dag> pattern>
1639   : NeonI<oops, iops, AddrModeNone, IndexModeNone, f, itin, opc, dt, asm, cstr,
1640           pattern> {
1641   let Inst{31-25} = 0b1111001;
1642   let PostEncoderMethod = "NEONThumb2DataIPostEncoder";
1643 }
1644
1645 class NDataXI<dag oops, dag iops, Format f, InstrItinClass itin,
1646               string opc, string asm, string cstr, list<dag> pattern>
1647   : NeonXI<oops, iops, AddrModeNone, IndexModeNone, f, itin, opc, asm,
1648            cstr, pattern> {
1649   let Inst{31-25} = 0b1111001;
1650   let PostEncoderMethod = "NEONThumb2DataIPostEncoder";
1651 }
1652
1653 // NEON "one register and a modified immediate" format.
1654 class N1ModImm<bit op23, bits<3> op21_19, bits<4> op11_8, bit op7, bit op6,
1655                bit op5, bit op4,
1656                dag oops, dag iops, InstrItinClass itin,
1657                string opc, string dt, string asm, string cstr,
1658                list<dag> pattern>
1659   : NDataI<oops, iops, N1RegModImmFrm, itin, opc, dt, asm, cstr, pattern> {
1660   let Inst{23}    = op23;
1661   let Inst{21-19} = op21_19;
1662   let Inst{11-8}  = op11_8;
1663   let Inst{7}     = op7;
1664   let Inst{6}     = op6;
1665   let Inst{5}     = op5;
1666   let Inst{4}     = op4;
1667
1668   // Instruction operands.
1669   bits<5> Vd;
1670   bits<13> SIMM;
1671
1672   let Inst{15-12} = Vd{3-0};
1673   let Inst{22}    = Vd{4};
1674   let Inst{24}    = SIMM{7};
1675   let Inst{18-16} = SIMM{6-4};
1676   let Inst{3-0}   = SIMM{3-0};
1677 }
1678
1679 // NEON 2 vector register format.
1680 class N2V<bits<2> op24_23, bits<2> op21_20, bits<2> op19_18, bits<2> op17_16,
1681           bits<5> op11_7, bit op6, bit op4,
1682           dag oops, dag iops, InstrItinClass itin,
1683           string opc, string dt, string asm, string cstr, list<dag> pattern>
1684   : NDataI<oops, iops, N2RegFrm, itin, opc, dt, asm, cstr, pattern> {
1685   let Inst{24-23} = op24_23;
1686   let Inst{21-20} = op21_20;
1687   let Inst{19-18} = op19_18;
1688   let Inst{17-16} = op17_16;
1689   let Inst{11-7}  = op11_7;
1690   let Inst{6}     = op6;
1691   let Inst{4}     = op4;
1692
1693   // Instruction operands.
1694   bits<5> Vd;
1695   bits<5> Vm;
1696
1697   let Inst{15-12} = Vd{3-0};
1698   let Inst{22}    = Vd{4};
1699   let Inst{3-0}   = Vm{3-0};
1700   let Inst{5}     = Vm{4};
1701 }
1702
1703 // Same as N2V except it doesn't have a datatype suffix.
1704 class N2VX<bits<2> op24_23, bits<2> op21_20, bits<2> op19_18, bits<2> op17_16,
1705            bits<5> op11_7, bit op6, bit op4,
1706            dag oops, dag iops, InstrItinClass itin,
1707            string opc, string asm, string cstr, list<dag> pattern>
1708   : NDataXI<oops, iops, N2RegFrm, itin, opc, asm, cstr, pattern> {
1709   let Inst{24-23} = op24_23;
1710   let Inst{21-20} = op21_20;
1711   let Inst{19-18} = op19_18;
1712   let Inst{17-16} = op17_16;
1713   let Inst{11-7}  = op11_7;
1714   let Inst{6}     = op6;
1715   let Inst{4}     = op4;
1716
1717   // Instruction operands.
1718   bits<5> Vd;
1719   bits<5> Vm;
1720
1721   let Inst{15-12} = Vd{3-0};
1722   let Inst{22}    = Vd{4};
1723   let Inst{3-0}   = Vm{3-0};
1724   let Inst{5}     = Vm{4};
1725 }
1726
1727 // NEON 2 vector register with immediate.
1728 class N2VImm<bit op24, bit op23, bits<4> op11_8, bit op7, bit op6, bit op4,
1729              dag oops, dag iops, Format f, InstrItinClass itin,
1730              string opc, string dt, string asm, string cstr, list<dag> pattern>
1731   : NDataI<oops, iops, f, itin, opc, dt, asm, cstr, pattern> {
1732   let Inst{24}   = op24;
1733   let Inst{23}   = op23;
1734   let Inst{11-8} = op11_8;
1735   let Inst{7}    = op7;
1736   let Inst{6}    = op6;
1737   let Inst{4}    = op4;
1738
1739   // Instruction operands.
1740   bits<5> Vd;
1741   bits<5> Vm;
1742   bits<6> SIMM;
1743
1744   let Inst{15-12} = Vd{3-0};
1745   let Inst{22}    = Vd{4};
1746   let Inst{3-0}   = Vm{3-0};
1747   let Inst{5}     = Vm{4};
1748   let Inst{21-16} = SIMM{5-0};
1749 }
1750
1751 // NEON 3 vector register format.
1752
1753 class N3VCommon<bit op24, bit op23, bits<2> op21_20, bits<4> op11_8, bit op6,
1754                 bit op4, dag oops, dag iops, Format f, InstrItinClass itin,
1755                 string opc, string dt, string asm, string cstr,
1756                 list<dag> pattern>
1757   : NDataI<oops, iops, f, itin, opc, dt, asm, cstr, pattern> {
1758   let Inst{24}    = op24;
1759   let Inst{23}    = op23;
1760   let Inst{21-20} = op21_20;
1761   let Inst{11-8}  = op11_8;
1762   let Inst{6}     = op6;
1763   let Inst{4}     = op4;
1764 }
1765
1766 class N3V<bit op24, bit op23, bits<2> op21_20, bits<4> op11_8, bit op6, bit op4,
1767           dag oops, dag iops, Format f, InstrItinClass itin,
1768           string opc, string dt, string asm, string cstr, list<dag> pattern>
1769   : N3VCommon<op24, op23, op21_20, op11_8, op6, op4,
1770               oops, iops, f, itin, opc, dt, asm, cstr, pattern> {
1771
1772   // Instruction operands.
1773   bits<5> Vd;
1774   bits<5> Vn;
1775   bits<5> Vm;
1776
1777   let Inst{15-12} = Vd{3-0};
1778   let Inst{22}    = Vd{4};
1779   let Inst{19-16} = Vn{3-0};
1780   let Inst{7}     = Vn{4};
1781   let Inst{3-0}   = Vm{3-0};
1782   let Inst{5}     = Vm{4};
1783 }
1784
1785 class N3VLane32<bit op24, bit op23, bits<2> op21_20, bits<4> op11_8, bit op6,
1786                 bit op4, dag oops, dag iops, Format f, InstrItinClass itin,
1787                 string opc, string dt, string asm, string cstr,
1788                 list<dag> pattern>
1789   : N3VCommon<op24, op23, op21_20, op11_8, op6, op4,
1790               oops, iops, f, itin, opc, dt, asm, cstr, pattern> {
1791
1792   // Instruction operands.
1793   bits<5> Vd;
1794   bits<5> Vn;
1795   bits<5> Vm;
1796   bit lane;
1797
1798   let Inst{15-12} = Vd{3-0};
1799   let Inst{22}    = Vd{4};
1800   let Inst{19-16} = Vn{3-0};
1801   let Inst{7}     = Vn{4};
1802   let Inst{3-0}   = Vm{3-0};
1803   let Inst{5}     = lane;
1804 }
1805
1806 class N3VLane16<bit op24, bit op23, bits<2> op21_20, bits<4> op11_8, bit op6,
1807                 bit op4, dag oops, dag iops, Format f, InstrItinClass itin,
1808                 string opc, string dt, string asm, string cstr,
1809                 list<dag> pattern>
1810   : N3VCommon<op24, op23, op21_20, op11_8, op6, op4,
1811               oops, iops, f, itin, opc, dt, asm, cstr, pattern> {
1812
1813   // Instruction operands.
1814   bits<5> Vd;
1815   bits<5> Vn;
1816   bits<5> Vm;
1817   bits<2> lane;
1818
1819   let Inst{15-12} = Vd{3-0};
1820   let Inst{22}    = Vd{4};
1821   let Inst{19-16} = Vn{3-0};
1822   let Inst{7}     = Vn{4};
1823   let Inst{2-0}   = Vm{2-0};
1824   let Inst{5}     = lane{1};
1825   let Inst{3}     = lane{0};
1826 }
1827
1828 // Same as N3V except it doesn't have a data type suffix.
1829 class N3VX<bit op24, bit op23, bits<2> op21_20, bits<4> op11_8, bit op6,
1830            bit op4,
1831            dag oops, dag iops, Format f, InstrItinClass itin,
1832            string opc, string asm, string cstr, list<dag> pattern>
1833   : NDataXI<oops, iops, f, itin, opc, asm, cstr, pattern> {
1834   let Inst{24}    = op24;
1835   let Inst{23}    = op23;
1836   let Inst{21-20} = op21_20;
1837   let Inst{11-8}  = op11_8;
1838   let Inst{6}     = op6;
1839   let Inst{4}     = op4;
1840
1841   // Instruction operands.
1842   bits<5> Vd;
1843   bits<5> Vn;
1844   bits<5> Vm;
1845
1846   let Inst{15-12} = Vd{3-0};
1847   let Inst{22}    = Vd{4};
1848   let Inst{19-16} = Vn{3-0};
1849   let Inst{7}     = Vn{4};
1850   let Inst{3-0}   = Vm{3-0};
1851   let Inst{5}     = Vm{4};
1852 }
1853
1854 // NEON VMOVs between scalar and core registers.
1855 class NVLaneOp<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1856                dag oops, dag iops, Format f, InstrItinClass itin,
1857                string opc, string dt, string asm, list<dag> pattern>
1858   : InstARM<AddrModeNone, Size4Bytes, IndexModeNone, f, NeonDomain,
1859             "", itin> {
1860   let Inst{27-20} = opcod1;
1861   let Inst{11-8}  = opcod2;
1862   let Inst{6-5}   = opcod3;
1863   let Inst{4}     = 1;
1864   // A8.6.303, A8.6.328, A8.6.329
1865   let Inst{3-0}   = 0b0000;
1866
1867   let OutOperandList = oops;
1868   let InOperandList = !con(iops, (ins pred:$p));
1869   let AsmString = !strconcat(opc, "${p}", ".", dt, "\t", asm);
1870   let Pattern = pattern;
1871   list<Predicate> Predicates = [HasNEON];
1872
1873   let PostEncoderMethod = "NEONThumb2DupPostEncoder";
1874
1875   bits<5> V;
1876   bits<4> R;
1877   bits<4> p;
1878   bits<4> lane;
1879
1880   let Inst{31-28} = p{3-0};
1881   let Inst{7}     = V{4};
1882   let Inst{19-16} = V{3-0};
1883   let Inst{15-12} = R{3-0};
1884 }
1885 class NVGetLane<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1886                 dag oops, dag iops, InstrItinClass itin,
1887                 string opc, string dt, string asm, list<dag> pattern>
1888   : NVLaneOp<opcod1, opcod2, opcod3, oops, iops, NGetLnFrm, itin,
1889              opc, dt, asm, pattern>;
1890 class NVSetLane<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1891                 dag oops, dag iops, InstrItinClass itin,
1892                 string opc, string dt, string asm, list<dag> pattern>
1893   : NVLaneOp<opcod1, opcod2, opcod3, oops, iops, NSetLnFrm, itin,
1894              opc, dt, asm, pattern>;
1895 class NVDup<bits<8> opcod1, bits<4> opcod2, bits<2> opcod3,
1896             dag oops, dag iops, InstrItinClass itin,
1897             string opc, string dt, string asm, list<dag> pattern>
1898   : NVLaneOp<opcod1, opcod2, opcod3, oops, iops, NDupFrm, itin,
1899              opc, dt, asm, pattern>;
1900
1901 // Vector Duplicate Lane (from scalar to all elements)
1902 class NVDupLane<bits<4> op19_16, bit op6, dag oops, dag iops,
1903                 InstrItinClass itin, string opc, string dt, string asm,
1904                 list<dag> pattern>
1905   : NDataI<oops, iops, NVDupLnFrm, itin, opc, dt, asm, "", pattern> {
1906   let Inst{24-23} = 0b11;
1907   let Inst{21-20} = 0b11;
1908   let Inst{19-16} = op19_16;
1909   let Inst{11-7}  = 0b11000;
1910   let Inst{6}     = op6;
1911   let Inst{4}     = 0;
1912
1913   bits<5> Vd;
1914   bits<5> Vm;
1915   bits<4> lane;
1916
1917   let Inst{22}     = Vd{4};
1918   let Inst{15-12} = Vd{3-0};
1919   let Inst{5}     = Vm{4};
1920   let Inst{3-0} = Vm{3-0};
1921 }
1922
1923 // NEONFPPat - Same as Pat<>, but requires that the compiler be using NEON
1924 // for single-precision FP.
1925 class NEONFPPat<dag pattern, dag result> : Pat<pattern, result> {
1926   list<Predicate> Predicates = [HasNEON,UseNEONForFP];
1927 }