lib/Target/ARM/ARMInstrThumb2.td

   1 //===- ARMInstrThumb2.td - Thumb2 support for ARM -------------------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Thumb2 instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 // IT block predicate field
  15 def it_pred : Operand<i32> {
  16   let PrintMethod = "printPredicateOperand";
  17 }
  18
  19 // IT block condition mask
  20 def it_mask : Operand<i32> {
  21   let PrintMethod = "printThumbITMask";
  22 }
  23
  24 // Shifted operands. No register controlled shifts for Thumb2.
  25 // Note: We do not support rrx shifted operands yet.
  26 def t2_so_reg : Operand<i32>,    // reg imm
  27                 ComplexPattern<i32, 2, "SelectT2ShifterOperandReg",
  28                                [shl,srl,sra,rotr]> {
  29   let PrintMethod = "printT2SOOperand";
  30   let MIOperandInfo = (ops GPR, i32imm);
  31 }
  32
  33 // t2_so_imm_not_XFORM - Return the complement of a t2_so_imm value
  34 def t2_so_imm_not_XFORM : SDNodeXForm<imm, [{
  35   return CurDAG->getTargetConstant(~((uint32_t)N->getZExtValue()), MVT::i32);
  36 }]>;
  37
  38 // t2_so_imm_neg_XFORM - Return the negation of a t2_so_imm value
  39 def t2_so_imm_neg_XFORM : SDNodeXForm<imm, [{
  40   return CurDAG->getTargetConstant(-((int)N->getZExtValue()), MVT::i32);
  41 }]>;
  42
  43 // t2_so_imm - Match a 32-bit immediate operand, which is an
  44 // 8-bit immediate rotated by an arbitrary number of bits, or an 8-bit
  45 // immediate splatted into multiple bytes of the word. t2_so_imm values are
  46 // represented in the imm field in the same 12-bit form that they are encoded
  47 // into t2_so_imm instructions: the 8-bit immediate is the least significant bits
  48 // [bits 0-7], the 4-bit shift/splat amount is the next 4 bits [bits 8-11].
  49 def t2_so_imm : Operand<i32>,
  50                 PatLeaf<(imm), [{
  51   return ARM_AM::getT2SOImmVal((uint32_t)N->getZExtValue()) != -1;
  52 }]>;
  53
  54 // t2_so_imm_not - Match an immediate that is a complement
  55 // of a t2_so_imm.
  56 def t2_so_imm_not : Operand<i32>,
  57                     PatLeaf<(imm), [{
  58   return ARM_AM::getT2SOImmVal(~((uint32_t)N->getZExtValue())) != -1;
  59 }], t2_so_imm_not_XFORM>;
  60
  61 // t2_so_imm_neg - Match an immediate that is a negation of a t2_so_imm.
  62 def t2_so_imm_neg : Operand<i32>,
  63                     PatLeaf<(imm), [{
  64   return ARM_AM::getT2SOImmVal(-((int)N->getZExtValue())) != -1;
  65 }], t2_so_imm_neg_XFORM>;
  66
  67 /// imm1_31 predicate - True if the 32-bit immediate is in the range [1,31].
  68 def imm1_31 : PatLeaf<(i32 imm), [{
  69   return (int32_t)N->getZExtValue() >= 1 && (int32_t)N->getZExtValue() < 32;
  70 }]>;
  71
  72 /// imm0_4095 predicate - True if the 32-bit immediate is in the range [0.4095].
  73 def imm0_4095 : PatLeaf<(i32 imm), [{
  74   return (uint32_t)N->getZExtValue() < 4096;
  75 }]>;
  76
  77 def imm0_4095_neg : PatLeaf<(i32 imm), [{
  78  return (uint32_t)(-N->getZExtValue()) < 4096;
  79 }], imm_neg_XFORM>;
  80
  81 /// imm0_65535 predicate - True if the 32-bit immediate is in the range
  82 /// [0.65535].
  83 def imm0_65535 : PatLeaf<(i32 imm), [{
  84   return (uint32_t)N->getZExtValue() < 65536;
  85 }]>;
  86
  87 /// Split a 32-bit immediate into two 16 bit parts.
  88 def t2_lo16 : SDNodeXForm<imm, [{
  89   return CurDAG->getTargetConstant((uint32_t)N->getZExtValue() & 0xffff,
  90                                    MVT::i32);
  91 }]>;
  92
  93 def t2_hi16 : SDNodeXForm<imm, [{
  94   return CurDAG->getTargetConstant((uint32_t)N->getZExtValue() >> 16, MVT::i32);
  95 }]>;
  96
  97 def t2_lo16AllZero : PatLeaf<(i32 imm), [{
  98   // Returns true if all low 16-bits are 0.
  99   return (((uint32_t)N->getZExtValue()) & 0xFFFFUL) == 0;
 100   }], t2_hi16>;
 101
 102
 103 // Define Thumb2 specific addressing modes.
 104
 105 // t2addrmode_imm12  := reg + imm12
 106 def t2addrmode_imm12 : Operand<i32>,
 107                        ComplexPattern<i32, 2, "SelectT2AddrModeImm12", []> {
 108   let PrintMethod = "printT2AddrModeImm12Operand";
 109   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 110 }
 111
 112 // t2addrmode_imm8  := reg - imm8
 113 def t2addrmode_imm8 : Operand<i32>,
 114                       ComplexPattern<i32, 2, "SelectT2AddrModeImm8", []> {
 115   let PrintMethod = "printT2AddrModeImm8Operand";
 116   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 117 }
 118
 119 def t2am_imm8_offset : Operand<i32>,
 120                        ComplexPattern<i32, 1, "SelectT2AddrModeImm8Offset", []>{
 121   let PrintMethod = "printT2AddrModeImm8OffsetOperand";
 122 }
 123
 124 // t2addrmode_imm8s4  := reg +/- (imm8 << 2)
 125 def t2addrmode_imm8s4 : Operand<i32>,
 126                         ComplexPattern<i32, 2, "SelectT2AddrModeImm8s4", []> {
 127   let PrintMethod = "printT2AddrModeImm8s4Operand";
 128   let MIOperandInfo = (ops GPR:$base, i32imm:$offsimm);
 129 }
 130
 131 // t2addrmode_so_reg  := reg + (reg << imm2)
 132 def t2addrmode_so_reg : Operand<i32>,
 133                         ComplexPattern<i32, 3, "SelectT2AddrModeSoReg", []> {
 134   let PrintMethod = "printT2AddrModeSoRegOperand";
 135   let MIOperandInfo = (ops GPR:$base, GPR:$offsreg, i32imm:$offsimm);
 136 }
 137
 138
 139 //===----------------------------------------------------------------------===//
 140 // Multiclass helpers...
 141 //
 142
 143 /// T2I_un_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 144 /// unary operation that produces a value. These are predicable and can be
 145 /// changed to modify CPSR.
 146 multiclass T2I_un_irs<string opc, PatFrag opnode, bit Cheap = 0, bit ReMat = 0>{
 147    // shifted imm
 148    def i : T2sI<(outs GPR:$dst), (ins t2_so_imm:$src),
 149                 opc, " $dst, $src",
 150                 [(set GPR:$dst, (opnode t2_so_imm:$src))]> {
 151      let isAsCheapAsAMove = Cheap;
 152      let isReMaterializable = ReMat;
 153    }
 154    // register
 155    def r : T2I<(outs GPR:$dst), (ins GPR:$src),
 156                opc, ".w $dst, $src",
 157                 [(set GPR:$dst, (opnode GPR:$src))]>;
 158    // shifted register
 159    def s : T2I<(outs GPR:$dst), (ins t2_so_reg:$src),
 160                opc, ".w $dst, $src",
 161                [(set GPR:$dst, (opnode t2_so_reg:$src))]>;
 162 }
 163
 164 /// T2I_bin_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 165 //  binary operation that produces a value. These are predicable and can be
 166 /// changed to modify CPSR.
 167 multiclass T2I_bin_irs<string opc, PatFrag opnode,
 168                        bit Commutable = 0, string wide =""> {
 169    // shifted imm
 170    def ri : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 171                  opc, " $dst, $lhs, $rhs",
 172                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 173    // register
 174    def rr : T2sI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 175                  opc, !strconcat(wide, " $dst, $lhs, $rhs"),
 176                  [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]> {
 177      let isCommutable = Commutable;
 178    }
 179    // shifted register
 180    def rs : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 181                  opc, !strconcat(wide, " $dst, $lhs, $rhs"),
 182                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 183 }
 184
 185 /// T2I_bin_w_irs - Same as T2I_bin_irs except these operations need
 186 //  the ".w" prefix to indicate that they are wide.
 187 multiclass T2I_bin_w_irs<string opc, PatFrag opnode, bit Commutable = 0> :
 188     T2I_bin_irs<opc, opnode, Commutable, ".w">;
 189
 190 /// T2I_rbin_is - Same as T2I_bin_irs except the order of operands are
 191 /// reversed. It doesn't define the 'rr' form since it's handled by its
 192 /// T2I_bin_irs counterpart.
 193 multiclass T2I_rbin_is<string opc, PatFrag opnode> {
 194    // shifted imm
 195    def ri : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_imm:$lhs),
 196                 opc, ".w $dst, $rhs, $lhs",
 197                 [(set GPR:$dst, (opnode t2_so_imm:$lhs, GPR:$rhs))]>;
 198    // shifted register
 199    def rs : T2I<(outs GPR:$dst), (ins GPR:$rhs, t2_so_reg:$lhs),
 200                 opc, " $dst, $rhs, $lhs",
 201                 [(set GPR:$dst, (opnode t2_so_reg:$lhs, GPR:$rhs))]>;
 202 }
 203
 204 /// T2I_bin_s_irs - Similar to T2I_bin_irs except it sets the 's' bit so the
 205 /// instruction modifies the CPSR register.
 206 let Defs = [CPSR] in {
 207 multiclass T2I_bin_s_irs<string opc, PatFrag opnode, bit Commutable = 0> {
 208    // shifted imm
 209    def ri : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 210                 !strconcat(opc, "s"), ".w $dst, $lhs, $rhs",
 211                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 212    // register
 213    def rr : T2I<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 214                 !strconcat(opc, "s"), ".w $dst, $lhs, $rhs",
 215                 [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]> {
 216      let isCommutable = Commutable;
 217    }
 218    // shifted register
 219    def rs : T2I<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 220                 !strconcat(opc, "s"), ".w $dst, $lhs, $rhs",
 221                 [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 222 }
 223 }
 224
 225 /// T2I_bin_ii12rs - Defines a set of (op reg, {so_imm|imm0_4095|r|so_reg})
 226 /// patterns for a binary operation that produces a value.
 227 multiclass T2I_bin_ii12rs<string opc, PatFrag opnode, bit Commutable = 0> {
 228    // shifted imm
 229    def ri : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 230                  opc, ".w $dst, $lhs, $rhs",
 231                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>;
 232    // 12-bit imm
 233    def ri12 : T2sI<(outs GPR:$dst), (ins GPR:$lhs, i32imm:$rhs),
 234                    !strconcat(opc, "w"), " $dst, $lhs, $rhs",
 235                    [(set GPR:$dst, (opnode GPR:$lhs, imm0_4095:$rhs))]>;
 236    // register
 237    def rr : T2sI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 238                  opc, ".w $dst, $lhs, $rhs",
 239                  [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]> {
 240      let isCommutable = Commutable;
 241    }
 242    // shifted register
 243    def rs : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 244                  opc, ".w $dst, $lhs, $rhs",
 245                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>;
 246 }
 247
 248 /// T2I_adde_sube_irs - Defines a set of (op reg, {so_imm|r|so_reg}) patterns for a
 249 /// binary operation that produces a value and use and define the carry bit.
 250 /// It's not predicable.
 251 let Uses = [CPSR] in {
 252 multiclass T2I_adde_sube_irs<string opc, PatFrag opnode, bit Commutable = 0> {
 253    // shifted imm
 254    def ri : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 255                  opc, " $dst, $lhs, $rhs",
 256                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>,
 257                  Requires<[IsThumb2, CarryDefIsUnused]>;
 258    // register
 259    def rr : T2sI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 260                  opc, ".w $dst, $lhs, $rhs",
 261                  [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>,
 262                  Requires<[IsThumb2, CarryDefIsUnused]> {
 263      let isCommutable = Commutable;
 264    }
 265    // shifted register
 266    def rs : T2sI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 267                  opc, ".w $dst, $lhs, $rhs",
 268                  [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>,
 269                  Requires<[IsThumb2, CarryDefIsUnused]>;
 270    // Carry setting variants
 271    // shifted imm
 272    def Sri : T2XI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_imm:$rhs),
 273                   !strconcat(opc, "s $dst, $lhs, $rhs"),
 274                   [(set GPR:$dst, (opnode GPR:$lhs, t2_so_imm:$rhs))]>,
 275                   Requires<[IsThumb2, CarryDefIsUsed]> {
 276                     let Defs = [CPSR];
 277                   }
 278    // register
 279    def Srr : T2XI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 280                   !strconcat(opc, "s.w $dst, $lhs, $rhs"),
 281                   [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>,
 282                   Requires<[IsThumb2, CarryDefIsUsed]> {
 283                     let Defs = [CPSR];
 284                     let isCommutable = Commutable;
 285    }
 286    // shifted register
 287    def Srs : T2XI<(outs GPR:$dst), (ins GPR:$lhs, t2_so_reg:$rhs),
 288                   !strconcat(opc, "s.w $dst, $lhs, $rhs"),
 289                   [(set GPR:$dst, (opnode GPR:$lhs, t2_so_reg:$rhs))]>,
 290                   Requires<[IsThumb2, CarryDefIsUsed]> {
 291                     let Defs = [CPSR];
 292    }
 293 }
 294 }
 295
 296 /// T2I_rbin_s_is - Same as T2I_rbin_is except sets 's' bit.
 297 let Defs = [CPSR] in {
 298 multiclass T2I_rbin_s_is<string opc, PatFrag opnode> {
 299    // shifted imm
 300    def ri : T2XI<(outs GPR:$dst), (ins GPR:$rhs, t2_so_imm:$lhs, cc_out:$s),
 301                  !strconcat(opc, "${s}.w $dst, $rhs, $lhs"),
 302                  [(set GPR:$dst, (opnode t2_so_imm:$lhs, GPR:$rhs))]>;
 303    // shifted register
 304    def rs : T2XI<(outs GPR:$dst), (ins GPR:$rhs, t2_so_reg:$lhs, cc_out:$s),
 305                  !strconcat(opc, "${s} $dst, $rhs, $lhs"),
 306                  [(set GPR:$dst, (opnode t2_so_reg:$lhs, GPR:$rhs))]>;
 307 }
 308 }
 309
 310 /// T2I_sh_ir - Defines a set of (op reg, {so_imm|r}) patterns for a shift /
 311 //  rotate operation that produces a value.
 312 multiclass T2I_sh_ir<string opc, PatFrag opnode> {
 313    // 5-bit imm
 314    def ri : T2sI<(outs GPR:$dst), (ins GPR:$lhs, i32imm:$rhs),
 315                  opc, ".w $dst, $lhs, $rhs",
 316                  [(set GPR:$dst, (opnode GPR:$lhs, imm1_31:$rhs))]>;
 317    // register
 318    def rr : T2sI<(outs GPR:$dst), (ins GPR:$lhs, GPR:$rhs),
 319                  opc, ".w $dst, $lhs, $rhs",
 320                  [(set GPR:$dst, (opnode GPR:$lhs, GPR:$rhs))]>;
 321 }
 322
 323 /// T21_cmp_irs - Defines a set of (op r, {so_imm|r|so_reg}) cmp / test
 324 /// patterns. Similar to T2I_bin_irs except the instruction does not produce
 325 /// a explicit result, only implicitly set CPSR.
 326 let Defs = [CPSR] in {
 327 multiclass T2I_cmp_is<string opc, PatFrag opnode> {
 328    // shifted imm
 329    def ri : T2I<(outs), (ins GPR:$lhs, t2_so_imm:$rhs),
 330                 opc, ".w $lhs, $rhs",
 331                 [(opnode GPR:$lhs, t2_so_imm:$rhs)]>;
 332    // register
 333    def rr : T2I<(outs), (ins GPR:$lhs, GPR:$rhs),
 334                 opc, ".w $lhs, $rhs",
 335                 [(opnode GPR:$lhs, GPR:$rhs)]>;
 336    // shifted register
 337    def rs : T2I<(outs), (ins GPR:$lhs, t2_so_reg:$rhs),
 338                 opc, ".w $lhs, $rhs",
 339                 [(opnode GPR:$lhs, t2_so_reg:$rhs)]>;
 340 }
 341 }
 342
 343 /// T2I_ld - Defines a set of (op r, {imm12|imm8|so_reg}) load patterns.
 344 multiclass T2I_ld<string opc, PatFrag opnode> {
 345   def i12 : T2Ii12<(outs GPR:$dst), (ins t2addrmode_imm12:$addr),
 346                    opc, ".w $dst, $addr",
 347                    [(set GPR:$dst, (opnode t2addrmode_imm12:$addr))]>;
 348   def i8  : T2Ii8 <(outs GPR:$dst), (ins t2addrmode_imm8:$addr),
 349                    opc, " $dst, $addr",
 350                    [(set GPR:$dst, (opnode t2addrmode_imm8:$addr))]>;
 351   def s   : T2Iso <(outs GPR:$dst), (ins t2addrmode_so_reg:$addr),
 352                    opc, ".w $dst, $addr",
 353                    [(set GPR:$dst, (opnode t2addrmode_so_reg:$addr))]>;
 354   def pci : T2Ipc <(outs GPR:$dst), (ins i32imm:$addr),
 355                    opc, ".w $dst, $addr",
 356                    [(set GPR:$dst, (opnode (ARMWrapper tconstpool:$addr)))]>;
 357 }
 358
 359 /// T2I_st - Defines a set of (op r, {imm12|imm8|so_reg}) store patterns.
 360 multiclass T2I_st<string opc, PatFrag opnode> {
 361   def i12 : T2Ii12<(outs), (ins GPR:$src, t2addrmode_imm12:$addr),
 362                    opc, ".w $src, $addr",
 363                    [(opnode GPR:$src, t2addrmode_imm12:$addr)]>;
 364   def i8  : T2Ii8 <(outs), (ins GPR:$src, t2addrmode_imm8:$addr),
 365                    opc, " $src, $addr",
 366                    [(opnode GPR:$src, t2addrmode_imm8:$addr)]>;
 367   def s   : T2Iso <(outs), (ins GPR:$src, t2addrmode_so_reg:$addr),
 368                    opc, ".w $src, $addr",
 369                    [(opnode GPR:$src, t2addrmode_so_reg:$addr)]>;
 370 }
 371
 372 /// T2I_picld - Defines the PIC load pattern.
 373 class T2I_picld<string opc, PatFrag opnode> :
 374       T2I<(outs GPR:$dst), (ins addrmodepc:$addr),
 375           !strconcat("${addr:label}:\n\t", opc), " $dst, $addr",
 376           [(set GPR:$dst, (opnode addrmodepc:$addr))]>;
 377
 378 /// T2I_picst - Defines the PIC store pattern.
 379 class T2I_picst<string opc, PatFrag opnode> :
 380       T2I<(outs), (ins GPR:$src, addrmodepc:$addr),
 381           !strconcat("${addr:label}:\n\t", opc), " $src, $addr",
 382           [(opnode GPR:$src, addrmodepc:$addr)]>;
 383
 384
 385 /// T2I_unary_rrot - A unary operation with two forms: one whose operand is a
 386 /// register and one whose operand is a register rotated by 8/16/24.
 387 multiclass T2I_unary_rrot<string opc, PatFrag opnode> {
 388   def r     : T2I<(outs GPR:$dst), (ins GPR:$Src),
 389                   opc, ".w $dst, $Src",
 390                  [(set GPR:$dst, (opnode GPR:$Src))]>;
 391   def r_rot : T2I<(outs GPR:$dst), (ins GPR:$Src, i32imm:$rot),
 392                   opc, ".w $dst, $Src, ror $rot",
 393                  [(set GPR:$dst, (opnode (rotr GPR:$Src, rot_imm:$rot)))]>;
 394 }
 395
 396 /// T2I_bin_rrot - A binary operation with two forms: one whose operand is a
 397 /// register and one whose operand is a register rotated by 8/16/24.
 398 multiclass T2I_bin_rrot<string opc, PatFrag opnode> {
 399   def rr     : T2I<(outs GPR:$dst), (ins GPR:$LHS, GPR:$RHS),
 400                   opc, " $dst, $LHS, $RHS",
 401                   [(set GPR:$dst, (opnode GPR:$LHS, GPR:$RHS))]>;
 402   def rr_rot : T2I<(outs GPR:$dst), (ins GPR:$LHS, GPR:$RHS, i32imm:$rot),
 403                   opc, " $dst, $LHS, $RHS, ror $rot",
 404                   [(set GPR:$dst, (opnode GPR:$LHS,
 405                                           (rotr GPR:$RHS, rot_imm:$rot)))]>;
 406 }
 407
 408 //===----------------------------------------------------------------------===//
 409 // Instructions
 410 //===----------------------------------------------------------------------===//
 411
 412 //===----------------------------------------------------------------------===//
 413 //  Miscellaneous Instructions.
 414 //
 415
 416 let isNotDuplicable = 1 in
 417 def t2PICADD : T2XI<(outs GPR:$dst), (ins GPR:$lhs, pclabel:$cp),
 418                     "$cp:\n\tadd.w $dst, $lhs, pc",
 419                     [(set GPR:$dst, (ARMpic_add GPR:$lhs, imm:$cp))]>;
 420
 421
 422 // LEApcrel - Load a pc-relative address into a register without offending the
 423 // assembler.
 424 def t2LEApcrel : T2XI<(outs GPR:$dst), (ins i32imm:$label, pred:$p),
 425                       "adr$p.w $dst, #$label", []>;
 426
 427 def t2LEApcrelJT : T2XI<(outs GPR:$dst),
 428                         (ins i32imm:$label, i32imm:$id, pred:$p),
 429                         "adr$p.w $dst, #${label}_${id:no_hash}", []>;
 430
 431 // ADD rd, sp, #so_imm
 432 def t2ADDrSPi : T2XI<(outs GPR:$dst), (ins GPR:$sp, t2_so_imm:$imm),
 433                      "add.w $dst, $sp, $imm",
 434                      []>;
 435
 436 // ADD rd, sp, #imm12
 437 def t2ADDrSPi12 : T2XI<(outs GPR:$dst), (ins GPR:$sp, i32imm:$imm),
 438                        "addw $dst, $sp, $imm",
 439                        []>;
 440
 441 def t2ADDrSPs : T2XI<(outs GPR:$dst), (ins GPR:$sp, t2_so_reg:$rhs),
 442                      "addw $dst, $sp, $rhs",
 443                      []>;
 444
 445
 446 //===----------------------------------------------------------------------===//
 447 //  Load / store Instructions.
 448 //
 449
 450 // Load
 451 let canFoldAsLoad = 1 in
 452 defm t2LDR   : T2I_ld<"ldr",  UnOpFrag<(load node:$Src)>>;
 453
 454 // Loads with zero extension
 455 defm t2LDRH  : T2I_ld<"ldrh", UnOpFrag<(zextloadi16 node:$Src)>>;
 456 defm t2LDRB  : T2I_ld<"ldrb", UnOpFrag<(zextloadi8  node:$Src)>>;
 457
 458 // Loads with sign extension
 459 defm t2LDRSH : T2I_ld<"ldrsh", UnOpFrag<(sextloadi16 node:$Src)>>;
 460 defm t2LDRSB : T2I_ld<"ldrsb", UnOpFrag<(sextloadi8  node:$Src)>>;
 461
 462 let mayLoad = 1 in {
 463 // Load doubleword
 464 def t2LDRDi8 : T2Ii8s4<(outs GPR:$dst), (ins t2addrmode_imm8s4:$addr),
 465                        "ldrd", " $dst, $addr", []>;
 466 def t2LDRDpci : T2Ii8s4<(outs GPR:$dst), (ins i32imm:$addr),
 467                        "ldrd", " $dst, $addr", []>;
 468 }
 469
 470 // zextload i1 -> zextload i8
 471 def : T2Pat<(zextloadi1 t2addrmode_imm12:$addr),
 472             (t2LDRBi12  t2addrmode_imm12:$addr)>;
 473 def : T2Pat<(zextloadi1 t2addrmode_imm8:$addr),
 474             (t2LDRBi8   t2addrmode_imm8:$addr)>;
 475 def : T2Pat<(zextloadi1 t2addrmode_so_reg:$addr),
 476             (t2LDRBs    t2addrmode_so_reg:$addr)>;
 477 def : T2Pat<(zextloadi1 (ARMWrapper tconstpool:$addr)),
 478             (t2LDRBpci  tconstpool:$addr)>;
 479
 480 // extload -> zextload
 481 // FIXME: Reduce the number of patterns by legalizing extload to zextload
 482 // earlier?
 483 def : T2Pat<(extloadi1  t2addrmode_imm12:$addr),
 484             (t2LDRBi12  t2addrmode_imm12:$addr)>;
 485 def : T2Pat<(extloadi1  t2addrmode_imm8:$addr),
 486             (t2LDRBi8   t2addrmode_imm8:$addr)>;
 487 def : T2Pat<(extloadi1  t2addrmode_so_reg:$addr),
 488             (t2LDRBs    t2addrmode_so_reg:$addr)>;
 489 def : T2Pat<(extloadi1  (ARMWrapper tconstpool:$addr)),
 490             (t2LDRBpci  tconstpool:$addr)>;
 491
 492 def : T2Pat<(extloadi8  t2addrmode_imm12:$addr),
 493             (t2LDRBi12  t2addrmode_imm12:$addr)>;
 494 def : T2Pat<(extloadi8  t2addrmode_imm8:$addr),
 495             (t2LDRBi8   t2addrmode_imm8:$addr)>;
 496 def : T2Pat<(extloadi8  t2addrmode_so_reg:$addr),
 497             (t2LDRBs    t2addrmode_so_reg:$addr)>;
 498 def : T2Pat<(extloadi8  (ARMWrapper tconstpool:$addr)),
 499             (t2LDRBpci  tconstpool:$addr)>;
 500
 501 def : T2Pat<(extloadi16 t2addrmode_imm12:$addr),
 502             (t2LDRHi12  t2addrmode_imm12:$addr)>;
 503 def : T2Pat<(extloadi16 t2addrmode_imm8:$addr),
 504             (t2LDRHi8   t2addrmode_imm8:$addr)>;
 505 def : T2Pat<(extloadi16 t2addrmode_so_reg:$addr),
 506             (t2LDRHs    t2addrmode_so_reg:$addr)>;
 507 def : T2Pat<(extloadi16 (ARMWrapper tconstpool:$addr)),
 508             (t2LDRHpci  tconstpool:$addr)>;
 509
 510 // Indexed loads
 511 let mayLoad = 1 in {
 512 def t2LDR_PRE  : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 513                             (ins t2addrmode_imm8:$addr),
 514                             AddrModeT2_i8, IndexModePre,
 515                             "ldr", " $dst, $addr!", "$addr.base = $base_wb",
 516                             []>;
 517
 518 def t2LDR_POST : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 519                             (ins GPR:$base, t2am_imm8_offset:$offset),
 520                             AddrModeT2_i8, IndexModePost,
 521                            "ldr", " $dst, [$base], $offset", "$base = $base_wb",
 522                             []>;
 523
 524 def t2LDRB_PRE : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 525                             (ins t2addrmode_imm8:$addr),
 526                             AddrModeT2_i8, IndexModePre,
 527                             "ldrb", " $dst, $addr!", "$addr.base = $base_wb",
 528                             []>;
 529 def t2LDRB_POST : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 530                             (ins GPR:$base, t2am_imm8_offset:$offset),
 531                             AddrModeT2_i8, IndexModePost,
 532                           "ldrb", " $dst, [$base], $offset", "$base = $base_wb",
 533                             []>;
 534
 535 def t2LDRH_PRE : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 536                             (ins t2addrmode_imm8:$addr),
 537                             AddrModeT2_i8, IndexModePre,
 538                             "ldrh", " $dst, $addr!", "$addr.base = $base_wb",
 539                             []>;
 540 def t2LDRH_POST : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 541                             (ins GPR:$base, t2am_imm8_offset:$offset),
 542                             AddrModeT2_i8, IndexModePost,
 543                           "ldrh", " $dst, [$base], $offset", "$base = $base_wb",
 544                             []>;
 545
 546 def t2LDRSB_PRE : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 547                             (ins t2addrmode_imm8:$addr),
 548                             AddrModeT2_i8, IndexModePre,
 549                             "ldrsb", " $dst, $addr!", "$addr.base = $base_wb",
 550                             []>;
 551 def t2LDRSB_POST : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 552                             (ins GPR:$base, t2am_imm8_offset:$offset),
 553                             AddrModeT2_i8, IndexModePost,
 554                          "ldrsb", " $dst, [$base], $offset", "$base = $base_wb",
 555                             []>;
 556
 557 def t2LDRSH_PRE : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 558                             (ins t2addrmode_imm8:$addr),
 559                             AddrModeT2_i8, IndexModePre,
 560                             "ldrsh", " $dst, $addr!", "$addr.base = $base_wb",
 561                             []>;
 562 def t2LDRSH_POST : T2Iidxldst<(outs GPR:$dst, GPR:$base_wb),
 563                             (ins GPR:$base, t2am_imm8_offset:$offset),
 564                             AddrModeT2_i8, IndexModePost,
 565                          "ldrsh", " $dst, [$base], $offset", "$base = $base_wb",
 566                             []>;
 567 }
 568
 569 // Store
 570 defm t2STR   : T2I_st<"str",  BinOpFrag<(store node:$LHS, node:$RHS)>>;
 571 defm t2STRB  : T2I_st<"strb", BinOpFrag<(truncstorei8 node:$LHS, node:$RHS)>>;
 572 defm t2STRH  : T2I_st<"strh", BinOpFrag<(truncstorei16 node:$LHS, node:$RHS)>>;
 573
 574 // Store doubleword
 575 let mayLoad = 1 in
 576 def t2STRDi8 : T2Ii8s4<(outs), (ins GPR:$src, t2addrmode_imm8s4:$addr),
 577                         "strd", " $src, $addr", []>;
 578
 579 // Indexed stores
 580 def t2STR_PRE  : T2Iidxldst<(outs GPR:$base_wb),
 581                             (ins GPR:$src, GPR:$base, t2am_imm8_offset:$offset),
 582                             AddrModeT2_i8, IndexModePre,
 583                           "str", " $src, [$base, $offset]!", "$base = $base_wb",
 584              [(set GPR:$base_wb,
 585                    (pre_store GPR:$src, GPR:$base, t2am_imm8_offset:$offset))]>;
 586
 587 def t2STR_POST : T2Iidxldst<(outs GPR:$base_wb),
 588                             (ins GPR:$src, GPR:$base, t2am_imm8_offset:$offset),
 589                             AddrModeT2_i8, IndexModePost,
 590                            "str", " $src, [$base], $offset", "$base = $base_wb",
 591              [(set GPR:$base_wb,
 592                    (post_store GPR:$src, GPR:$base, t2am_imm8_offset:$offset))]>;
 593
 594 def t2STRH_PRE  : T2Iidxldst<(outs GPR:$base_wb),
 595                             (ins GPR:$src, GPR:$base, t2am_imm8_offset:$offset),
 596                             AddrModeT2_i8, IndexModePre,
 597                          "strh", " $src, [$base, $offset]!", "$base = $base_wb",
 598         [(set GPR:$base_wb,
 599               (pre_truncsti16 GPR:$src, GPR:$base, t2am_imm8_offset:$offset))]>;
 600
 601 def t2STRH_POST : T2Iidxldst<(outs GPR:$base_wb),
 602                             (ins GPR:$src, GPR:$base, t2am_imm8_offset:$offset),
 603                             AddrModeT2_i8, IndexModePost,
 604                           "strh", " $src, [$base], $offset", "$base = $base_wb",
 605        [(set GPR:$base_wb,
 606              (post_truncsti16 GPR:$src, GPR:$base, t2am_imm8_offset:$offset))]>;
 607
 608 def t2STRB_PRE  : T2Iidxldst<(outs GPR:$base_wb),
 609                             (ins GPR:$src, GPR:$base, t2am_imm8_offset:$offset),
 610                             AddrModeT2_i8, IndexModePre,
 611                          "strb", " $src, [$base, $offset]!", "$base = $base_wb",
 612          [(set GPR:$base_wb,
 613                (pre_truncsti8 GPR:$src, GPR:$base, t2am_imm8_offset:$offset))]>;
 614
 615 def t2STRB_POST : T2Iidxldst<(outs GPR:$base_wb),
 616                             (ins GPR:$src, GPR:$base, t2am_imm8_offset:$offset),
 617                             AddrModeT2_i8, IndexModePost,
 618                           "strb", " $src, [$base], $offset", "$base = $base_wb",
 619         [(set GPR:$base_wb,
 620               (post_truncsti8 GPR:$src, GPR:$base, t2am_imm8_offset:$offset))]>;
 621
 622
 623 // FIXME: ldrd / strd pre / post variants
 624
 625 //===----------------------------------------------------------------------===//
 626 //  Load / store multiple Instructions.
 627 //
 628
 629 let mayLoad = 1 in
 630 def t2LDM : T2XI<(outs),
 631                  (ins addrmode4:$addr, pred:$p, reglist:$dst1, variable_ops),
 632                  "ldm${addr:submode}${p}.w $addr, $dst1", []>;
 633
 634 let mayStore = 1 in
 635 def t2STM : T2XI<(outs),
 636                  (ins addrmode4:$addr, pred:$p, reglist:$src1, variable_ops),
 637                  "stm${addr:submode}${p}.w $addr, $src1", []>;
 638
 639 //===----------------------------------------------------------------------===//
 640 //  Move Instructions.
 641 //
 642
 643 let neverHasSideEffects = 1 in
 644 def t2MOVr : T2sI<(outs GPR:$dst), (ins GPR:$src),
 645                    "mov", ".w $dst, $src", []>;
 646
 647 let isReMaterializable = 1, isAsCheapAsAMove = 1 in
 648 def t2MOVi : T2sI<(outs GPR:$dst), (ins t2_so_imm:$src),
 649                    "mov", ".w $dst, $src",
 650                    [(set GPR:$dst, t2_so_imm:$src)]>;
 651
 652 let isReMaterializable = 1, isAsCheapAsAMove = 1 in
 653 def t2MOVi16 : T2I<(outs GPR:$dst), (ins i32imm:$src),
 654                    "movw", " $dst, $src",
 655                    [(set GPR:$dst, imm0_65535:$src)]>;
 656
 657 // FIXME: Also available in ARM mode.
 658 let Constraints = "$src = $dst" in
 659 def t2MOVTi16 : T2sI<(outs GPR:$dst), (ins GPR:$src, i32imm:$imm),
 660                      "movt", " $dst, $imm",
 661                      [(set GPR:$dst,
 662                            (or (and GPR:$src, 0xffff), t2_lo16AllZero:$imm))]>;
 663
 664 //===----------------------------------------------------------------------===//
 665 //  Extend Instructions.
 666 //
 667
 668 // Sign extenders
 669
 670 defm t2SXTB  : T2I_unary_rrot<"sxtb", UnOpFrag<(sext_inreg node:$Src, i8)>>;
 671 defm t2SXTH  : T2I_unary_rrot<"sxth", UnOpFrag<(sext_inreg node:$Src, i16)>>;
 672
 673 defm t2SXTAB : T2I_bin_rrot<"sxtab",
 674                         BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS, i8))>>;
 675 defm t2SXTAH : T2I_bin_rrot<"sxtah",
 676                         BinOpFrag<(add node:$LHS, (sext_inreg node:$RHS,i16))>>;
 677
 678 // TODO: SXT(A){B|H}16
 679
 680 // Zero extenders
 681
 682 let AddedComplexity = 16 in {
 683 defm t2UXTB   : T2I_unary_rrot<"uxtb"  , UnOpFrag<(and node:$Src, 0x000000FF)>>;
 684 defm t2UXTH   : T2I_unary_rrot<"uxth"  , UnOpFrag<(and node:$Src, 0x0000FFFF)>>;
 685 defm t2UXTB16 : T2I_unary_rrot<"uxtb16", UnOpFrag<(and node:$Src, 0x00FF00FF)>>;
 686
 687 def : T2Pat<(and (shl GPR:$Src, (i32 8)), 0xFF00FF),
 688             (t2UXTB16r_rot GPR:$Src, 24)>;
 689 def : T2Pat<(and (srl GPR:$Src, (i32 8)), 0xFF00FF),
 690             (t2UXTB16r_rot GPR:$Src, 8)>;
 691
 692 defm t2UXTAB : T2I_bin_rrot<"uxtab",
 693                             BinOpFrag<(add node:$LHS, (and node:$RHS, 0x00FF))>>;
 694 defm t2UXTAH : T2I_bin_rrot<"uxtah",
 695                             BinOpFrag<(add node:$LHS, (and node:$RHS, 0xFFFF))>>;
 696 }
 697
 698 //===----------------------------------------------------------------------===//
 699 //  Arithmetic Instructions.
 700 //
 701
 702 defm t2ADD  : T2I_bin_ii12rs<"add", BinOpFrag<(add  node:$LHS, node:$RHS)>, 1>;
 703 defm t2SUB  : T2I_bin_ii12rs<"sub", BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
 704
 705 // ADD and SUB with 's' bit set. No 12-bit immediate (T4) variants.
 706 defm t2ADDS : T2I_bin_s_irs <"add",  BinOpFrag<(addc node:$LHS, node:$RHS)>, 1>;
 707 defm t2SUBS : T2I_bin_s_irs <"sub",  BinOpFrag<(subc node:$LHS, node:$RHS)>>;
 708
 709 defm t2ADC  : T2I_adde_sube_irs<"adc",BinOpFrag<(adde node:$LHS, node:$RHS)>,1>;
 710 defm t2SBC  : T2I_adde_sube_irs<"sbc",BinOpFrag<(sube node:$LHS, node:$RHS)>>;
 711
 712 // RSB
 713 defm t2RSB  : T2I_rbin_is   <"rsb", BinOpFrag<(sub  node:$LHS, node:$RHS)>>;
 714 defm t2RSBS : T2I_rbin_s_is <"rsb", BinOpFrag<(subc node:$LHS, node:$RHS)>>;
 715
 716 // (sub X, imm) gets canonicalized to (add X, -imm).  Match this form.
 717 def : T2Pat<(add       GPR:$src, t2_so_imm_neg:$imm),
 718             (t2SUBri   GPR:$src, t2_so_imm_neg:$imm)>;
 719 def : T2Pat<(add       GPR:$src, imm0_4095_neg:$imm),
 720             (t2SUBri12 GPR:$src, imm0_4095_neg:$imm)>;
 721
 722
 723 //===----------------------------------------------------------------------===//
 724 //  Shift and rotate Instructions.
 725 //
 726
 727 defm t2LSL  : T2I_sh_ir<"lsl", BinOpFrag<(shl  node:$LHS, node:$RHS)>>;
 728 defm t2LSR  : T2I_sh_ir<"lsr", BinOpFrag<(srl  node:$LHS, node:$RHS)>>;
 729 defm t2ASR  : T2I_sh_ir<"asr", BinOpFrag<(sra  node:$LHS, node:$RHS)>>;
 730 defm t2ROR  : T2I_sh_ir<"ror", BinOpFrag<(rotr node:$LHS, node:$RHS)>>;
 731
 732 def t2MOVrx : T2sI<(outs GPR:$dst), (ins GPR:$src),
 733                    "mov", " $dst, $src, rrx",
 734                    [(set GPR:$dst, (ARMrrx GPR:$src))]>;
 735
 736 //===----------------------------------------------------------------------===//
 737 //  Bitwise Instructions.
 738 //
 739
 740 defm t2AND  : T2I_bin_w_irs<"and", BinOpFrag<(and node:$LHS, node:$RHS)>, 1>;
 741 defm t2ORR  : T2I_bin_w_irs<"orr", BinOpFrag<(or  node:$LHS, node:$RHS)>, 1>;
 742 defm t2EOR  : T2I_bin_w_irs<"eor", BinOpFrag<(xor node:$LHS, node:$RHS)>, 1>;
 743
 744 defm t2BIC  : T2I_bin_w_irs<"bic", BinOpFrag<(and node:$LHS, (not node:$RHS))>>;
 745
 746 let Constraints = "$src = $dst" in
 747 def t2BFC : T2I<(outs GPR:$dst), (ins GPR:$src, bf_inv_mask_imm:$imm),
 748                 "bfc", " $dst, $imm",
 749                 [(set GPR:$dst, (and GPR:$src, bf_inv_mask_imm:$imm))]>;
 750
 751 // FIXME: A8.6.18  BFI - Bitfield insert (Encoding T1)
 752
 753 defm t2ORN  : T2I_bin_irs<"orn", BinOpFrag<(or  node:$LHS, (not node:$RHS))>>;
 754
 755 // Prefer over of t2EORri ra, rb, -1 because mvn has 16-bit version
 756 let AddedComplexity = 1 in
 757 defm t2MVN  : T2I_un_irs  <"mvn", UnOpFrag<(not node:$Src)>, 1, 1>;
 758
 759
 760 def : T2Pat<(and     GPR:$src, t2_so_imm_not:$imm),
 761             (t2BICri GPR:$src, t2_so_imm_not:$imm)>;
 762
 763 def : T2Pat<(or      GPR:$src, t2_so_imm_not:$imm),
 764             (t2ORNri GPR:$src, t2_so_imm_not:$imm)>;
 765
 766 def : T2Pat<(t2_so_imm_not:$src),
 767             (t2MVNi t2_so_imm_not:$src)>;
 768
 769 //===----------------------------------------------------------------------===//
 770 //  Multiply Instructions.
 771 //
 772 let isCommutable = 1 in
 773 def t2MUL: T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 774                 "mul", " $dst, $a, $b",
 775                 [(set GPR:$dst, (mul GPR:$a, GPR:$b))]>;
 776
 777 def t2MLA: T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 778                 "mla", " $dst, $a, $b, $c",
 779                 [(set GPR:$dst, (add (mul GPR:$a, GPR:$b), GPR:$c))]>;
 780
 781 def t2MLS: T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 782                 "mls", " $dst, $a, $b, $c",
 783                 [(set GPR:$dst, (sub GPR:$c, (mul GPR:$a, GPR:$b)))]>;
 784
 785 // Extra precision multiplies with low / high results
 786 let neverHasSideEffects = 1 in {
 787 let isCommutable = 1 in {
 788 def t2SMULL : T2I<(outs GPR:$ldst, GPR:$hdst), (ins GPR:$a, GPR:$b),
 789                    "smull", " $ldst, $hdst, $a, $b", []>;
 790
 791 def t2UMULL : T2I<(outs GPR:$ldst, GPR:$hdst), (ins GPR:$a, GPR:$b),
 792                    "umull", " $ldst, $hdst, $a, $b", []>;
 793 }
 794
 795 // Multiply + accumulate
 796 def t2SMLAL : T2I<(outs GPR:$ldst, GPR:$hdst), (ins GPR:$a, GPR:$b),
 797                   "smlal", " $ldst, $hdst, $a, $b", []>;
 798
 799 def t2UMLAL : T2I<(outs GPR:$ldst, GPR:$hdst), (ins GPR:$a, GPR:$b),
 800                   "umlal", " $ldst, $hdst, $a, $b", []>;
 801
 802 def t2UMAAL : T2I<(outs GPR:$ldst, GPR:$hdst), (ins GPR:$a, GPR:$b),
 803                   "umaal", " $ldst, $hdst, $a, $b", []>;
 804 } // neverHasSideEffects
 805
 806 // Most significant word multiply
 807 def t2SMMUL : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 808                   "smmul", " $dst, $a, $b",
 809                   [(set GPR:$dst, (mulhs GPR:$a, GPR:$b))]>;
 810
 811 def t2SMMLA : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 812                   "smmla", " $dst, $a, $b, $c",
 813                   [(set GPR:$dst, (add (mulhs GPR:$a, GPR:$b), GPR:$c))]>;
 814
 815
 816 def t2SMMLS : T2I <(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$c),
 817                    "smmls", " $dst, $a, $b, $c",
 818                    [(set GPR:$dst, (sub GPR:$c, (mulhs GPR:$a, GPR:$b)))]>;
 819
 820 multiclass T2I_smul<string opc, PatFrag opnode> {
 821   def BB : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 822               !strconcat(opc, "bb"), " $dst, $a, $b",
 823               [(set GPR:$dst, (opnode (sext_inreg GPR:$a, i16),
 824                                       (sext_inreg GPR:$b, i16)))]>;
 825
 826   def BT : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 827               !strconcat(opc, "bt"), " $dst, $a, $b",
 828               [(set GPR:$dst, (opnode (sext_inreg GPR:$a, i16),
 829                                       (sra GPR:$b, (i32 16))))]>;
 830
 831   def TB : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 832               !strconcat(opc, "tb"), " $dst, $a, $b",
 833               [(set GPR:$dst, (opnode (sra GPR:$a, (i32 16)),
 834                                       (sext_inreg GPR:$b, i16)))]>;
 835
 836   def TT : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 837               !strconcat(opc, "tt"), " $dst, $a, $b",
 838               [(set GPR:$dst, (opnode (sra GPR:$a, (i32 16)),
 839                                       (sra GPR:$b, (i32 16))))]>;
 840
 841   def WB : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 842               !strconcat(opc, "wb"), " $dst, $a, $b",
 843               [(set GPR:$dst, (sra (opnode GPR:$a,
 844                                     (sext_inreg GPR:$b, i16)), (i32 16)))]>;
 845
 846   def WT : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b),
 847               !strconcat(opc, "wt"), " $dst, $a, $b",
 848               [(set GPR:$dst, (sra (opnode GPR:$a,
 849                                     (sra GPR:$b, (i32 16))), (i32 16)))]>;
 850 }
 851
 852
 853 multiclass T2I_smla<string opc, PatFrag opnode> {
 854   def BB : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
 855               !strconcat(opc, "bb"), " $dst, $a, $b, $acc",
 856               [(set GPR:$dst, (add GPR:$acc,
 857                                (opnode (sext_inreg GPR:$a, i16),
 858                                        (sext_inreg GPR:$b, i16))))]>;
 859
 860   def BT : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
 861              !strconcat(opc, "bt"), " $dst, $a, $b, $acc",
 862              [(set GPR:$dst, (add GPR:$acc, (opnode (sext_inreg GPR:$a, i16),
 863                                                     (sra GPR:$b, (i32 16)))))]>;
 864
 865   def TB : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
 866               !strconcat(opc, "tb"), " $dst, $a, $b, $acc",
 867               [(set GPR:$dst, (add GPR:$acc, (opnode (sra GPR:$a, (i32 16)),
 868                                                  (sext_inreg GPR:$b, i16))))]>;
 869
 870   def TT : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
 871               !strconcat(opc, "tt"), " $dst, $a, $b, $acc",
 872              [(set GPR:$dst, (add GPR:$acc, (opnode (sra GPR:$a, (i32 16)),
 873                                                     (sra GPR:$b, (i32 16)))))]>;
 874
 875   def WB : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
 876               !strconcat(opc, "wb"), " $dst, $a, $b, $acc",
 877               [(set GPR:$dst, (add GPR:$acc, (sra (opnode GPR:$a,
 878                                        (sext_inreg GPR:$b, i16)), (i32 16))))]>;
 879
 880   def WT : T2I<(outs GPR:$dst), (ins GPR:$a, GPR:$b, GPR:$acc),
 881               !strconcat(opc, "wt"), " $dst, $a, $b, $acc",
 882               [(set GPR:$dst, (add GPR:$acc, (sra (opnode GPR:$a,
 883                                          (sra GPR:$b, (i32 16))), (i32 16))))]>;
 884 }
 885
 886 defm t2SMUL : T2I_smul<"smul", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
 887 defm t2SMLA : T2I_smla<"smla", BinOpFrag<(mul node:$LHS, node:$RHS)>>;
 888
 889 // TODO: Halfword multiple accumulate long: SMLAL<x><y>
 890 // TODO: Dual halfword multiple: SMUAD, SMUSD, SMLAD, SMLSD, SMLALD, SMLSLD
 891
 892
 893 //===----------------------------------------------------------------------===//
 894 //  Misc. Arithmetic Instructions.
 895 //
 896
 897 def t2CLZ : T2I<(outs GPR:$dst), (ins GPR:$src),
 898                 "clz", " $dst, $src",
 899                 [(set GPR:$dst, (ctlz GPR:$src))]>;
 900
 901 def t2REV : T2I<(outs GPR:$dst), (ins GPR:$src),
 902                 "rev", ".w $dst, $src",
 903                 [(set GPR:$dst, (bswap GPR:$src))]>;
 904
 905 def t2REV16 : T2I<(outs GPR:$dst), (ins GPR:$src),
 906                 "rev16", ".w $dst, $src",
 907                 [(set GPR:$dst,
 908                     (or (and (srl GPR:$src, (i32 8)), 0xFF),
 909                         (or (and (shl GPR:$src, (i32 8)), 0xFF00),
 910                             (or (and (srl GPR:$src, (i32 8)), 0xFF0000),
 911                                 (and (shl GPR:$src, (i32 8)), 0xFF000000)))))]>;
 912
 913 def t2REVSH : T2I<(outs GPR:$dst), (ins GPR:$src),
 914                  "revsh", ".w $dst, $src",
 915                  [(set GPR:$dst,
 916                     (sext_inreg
 917                       (or (srl (and GPR:$src, 0xFFFF), (i32 8)),
 918                           (shl GPR:$src, (i32 8))), i16))]>;
 919
 920 def t2PKHBT : T2I<(outs GPR:$dst), (ins GPR:$src1, GPR:$src2, i32imm:$shamt),
 921                   "pkhbt", " $dst, $src1, $src2, LSL $shamt",
 922                   [(set GPR:$dst, (or (and GPR:$src1, 0xFFFF),
 923                                       (and (shl GPR:$src2, (i32 imm:$shamt)),
 924                                            0xFFFF0000)))]>;
 925
 926 // Alternate cases for PKHBT where identities eliminate some nodes.
 927 def : T2Pat<(or (and GPR:$src1, 0xFFFF), (and GPR:$src2, 0xFFFF0000)),
 928             (t2PKHBT GPR:$src1, GPR:$src2, 0)>;
 929 def : T2Pat<(or (and GPR:$src1, 0xFFFF), (shl GPR:$src2, imm16_31:$shamt)),
 930             (t2PKHBT GPR:$src1, GPR:$src2, imm16_31:$shamt)>;
 931
 932 def t2PKHTB : T2I<(outs GPR:$dst), (ins GPR:$src1, GPR:$src2, i32imm:$shamt),
 933                   "pkhtb", " $dst, $src1, $src2, ASR $shamt",
 934                   [(set GPR:$dst, (or (and GPR:$src1, 0xFFFF0000),
 935                                       (and (sra GPR:$src2, imm16_31:$shamt),
 936                                            0xFFFF)))]>;
 937
 938 // Alternate cases for PKHTB where identities eliminate some nodes.  Note that
 939 // a shift amount of 0 is *not legal* here, it is PKHBT instead.
 940 def : T2Pat<(or (and GPR:$src1, 0xFFFF0000), (srl GPR:$src2, (i32 16))),
 941             (t2PKHTB GPR:$src1, GPR:$src2, 16)>;
 942 def : T2Pat<(or (and GPR:$src1, 0xFFFF0000),
 943                      (and (srl GPR:$src2, imm1_15:$shamt), 0xFFFF)),
 944             (t2PKHTB GPR:$src1, GPR:$src2, imm1_15:$shamt)>;
 945
 946 //===----------------------------------------------------------------------===//
 947 //  Comparison Instructions...
 948 //
 949
 950 defm t2CMP   : T2I_cmp_is<"cmp",
 951                           BinOpFrag<(ARMcmp node:$LHS, node:$RHS)>>;
 952 defm t2CMPz : T2I_cmp_is<"cmp",
 953                          BinOpFrag<(ARMcmpZ node:$LHS, node:$RHS)>>;
 954
 955 defm t2CMN   : T2I_cmp_is<"cmn",
 956                           BinOpFrag<(ARMcmp node:$LHS,(ineg node:$RHS))>>;
 957 defm t2CMNz : T2I_cmp_is<"cmn",
 958                          BinOpFrag<(ARMcmpZ node:$LHS,(ineg node:$RHS))>>;
 959
 960 def : T2Pat<(ARMcmp  GPR:$src, t2_so_imm_neg:$imm),
 961             (t2CMNri GPR:$src, t2_so_imm_neg:$imm)>;
 962
 963 def : T2Pat<(ARMcmpZ  GPR:$src, t2_so_imm_neg:$imm),
 964             (t2CMNri   GPR:$src, t2_so_imm_neg:$imm)>;
 965
 966 defm t2TST  : T2I_cmp_is<"tst",
 967                          BinOpFrag<(ARMcmpZ (and node:$LHS, node:$RHS), 0)>>;
 968 defm t2TEQ  : T2I_cmp_is<"teq",
 969                          BinOpFrag<(ARMcmpZ (xor node:$LHS, node:$RHS), 0)>>;
 970
 971 // A8.6.27  CBNZ, CBZ - Compare and branch on (non)zero.
 972 // Short range conditional branch. Looks awesome for loops. Need to figure
 973 // out how to use this one.
 974
 975
 976 // Conditional moves
 977 // FIXME: should be able to write a pattern for ARMcmov, but can't use
 978 // a two-value operand where a dag node expects two operands. :(
 979 def t2MOVCCr : T2I<(outs GPR:$dst), (ins GPR:$false, GPR:$true),
 980                    "mov", " $dst, $true",
 981       [/*(set GPR:$dst, (ARMcmov GPR:$false, GPR:$true, imm:$cc, CCR:$ccr))*/]>,
 982                 RegConstraint<"$false = $dst">;
 983
 984 def t2MOVCCs : T2I<(outs GPR:$dst), (ins GPR:$false, t2_so_reg:$true),
 985                    "mov", " $dst, $true",
 986 [/*(set GPR:$dst, (ARMcmov GPR:$false, t2_so_reg:$true, imm:$cc, CCR:$ccr))*/]>,
 987                    RegConstraint<"$false = $dst">;
 988
 989 def t2MOVCCi : T2I<(outs GPR:$dst), (ins GPR:$false, t2_so_imm:$true),
 990                    "mov", " $dst, $true",
 991 [/*(set GPR:$dst, (ARMcmov GPR:$false, t2_so_imm:$true, imm:$cc, CCR:$ccr))*/]>,
 992                    RegConstraint<"$false = $dst">;
 993
 994 //===----------------------------------------------------------------------===//
 995 // TLS Instructions
 996 //
 997
 998 // __aeabi_read_tp preserves the registers r1-r3.
 999 let isCall = 1,
1000   Defs = [R0, R12, LR, CPSR] in {
1001   def t2TPsoft : T2XI<(outs), (ins),
1002                      "bl __aeabi_read_tp",
1003                      [(set R0, ARMthread_pointer)]>;
1004 }
1005
1006 //===----------------------------------------------------------------------===//
1007 // Control-Flow Instructions
1008 //
1009
1010 // FIXME: remove when we have a way to marking a MI with these properties.
1011 // FIXME: $dst1 should be a def. But the extra ops must be in the end of the
1012 // operand list.
1013 // FIXME: Should pc be an implicit operand like PICADD, etc?
1014 let isReturn = 1, isTerminator = 1, mayLoad = 1 in
1015   def t2LDM_RET : T2XI<(outs),
1016                     (ins addrmode4:$addr, pred:$p, reglist:$dst1, variable_ops),
1017                     "ldm${addr:submode}${p} $addr, $dst1",
1018                     []>;
1019
1020 // On non-Darwin platforms R9 is callee-saved.
1021 let isCall = 1,
1022   Defs = [R0,  R1,  R2,  R3,  R12, LR,
1023           D0,  D1,  D2,  D3,  D4,  D5,  D6,  D7,
1024           D16, D17, D18, D19, D20, D21, D22, D23,
1025           D24, D25, D26, D27, D28, D29, D31, D31, CPSR] in {
1026 def t2BL  : T2XI<(outs), (ins i32imm:$func, variable_ops),
1027                  "bl ${func:call}",
1028                   [(ARMcall tglobaladdr:$func)]>, Requires<[IsNotDarwin]>;
1029
1030 def t2BLX : T2XI<(outs), (ins GPR:$func, variable_ops),
1031                 "blx $func",
1032                 [(ARMcall GPR:$func)]>, Requires<[IsNotDarwin]>;
1033 }
1034
1035 // On Darwin R9 is call-clobbered.
1036 let isCall = 1,
1037   Defs = [R0, R1, R2, R3, R9, R12, LR,
1038           D0, D1, D2, D3, D4, D5, D6, D7, CPSR] in {
1039 def t2BLr9  : T2XI<(outs), (ins i32imm:$func, variable_ops),
1040                   "bl ${func:call}",
1041                   [(ARMcall tglobaladdr:$func)]>, Requires<[IsDarwin]>;
1042
1043 def t2BLXr9 : T2XI<(outs), (ins GPR:$func, variable_ops),
1044                   "blx $func",
1045                   [(ARMcall GPR:$func)]>, Requires<[IsDarwin]>;
1046 }
1047
1048 let isBranch = 1, isTerminator = 1, isBarrier = 1 in {
1049 let isPredicable = 1 in
1050 def t2B   : T2XI<(outs), (ins brtarget:$target),
1051                  "b.w $target",
1052                  [(br bb:$target)]>;
1053
1054 let isNotDuplicable = 1, isIndirectBranch = 1 in
1055 def t2BR_JT :
1056     T2JTI<(outs),
1057           (ins GPR:$base, GPR:$idx, jt2block_operand:$jt, i32imm:$id),
1058           "add.w pc, $base, $idx, lsl #2\n$jt",
1059           [(ARMbr2jt GPR:$base, GPR:$idx, tjumptable:$jt, imm:$id)]>;
1060 } // isBranch, isTerminator, isBarrier
1061
1062 // FIXME: should be able to write a pattern for ARMBrcond, but can't use
1063 // a two-value operand where a dag node expects two operands. :(
1064 let isBranch = 1, isTerminator = 1 in
1065 def t2Bcc : T2I<(outs), (ins brtarget:$target),
1066                 "b", ".w $target",
1067                 [/*(ARMbrcond bb:$target, imm:$cc)*/]>;
1068
1069
1070 // IT block
1071 def t2IT : Thumb2XI<(outs), (ins it_pred:$cc, it_mask:$mask),
1072                     AddrModeNone, Size2Bytes,
1073                     "it$mask $cc", "", []>;
1074
1075 //===----------------------------------------------------------------------===//
1076 // Non-Instruction Patterns
1077 //
1078
1079 // ConstantPool, GlobalAddress, and JumpTable
1080 def : T2Pat<(ARMWrapper  tglobaladdr :$dst), (t2LEApcrel tglobaladdr :$dst)>;
1081 def : T2Pat<(ARMWrapper  tconstpool  :$dst), (t2LEApcrel tconstpool  :$dst)>;
1082 def : T2Pat<(ARMWrapperJT tjumptable:$dst, imm:$id),
1083             (t2LEApcrelJT tjumptable:$dst, imm:$id)>;
1084
1085 // Large immediate handling.
1086
1087 def : T2Pat<(i32 imm:$src),
1088             (t2MOVTi16 (t2MOVi16 (t2_lo16 imm:$src)), (t2_hi16 imm:$src))>;