lib/Target/IA64/IA64InstrInfo.td

   1 //===- IA64InstrInfo.td - Describe the IA64 Instruction Set -----*- C++ -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Duraid Madina and is distributed under the
   6 // University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the IA64 instruction set, defining the instructions, and
  11 // properties of the instructions which are needed for code generation, machine
  12 // code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 include "IA64InstrFormats.td"
  17
  18 //===----------------------------------------------------------------------===//
  19 // IA-64 specific DAG Nodes.
  20 //
  21
  22 def IA64getfd : SDNode<"IA64ISD::GETFD", SDTFPToIntOp, []>;
  23
  24 //===---------
  25
  26 def u2imm : Operand<i8>;
  27 def u6imm : Operand<i8>;
  28 def s8imm : Operand<i8> {
  29   let PrintMethod = "printS8ImmOperand";
  30 }
  31 def s14imm  : Operand<i64> {
  32   let PrintMethod = "printS14ImmOperand";
  33 }
  34 def s22imm  : Operand<i64> {
  35   let PrintMethod = "printS22ImmOperand";
  36 }
  37 def u64imm  : Operand<i64> {
  38   let PrintMethod = "printU64ImmOperand";
  39 }
  40 def s64imm  : Operand<i64> {
  41   let PrintMethod = "printS64ImmOperand";
  42 }
  43
  44 let PrintMethod = "printGlobalOperand" in
  45   def globaladdress : Operand<i64>;
  46
  47 // the asmprinter needs to know about calls
  48 let PrintMethod = "printCallOperand" in
  49   def calltarget : Operand<i64>;
  50
  51 /* new daggy action!!! */
  52
  53 def is32ones : PatLeaf<(i64 imm), [{
  54   // is32ones predicate - True if the immediate is 0x00000000FFFFFFFF
  55   // Used to create ZXT4s appropriately
  56   uint64_t v = (uint64_t)N->getValue();
  57   return (v == 0x00000000FFFFFFFFLL);
  58 }]>;
  59
  60 // isMIXable predicates - True if the immediate is
  61 // 0xFF00FF00FF00FF00, 0x00FF00FF00FF00FF
  62 // etc, through 0x00000000FFFFFFFF
  63 // Used to test for the suitability of mix*
  64 def isMIX1Lable: PatLeaf<(i64 imm), [{
  65   return((uint64_t)N->getValue()==0xFF00FF00FF00FF00LL);
  66 }]>;
  67 def isMIX1Rable: PatLeaf<(i64 imm), [{
  68   return((uint64_t)N->getValue()==0x00FF00FF00FF00FFLL);
  69 }]>;
  70 def isMIX2Lable: PatLeaf<(i64 imm), [{
  71   return((uint64_t)N->getValue()==0xFFFF0000FFFF0000LL);
  72 }]>;
  73 def isMIX2Rable: PatLeaf<(i64 imm), [{
  74   return((uint64_t)N->getValue()==0x0000FFFF0000FFFFLL);
  75 }]>;
  76 def isMIX4Lable: PatLeaf<(i64 imm), [{
  77   return((uint64_t)N->getValue()==0xFFFFFFFF00000000LL);
  78 }]>;
  79 def isMIX4Rable: PatLeaf<(i64 imm), [{
  80   return((uint64_t)N->getValue()==0x00000000FFFFFFFFLL);
  81 }]>;
  82
  83 def isSHLADDimm: PatLeaf<(i64 imm), [{
  84   // isSHLADDimm predicate - True if the immediate is exactly 1, 2, 3 or 4
  85   // - 0 is *not* okay.
  86   // Used to create shladd instructions appropriately
  87   int64_t v = (int64_t)N->getValue();
  88   return (v >= 1 && v <= 4);
  89 }]>;
  90
  91 def immSExt14  : PatLeaf<(i64 imm), [{
  92   // immSExt14 predicate - True if the immediate fits in a 14-bit sign extended
  93   // field.  Used by instructions like 'adds'.
  94   int64_t v = (int64_t)N->getValue();
  95   return (v <= 8191 && v >= -8192);
  96 }]>;
  97
  98 def imm64  : PatLeaf<(i64 imm), [{
  99   // imm64 predicate - True if the immediate fits in a 64-bit
 100   // field - i.e., true. used to keep movl happy
 101   return true;
 102 }]>;
 103
 104 def ADD  : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 105            "add $dst = $src1, $src2;;",
 106            [(set GR:$dst, (add GR:$src1, GR:$src2))]>;
 107
 108 def ADD1 : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 109            "add $dst = $src1, $src2, 1;;",
 110            [(set GR:$dst, (add (add GR:$src1, GR:$src2), 1))]>;
 111
 112 def ADDS : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, s14imm:$imm),
 113            "adds $dst = $imm, $src1;;",
 114            [(set GR:$dst, (add GR:$src1, immSExt14:$imm))]>;
 115
 116 def MOVL : AForm_DAG<0x03, 0x0b, (ops GR:$dst, s64imm:$imm),
 117            "movl $dst = $imm;;",
 118            [(set GR:$dst, imm64:$imm)]>;
 119
 120 def ADDL_GA : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, globaladdress:$imm),
 121            "addl $dst = $imm, $src1;;",
 122            []>;
 123
 124 // hmm
 125 def ADDL_EA : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, calltarget:$imm),
 126            "addl $dst = $imm, $src1;;",
 127            []>;
 128
 129 def SUB  : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 130            "sub $dst = $src1, $src2;;",
 131            [(set GR:$dst, (sub GR:$src1, GR:$src2))]>;
 132
 133 def SUB1 : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 134            "sub $dst = $src1, $src2, 1;;",
 135            [(set GR:$dst, (add (sub GR: $src1, GR:$src2), -1))]>;
 136
 137 let isTwoAddress = 1 in {
 138 def TPCADDIMM22 : AForm<0x03, 0x0b,
 139   (ops GR:$dst, GR:$src1, s22imm:$imm, PR:$qp),
 140     "($qp) add $dst = $imm, $dst;;">;
 141 def TPCADDS : AForm_DAG<0x03, 0x0b,
 142   (ops GR:$dst, GR:$src1, s14imm:$imm, PR:$qp),
 143     "($qp) adds $dst = $imm, $dst;;",
 144     []>;
 145 def TPCMPIMM8NE : AForm<0x03, 0x0b,
 146   (ops PR:$dst, PR:$src1, s22imm:$imm, GR:$src2, PR:$qp),
 147     "($qp) cmp.ne $dst , p0 = $imm, $src2;;">;
 148 }
 149
 150 // zero extend a bool (predicate reg) into an integer reg
 151 def ZXTb : Pat<(zext PR:$src),
 152           (TPCADDIMM22 (ADDS r0, 0), 1, PR:$src)>;
 153
 154 // normal sign/zero-extends
 155 def SXT1 : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src), "sxt1 $dst = $src;;",
 156            [(set GR:$dst, (sext_inreg GR:$src, i8))]>;
 157 def ZXT1 : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src), "zxt1 $dst = $src;;",
 158            [(set GR:$dst, (and GR:$src, 255))]>;
 159 def SXT2 : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src), "sxt2 $dst = $src;;",
 160            [(set GR:$dst, (sext_inreg GR:$src, i16))]>;
 161 def ZXT2 : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src), "zxt2 $dst = $src;;",
 162            [(set GR:$dst, (and GR:$src, 65535))]>;
 163 def SXT4 : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src), "sxt4 $dst = $src;;",
 164            [(set GR:$dst, (sext_inreg GR:$src, i32))]>;
 165 def ZXT4 : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src), "zxt4 $dst = $src;;",
 166            [(set GR:$dst, (and GR:$src, is32ones))]>;
 167
 168 // fixme: shrs vs shru?
 169 def MIX1L : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 170           "mix1.l $dst = $src1, $src2;;",
 171           [(set GR:$dst, (or (and GR:$src1, isMIX1Lable),
 172                              (and (srl GR:$src2, (i64 8)), isMIX1Lable)))]>;
 173
 174 def MIX2L : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 175           "mix2.l $dst = $src1, $src2;;",
 176           [(set GR:$dst, (or (and GR:$src1, isMIX2Lable),
 177                              (and (srl GR:$src2, (i64 16)), isMIX2Lable)))]>;
 178
 179 def MIX4L : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 180           "mix4.l $dst = $src1, $src2;;",
 181           [(set GR:$dst, (or (and GR:$src1, isMIX4Lable),
 182                              (and (srl GR:$src2, (i64 32)), isMIX4Lable)))]>;
 183
 184 def MIX1R : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 185           "mix1.r $dst = $src1, $src2;;",
 186           [(set GR:$dst, (or (and (shl GR:$src1, (i64 8)), isMIX1Rable),
 187                              (and GR:$src2, isMIX1Rable)))]>;
 188
 189 def MIX2R : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 190           "mix2.r $dst = $src1, $src2;;",
 191           [(set GR:$dst, (or (and (shl GR:$src1, (i64 16)), isMIX2Rable),
 192                              (and GR:$src2, isMIX2Rable)))]>;
 193
 194 def MIX4R : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 195           "mix4.r $dst = $src1, $src2;;",
 196           [(set GR:$dst, (or (and (shl GR:$src1, (i64 32)), isMIX4Rable),
 197                              (and GR:$src2, isMIX4Rable)))]>;
 198
 199 def GETFSIGD : AForm_DAG<0x03, 0x0b, (ops GR:$dst, FP:$src),
 200   "getf.sig $dst = $src;;",
 201   []>;
 202
 203 def SETFSIGD : AForm_DAG<0x03, 0x0b, (ops FP:$dst, GR:$src),
 204   "setf.sig $dst = $src;;",
 205   []>;
 206
 207 def XMALD : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3),
 208   "xma.l $dst = $src1, $src2, $src3;;",
 209   []>;
 210 def XMAHD : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3),
 211   "xma.h $dst = $src1, $src2, $src3;;",
 212   []>;
 213 def XMAHUD : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3),
 214   "xma.hu $dst = $src1, $src2, $src3;;",
 215   []>;
 216
 217 // pseudocode for integer multiplication
 218 def : Pat<(mul GR:$src1, GR:$src2),
 219            (GETFSIGD (XMALD (SETFSIGD GR:$src1), (SETFSIGD GR:$src2), F0))>;
 220 def : Pat<(mulhs GR:$src1, GR:$src2),
 221            (GETFSIGD (XMAHD (SETFSIGD GR:$src1), (SETFSIGD GR:$src2), F0))>;
 222 def : Pat<(mulhu GR:$src1, GR:$src2),
 223            (GETFSIGD (XMAHUD (SETFSIGD GR:$src1), (SETFSIGD GR:$src2), F0))>;
 224
 225 // TODO: addp4 (addp4 dst = src, r0 is a 32-bit add)
 226 // has imm form, too
 227
 228 // def ADDS : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, s14imm:$imm),
 229 //   "adds $dst = $imm, $src1;;">;
 230
 231 def AND   : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 232           "and $dst = $src1, $src2;;",
 233           [(set GR:$dst, (and GR:$src1, GR:$src2))]>;
 234 def ANDCM : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 235           "andcm $dst = $src1, $src2;;",
 236           [(set GR:$dst, (and GR:$src1, (not GR:$src2)))]>;
 237 // TODO: and/andcm/or/xor/add/sub/shift immediate forms
 238 def OR    : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 239           "or $dst = $src1, $src2;;",
 240           [(set GR:$dst, (or GR:$src1, GR:$src2))]>;
 241
 242 def pOR   : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2, PR:$qp),
 243           "($qp) or $dst = $src1, $src2;;">;
 244
 245 // the following are all a bit unfortunate: we throw away the complement
 246 // of the compare!
 247 def CMPEQ : AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 248           "cmp.eq $dst, p0 = $src1, $src2;;",
 249           [(set PR:$dst, (seteq GR:$src1, GR:$src2))]>;
 250 def CMPGT : AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 251           "cmp.gt $dst, p0 = $src1, $src2;;",
 252           [(set PR:$dst, (setgt GR:$src1, GR:$src2))]>;
 253 def CMPGE : AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 254           "cmp.ge $dst, p0 = $src1, $src2;;",
 255           [(set PR:$dst, (setge GR:$src1, GR:$src2))]>;
 256 def CMPLT : AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 257           "cmp.lt $dst, p0 = $src1, $src2;;",
 258           [(set PR:$dst, (setlt GR:$src1, GR:$src2))]>;
 259 def CMPLE : AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 260           "cmp.le $dst, p0 = $src1, $src2;;",
 261           [(set PR:$dst, (setle GR:$src1, GR:$src2))]>;
 262 def CMPNE : AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 263           "cmp.ne $dst, p0 = $src1, $src2;;",
 264           [(set PR:$dst, (setne GR:$src1, GR:$src2))]>;
 265 def CMPLTU: AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 266           "cmp.ltu $dst, p0 = $src1, $src2;;",
 267           [(set PR:$dst, (setult GR:$src1, GR:$src2))]>;
 268 def CMPGTU: AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 269           "cmp.gtu $dst, p0 = $src1, $src2;;",
 270           [(set PR:$dst, (setugt GR:$src1, GR:$src2))]>;
 271 def CMPLEU: AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 272           "cmp.leu $dst, p0 = $src1, $src2;;",
 273           [(set PR:$dst, (setule GR:$src1, GR:$src2))]>;
 274 def CMPGEU: AForm_DAG<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2),
 275           "cmp.geu $dst, p0 = $src1, $src2;;",
 276           [(set PR:$dst, (setuge GR:$src1, GR:$src2))]>;
 277
 278 // and we do the whole thing again for FP compares!
 279 def FCMPEQ : AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 280           "fcmp.eq $dst, p0 = $src1, $src2;;",
 281           [(set PR:$dst, (seteq FP:$src1, FP:$src2))]>;
 282 def FCMPGT : AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 283           "fcmp.gt $dst, p0 = $src1, $src2;;",
 284           [(set PR:$dst, (setgt FP:$src1, FP:$src2))]>;
 285 def FCMPGE : AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 286           "fcmp.ge $dst, p0 = $src1, $src2;;",
 287           [(set PR:$dst, (setge FP:$src1, FP:$src2))]>;
 288 def FCMPLT : AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 289           "fcmp.lt $dst, p0 = $src1, $src2;;",
 290           [(set PR:$dst, (setlt FP:$src1, FP:$src2))]>;
 291 def FCMPLE : AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 292           "fcmp.le $dst, p0 = $src1, $src2;;",
 293           [(set PR:$dst, (setle FP:$src1, FP:$src2))]>;
 294 def FCMPNE : AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 295           "fcmp.neq $dst, p0 = $src1, $src2;;",
 296           [(set PR:$dst, (setne FP:$src1, FP:$src2))]>;
 297 def FCMPLTU: AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 298           "fcmp.ltu $dst, p0 = $src1, $src2;;",
 299           [(set PR:$dst, (setult FP:$src1, FP:$src2))]>;
 300 def FCMPGTU: AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 301           "fcmp.gtu $dst, p0 = $src1, $src2;;",
 302           [(set PR:$dst, (setugt FP:$src1, FP:$src2))]>;
 303 def FCMPLEU: AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 304           "fcmp.leu $dst, p0 = $src1, $src2;;",
 305           [(set PR:$dst, (setule FP:$src1, FP:$src2))]>;
 306 def FCMPGEU: AForm_DAG<0x03, 0x0b, (ops PR:$dst, FP:$src1, FP:$src2),
 307           "fcmp.geu $dst, p0 = $src1, $src2;;",
 308           [(set PR:$dst, (setuge FP:$src1, FP:$src2))]>;
 309
 310 def PCMPEQUNCR0R0 : AForm<0x03, 0x0b, (ops PR:$dst, PR:$qp),
 311     "($qp) cmp.eq.unc $dst, p0 = r0, r0;;">;
 312
 313 def : Pat<(trunc GR:$src),  // truncate i64 to i1
 314           (CMPNE GR:$src, r0)>; // $src!=0? If so, PR:$dst=true
 315
 316 let isTwoAddress=1 in {
 317   def TPCMPEQR0R0 : AForm<0x03, 0x0b, (ops PR:$dst, PR:$bogus, PR:$qp),
 318     "($qp) cmp.eq $dst, p0 = r0, r0;;">;
 319   def TPCMPNER0R0 : AForm<0x03, 0x0b, (ops PR:$dst, PR:$bogus, PR:$qp),
 320     "($qp) cmp.ne $dst, p0 = r0, r0;;">;
 321 }
 322
 323 /* our pseudocode for OR on predicates is:
 324 pC = pA OR pB
 325 -------------
 326 (pA) cmp.eq.unc pC,p0 = r0,r0  // pC = pA
 327  ;;
 328 (pB) cmp.eq pC,p0 = r0,r0 // if (pB) pC = 1 */
 329
 330 def bOR   : Pat<(or PR:$src1, PR:$src2),
 331           (TPCMPEQR0R0 (PCMPEQUNCR0R0 PR:$src1), PR:$src2)>;
 332
 333 /* our pseudocode for AND on predicates is:
 334  *
 335 (pA) cmp.eq.unc pC,p0 = r0,r0   // pC = pA
 336      cmp.eq pTemp,p0 = r0,r0    // pTemp = NOT pB
 337      ;;
 338 (pB) cmp.ne pTemp,p0 = r0,r0
 339      ;;
 340 (pTemp)cmp.ne pC,p0 = r0,r0    // if (NOT pB) pC = 0  */
 341
 342 def bAND  : Pat<(and PR:$src1, PR:$src2),
 343           ( TPCMPNER0R0 (PCMPEQUNCR0R0 PR:$src1),
 344             (TPCMPNER0R0 (CMPEQ r0, r0), PR:$src2) )>;
 345
 346 /* one possible routine for XOR on predicates is:
 347
 348       // Compute px = py ^ pz
 349         // using sum of products: px = (py & !pz) | (pz & !py)
 350         // Uses 5 instructions in 3 cycles.
 351         // cycle 1
 352 (pz)    cmp.eq.unc      px = r0, r0     // px = pz
 353 (py)    cmp.eq.unc      pt = r0, r0     // pt = py
 354         ;;
 355         // cycle 2
 356 (pt)    cmp.ne.and      px = r0, r0     // px = px & !pt (px = pz & !pt)
 357 (pz)    cmp.ne.and      pt = r0, r0     // pt = pt & !pz
 358         ;;
 359         } { .mmi
 360         // cycle 3
 361 (pt)    cmp.eq.or       px = r0, r0     // px = px | pt
 362
 363 *** Another, which we use here, requires one scratch GR. it is:
 364
 365         mov             rt = 0          // initialize rt off critical path
 366         ;;
 367
 368         // cycle 1
 369 (pz)    cmp.eq.unc      px = r0, r0     // px = pz
 370 (pz)    mov             rt = 1          // rt = pz
 371         ;;
 372         // cycle 2
 373 (py)    cmp.ne          px = 1, rt      // if (py) px = !pz
 374
 375 .. these routines kindly provided by Jim Hull
 376 */
 377
 378 def bXOR  : Pat<(xor PR:$src1, PR:$src2),
 379           (TPCMPIMM8NE (PCMPEQUNCR0R0 PR:$src2), 1,
 380                        (TPCADDS (ADDS r0, 0), 1, PR:$src2),
 381                         PR:$src1)>;
 382
 383 def XOR   : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 384           "xor $dst = $src1, $src2;;",
 385           [(set GR:$dst, (xor GR:$src1, GR:$src2))]>;
 386
 387 def SHLADD: AForm_DAG<0x03, 0x0b, (ops GR:$dst,GR:$src1,s64imm:$imm,GR:$src2),
 388           "shladd $dst = $src1, $imm, $src2;;",
 389           [(set GR:$dst, (add GR:$src2, (shl GR:$src1, isSHLADDimm:$imm)))]>;
 390
 391 def SHL   : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 392           "shl $dst = $src1, $src2;;",
 393           [(set GR:$dst, (shl GR:$src1, GR:$src2))]>;
 394
 395 def SHRU  : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 396           "shr.u $dst = $src1, $src2;;",
 397           [(set GR:$dst, (srl GR:$src1, GR:$src2))]>;
 398
 399 def SHRS  : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src1, GR:$src2),
 400           "shr $dst = $src1, $src2;;",
 401           [(set GR:$dst, (sra GR:$src1, GR:$src2))]>;
 402
 403 def MOV : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src), "mov $dst = $src;;">;
 404 def FMOV : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 405   "mov $dst = $src;;">; // XXX: there _is_ no fmov
 406 def PMOV : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src, PR:$qp),
 407   "($qp) mov $dst = $src;;">;
 408
 409 def SPILL_ALL_PREDICATES_TO_GR : AForm<0x03, 0x0b, (ops GR:$dst),
 410   "mov $dst = pr;;">;
 411 def FILL_ALL_PREDICATES_FROM_GR : AForm<0x03, 0x0b, (ops GR:$src),
 412   "mov pr = $src;;">;
 413
 414 let isTwoAddress = 1 in {
 415   def CMOV : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src2, GR:$src, PR:$qp),
 416     "($qp) mov $dst = $src;;">;
 417 }
 418
 419 def PFMOV : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src, PR:$qp),
 420   "($qp) mov $dst = $src;;">;
 421
 422 let isTwoAddress = 1 in {
 423   def CFMOV : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src2, FP:$src, PR:$qp),
 424     "($qp) mov $dst = $src;;">;
 425 }
 426
 427 def SELECTINT : Pat<(select PR:$which, GR:$src1, GR:$src2),
 428           (CMOV (MOV GR:$src2), GR:$src1, PR:$which)>; // note order!
 429 def SELECTFP : Pat<(select PR:$which, FP:$src1, FP:$src2),
 430           (CFMOV (FMOV FP:$src2), FP:$src1, PR:$which)>; // note order!
 431 // TODO: can do this faster, w/o using any integer regs (see pattern isel)
 432 def SELECTBOOL : Pat<(select PR:$which, PR:$src1, PR:$src2), // note order!
 433           (CMPNE (CMOV
 434             (MOV (TPCADDIMM22 (ADDS r0, 0), 1, PR:$src2)),
 435             (TPCADDIMM22 (ADDS r0, 0), 1, PR:$src1), PR:$which), r0)>;
 436
 437 // load constants of various sizes // FIXME: prettyprint -ve constants
 438 def : Pat<(i64 immSExt14:$imm), (ADDS r0, immSExt14:$imm)>;
 439 def : Pat<(i64 imm64:$imm), (MOVL imm64:$imm)>;
 440 def : Pat<(i1 -1), (CMPEQ r0, r0)>; // TODO: this should just be a ref to p0
 441 def : Pat<(i1  0), (CMPNE r0, r0)>; // TODO: any instruction actually *using*
 442                                     //       this predicate should be killed!
 443
 444 // TODO: support postincrement (reg, imm9) loads+stores - this needs more
 445 // tablegen support
 446
 447 def PHI : PseudoInstIA64<(ops variable_ops), "PHI">;
 448 def IDEF : PseudoInstIA64<(ops variable_ops), "// IDEF">;
 449
 450 def IDEF_GR_D : PseudoInstIA64_DAG<(ops GR:$reg), "// $reg = IDEF",
 451     [(set GR:$reg, (undef))]>;
 452 def IDEF_FP_D : PseudoInstIA64_DAG<(ops FP:$reg), "// $reg = IDEF",
 453     [(set FP:$reg, (undef))]>;
 454 def IDEF_PR_D : PseudoInstIA64_DAG<(ops PR:$reg), "// $reg = IDEF",
 455     [(set PR:$reg, (undef))]>;
 456
 457 def IUSE : PseudoInstIA64<(ops variable_ops), "// IUSE">;
 458 def ADJUSTCALLSTACKUP : PseudoInstIA64<(ops variable_ops),
 459                                         "// ADJUSTCALLSTACKUP">;
 460 def ADJUSTCALLSTACKDOWN : PseudoInstIA64<(ops variable_ops),
 461                                          "// ADJUSTCALLSTACKDOWN">;
 462 def PSEUDO_ALLOC : PseudoInstIA64<(ops GR:$foo), "// PSEUDO_ALLOC">;
 463
 464 def ALLOC : AForm<0x03, 0x0b,
 465   (ops GR:$dst, i8imm:$inputs, i8imm:$locals, i8imm:$outputs, i8imm:$rotating),
 466     "alloc $dst = ar.pfs,$inputs,$locals,$outputs,$rotating;;">;
 467
 468 let isTwoAddress = 1 in {
 469   def TCMPNE : AForm<0x03, 0x0b,
 470   (ops PR:$dst, PR:$src2, GR:$src3, GR:$src4),
 471     "cmp.ne $dst, p0 = $src3, $src4;;">;
 472
 473   def TPCMPEQOR : AForm<0x03, 0x0b,
 474   (ops PR:$dst, PR:$src2, GR:$src3, GR:$src4, PR:$qp),
 475     "($qp) cmp.eq.or $dst, p0 = $src3, $src4;;">;
 476
 477   def TPCMPNE : AForm<0x03, 0x0b,
 478   (ops PR:$dst, PR:$src2, GR:$src3, GR:$src4, PR:$qp),
 479     "($qp) cmp.ne $dst, p0 = $src3, $src4;;">;
 480
 481   def TPCMPEQ : AForm<0x03, 0x0b,
 482   (ops PR:$dst, PR:$src2, GR:$src3, GR:$src4, PR:$qp),
 483     "($qp) cmp.eq $dst, p0 = $src3, $src4;;">;
 484 }
 485
 486 def MOVSIMM14 : AForm<0x03, 0x0b, (ops GR:$dst, s14imm:$imm),
 487   "mov $dst = $imm;;">;
 488 def MOVSIMM22 : AForm<0x03, 0x0b, (ops GR:$dst, s22imm:$imm),
 489   "mov $dst = $imm;;">;
 490 def MOVLIMM64 : AForm<0x03, 0x0b, (ops GR:$dst, s64imm:$imm),
 491   "movl $dst = $imm;;">;
 492
 493 def SHLI : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, u6imm:$imm),
 494   "shl $dst = $src1, $imm;;">;
 495 def SHRUI : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, u6imm:$imm),
 496   "shr.u $dst = $src1, $imm;;">;
 497 def SHRSI : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, u6imm:$imm),
 498   "shr $dst = $src1, $imm;;">;
 499
 500 def EXTRU : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, u6imm:$imm1, u6imm:$imm2),
 501   "extr.u $dst = $src1, $imm1, $imm2;;">;
 502
 503 def DEPZ : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, u6imm:$imm1, u6imm:$imm2),   "dep.z $dst = $src1, $imm1, $imm2;;">;
 504
 505 def PCMPEQOR : AForm<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2, PR:$qp),
 506   "($qp) cmp.eq.or $dst, p0 = $src1, $src2;;">;
 507 def PCMPEQUNC : AForm<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2, PR:$qp),
 508   "($qp) cmp.eq.unc $dst, p0 = $src1, $src2;;">;
 509 def PCMPNE : AForm<0x03, 0x0b, (ops PR:$dst, GR:$src1, GR:$src2, PR:$qp),
 510   "($qp) cmp.ne $dst, p0 = $src1, $src2;;">;
 511
 512 // two destinations!
 513 def BCMPEQ : AForm<0x03, 0x0b, (ops PR:$dst1, PR:$dst2, GR:$src1, GR:$src2),
 514   "cmp.eq $dst1, dst2 = $src1, $src2;;">;
 515
 516 def ADDIMM14 : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, s14imm:$imm),
 517   "adds $dst = $imm, $src1;;">;
 518
 519 def ADDIMM22 : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, s22imm:$imm),
 520   "add $dst = $imm, $src1;;">;
 521 def CADDIMM22 : AForm<0x03, 0x0b, (ops GR:$dst, GR:$src1, s22imm:$imm, PR:$qp),
 522   "($qp) add $dst = $imm, $src1;;">;
 523
 524 def SUBIMM8 : AForm<0x03, 0x0b, (ops GR:$dst, s8imm:$imm, GR:$src2),
 525   "sub $dst = $imm, $src2;;">;
 526
 527 let isStore = 1, noResults = 1 in {
 528   def ST1 : AForm<0x03, 0x0b, (ops GR:$dstPtr, GR:$value),
 529     "st1 [$dstPtr] = $value;;">;
 530   def ST2 : AForm<0x03, 0x0b, (ops GR:$dstPtr, GR:$value),
 531     "st2 [$dstPtr] = $value;;">;
 532   def ST4 : AForm<0x03, 0x0b, (ops GR:$dstPtr, GR:$value),
 533     "st4 [$dstPtr] = $value;;">;
 534   def ST8 : AForm<0x03, 0x0b, (ops GR:$dstPtr, GR:$value),
 535     "st8 [$dstPtr] = $value;;">;
 536   def STF4 : AForm<0x03, 0x0b, (ops GR:$dstPtr, FP:$value),
 537     "stfs [$dstPtr] = $value;;">;
 538   def STF8 : AForm<0x03, 0x0b, (ops GR:$dstPtr, FP:$value),
 539     "stfd [$dstPtr] = $value;;">;
 540   def STF_SPILL : AForm<0x03, 0x0b, (ops GR:$dstPtr, FP:$value),
 541     "stf.spill [$dstPtr] = $value;;">;
 542 }
 543
 544 let isLoad = 1 in {
 545   def LD1 : AForm<0x03, 0x0b, (ops GR:$dst, GR:$srcPtr),
 546     "ld1 $dst = [$srcPtr];;">;
 547   def LD2 : AForm<0x03, 0x0b, (ops GR:$dst, GR:$srcPtr),
 548     "ld2 $dst = [$srcPtr];;">;
 549   def LD4 : AForm<0x03, 0x0b, (ops GR:$dst, GR:$srcPtr),
 550     "ld4 $dst = [$srcPtr];;">;
 551   def LD8 : AForm<0x03, 0x0b, (ops GR:$dst, GR:$srcPtr),
 552     "ld8 $dst = [$srcPtr];;">;
 553   def LDF4 : AForm<0x03, 0x0b, (ops FP:$dst, GR:$srcPtr),
 554     "ldfs $dst = [$srcPtr];;">;
 555   def LDF8 : AForm<0x03, 0x0b, (ops FP:$dst, GR:$srcPtr),
 556     "ldfd $dst = [$srcPtr];;">;
 557   def LDF_FILL : AForm<0x03, 0x0b, (ops FP:$dst, GR:$srcPtr),
 558     "ldf.fill $dst = [$srcPtr];;">;
 559 }
 560
 561 def POPCNT : AForm_DAG<0x03, 0x0b, (ops GR:$dst, GR:$src),
 562   "popcnt $dst = $src;;",
 563   [(set GR:$dst, (ctpop GR:$src))]>;
 564
 565 // some FP stuff:  // TODO: single-precision stuff?
 566 def FADD : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2),
 567   "fadd $dst = $src1, $src2;;",
 568   [(set FP:$dst, (fadd FP:$src1, FP:$src2))]>;
 569 def FADDS: AForm<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2),
 570   "fadd.s $dst = $src1, $src2;;">;
 571 def FSUB : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2),
 572   "fsub $dst = $src1, $src2;;",
 573   [(set FP:$dst, (fsub FP:$src1, FP:$src2))]>;
 574 def FMPY : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2),
 575   "fmpy $dst = $src1, $src2;;",
 576   [(set FP:$dst, (fmul FP:$src1, FP:$src2))]>;
 577 def FMA : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3),
 578   "fma $dst = $src1, $src2, $src3;;",
 579   [(set FP:$dst, (fadd (fmul FP:$src1, FP:$src2), FP:$src3))]>;
 580 def FMS : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3),
 581   "fms $dst = $src1, $src2, $src3;;",
 582   [(set FP:$dst, (fsub (fmul FP:$src1, FP:$src2), FP:$src3))]>;
 583 def FNMA : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3),
 584   "fnma $dst = $src1, $src2, $src3;;",
 585   [(set FP:$dst, (fneg (fadd (fmul FP:$src1, FP:$src2), FP:$src3)))]>;
 586 def FABS : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src),
 587   "fabs $dst = $src;;",
 588   [(set FP:$dst, (fabs FP:$src))]>;
 589 def FNEG : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src),
 590   "fneg $dst = $src;;",
 591   [(set FP:$dst, (fneg FP:$src))]>;
 592 def FNEGABS : AForm_DAG<0x03, 0x0b, (ops FP:$dst, FP:$src),
 593   "fnegabs $dst = $src;;",
 594   [(set FP:$dst, (fneg (fabs FP:$src)))]>;
 595
 596 let isTwoAddress=1 in {
 597 def TCFMAS1 : AForm<0x03, 0x0b,
 598   (ops FP:$dst, FP:$bogussrc, FP:$src1, FP:$src2, FP:$src3, PR:$qp),
 599     "($qp) fma.s1 $dst = $src1, $src2, $src3;;">;
 600 def TCFMADS0 : AForm<0x03, 0x0b,
 601   (ops FP:$dst, FP:$bogussrc, FP:$src1, FP:$src2, FP:$src3, PR:$qp),
 602     "($qp) fma.d.s0 $dst = $src1, $src2, $src3;;">;
 603 }
 604
 605 def CFMAS1 : AForm<0x03, 0x0b,
 606   (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3, PR:$qp),
 607     "($qp) fma.s1 $dst = $src1, $src2, $src3;;">;
 608 def CFNMAS1 : AForm<0x03, 0x0b,
 609   (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3, PR:$qp),
 610     "($qp) fnma.s1 $dst = $src1, $src2, $src3;;">;
 611
 612 def CFMADS1 : AForm<0x03, 0x0b,
 613   (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3, PR:$qp),
 614     "($qp) fma.d.s1 $dst = $src1, $src2, $src3;;">;
 615 def CFMADS0 : AForm<0x03, 0x0b,
 616   (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3, PR:$qp),
 617     "($qp) fma.d.s0 $dst = $src1, $src2, $src3;;">;
 618 def CFNMADS1 : AForm<0x03, 0x0b,
 619   (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3, PR:$qp),
 620     "($qp) fnma.d.s1 $dst = $src1, $src2, $src3;;">;
 621
 622 def FRCPAS0 : AForm<0x03, 0x0b, (ops FP:$dstFR, PR:$dstPR, FP:$src1, FP:$src2),
 623   "frcpa.s0 $dstFR, $dstPR = $src1, $src2;;">;
 624 def FRCPAS1 : AForm<0x03, 0x0b, (ops FP:$dstFR, PR:$dstPR, FP:$src1, FP:$src2),
 625   "frcpa.s1 $dstFR, $dstPR = $src1, $src2;;">;
 626
 627 def XMAL : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src1, FP:$src2, FP:$src3),
 628   "xma.l $dst = $src1, $src2, $src3;;">;
 629
 630 def FCVTXF : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 631   "fcvt.xf $dst = $src;;">;
 632 def FCVTXUF : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 633   "fcvt.xuf $dst = $src;;">;
 634 def FCVTXUFS1 : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 635   "fcvt.xuf.s1 $dst = $src;;">;
 636 def FCVTFX : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 637   "fcvt.fx $dst = $src;;">;
 638 def FCVTFXU : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 639   "fcvt.fxu $dst = $src;;">;
 640
 641 def FCVTFXTRUNC : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 642   "fcvt.fx.trunc $dst = $src;;">;
 643 def FCVTFXUTRUNC : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 644   "fcvt.fxu.trunc $dst = $src;;">;
 645
 646 def FCVTFXTRUNCS1 : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 647   "fcvt.fx.trunc.s1 $dst = $src;;">;
 648 def FCVTFXUTRUNCS1 : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 649   "fcvt.fxu.trunc.s1 $dst = $src;;">;
 650
 651 def FNORMD : AForm<0x03, 0x0b, (ops FP:$dst, FP:$src),
 652   "fnorm.d $dst = $src;;">;
 653
 654 def GETFD : AForm<0x03, 0x0b, (ops GR:$dst, FP:$src),
 655   "getf.d $dst = $src;;">;
 656 def SETFD : AForm<0x03, 0x0b, (ops FP:$dst, GR:$src),
 657   "setf.d $dst = $src;;">;
 658
 659 def GETFSIG : AForm<0x03, 0x0b, (ops GR:$dst, FP:$src),
 660   "getf.sig $dst = $src;;">;
 661 def SETFSIG : AForm<0x03, 0x0b, (ops FP:$dst, GR:$src),
 662   "setf.sig $dst = $src;;">;
 663
 664 // these four FP<->int conversion patterns need checking/cleaning
 665 def SINT_TO_FP : Pat<(sint_to_fp GR:$src),
 666   (FNORMD (FCVTXF (SETFSIG GR:$src)))>;
 667 def UINT_TO_FP : Pat<(uint_to_fp GR:$src),
 668   (FNORMD (FCVTXUF (SETFSIG GR:$src)))>;
 669 def FP_TO_SINT : Pat<(i64 (fp_to_sint FP:$src)),
 670   (GETFSIG (FCVTFXTRUNC FP:$src))>;
 671 def FP_TO_UINT : Pat<(i64 (fp_to_uint FP:$src)),
 672   (GETFSIG (FCVTFXUTRUNC FP:$src))>;
 673
 674
 675 let isTerminator = 1, isBranch = 1, noResults = 1 in {
 676   def BRL_NOTCALL : RawForm<0x03, 0xb0, (ops i64imm:$dst),
 677     "(p0) brl.cond.sptk $dst;;">;
 678   def BRLCOND_NOTCALL : RawForm<0x03, 0xb0, (ops PR:$qp, i64imm:$dst),
 679     "($qp) brl.cond.sptk $dst;;">;
 680   def BRCOND_NOTCALL : RawForm<0x03, 0xb0, (ops PR:$qp, GR:$dst),
 681     "($qp) br.cond.sptk $dst;;">;
 682 }
 683
 684 let isCall = 1, noResults = 1, /* isTerminator = 1, isBranch = 1, */
 685   Uses = [out0,out1,out2,out3,out4,out5,out6,out7],
 686 // all calls clobber non-callee-saved registers, and for now, they are these:
 687   Defs = [r2,r3,r8,r9,r10,r11,r14,r15,r16,r17,r18,r19,r20,r21,r22,r23,r24,
 688   r25,r26,r27,r28,r29,r30,r31,
 689   p6,p7,p8,p9,p10,p11,p12,p13,p14,p15,
 690   F6,F7,F8,F9,F10,F11,F12,F13,F14,F15,
 691   F32,F33,F34,F35,F36,F37,F38,F39,F40,F41,F42,F43,F44,F45,F46,F47,F48,F49,
 692   F50,F51,F52,F53,F54,F55,F56,
 693   F57,F58,F59,F60,F61,F62,F63,F64,F65,F66,F67,F68,F69,F70,F71,F72,F73,F74,
 694   F75,F76,F77,F78,F79,F80,F81,
 695   F82,F83,F84,F85,F86,F87,F88,F89,F90,F91,F92,F93,F94,F95,F96,F97,F98,F99,
 696   F100,F101,F102,F103,F104,F105,
 697   F106,F107,F108,F109,F110,F111,F112,F113,F114,F115,F116,F117,F118,F119,
 698   F120,F121,F122,F123,F124,F125,F126,F127,
 699   out0,out1,out2,out3,out4,out5,out6,out7] in {
 700 // old pattern call
 701   def BRCALL: RawForm<0x03, 0xb0, (ops calltarget:$dst),
 702   "br.call.sptk rp = $dst;;">;       // FIXME: teach llvm about branch regs?
 703 // new daggy stuff!
 704
 705 // calls a globaladdress
 706   def BRCALL_IPREL_GA : RawForm<0x03, 0xb0, (ops calltarget:$dst),
 707   "br.call.sptk rp = $dst;;">;       // FIXME: teach llvm about branch regs?
 708 // calls an externalsymbol
 709   def BRCALL_IPREL_ES : RawForm<0x03, 0xb0, (ops calltarget:$dst),
 710   "br.call.sptk rp = $dst;;">;       // FIXME: teach llvm about branch regs?
 711 // calls through a function descriptor
 712   def BRCALL_INDIRECT : RawForm<0x03, 0xb0, (ops GR:$branchreg),
 713   "br.call.sptk rp = $branchreg;;">; // FIXME: teach llvm about branch regs?
 714   def BRLCOND_CALL : RawForm<0x03, 0xb0, (ops PR:$qp, i64imm:$dst),
 715     "($qp) brl.cond.call.sptk $dst;;">;
 716   def BRCOND_CALL : RawForm<0x03, 0xb0, (ops PR:$qp, GR:$dst),
 717     "($qp) br.cond.call.sptk $dst;;">;
 718 }
 719
 720 let isTerminator = 1, isReturn = 1, noResults = 1 in
 721   def RET : RawForm<0x03, 0xb0, (ops), "br.ret.sptk.many rp;;">; // return
 722
 723