lib/Target/ARM/ARMInstrThumb.td

   1 //===-- ARMInstrThumb.td - Thumb support for ARM -----------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Thumb instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Thumb specific DAG Nodes.
  16 //
  17
  18 def ARMtcall : SDNode<"ARMISD::tCALL", SDT_ARMcall,
  19                       [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
  20                        SDNPVariadic]>;
  21
  22 def imm_sr_XFORM: SDNodeXForm<imm, [{
  23   unsigned Imm = N->getZExtValue();
  24   return CurDAG->getTargetConstant((Imm == 32 ? 0 : Imm), MVT::i32);
  25 }]>;
  26 def ThumbSRImmAsmOperand: AsmOperandClass { let Name = "ImmThumbSR"; }
  27 def imm_sr : Operand<i32>, PatLeaf<(imm), [{
  28   uint64_t Imm = N->getZExtValue();
  29   return Imm > 0 && Imm <= 32;
  30 }], imm_sr_XFORM> {
  31   let PrintMethod = "printThumbSRImm";
  32   let ParserMatchClass = ThumbSRImmAsmOperand;
  33 }
  34
  35 def imm_comp_XFORM : SDNodeXForm<imm, [{
  36   return CurDAG->getTargetConstant(~((uint32_t)N->getZExtValue()), MVT::i32);
  37 }]>;
  38
  39 def imm0_7_neg : PatLeaf<(i32 imm), [{
  40   return (uint32_t)-N->getZExtValue() < 8;
  41 }], imm_neg_XFORM>;
  42
  43 def imm0_255_comp : PatLeaf<(i32 imm), [{
  44   return ~((uint32_t)N->getZExtValue()) < 256;
  45 }]>;
  46
  47 def imm8_255 : ImmLeaf<i32, [{
  48   return Imm >= 8 && Imm < 256;
  49 }]>;
  50 def imm8_255_neg : PatLeaf<(i32 imm), [{
  51   unsigned Val = -N->getZExtValue();
  52   return Val >= 8 && Val < 256;
  53 }], imm_neg_XFORM>;
  54
  55 // Break imm's up into two pieces: an immediate + a left shift. This uses
  56 // thumb_immshifted to match and thumb_immshifted_val and thumb_immshifted_shamt
  57 // to get the val/shift pieces.
  58 def thumb_immshifted : PatLeaf<(imm), [{
  59   return ARM_AM::isThumbImmShiftedVal((unsigned)N->getZExtValue());
  60 }]>;
  61
  62 def thumb_immshifted_val : SDNodeXForm<imm, [{
  63   unsigned V = ARM_AM::getThumbImmNonShiftedVal((unsigned)N->getZExtValue());
  64   return CurDAG->getTargetConstant(V, MVT::i32);
  65 }]>;
  66
  67 def thumb_immshifted_shamt : SDNodeXForm<imm, [{
  68   unsigned V = ARM_AM::getThumbImmValShift((unsigned)N->getZExtValue());
  69   return CurDAG->getTargetConstant(V, MVT::i32);
  70 }]>;
  71
  72 // ADR instruction labels.
  73 def t_adrlabel : Operand<i32> {
  74   let EncoderMethod = "getThumbAdrLabelOpValue";
  75 }
  76
  77 // Scaled 4 immediate.
  78 def t_imm0_1020s4_asmoperand: AsmOperandClass { let Name = "Imm0_1020s4"; }
  79 def t_imm0_1020s4 : Operand<i32> {
  80   let PrintMethod = "printThumbS4ImmOperand";
  81   let ParserMatchClass = t_imm0_1020s4_asmoperand;
  82   let OperandType = "OPERAND_IMMEDIATE";
  83 }
  84
  85 def t_imm0_508s4_asmoperand: AsmOperandClass { let Name = "Imm0_508s4"; }
  86 def t_imm0_508s4 : Operand<i32> {
  87   let PrintMethod = "printThumbS4ImmOperand";
  88   let ParserMatchClass = t_imm0_508s4_asmoperand;
  89   let OperandType = "OPERAND_IMMEDIATE";
  90 }
  91 // Alias use only, so no printer is necessary.
  92 def t_imm0_508s4_neg_asmoperand: AsmOperandClass { let Name = "Imm0_508s4Neg"; }
  93 def t_imm0_508s4_neg : Operand<i32> {
  94   let ParserMatchClass = t_imm0_508s4_neg_asmoperand;
  95   let OperandType = "OPERAND_IMMEDIATE";
  96 }
  97
  98 // Define Thumb specific addressing modes.
  99
 100 let OperandType = "OPERAND_PCREL" in {
 101 def t_brtarget : Operand<OtherVT> {
 102   let EncoderMethod = "getThumbBRTargetOpValue";
 103   let DecoderMethod = "DecodeThumbBROperand";
 104 }
 105
 106 def t_bcctarget : Operand<i32> {
 107   let EncoderMethod = "getThumbBCCTargetOpValue";
 108   let DecoderMethod = "DecodeThumbBCCTargetOperand";
 109 }
 110
 111 def t_cbtarget : Operand<i32> {
 112   let EncoderMethod = "getThumbCBTargetOpValue";
 113   let DecoderMethod = "DecodeThumbCmpBROperand";
 114 }
 115
 116 def t_bltarget : Operand<i32> {
 117   let EncoderMethod = "getThumbBLTargetOpValue";
 118   let DecoderMethod = "DecodeThumbBLTargetOperand";
 119 }
 120
 121 def t_blxtarget : Operand<i32> {
 122   let EncoderMethod = "getThumbBLXTargetOpValue";
 123   let DecoderMethod = "DecodeThumbBLXOffset";
 124 }
 125 }
 126
 127 // t_addrmode_rr := reg + reg
 128 //
 129 def t_addrmode_rr_asm_operand : AsmOperandClass { let Name = "MemThumbRR"; }
 130 def t_addrmode_rr : Operand<i32>,
 131                     ComplexPattern<i32, 2, "SelectThumbAddrModeRR", []> {
 132   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 133   let PrintMethod = "printThumbAddrModeRROperand";
 134   let DecoderMethod = "DecodeThumbAddrModeRR";
 135   let ParserMatchClass = t_addrmode_rr_asm_operand;
 136   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 137 }
 138
 139 // t_addrmode_rrs := reg + reg
 140 //
 141 // We use separate scaled versions because the Select* functions need
 142 // to explicitly check for a matching constant and return false here so that
 143 // the reg+imm forms will match instead. This is a horrible way to do that,
 144 // as it forces tight coupling between the methods, but it's how selectiondag
 145 // currently works.
 146 def t_addrmode_rrs1 : Operand<i32>,
 147                       ComplexPattern<i32, 2, "SelectThumbAddrModeRI5S1", []> {
 148   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 149   let PrintMethod = "printThumbAddrModeRROperand";
 150   let DecoderMethod = "DecodeThumbAddrModeRR";
 151   let ParserMatchClass = t_addrmode_rr_asm_operand;
 152   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 153 }
 154 def t_addrmode_rrs2 : Operand<i32>,
 155                       ComplexPattern<i32, 2, "SelectThumbAddrModeRI5S2", []> {
 156   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 157   let DecoderMethod = "DecodeThumbAddrModeRR";
 158   let PrintMethod = "printThumbAddrModeRROperand";
 159   let ParserMatchClass = t_addrmode_rr_asm_operand;
 160   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 161 }
 162 def t_addrmode_rrs4 : Operand<i32>,
 163                       ComplexPattern<i32, 2, "SelectThumbAddrModeRI5S4", []> {
 164   let EncoderMethod = "getThumbAddrModeRegRegOpValue";
 165   let DecoderMethod = "DecodeThumbAddrModeRR";
 166   let PrintMethod = "printThumbAddrModeRROperand";
 167   let ParserMatchClass = t_addrmode_rr_asm_operand;
 168   let MIOperandInfo = (ops tGPR:$base, tGPR:$offsreg);
 169 }
 170
 171 // t_addrmode_is4 := reg + imm5 * 4
 172 //
 173 def t_addrmode_is4_asm_operand : AsmOperandClass { let Name = "MemThumbRIs4"; }
 174 def t_addrmode_is4 : Operand<i32>,
 175                      ComplexPattern<i32, 2, "SelectThumbAddrModeImm5S4", []> {
 176   let EncoderMethod = "getAddrModeISOpValue";
 177   let DecoderMethod = "DecodeThumbAddrModeIS";
 178   let PrintMethod = "printThumbAddrModeImm5S4Operand";
 179   let ParserMatchClass = t_addrmode_is4_asm_operand;
 180   let MIOperandInfo = (ops tGPR:$base, i32imm:$offsimm);
 181 }
 182
 183 // t_addrmode_is2 := reg + imm5 * 2
 184 //
 185 def t_addrmode_is2_asm_operand : AsmOperandClass { let Name = "MemThumbRIs2"; }
 186 def t_addrmode_is2 : Operand<i32>,
 187                      ComplexPattern<i32, 2, "SelectThumbAddrModeImm5S2", []> {
 188   let EncoderMethod = "getAddrModeISOpValue";
 189   let DecoderMethod = "DecodeThumbAddrModeIS";
 190   let PrintMethod = "printThumbAddrModeImm5S2Operand";
 191   let ParserMatchClass = t_addrmode_is2_asm_operand;
 192   let MIOperandInfo = (ops tGPR:$base, i32imm:$offsimm);
 193 }
 194
 195 // t_addrmode_is1 := reg + imm5
 196 //
 197 def t_addrmode_is1_asm_operand : AsmOperandClass { let Name = "MemThumbRIs1"; }
 198 def t_addrmode_is1 : Operand<i32>,
 199                      ComplexPattern<i32, 2, "SelectThumbAddrModeImm5S1", []> {
 200   let EncoderMethod = "getAddrModeISOpValue";
 201   let DecoderMethod = "DecodeThumbAddrModeIS";
 202   let PrintMethod = "printThumbAddrModeImm5S1Operand";
 203   let ParserMatchClass = t_addrmode_is1_asm_operand;
 204   let MIOperandInfo = (ops tGPR:$base, i32imm:$offsimm);
 205 }
 206
 207 // t_addrmode_sp := sp + imm8 * 4
 208 //
 209 // FIXME: This really shouldn't have an explicit SP operand at all. It should
 210 // be implicit, just like in the instruction encoding itself.
 211 def t_addrmode_sp_asm_operand : AsmOperandClass { let Name = "MemThumbSPI"; }
 212 def t_addrmode_sp : Operand<i32>,
 213                     ComplexPattern<i32, 2, "SelectThumbAddrModeSP", []> {
 214   let EncoderMethod = "getAddrModeThumbSPOpValue";
 215   let DecoderMethod = "DecodeThumbAddrModeSP";
 216   let PrintMethod = "printThumbAddrModeSPOperand";
 217   let ParserMatchClass = t_addrmode_sp_asm_operand;
 218   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 219 }
 220
 221 // t_addrmode_pc := <label> => pc + imm8 * 4
 222 //
 223 def t_addrmode_pc : Operand<i32> {
 224   let EncoderMethod = "getAddrModePCOpValue";
 225   let DecoderMethod = "DecodeThumbAddrModePC";
 226 }
 227
 228 //===----------------------------------------------------------------------===//
 229 //  Miscellaneous Instructions.
 230 //
 231
 232 // FIXME: Marking these as hasSideEffects is necessary to prevent machine DCE
 233 // from removing one half of the matched pairs. That breaks PEI, which assumes
 234 // these will always be in pairs, and asserts if it finds otherwise. Better way?
 235 let Defs = [SP], Uses = [SP], hasSideEffects = 1 in {
 236 def tADJCALLSTACKUP :
 237   PseudoInst<(outs), (ins i32imm:$amt1, i32imm:$amt2), NoItinerary,
 238              [(ARMcallseq_end imm:$amt1, imm:$amt2)]>,
 239             Requires<[IsThumb, IsThumb1Only]>;
 240
 241 def tADJCALLSTACKDOWN :
 242   PseudoInst<(outs), (ins i32imm:$amt), NoItinerary,
 243              [(ARMcallseq_start imm:$amt)]>,
 244             Requires<[IsThumb, IsThumb1Only]>;
 245 }
 246
 247 class T1SystemEncoding<bits<8> opc>
 248   : T1Encoding<0b101111> {
 249   let Inst{9-8} = 0b11;
 250   let Inst{7-0} = opc;
 251 }
 252
 253 def tNOP : T1pI<(outs), (ins), NoItinerary, "nop", "", []>,
 254            T1SystemEncoding<0x00>, // A8.6.110
 255         Requires<[IsThumb2]>;
 256
 257 def tYIELD : T1pI<(outs), (ins), NoItinerary, "yield", "", []>,
 258            T1SystemEncoding<0x10>, // A8.6.410
 259            Requires<[IsThumb2]>;
 260
 261 def tWFE : T1pI<(outs), (ins), NoItinerary, "wfe", "", []>,
 262            T1SystemEncoding<0x20>, // A8.6.408
 263            Requires<[IsThumb2]>;
 264
 265 def tWFI : T1pI<(outs), (ins), NoItinerary, "wfi", "", []>,
 266            T1SystemEncoding<0x30>, // A8.6.409
 267            Requires<[IsThumb2]>;
 268
 269 def tSEV : T1pI<(outs), (ins), NoItinerary, "sev", "", []>,
 270            T1SystemEncoding<0x40>, // A8.6.157
 271            Requires<[IsThumb2]>;
 272
 273 // The imm operand $val can be used by a debugger to store more information
 274 // about the breakpoint.
 275 def tBKPT : T1I<(outs), (ins imm0_255:$val), NoItinerary, "bkpt\t$val",
 276                 []>,
 277            T1Encoding<0b101111> {
 278   let Inst{9-8} = 0b10;
 279   // A8.6.22
 280   bits<8> val;
 281   let Inst{7-0} = val;
 282 }
 283
 284 def tSETEND : T1I<(outs), (ins setend_op:$end), NoItinerary, "setend\t$end",
 285                   []>, T1Encoding<0b101101> {
 286   bits<1> end;
 287   // A8.6.156
 288   let Inst{9-5} = 0b10010;
 289   let Inst{4}   = 1;
 290   let Inst{3}   = end;
 291   let Inst{2-0} = 0b000;
 292 }
 293
 294 // Change Processor State is a system instruction -- for disassembly only.
 295 def tCPS : T1I<(outs), (ins imod_op:$imod, iflags_op:$iflags),
 296                 NoItinerary, "cps$imod $iflags", []>,
 297            T1Misc<0b0110011> {
 298   // A8.6.38 & B6.1.1
 299   bit imod;
 300   bits<3> iflags;
 301
 302   let Inst{4}   = imod;
 303   let Inst{3}   = 0;
 304   let Inst{2-0} = iflags;
 305   let DecoderMethod = "DecodeThumbCPS";
 306 }
 307
 308 // For both thumb1 and thumb2.
 309 let isNotDuplicable = 1, isCodeGenOnly = 1 in
 310 def tPICADD : TIt<(outs GPR:$dst), (ins GPR:$lhs, pclabel:$cp), IIC_iALUr, "",
 311                   [(set GPR:$dst, (ARMpic_add GPR:$lhs, imm:$cp))]>,
 312               T1Special<{0,0,?,?}> {
 313   // A8.6.6
 314   bits<3> dst;
 315   let Inst{6-3} = 0b1111; // Rm = pc
 316   let Inst{2-0} = dst;
 317 }
 318
 319 // ADD <Rd>, sp, #<imm8>
 320 // FIXME: This should not be marked as having side effects, and it should be
 321 // rematerializable. Clearing the side effect bit causes miscompilations,
 322 // probably because the instruction can be moved around.
 323 def tADDrSPi : T1pI<(outs tGPR:$dst), (ins GPRsp:$sp, t_imm0_1020s4:$imm),
 324                     IIC_iALUi, "add", "\t$dst, $sp, $imm", []>,
 325                T1Encoding<{1,0,1,0,1,?}> {
 326   // A6.2 & A8.6.8
 327   bits<3> dst;
 328   bits<8> imm;
 329   let Inst{10-8} = dst;
 330   let Inst{7-0}  = imm;
 331   let DecoderMethod = "DecodeThumbAddSpecialReg";
 332 }
 333
 334 // ADD sp, sp, #<imm7>
 335 def tADDspi : T1pIt<(outs GPRsp:$Rdn), (ins GPRsp:$Rn, t_imm0_508s4:$imm),
 336                      IIC_iALUi, "add", "\t$Rdn, $imm", []>,
 337               T1Misc<{0,0,0,0,0,?,?}> {
 338   // A6.2.5 & A8.6.8
 339   bits<7> imm;
 340   let Inst{6-0} = imm;
 341   let DecoderMethod = "DecodeThumbAddSPImm";
 342 }
 343
 344 // SUB sp, sp, #<imm7>
 345 // FIXME: The encoding and the ASM string don't match up.
 346 def tSUBspi : T1pIt<(outs GPRsp:$Rdn), (ins GPRsp:$Rn, t_imm0_508s4:$imm),
 347                     IIC_iALUi, "sub", "\t$Rdn, $imm", []>,
 348               T1Misc<{0,0,0,0,1,?,?}> {
 349   // A6.2.5 & A8.6.214
 350   bits<7> imm;
 351   let Inst{6-0} = imm;
 352   let DecoderMethod = "DecodeThumbAddSPImm";
 353 }
 354
 355 def : tInstAlias<"add${p} sp, $imm",
 356                  (tSUBspi SP, t_imm0_508s4_neg:$imm, pred:$p)>;
 357 def : tInstAlias<"add${p} sp, sp, $imm",
 358                  (tSUBspi SP, t_imm0_508s4_neg:$imm, pred:$p)>;
 359
 360 // Can optionally specify SP as a three operand instruction.
 361 def : tInstAlias<"add${p} sp, sp, $imm",
 362                  (tADDspi SP, t_imm0_508s4:$imm, pred:$p)>;
 363 def : tInstAlias<"sub${p} sp, sp, $imm",
 364                  (tSUBspi SP, t_imm0_508s4:$imm, pred:$p)>;
 365
 366 // ADD <Rm>, sp
 367 def tADDrSP : T1pI<(outs GPR:$Rdn), (ins GPRsp:$sp, GPR:$Rn), IIC_iALUr,
 368                    "add", "\t$Rdn, $sp, $Rn", []>,
 369               T1Special<{0,0,?,?}> {
 370   // A8.6.9 Encoding T1
 371   bits<4> Rdn;
 372   let Inst{7}   = Rdn{3};
 373   let Inst{6-3} = 0b1101;
 374   let Inst{2-0} = Rdn{2-0};
 375   let DecoderMethod = "DecodeThumbAddSPReg";
 376 }
 377
 378 // ADD sp, <Rm>
 379 def tADDspr : T1pIt<(outs GPRsp:$Rdn), (ins GPRsp:$Rn, GPR:$Rm), IIC_iALUr,
 380                   "add", "\t$Rdn, $Rm", []>,
 381               T1Special<{0,0,?,?}> {
 382   // A8.6.9 Encoding T2
 383   bits<4> Rm;
 384   let Inst{7} = 1;
 385   let Inst{6-3} = Rm;
 386   let Inst{2-0} = 0b101;
 387   let DecoderMethod = "DecodeThumbAddSPReg";
 388 }
 389
 390 //===----------------------------------------------------------------------===//
 391 //  Control Flow Instructions.
 392 //
 393
 394 // Indirect branches
 395 let isBranch = 1, isTerminator = 1, isBarrier = 1, isIndirectBranch = 1 in {
 396   def tBX : TI<(outs), (ins GPR:$Rm, pred:$p), IIC_Br, "bx${p}\t$Rm", []>,
 397             T1Special<{1,1,0,?}> {
 398     // A6.2.3 & A8.6.25
 399     bits<4> Rm;
 400     let Inst{6-3} = Rm;
 401     let Inst{2-0} = 0b000;
 402     let Unpredictable{2-0} = 0b111;
 403   }
 404 }
 405
 406 let isReturn = 1, isTerminator = 1, isBarrier = 1 in {
 407   def tBX_RET : tPseudoExpand<(outs), (ins pred:$p), 2, IIC_Br,
 408                    [(ARMretflag)], (tBX LR, pred:$p)>;
 409
 410   // Alternative return instruction used by vararg functions.
 411   def tBX_RET_vararg : tPseudoExpand<(outs), (ins tGPR:$Rm, pred:$p),
 412                    2, IIC_Br, [],
 413                    (tBX GPR:$Rm, pred:$p)>;
 414 }
 415
 416 // All calls clobber the non-callee saved registers. SP is marked as a use to
 417 // prevent stack-pointer assignments that appear immediately before calls from
 418 // potentially appearing dead.
 419 let isCall = 1,
 420   Defs = [LR], Uses = [SP] in {
 421   // Also used for Thumb2
 422   def tBL  : TIx2<0b11110, 0b11, 1,
 423                   (outs), (ins pred:$p, t_bltarget:$func), IIC_Br,
 424                   "bl${p}\t$func",
 425                   [(ARMtcall tglobaladdr:$func)]>,
 426              Requires<[IsThumb]> {
 427     bits<24> func;
 428     let Inst{26} = func{23};
 429     let Inst{25-16} = func{20-11};
 430     let Inst{13} = func{22};
 431     let Inst{11} = func{21};
 432     let Inst{10-0} = func{10-0};
 433   }
 434
 435   // ARMv5T and above, also used for Thumb2
 436   def tBLXi : TIx2<0b11110, 0b11, 0,
 437                  (outs), (ins pred:$p, t_blxtarget:$func), IIC_Br,
 438                    "blx${p}\t$func",
 439                    [(ARMcall tglobaladdr:$func)]>,
 440               Requires<[IsThumb, HasV5T]> {
 441     bits<24> func;
 442     let Inst{26} = func{23};
 443     let Inst{25-16} = func{20-11};
 444     let Inst{13} = func{22};
 445     let Inst{11} = func{21};
 446     let Inst{10-1} = func{10-1};
 447     let Inst{0} = 0; // func{0} is assumed zero
 448   }
 449
 450   // Also used for Thumb2
 451   def tBLXr : TI<(outs), (ins pred:$p, GPR:$func), IIC_Br,
 452                   "blx${p}\t$func",
 453                   [(ARMtcall GPR:$func)]>,
 454               Requires<[IsThumb, HasV5T]>,
 455               T1Special<{1,1,1,?}> { // A6.2.3 & A8.6.24;
 456     bits<4> func;
 457     let Inst{6-3} = func;
 458     let Inst{2-0} = 0b000;
 459   }
 460
 461   // ARMv4T
 462   def tBX_CALL : tPseudoInst<(outs), (ins tGPR:$func),
 463                   4, IIC_Br,
 464                   [(ARMcall_nolink tGPR:$func)]>,
 465             Requires<[IsThumb, IsThumb1Only]>;
 466 }
 467
 468 let isBranch = 1, isTerminator = 1, isBarrier = 1 in {
 469   let isPredicable = 1 in
 470   def tB   : T1pI<(outs), (ins t_brtarget:$target), IIC_Br,
 471                  "b", "\t$target", [(br bb:$target)]>,
 472              T1Encoding<{1,1,1,0,0,?}> {
 473     bits<11> target;
 474     let Inst{10-0} = target;
 475   }
 476
 477   // Far jump
 478   // Just a pseudo for a tBL instruction. Needed to let regalloc know about
 479   // the clobber of LR.
 480   let Defs = [LR] in
 481   def tBfar : tPseudoExpand<(outs), (ins t_bltarget:$target, pred:$p),
 482                           4, IIC_Br, [], (tBL pred:$p, t_bltarget:$target)>;
 483
 484   def tBR_JTr : tPseudoInst<(outs),
 485                       (ins tGPR:$target, i32imm:$jt, i32imm:$id),
 486                       0, IIC_Br,
 487                       [(ARMbrjt tGPR:$target, tjumptable:$jt, imm:$id)]> {
 488     list<Predicate> Predicates = [IsThumb, IsThumb1Only];
 489   }
 490 }
 491
 492 // FIXME: should be able to write a pattern for ARMBrcond, but can't use
 493 // a two-value operand where a dag node expects two operands. :(
 494 let isBranch = 1, isTerminator = 1 in
 495   def tBcc : T1I<(outs), (ins t_bcctarget:$target, pred:$p), IIC_Br,
 496                  "b${p}\t$target",
 497                  [/*(ARMbrcond bb:$target, imm:$cc)*/]>,
 498              T1BranchCond<{1,1,0,1}> {
 499   bits<4> p;
 500   bits<8> target;
 501   let Inst{11-8} = p;
 502   let Inst{7-0} = target;
 503 }
 504
 505 // Tail calls
 506 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1 in {
 507   // IOS versions.
 508   let Uses = [SP] in {
 509     def tTAILJMPr : tPseudoExpand<(outs), (ins tcGPR:$dst),
 510                      4, IIC_Br, [],
 511                      (tBX GPR:$dst, (ops 14, zero_reg))>,
 512                      Requires<[IsThumb]>;
 513   }
 514   // tTAILJMPd: IOS version uses a Thumb2 branch (no Thumb1 tail calls
 515   // on IOS), so it's in ARMInstrThumb2.td.
 516   // Non-IOS version:
 517   let Uses = [SP] in {
 518     def tTAILJMPdND : tPseudoExpand<(outs),
 519                    (ins t_brtarget:$dst, pred:$p),
 520                    4, IIC_Br, [],
 521                    (tB t_brtarget:$dst, pred:$p)>,
 522                  Requires<[IsThumb, IsNotIOS]>;
 523   }
 524 }
 525
 526
 527 // A8.6.218 Supervisor Call (Software Interrupt)
 528 // A8.6.16 B: Encoding T1
 529 // If Inst{11-8} == 0b1111 then SEE SVC
 530 let isCall = 1, Uses = [SP] in
 531 def tSVC : T1pI<(outs), (ins imm0_255:$imm), IIC_Br,
 532                 "svc", "\t$imm", []>, Encoding16 {
 533   bits<8> imm;
 534   let Inst{15-12} = 0b1101;
 535   let Inst{11-8}  = 0b1111;
 536   let Inst{7-0}   = imm;
 537 }
 538
 539 // The assembler uses 0xDEFE for a trap instruction.
 540 let isBarrier = 1, isTerminator = 1 in
 541 def tTRAP : TI<(outs), (ins), IIC_Br,
 542                "trap", [(trap)]>, Encoding16 {
 543   let Inst = 0xdefe;
 544 }
 545
 546 //===----------------------------------------------------------------------===//
 547 //  Load Store Instructions.
 548 //
 549
 550 // Loads: reg/reg and reg/imm5
 551 let canFoldAsLoad = 1, isReMaterializable = 1 in
 552 multiclass thumb_ld_rr_ri_enc<bits<3> reg_opc, bits<4> imm_opc,
 553                               Operand AddrMode_r, Operand AddrMode_i,
 554                               AddrMode am, InstrItinClass itin_r,
 555                               InstrItinClass itin_i, string asm,
 556                               PatFrag opnode> {
 557   def r : // reg/reg
 558     T1pILdStEncode<reg_opc,
 559                    (outs tGPR:$Rt), (ins AddrMode_r:$addr),
 560                    am, itin_r, asm, "\t$Rt, $addr",
 561                    [(set tGPR:$Rt, (opnode AddrMode_r:$addr))]>;
 562   def i : // reg/imm5
 563     T1pILdStEncodeImm<imm_opc, 1 /* Load */,
 564                       (outs tGPR:$Rt), (ins AddrMode_i:$addr),
 565                       am, itin_i, asm, "\t$Rt, $addr",
 566                       [(set tGPR:$Rt, (opnode AddrMode_i:$addr))]>;
 567 }
 568 // Stores: reg/reg and reg/imm5
 569 multiclass thumb_st_rr_ri_enc<bits<3> reg_opc, bits<4> imm_opc,
 570                               Operand AddrMode_r, Operand AddrMode_i,
 571                               AddrMode am, InstrItinClass itin_r,
 572                               InstrItinClass itin_i, string asm,
 573                               PatFrag opnode> {
 574   def r : // reg/reg
 575     T1pILdStEncode<reg_opc,
 576                    (outs), (ins tGPR:$Rt, AddrMode_r:$addr),
 577                    am, itin_r, asm, "\t$Rt, $addr",
 578                    [(opnode tGPR:$Rt, AddrMode_r:$addr)]>;
 579   def i : // reg/imm5
 580     T1pILdStEncodeImm<imm_opc, 0 /* Store */,
 581                       (outs), (ins tGPR:$Rt, AddrMode_i:$addr),
 582                       am, itin_i, asm, "\t$Rt, $addr",
 583                       [(opnode tGPR:$Rt, AddrMode_i:$addr)]>;
 584 }
 585
 586 // A8.6.57 & A8.6.60
 587 defm tLDR  : thumb_ld_rr_ri_enc<0b100, 0b0110, t_addrmode_rrs4,
 588                                 t_addrmode_is4, AddrModeT1_4,
 589                                 IIC_iLoad_r, IIC_iLoad_i, "ldr",
 590                                 UnOpFrag<(load node:$Src)>>;
 591
 592 // A8.6.64 & A8.6.61
 593 defm tLDRB : thumb_ld_rr_ri_enc<0b110, 0b0111, t_addrmode_rrs1,
 594                                 t_addrmode_is1, AddrModeT1_1,
 595                                 IIC_iLoad_bh_r, IIC_iLoad_bh_i, "ldrb",
 596                                 UnOpFrag<(zextloadi8 node:$Src)>>;
 597
 598 // A8.6.76 & A8.6.73
 599 defm tLDRH : thumb_ld_rr_ri_enc<0b101, 0b1000, t_addrmode_rrs2,
 600                                 t_addrmode_is2, AddrModeT1_2,
 601                                 IIC_iLoad_bh_r, IIC_iLoad_bh_i, "ldrh",
 602                                 UnOpFrag<(zextloadi16 node:$Src)>>;
 603
 604 let AddedComplexity = 10 in
 605 def tLDRSB :                    // A8.6.80
 606   T1pILdStEncode<0b011, (outs tGPR:$Rt), (ins t_addrmode_rr:$addr),
 607                  AddrModeT1_1, IIC_iLoad_bh_r,
 608                  "ldrsb", "\t$Rt, $addr",
 609                  [(set tGPR:$Rt, (sextloadi8 t_addrmode_rr:$addr))]>;
 610
 611 let AddedComplexity = 10 in
 612 def tLDRSH :                    // A8.6.84
 613   T1pILdStEncode<0b111, (outs tGPR:$Rt), (ins t_addrmode_rr:$addr),
 614                  AddrModeT1_2, IIC_iLoad_bh_r,
 615                  "ldrsh", "\t$Rt, $addr",
 616                  [(set tGPR:$Rt, (sextloadi16 t_addrmode_rr:$addr))]>;
 617
 618 let canFoldAsLoad = 1 in
 619 def tLDRspi : T1pIs<(outs tGPR:$Rt), (ins t_addrmode_sp:$addr), IIC_iLoad_i,
 620                     "ldr", "\t$Rt, $addr",
 621                     [(set tGPR:$Rt, (load t_addrmode_sp:$addr))]>,
 622               T1LdStSP<{1,?,?}> {
 623   bits<3> Rt;
 624   bits<8> addr;
 625   let Inst{10-8} = Rt;
 626   let Inst{7-0} = addr;
 627 }
 628
 629 // Load tconstpool
 630 // FIXME: Use ldr.n to work around a darwin assembler bug.
 631 let canFoldAsLoad = 1, isReMaterializable = 1, isCodeGenOnly = 1 in
 632 def tLDRpci : T1pIs<(outs tGPR:$Rt), (ins t_addrmode_pc:$addr), IIC_iLoad_i,
 633                   "ldr", ".n\t$Rt, $addr",
 634                   [(set tGPR:$Rt, (load (ARMWrapper tconstpool:$addr)))]>,
 635               T1Encoding<{0,1,0,0,1,?}> {
 636   // A6.2 & A8.6.59
 637   bits<3> Rt;
 638   bits<8> addr;
 639   let Inst{10-8} = Rt;
 640   let Inst{7-0}  = addr;
 641 }
 642
 643 // FIXME: Remove this entry when the above ldr.n workaround is fixed.
 644 // For assembly/disassembly use only.
 645 def tLDRpciASM : T1pIs<(outs tGPR:$Rt), (ins t_addrmode_pc:$addr), IIC_iLoad_i,
 646                        "ldr", "\t$Rt, $addr", []>,
 647                  T1Encoding<{0,1,0,0,1,?}> {
 648   // A6.2 & A8.6.59
 649   bits<3> Rt;
 650   bits<8> addr;
 651   let Inst{10-8} = Rt;
 652   let Inst{7-0}  = addr;
 653 }
 654
 655 // A8.6.194 & A8.6.192
 656 defm tSTR  : thumb_st_rr_ri_enc<0b000, 0b0110, t_addrmode_rrs4,
 657                                 t_addrmode_is4, AddrModeT1_4,
 658                                 IIC_iStore_r, IIC_iStore_i, "str",
 659                                 BinOpFrag<(store node:$LHS, node:$RHS)>>;
 660
 661 // A8.6.197 & A8.6.195
 662 defm tSTRB : thumb_st_rr_ri_enc<0b010, 0b0111, t_addrmode_rrs1,
 663                                 t_addrmode_is1, AddrModeT1_1,
 664                                 IIC_iStore_bh_r, IIC_iStore_bh_i, "strb",
 665                                 BinOpFrag<(truncstorei8 node:$LHS, node:$RHS)>>;
 666
 667 // A8.6.207 & A8.6.205
 668 defm tSTRH : thumb_st_rr_ri_enc<0b001, 0b1000, t_addrmode_rrs2,
 669                                t_addrmode_is2, AddrModeT1_2,
 670                                IIC_iStore_bh_r, IIC_iStore_bh_i, "strh",
 671                                BinOpFrag<(truncstorei16 node:$LHS, node:$RHS)>>;
 672
 673
 674 def tSTRspi : T1pIs<(outs), (ins tGPR:$Rt, t_addrmode_sp:$addr), IIC_iStore_i,
 675                     "str", "\t$Rt, $addr",
 676                     [(store tGPR:$Rt, t_addrmode_sp:$addr)]>,
 677               T1LdStSP<{0,?,?}> {
 678   bits<3> Rt;
 679   bits<8> addr;
 680   let Inst{10-8} = Rt;
 681   let Inst{7-0} = addr;
 682 }
 683
 684 // Atomic loads. These pseudos expand to the loads above, but the have mayStore
 685 // = 1 so they can't be reordered.
 686 let mayLoad = 1, mayStore = 1, hasSideEffects = 0 in {
 687 let AM = AddrModeT1_1 in {
 688 def ATOMIC_tLDRBi : tPseudoExpand<(outs tGPR:$Rt),
 689                                    (ins t_addrmode_is1:$addr, pred:$p),
 690                                    2, IIC_iLoad_bh_i, [],
 691                               (tLDRBi tGPR:$Rt, t_addrmode_is1:$addr, pred:$p)>;
 692 def ATOMIC_tLDRBr : tPseudoExpand<(outs tGPR:$Rt),
 693                                    (ins t_addrmode_rrs1:$addr, pred:$p),
 694                                    2, IIC_iLoad_bh_r, [],
 695                              (tLDRBr tGPR:$Rt, t_addrmode_rrs1:$addr, pred:$p)>;
 696 }
 697 let AM = AddrModeT1_2 in {
 698 def ATOMIC_tLDRHi : tPseudoExpand<(outs tGPR:$Rt),
 699                                    (ins t_addrmode_is2:$addr, pred:$p),
 700                                    2, IIC_iLoad_bh_i, [],
 701                               (tLDRHi tGPR:$Rt, t_addrmode_is2:$addr, pred:$p)>;
 702 def ATOMIC_tLDRHr : tPseudoExpand<(outs tGPR:$Rt),
 703                                    (ins t_addrmode_rrs2:$addr, pred:$p),
 704                                    2, IIC_iLoad_bh_r, [],
 705                              (tLDRHr tGPR:$Rt, t_addrmode_rrs2:$addr, pred:$p)>;
 706 }
 707 let AM = AddrModeT1_4 in {
 708 def ATOMIC_tLDRi  : tPseudoExpand<(outs tGPR:$Rt),
 709                                    (ins t_addrmode_is4:$addr, pred:$p),
 710                                    2, IIC_iLoad_i, [],
 711                                (tLDRi tGPR:$Rt, t_addrmode_is4:$addr, pred:$p)>;
 712 def ATOMIC_tLDRr  : tPseudoExpand<(outs tGPR:$Rt),
 713                                    (ins t_addrmode_rrs4:$addr, pred:$p),
 714                                    2, IIC_iLoad_r, [],
 715                               (tLDRr tGPR:$Rt, t_addrmode_rrs4:$addr, pred:$p)>;
 716 }
 717 }
 718
 719 //===----------------------------------------------------------------------===//
 720 //  Load / store multiple Instructions.
 721 //
 722
 723 // These require base address to be written back or one of the loaded regs.
 724 let neverHasSideEffects = 1 in {
 725
 726 let mayLoad = 1, hasExtraDefRegAllocReq = 1 in
 727 def tLDMIA : T1I<(outs), (ins tGPR:$Rn, pred:$p, reglist:$regs, variable_ops),
 728         IIC_iLoad_m, "ldm${p}\t$Rn, $regs", []>, T1Encoding<{1,1,0,0,1,?}> {
 729   bits<3> Rn;
 730   bits<8> regs;
 731   let Inst{10-8} = Rn;
 732   let Inst{7-0}  = regs;
 733 }
 734
 735 // Writeback version is just a pseudo, as there's no encoding difference.
 736 // Writeback happens iff the base register is not in the destination register
 737 // list.
 738 def tLDMIA_UPD :
 739     InstTemplate<AddrModeNone, 0, IndexModeNone, Pseudo, GenericDomain,
 740                  "$Rn = $wb", IIC_iLoad_mu>,
 741     PseudoInstExpansion<(tLDMIA tGPR:$Rn, pred:$p, reglist:$regs)> {
 742   let Size = 2;
 743   let OutOperandList = (outs GPR:$wb);
 744   let InOperandList = (ins GPR:$Rn, pred:$p, reglist:$regs, variable_ops);
 745   let Pattern = [];
 746   let isCodeGenOnly = 1;
 747   let isPseudo = 1;
 748   list<Predicate> Predicates = [IsThumb];
 749 }
 750
 751 // There is no non-writeback version of STM for Thumb.
 752 let mayStore = 1, hasExtraSrcRegAllocReq = 1 in
 753 def tSTMIA_UPD : Thumb1I<(outs GPR:$wb),
 754                          (ins tGPR:$Rn, pred:$p, reglist:$regs, variable_ops),
 755                          AddrModeNone, 2, IIC_iStore_mu,
 756                          "stm${p}\t$Rn!, $regs", "$Rn = $wb", []>,
 757                      T1Encoding<{1,1,0,0,0,?}> {
 758   bits<3> Rn;
 759   bits<8> regs;
 760   let Inst{10-8} = Rn;
 761   let Inst{7-0}  = regs;
 762 }
 763
 764 } // neverHasSideEffects
 765
 766 def : InstAlias<"ldm${p} $Rn!, $regs",
 767                 (tLDMIA tGPR:$Rn, pred:$p, reglist:$regs)>,
 768         Requires<[IsThumb, IsThumb1Only]>;
 769
 770 let mayLoad = 1, Uses = [SP], Defs = [SP], hasExtraDefRegAllocReq = 1 in
 771 def tPOP : T1I<(outs), (ins pred:$p, reglist:$regs, variable_ops),
 772                IIC_iPop,
 773                "pop${p}\t$regs", []>,
 774            T1Misc<{1,1,0,?,?,?,?}> {
 775   bits<16> regs;
 776   let Inst{8}   = regs{15};
 777   let Inst{7-0} = regs{7-0};
 778 }
 779
 780 let mayStore = 1, Uses = [SP], Defs = [SP], hasExtraSrcRegAllocReq = 1 in
 781 def tPUSH : T1I<(outs), (ins pred:$p, reglist:$regs, variable_ops),
 782                 IIC_iStore_m,
 783                 "push${p}\t$regs", []>,
 784             T1Misc<{0,1,0,?,?,?,?}> {
 785   bits<16> regs;
 786   let Inst{8}   = regs{14};
 787   let Inst{7-0} = regs{7-0};
 788 }
 789
 790 //===----------------------------------------------------------------------===//
 791 //  Arithmetic Instructions.
 792 //
 793
 794 // Helper classes for encoding T1pI patterns:
 795 class T1pIDPEncode<bits<4> opA, dag oops, dag iops, InstrItinClass itin,
 796                    string opc, string asm, list<dag> pattern>
 797     : T1pI<oops, iops, itin, opc, asm, pattern>,
 798       T1DataProcessing<opA> {
 799   bits<3> Rm;
 800   bits<3> Rn;
 801   let Inst{5-3} = Rm;
 802   let Inst{2-0} = Rn;
 803 }
 804 class T1pIMiscEncode<bits<7> opA, dag oops, dag iops, InstrItinClass itin,
 805                      string opc, string asm, list<dag> pattern>
 806     : T1pI<oops, iops, itin, opc, asm, pattern>,
 807       T1Misc<opA> {
 808   bits<3> Rm;
 809   bits<3> Rd;
 810   let Inst{5-3} = Rm;
 811   let Inst{2-0} = Rd;
 812 }
 813
 814 // Helper classes for encoding T1sI patterns:
 815 class T1sIDPEncode<bits<4> opA, dag oops, dag iops, InstrItinClass itin,
 816                    string opc, string asm, list<dag> pattern>
 817     : T1sI<oops, iops, itin, opc, asm, pattern>,
 818       T1DataProcessing<opA> {
 819   bits<3> Rd;
 820   bits<3> Rn;
 821   let Inst{5-3} = Rn;
 822   let Inst{2-0} = Rd;
 823 }
 824 class T1sIGenEncode<bits<5> opA, dag oops, dag iops, InstrItinClass itin,
 825                     string opc, string asm, list<dag> pattern>
 826     : T1sI<oops, iops, itin, opc, asm, pattern>,
 827       T1General<opA> {
 828   bits<3> Rm;
 829   bits<3> Rn;
 830   bits<3> Rd;
 831   let Inst{8-6} = Rm;
 832   let Inst{5-3} = Rn;
 833   let Inst{2-0} = Rd;
 834 }
 835 class T1sIGenEncodeImm<bits<5> opA, dag oops, dag iops, InstrItinClass itin,
 836                        string opc, string asm, list<dag> pattern>
 837     : T1sI<oops, iops, itin, opc, asm, pattern>,
 838       T1General<opA> {
 839   bits<3> Rd;
 840   bits<3> Rm;
 841   let Inst{5-3} = Rm;
 842   let Inst{2-0} = Rd;
 843 }
 844
 845 // Helper classes for encoding T1sIt patterns:
 846 class T1sItDPEncode<bits<4> opA, dag oops, dag iops, InstrItinClass itin,
 847                     string opc, string asm, list<dag> pattern>
 848     : T1sIt<oops, iops, itin, opc, asm, pattern>,
 849       T1DataProcessing<opA> {
 850   bits<3> Rdn;
 851   bits<3> Rm;
 852   let Inst{5-3} = Rm;
 853   let Inst{2-0} = Rdn;
 854 }
 855 class T1sItGenEncodeImm<bits<5> opA, dag oops, dag iops, InstrItinClass itin,
 856                         string opc, string asm, list<dag> pattern>
 857     : T1sIt<oops, iops, itin, opc, asm, pattern>,
 858       T1General<opA> {
 859   bits<3> Rdn;
 860   bits<8> imm8;
 861   let Inst{10-8} = Rdn;
 862   let Inst{7-0}  = imm8;
 863 }
 864
 865 // Add with carry register
 866 let isCommutable = 1, Uses = [CPSR] in
 867 def tADC :                      // A8.6.2
 868   T1sItDPEncode<0b0101, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm), IIC_iALUr,
 869                 "adc", "\t$Rdn, $Rm",
 870                 [(set tGPR:$Rdn, (adde tGPR:$Rn, tGPR:$Rm))]>;
 871
 872 // Add immediate
 873 def tADDi3 :                    // A8.6.4 T1
 874   T1sIGenEncodeImm<0b01110, (outs tGPR:$Rd), (ins tGPR:$Rm, imm0_7:$imm3),
 875                    IIC_iALUi,
 876                    "add", "\t$Rd, $Rm, $imm3",
 877                    [(set tGPR:$Rd, (add tGPR:$Rm, imm0_7:$imm3))]> {
 878   bits<3> imm3;
 879   let Inst{8-6} = imm3;
 880 }
 881
 882 def tADDi8 :                    // A8.6.4 T2
 883   T1sItGenEncodeImm<{1,1,0,?,?}, (outs tGPR:$Rdn),
 884                     (ins tGPR:$Rn, imm0_255:$imm8), IIC_iALUi,
 885                     "add", "\t$Rdn, $imm8",
 886                     [(set tGPR:$Rdn, (add tGPR:$Rn, imm8_255:$imm8))]>;
 887
 888 // Add register
 889 let isCommutable = 1 in
 890 def tADDrr :                    // A8.6.6 T1
 891   T1sIGenEncode<0b01100, (outs tGPR:$Rd), (ins tGPR:$Rn, tGPR:$Rm),
 892                 IIC_iALUr,
 893                 "add", "\t$Rd, $Rn, $Rm",
 894                 [(set tGPR:$Rd, (add tGPR:$Rn, tGPR:$Rm))]>;
 895
 896 let neverHasSideEffects = 1 in
 897 def tADDhirr : T1pIt<(outs GPR:$Rdn), (ins GPR:$Rn, GPR:$Rm), IIC_iALUr,
 898                      "add", "\t$Rdn, $Rm", []>,
 899                T1Special<{0,0,?,?}> {
 900   // A8.6.6 T2
 901   bits<4> Rdn;
 902   bits<4> Rm;
 903   let Inst{7}   = Rdn{3};
 904   let Inst{6-3} = Rm;
 905   let Inst{2-0} = Rdn{2-0};
 906 }
 907
 908 // AND register
 909 let isCommutable = 1 in
 910 def tAND :                      // A8.6.12
 911   T1sItDPEncode<0b0000, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 912                 IIC_iBITr,
 913                 "and", "\t$Rdn, $Rm",
 914                 [(set tGPR:$Rdn, (and tGPR:$Rn, tGPR:$Rm))]>;
 915
 916 // ASR immediate
 917 def tASRri :                    // A8.6.14
 918   T1sIGenEncodeImm<{0,1,0,?,?}, (outs tGPR:$Rd), (ins tGPR:$Rm, imm_sr:$imm5),
 919                    IIC_iMOVsi,
 920                    "asr", "\t$Rd, $Rm, $imm5",
 921                    [(set tGPR:$Rd, (sra tGPR:$Rm, (i32 imm_sr:$imm5)))]> {
 922   bits<5> imm5;
 923   let Inst{10-6} = imm5;
 924 }
 925
 926 // ASR register
 927 def tASRrr :                    // A8.6.15
 928   T1sItDPEncode<0b0100, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 929                 IIC_iMOVsr,
 930                 "asr", "\t$Rdn, $Rm",
 931                 [(set tGPR:$Rdn, (sra tGPR:$Rn, tGPR:$Rm))]>;
 932
 933 // BIC register
 934 def tBIC :                      // A8.6.20
 935   T1sItDPEncode<0b1110, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 936                 IIC_iBITr,
 937                 "bic", "\t$Rdn, $Rm",
 938                 [(set tGPR:$Rdn, (and tGPR:$Rn, (not tGPR:$Rm)))]>;
 939
 940 // CMN register
 941 let isCompare = 1, Defs = [CPSR] in {
 942 //FIXME: Disable CMN, as CCodes are backwards from compare expectations
 943 //       Compare-to-zero still works out, just not the relationals
 944 //def tCMN :                     // A8.6.33
 945 //  T1pIDPEncode<0b1011, (outs), (ins tGPR:$lhs, tGPR:$rhs),
 946 //               IIC_iCMPr,
 947 //               "cmn", "\t$lhs, $rhs",
 948 //               [(ARMcmp tGPR:$lhs, (ineg tGPR:$rhs))]>;
 949
 950 def tCMNz :                     // A8.6.33
 951   T1pIDPEncode<0b1011, (outs), (ins tGPR:$Rn, tGPR:$Rm),
 952                IIC_iCMPr,
 953                "cmn", "\t$Rn, $Rm",
 954                [(ARMcmpZ tGPR:$Rn, (ineg tGPR:$Rm))]>;
 955
 956 } // isCompare = 1, Defs = [CPSR]
 957
 958 // CMP immediate
 959 let isCompare = 1, Defs = [CPSR] in {
 960 def tCMPi8 : T1pI<(outs), (ins tGPR:$Rn, imm0_255:$imm8), IIC_iCMPi,
 961                   "cmp", "\t$Rn, $imm8",
 962                   [(ARMcmp tGPR:$Rn, imm0_255:$imm8)]>,
 963              T1General<{1,0,1,?,?}> {
 964   // A8.6.35
 965   bits<3> Rn;
 966   bits<8> imm8;
 967   let Inst{10-8} = Rn;
 968   let Inst{7-0}  = imm8;
 969 }
 970
 971 // CMP register
 972 def tCMPr :                     // A8.6.36 T1
 973   T1pIDPEncode<0b1010, (outs), (ins tGPR:$Rn, tGPR:$Rm),
 974                IIC_iCMPr,
 975                "cmp", "\t$Rn, $Rm",
 976                [(ARMcmp tGPR:$Rn, tGPR:$Rm)]>;
 977
 978 def tCMPhir : T1pI<(outs), (ins GPR:$Rn, GPR:$Rm), IIC_iCMPr,
 979                    "cmp", "\t$Rn, $Rm", []>,
 980               T1Special<{0,1,?,?}> {
 981   // A8.6.36 T2
 982   bits<4> Rm;
 983   bits<4> Rn;
 984   let Inst{7}   = Rn{3};
 985   let Inst{6-3} = Rm;
 986   let Inst{2-0} = Rn{2-0};
 987 }
 988 } // isCompare = 1, Defs = [CPSR]
 989
 990
 991 // XOR register
 992 let isCommutable = 1 in
 993 def tEOR :                      // A8.6.45
 994   T1sItDPEncode<0b0001, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
 995                 IIC_iBITr,
 996                 "eor", "\t$Rdn, $Rm",
 997                 [(set tGPR:$Rdn, (xor tGPR:$Rn, tGPR:$Rm))]>;
 998
 999 // LSL immediate
1000 def tLSLri :                    // A8.6.88
1001   T1sIGenEncodeImm<{0,0,0,?,?}, (outs tGPR:$Rd), (ins tGPR:$Rm, imm0_31:$imm5),
1002                    IIC_iMOVsi,
1003                    "lsl", "\t$Rd, $Rm, $imm5",
1004                    [(set tGPR:$Rd, (shl tGPR:$Rm, (i32 imm:$imm5)))]> {
1005   bits<5> imm5;
1006   let Inst{10-6} = imm5;
1007 }
1008
1009 // LSL register
1010 def tLSLrr :                    // A8.6.89
1011   T1sItDPEncode<0b0010, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1012                 IIC_iMOVsr,
1013                 "lsl", "\t$Rdn, $Rm",
1014                 [(set tGPR:$Rdn, (shl tGPR:$Rn, tGPR:$Rm))]>;
1015
1016 // LSR immediate
1017 def tLSRri :                    // A8.6.90
1018   T1sIGenEncodeImm<{0,0,1,?,?}, (outs tGPR:$Rd), (ins tGPR:$Rm, imm_sr:$imm5),
1019                    IIC_iMOVsi,
1020                    "lsr", "\t$Rd, $Rm, $imm5",
1021                    [(set tGPR:$Rd, (srl tGPR:$Rm, (i32 imm_sr:$imm5)))]> {
1022   bits<5> imm5;
1023   let Inst{10-6} = imm5;
1024 }
1025
1026 // LSR register
1027 def tLSRrr :                    // A8.6.91
1028   T1sItDPEncode<0b0011, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1029                 IIC_iMOVsr,
1030                 "lsr", "\t$Rdn, $Rm",
1031                 [(set tGPR:$Rdn, (srl tGPR:$Rn, tGPR:$Rm))]>;
1032
1033 // Move register
1034 let isMoveImm = 1 in
1035 def tMOVi8 : T1sI<(outs tGPR:$Rd), (ins imm0_255:$imm8), IIC_iMOVi,
1036                   "mov", "\t$Rd, $imm8",
1037                   [(set tGPR:$Rd, imm0_255:$imm8)]>,
1038              T1General<{1,0,0,?,?}> {
1039   // A8.6.96
1040   bits<3> Rd;
1041   bits<8> imm8;
1042   let Inst{10-8} = Rd;
1043   let Inst{7-0}  = imm8;
1044 }
1045 // Because we have an explicit tMOVSr below, we need an alias to handle
1046 // the immediate "movs" form here. Blech.
1047 def : tInstAlias <"movs $Rdn, $imm",
1048                  (tMOVi8 tGPR:$Rdn, CPSR, imm0_255:$imm, 14, 0)>;
1049
1050 // A7-73: MOV(2) - mov setting flag.
1051
1052 let neverHasSideEffects = 1 in {
1053 def tMOVr : Thumb1pI<(outs GPR:$Rd), (ins GPR:$Rm), AddrModeNone,
1054                       2, IIC_iMOVr,
1055                       "mov", "\t$Rd, $Rm", "", []>,
1056                   T1Special<{1,0,?,?}> {
1057   // A8.6.97
1058   bits<4> Rd;
1059   bits<4> Rm;
1060   let Inst{7}   = Rd{3};
1061   let Inst{6-3} = Rm;
1062   let Inst{2-0} = Rd{2-0};
1063 }
1064 let Defs = [CPSR] in
1065 def tMOVSr      : T1I<(outs tGPR:$Rd), (ins tGPR:$Rm), IIC_iMOVr,
1066                       "movs\t$Rd, $Rm", []>, Encoding16 {
1067   // A8.6.97
1068   bits<3> Rd;
1069   bits<3> Rm;
1070   let Inst{15-6} = 0b0000000000;
1071   let Inst{5-3}  = Rm;
1072   let Inst{2-0}  = Rd;
1073 }
1074 } // neverHasSideEffects
1075
1076 // Multiply register
1077 let isCommutable = 1 in
1078 def tMUL :                      // A8.6.105 T1
1079   Thumb1sI<(outs tGPR:$Rd), (ins tGPR:$Rn, tGPR:$Rm), AddrModeNone, 2,
1080            IIC_iMUL32, "mul", "\t$Rd, $Rn, $Rm", "$Rm = $Rd",
1081            [(set tGPR:$Rd, (mul tGPR:$Rn, tGPR:$Rm))]>,
1082       T1DataProcessing<0b1101> {
1083   bits<3> Rd;
1084   bits<3> Rn;
1085   let Inst{5-3} = Rn;
1086   let Inst{2-0} = Rd;
1087   let AsmMatchConverter = "cvtThumbMultiply";
1088 }
1089
1090 def :tInstAlias<"mul${s}${p} $Rdm, $Rn", (tMUL tGPR:$Rdm, s_cc_out:$s, tGPR:$Rn,
1091                                                pred:$p)>;
1092
1093 // Move inverse register
1094 def tMVN :                      // A8.6.107
1095   T1sIDPEncode<0b1111, (outs tGPR:$Rd), (ins tGPR:$Rn), IIC_iMVNr,
1096                "mvn", "\t$Rd, $Rn",
1097                [(set tGPR:$Rd, (not tGPR:$Rn))]>;
1098
1099 // Bitwise or register
1100 let isCommutable = 1 in
1101 def tORR :                      // A8.6.114
1102   T1sItDPEncode<0b1100, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1103                 IIC_iBITr,
1104                 "orr", "\t$Rdn, $Rm",
1105                 [(set tGPR:$Rdn, (or tGPR:$Rn, tGPR:$Rm))]>;
1106
1107 // Swaps
1108 def tREV :                      // A8.6.134
1109   T1pIMiscEncode<{1,0,1,0,0,0,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1110                  IIC_iUNAr,
1111                  "rev", "\t$Rd, $Rm",
1112                  [(set tGPR:$Rd, (bswap tGPR:$Rm))]>,
1113                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1114
1115 def tREV16 :                    // A8.6.135
1116   T1pIMiscEncode<{1,0,1,0,0,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1117                  IIC_iUNAr,
1118                  "rev16", "\t$Rd, $Rm",
1119              [(set tGPR:$Rd, (rotr (bswap tGPR:$Rm), (i32 16)))]>,
1120                 Requires<[IsThumb, IsThumb1Only, HasV6]>;
1121
1122 def tREVSH :                    // A8.6.136
1123   T1pIMiscEncode<{1,0,1,0,1,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1124                  IIC_iUNAr,
1125                  "revsh", "\t$Rd, $Rm",
1126                  [(set tGPR:$Rd, (sra (bswap tGPR:$Rm), (i32 16)))]>,
1127                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1128
1129 // Rotate right register
1130 def tROR :                      // A8.6.139
1131   T1sItDPEncode<0b0111, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1132                 IIC_iMOVsr,
1133                 "ror", "\t$Rdn, $Rm",
1134                 [(set tGPR:$Rdn, (rotr tGPR:$Rn, tGPR:$Rm))]>;
1135
1136 // Negate register
1137 def tRSB :                      // A8.6.141
1138   T1sIDPEncode<0b1001, (outs tGPR:$Rd), (ins tGPR:$Rn),
1139                IIC_iALUi,
1140                "rsb", "\t$Rd, $Rn, #0",
1141                [(set tGPR:$Rd, (ineg tGPR:$Rn))]>;
1142
1143 // Subtract with carry register
1144 let Uses = [CPSR] in
1145 def tSBC :                      // A8.6.151
1146   T1sItDPEncode<0b0110, (outs tGPR:$Rdn), (ins tGPR:$Rn, tGPR:$Rm),
1147                 IIC_iALUr,
1148                 "sbc", "\t$Rdn, $Rm",
1149                 [(set tGPR:$Rdn, (sube tGPR:$Rn, tGPR:$Rm))]>;
1150
1151 // Subtract immediate
1152 def tSUBi3 :                    // A8.6.210 T1
1153   T1sIGenEncodeImm<0b01111, (outs tGPR:$Rd), (ins tGPR:$Rm, imm0_7:$imm3),
1154                    IIC_iALUi,
1155                    "sub", "\t$Rd, $Rm, $imm3",
1156                    [(set tGPR:$Rd, (add tGPR:$Rm, imm0_7_neg:$imm3))]> {
1157   bits<3> imm3;
1158   let Inst{8-6} = imm3;
1159 }
1160
1161 def tSUBi8 :                    // A8.6.210 T2
1162   T1sItGenEncodeImm<{1,1,1,?,?}, (outs tGPR:$Rdn),
1163                     (ins tGPR:$Rn, imm0_255:$imm8), IIC_iALUi,
1164                     "sub", "\t$Rdn, $imm8",
1165                     [(set tGPR:$Rdn, (add tGPR:$Rn, imm8_255_neg:$imm8))]>;
1166
1167 // Subtract register
1168 def tSUBrr :                    // A8.6.212
1169   T1sIGenEncode<0b01101, (outs tGPR:$Rd), (ins tGPR:$Rn, tGPR:$Rm),
1170                 IIC_iALUr,
1171                 "sub", "\t$Rd, $Rn, $Rm",
1172                 [(set tGPR:$Rd, (sub tGPR:$Rn, tGPR:$Rm))]>;
1173
1174 // Sign-extend byte
1175 def tSXTB :                     // A8.6.222
1176   T1pIMiscEncode<{0,0,1,0,0,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1177                  IIC_iUNAr,
1178                  "sxtb", "\t$Rd, $Rm",
1179                  [(set tGPR:$Rd, (sext_inreg tGPR:$Rm, i8))]>,
1180                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1181
1182 // Sign-extend short
1183 def tSXTH :                     // A8.6.224
1184   T1pIMiscEncode<{0,0,1,0,0,0,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1185                  IIC_iUNAr,
1186                  "sxth", "\t$Rd, $Rm",
1187                  [(set tGPR:$Rd, (sext_inreg tGPR:$Rm, i16))]>,
1188                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1189
1190 // Test
1191 let isCompare = 1, isCommutable = 1, Defs = [CPSR] in
1192 def tTST :                      // A8.6.230
1193   T1pIDPEncode<0b1000, (outs), (ins tGPR:$Rn, tGPR:$Rm), IIC_iTSTr,
1194                "tst", "\t$Rn, $Rm",
1195                [(ARMcmpZ (and_su tGPR:$Rn, tGPR:$Rm), 0)]>;
1196
1197 // Zero-extend byte
1198 def tUXTB :                     // A8.6.262
1199   T1pIMiscEncode<{0,0,1,0,1,1,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1200                  IIC_iUNAr,
1201                  "uxtb", "\t$Rd, $Rm",
1202                  [(set tGPR:$Rd, (and tGPR:$Rm, 0xFF))]>,
1203                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1204
1205 // Zero-extend short
1206 def tUXTH :                     // A8.6.264
1207   T1pIMiscEncode<{0,0,1,0,1,0,?}, (outs tGPR:$Rd), (ins tGPR:$Rm),
1208                  IIC_iUNAr,
1209                  "uxth", "\t$Rd, $Rm",
1210                  [(set tGPR:$Rd, (and tGPR:$Rm, 0xFFFF))]>,
1211                  Requires<[IsThumb, IsThumb1Only, HasV6]>;
1212
1213 // Conditional move tMOVCCr - Used to implement the Thumb SELECT_CC operation.
1214 // Expanded after instruction selection into a branch sequence.
1215 let usesCustomInserter = 1 in  // Expanded after instruction selection.
1216   def tMOVCCr_pseudo :
1217   PseudoInst<(outs tGPR:$dst), (ins tGPR:$false, tGPR:$true, pred:$cc),
1218               NoItinerary,
1219              [/*(set tGPR:$dst, (ARMcmov tGPR:$false, tGPR:$true, imm:$cc))*/]>;
1220
1221 // tLEApcrel - Load a pc-relative address into a register without offending the
1222 // assembler.
1223
1224 def tADR : T1I<(outs tGPR:$Rd), (ins t_adrlabel:$addr, pred:$p),
1225                IIC_iALUi, "adr{$p}\t$Rd, $addr", []>,
1226                T1Encoding<{1,0,1,0,0,?}> {
1227   bits<3> Rd;
1228   bits<8> addr;
1229   let Inst{10-8} = Rd;
1230   let Inst{7-0} = addr;
1231   let DecoderMethod = "DecodeThumbAddSpecialReg";
1232 }
1233
1234 let neverHasSideEffects = 1, isReMaterializable = 1 in
1235 def tLEApcrel   : tPseudoInst<(outs tGPR:$Rd), (ins i32imm:$label, pred:$p),
1236                               2, IIC_iALUi, []>;
1237
1238 let hasSideEffects = 1 in
1239 def tLEApcrelJT : tPseudoInst<(outs tGPR:$Rd),
1240                               (ins i32imm:$label, nohash_imm:$id, pred:$p),
1241                               2, IIC_iALUi, []>;
1242
1243 //===----------------------------------------------------------------------===//
1244 // TLS Instructions
1245 //
1246
1247 // __aeabi_read_tp preserves the registers r1-r3.
1248 // This is a pseudo inst so that we can get the encoding right,
1249 // complete with fixup for the aeabi_read_tp function.
1250 let isCall = 1, Defs = [R0, R12, LR, CPSR], Uses = [SP] in
1251 def tTPsoft : tPseudoInst<(outs), (ins), 4, IIC_Br,
1252                           [(set R0, ARMthread_pointer)]>;
1253
1254 //===----------------------------------------------------------------------===//
1255 // SJLJ Exception handling intrinsics
1256 //
1257
1258 // eh_sjlj_setjmp() is an instruction sequence to store the return address and
1259 // save #0 in R0 for the non-longjmp case.  Since by its nature we may be coming
1260 // from some other function to get here, and we're using the stack frame for the
1261 // containing function to save/restore registers, we can't keep anything live in
1262 // regs across the eh_sjlj_setjmp(), else it will almost certainly have been
1263 // tromped upon when we get here from a longjmp(). We force everything out of
1264 // registers except for our own input by listing the relevant registers in
1265 // Defs. By doing so, we also cause the prologue/epilogue code to actively
1266 // preserve all of the callee-saved resgisters, which is exactly what we want.
1267 // $val is a scratch register for our use.
1268 let Defs = [ R0,  R1,  R2,  R3,  R4,  R5,  R6,  R7, R12, CPSR ],
1269     hasSideEffects = 1, isBarrier = 1, isCodeGenOnly = 1,
1270     usesCustomInserter = 1 in
1271 def tInt_eh_sjlj_setjmp : ThumbXI<(outs),(ins tGPR:$src, tGPR:$val),
1272                                   AddrModeNone, 0, NoItinerary, "","",
1273                           [(set R0, (ARMeh_sjlj_setjmp tGPR:$src, tGPR:$val))]>;
1274
1275 // FIXME: Non-IOS version(s)
1276 let isBarrier = 1, hasSideEffects = 1, isTerminator = 1, isCodeGenOnly = 1,
1277     Defs = [ R7, LR, SP ] in
1278 def tInt_eh_sjlj_longjmp : XI<(outs), (ins GPR:$src, GPR:$scratch),
1279                               AddrModeNone, 0, IndexModeNone,
1280                               Pseudo, NoItinerary, "", "",
1281                               [(ARMeh_sjlj_longjmp GPR:$src, GPR:$scratch)]>,
1282                              Requires<[IsThumb, IsIOS]>;
1283
1284 let Defs = [ R0,  R1,  R2,  R3,  R4,  R5,  R6,  R7, R12, CPSR ],
1285     isBarrier = 1 in
1286 def tInt_eh_sjlj_dispatchsetup : PseudoInst<(outs), (ins), NoItinerary, []>;
1287
1288 //===----------------------------------------------------------------------===//
1289 // Non-Instruction Patterns
1290 //
1291
1292 // Comparisons
1293 def : T1Pat<(ARMcmpZ tGPR:$Rn, imm0_255:$imm8),
1294             (tCMPi8  tGPR:$Rn, imm0_255:$imm8)>;
1295 def : T1Pat<(ARMcmpZ tGPR:$Rn, tGPR:$Rm),
1296             (tCMPr   tGPR:$Rn, tGPR:$Rm)>;
1297
1298 // Add with carry
1299 def : T1Pat<(addc   tGPR:$lhs, imm0_7:$rhs),
1300             (tADDi3 tGPR:$lhs, imm0_7:$rhs)>;
1301 def : T1Pat<(addc   tGPR:$lhs, imm8_255:$rhs),
1302             (tADDi8 tGPR:$lhs, imm8_255:$rhs)>;
1303 def : T1Pat<(addc   tGPR:$lhs, tGPR:$rhs),
1304             (tADDrr tGPR:$lhs, tGPR:$rhs)>;
1305
1306 // Subtract with carry
1307 def : T1Pat<(addc   tGPR:$lhs, imm0_7_neg:$rhs),
1308             (tSUBi3 tGPR:$lhs, imm0_7_neg:$rhs)>;
1309 def : T1Pat<(addc   tGPR:$lhs, imm8_255_neg:$rhs),
1310             (tSUBi8 tGPR:$lhs, imm8_255_neg:$rhs)>;
1311 def : T1Pat<(subc   tGPR:$lhs, tGPR:$rhs),
1312             (tSUBrr tGPR:$lhs, tGPR:$rhs)>;
1313
1314 // ConstantPool, GlobalAddress
1315 def : T1Pat<(ARMWrapper  tglobaladdr :$dst), (tLEApcrel tglobaladdr :$dst)>;
1316 def : T1Pat<(ARMWrapper  tconstpool  :$dst), (tLEApcrel tconstpool  :$dst)>;
1317
1318 // JumpTable
1319 def : T1Pat<(ARMWrapperJT tjumptable:$dst, imm:$id),
1320             (tLEApcrelJT tjumptable:$dst, imm:$id)>;
1321
1322 // Direct calls
1323 def : T1Pat<(ARMtcall texternalsym:$func), (tBL texternalsym:$func)>,
1324       Requires<[IsThumb]>;
1325
1326 def : Tv5Pat<(ARMcall texternalsym:$func), (tBLXi texternalsym:$func)>,
1327       Requires<[IsThumb, HasV5T]>;
1328
1329 // Indirect calls to ARM routines
1330 def : Tv5Pat<(ARMcall GPR:$dst), (tBLXr GPR:$dst)>,
1331       Requires<[IsThumb, HasV5T]>;
1332
1333 // zextload i1 -> zextload i8
1334 def : T1Pat<(zextloadi1 t_addrmode_rrs1:$addr),
1335             (tLDRBr t_addrmode_rrs1:$addr)>;
1336 def : T1Pat<(zextloadi1 t_addrmode_is1:$addr),
1337             (tLDRBi t_addrmode_is1:$addr)>;
1338
1339 // extload -> zextload
1340 def : T1Pat<(extloadi1  t_addrmode_rrs1:$addr), (tLDRBr t_addrmode_rrs1:$addr)>;
1341 def : T1Pat<(extloadi1  t_addrmode_is1:$addr),  (tLDRBi t_addrmode_is1:$addr)>;
1342 def : T1Pat<(extloadi8  t_addrmode_rrs1:$addr), (tLDRBr t_addrmode_rrs1:$addr)>;
1343 def : T1Pat<(extloadi8  t_addrmode_is1:$addr),  (tLDRBi t_addrmode_is1:$addr)>;
1344 def : T1Pat<(extloadi16 t_addrmode_rrs2:$addr), (tLDRHr t_addrmode_rrs2:$addr)>;
1345 def : T1Pat<(extloadi16 t_addrmode_is2:$addr),  (tLDRHi t_addrmode_is2:$addr)>;
1346
1347 // If it's impossible to use [r,r] address mode for sextload, select to
1348 // ldr{b|h} + sxt{b|h} instead.
1349 def : T1Pat<(sextloadi8 t_addrmode_is1:$addr),
1350             (tSXTB (tLDRBi t_addrmode_is1:$addr))>,
1351       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1352 def : T1Pat<(sextloadi8 t_addrmode_rrs1:$addr),
1353             (tSXTB (tLDRBr t_addrmode_rrs1:$addr))>,
1354       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1355 def : T1Pat<(sextloadi16 t_addrmode_is2:$addr),
1356             (tSXTH (tLDRHi t_addrmode_is2:$addr))>,
1357       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1358 def : T1Pat<(sextloadi16 t_addrmode_rrs2:$addr),
1359             (tSXTH (tLDRHr t_addrmode_rrs2:$addr))>,
1360       Requires<[IsThumb, IsThumb1Only, HasV6]>;
1361
1362 def : T1Pat<(sextloadi8 t_addrmode_rrs1:$addr),
1363             (tASRri (tLSLri (tLDRBr t_addrmode_rrs1:$addr), 24), 24)>;
1364 def : T1Pat<(sextloadi8 t_addrmode_is1:$addr),
1365             (tASRri (tLSLri (tLDRBi t_addrmode_is1:$addr), 24), 24)>;
1366 def : T1Pat<(sextloadi16 t_addrmode_rrs2:$addr),
1367             (tASRri (tLSLri (tLDRHr t_addrmode_rrs2:$addr), 16), 16)>;
1368 def : T1Pat<(sextloadi16 t_addrmode_is2:$addr),
1369             (tASRri (tLSLri (tLDRHi t_addrmode_is2:$addr), 16), 16)>;
1370
1371 def : T1Pat<(atomic_load_8 t_addrmode_is1:$src),
1372              (ATOMIC_tLDRBi t_addrmode_is1:$src)>;
1373 def : T1Pat<(atomic_load_8 t_addrmode_rrs1:$src),
1374              (ATOMIC_tLDRBr t_addrmode_rrs1:$src)>;
1375 def : T1Pat<(atomic_load_16 t_addrmode_is2:$src),
1376              (ATOMIC_tLDRHi t_addrmode_is2:$src)>;
1377 def : T1Pat<(atomic_load_16 t_addrmode_rrs2:$src),
1378              (ATOMIC_tLDRHr t_addrmode_rrs2:$src)>;
1379 def : T1Pat<(atomic_load_32 t_addrmode_is4:$src),
1380              (ATOMIC_tLDRi t_addrmode_is4:$src)>;
1381 def : T1Pat<(atomic_load_32 t_addrmode_rrs4:$src),
1382              (ATOMIC_tLDRr t_addrmode_rrs4:$src)>;
1383 def : T1Pat<(atomic_store_8 t_addrmode_is1:$ptr, tGPR:$val),
1384              (tSTRBi tGPR:$val, t_addrmode_is1:$ptr)>;
1385 def : T1Pat<(atomic_store_8 t_addrmode_rrs1:$ptr, tGPR:$val),
1386              (tSTRBr tGPR:$val, t_addrmode_rrs1:$ptr)>;
1387 def : T1Pat<(atomic_store_16 t_addrmode_is2:$ptr, tGPR:$val),
1388              (tSTRHi tGPR:$val, t_addrmode_is2:$ptr)>;
1389 def : T1Pat<(atomic_store_16 t_addrmode_rrs2:$ptr, tGPR:$val),
1390              (tSTRHr tGPR:$val, t_addrmode_rrs2:$ptr)>;
1391 def : T1Pat<(atomic_store_32 t_addrmode_is4:$ptr, tGPR:$val),
1392              (tSTRi tGPR:$val, t_addrmode_is4:$ptr)>;
1393 def : T1Pat<(atomic_store_32 t_addrmode_rrs4:$ptr, tGPR:$val),
1394              (tSTRr tGPR:$val, t_addrmode_rrs4:$ptr)>;
1395
1396 // Large immediate handling.
1397
1398 // Two piece imms.
1399 def : T1Pat<(i32 thumb_immshifted:$src),
1400             (tLSLri (tMOVi8 (thumb_immshifted_val imm:$src)),
1401                     (thumb_immshifted_shamt imm:$src))>;
1402
1403 def : T1Pat<(i32 imm0_255_comp:$src),
1404             (tMVN (tMOVi8 (imm_comp_XFORM imm:$src)))>;
1405
1406 // Pseudo instruction that combines ldr from constpool and add pc. This should
1407 // be expanded into two instructions late to allow if-conversion and
1408 // scheduling.
1409 let isReMaterializable = 1 in
1410 def tLDRpci_pic : PseudoInst<(outs GPR:$dst), (ins i32imm:$addr, pclabel:$cp),
1411                              NoItinerary,
1412                [(set GPR:$dst, (ARMpic_add (load (ARMWrapper tconstpool:$addr)),
1413                                            imm:$cp))]>,
1414                Requires<[IsThumb, IsThumb1Only]>;
1415
1416 // Pseudo-instruction for merged POP and return.
1417 // FIXME: remove when we have a way to marking a MI with these properties.
1418 let isReturn = 1, isTerminator = 1, isBarrier = 1, mayLoad = 1,
1419     hasExtraDefRegAllocReq = 1 in
1420 def tPOP_RET : tPseudoExpand<(outs), (ins pred:$p, reglist:$regs, variable_ops),
1421                            2, IIC_iPop_Br, [],
1422                            (tPOP pred:$p, reglist:$regs)>;
1423
1424 // Indirect branch using "mov pc, $Rm"
1425 let isBranch = 1, isTerminator = 1, isBarrier = 1, isIndirectBranch = 1 in {
1426   def tBRIND : tPseudoExpand<(outs), (ins GPR:$Rm, pred:$p),
1427                   2, IIC_Br, [(brind GPR:$Rm)],
1428                   (tMOVr PC, GPR:$Rm, pred:$p)>;
1429 }
1430
1431
1432 // In Thumb1, "nop" is encoded as a "mov r8, r8". Technically, the bf00
1433 // encoding is available on ARMv6K, but we don't differentiate that finely.
1434 def : InstAlias<"nop", (tMOVr R8, R8, 14, 0)>,Requires<[IsThumb, IsThumb1Only]>;
1435
1436
1437 // For round-trip assembly/disassembly, we have to handle a CPS instruction
1438 // without any iflags. That's not, strictly speaking, valid syntax, but it's
1439 // a useful extension and assembles to defined behaviour (the insn does
1440 // nothing).
1441 def : tInstAlias<"cps$imod", (tCPS imod_op:$imod, 0)>;
1442 def : tInstAlias<"cps$imod", (tCPS imod_op:$imod, 0)>;
1443
1444 // "neg" is and alias for "rsb rd, rn, #0"
1445 def : tInstAlias<"neg${s}${p} $Rd, $Rm",
1446                  (tRSB tGPR:$Rd, s_cc_out:$s, tGPR:$Rm, pred:$p)>;
1447
1448
1449 // Implied destination operand forms for shifts.
1450 def : tInstAlias<"lsl${s}${p} $Rdm, $imm",
1451              (tLSLri tGPR:$Rdm, cc_out:$s, tGPR:$Rdm, imm0_31:$imm, pred:$p)>;
1452 def : tInstAlias<"lsr${s}${p} $Rdm, $imm",
1453              (tLSRri tGPR:$Rdm, cc_out:$s, tGPR:$Rdm, imm_sr:$imm, pred:$p)>;
1454 def : tInstAlias<"asr${s}${p} $Rdm, $imm",
1455              (tASRri tGPR:$Rdm, cc_out:$s, tGPR:$Rdm, imm_sr:$imm, pred:$p)>;