lib/Target/MBlaze/MBlazeInstrInfo.td

   1 //===- MBlazeInstrInfo.td - MBlaze Instruction defs --------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // Instruction format superclass
  12 //===----------------------------------------------------------------------===//
  13 include "MBlazeInstrFormats.td"
  14
  15 //===----------------------------------------------------------------------===//
  16 // MBlaze type profiles
  17 //===----------------------------------------------------------------------===//
  18
  19 // def SDTMBlazeSelectCC : SDTypeProfile<1, 3, [SDTCisSameAs<0, 1>]>;
  20 def SDT_MBlazeRet     : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
  21 def SDT_MBlazeIRet    : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
  22 def SDT_MBlazeJmpLink : SDTypeProfile<0, -1, [SDTCisVT<0, i32>]>;
  23 def SDT_MBCallSeqStart : SDCallSeqStart<[SDTCisVT<0, i32>]>;
  24 def SDT_MBCallSeqEnd   : SDCallSeqEnd<[SDTCisVT<0, i32>, SDTCisVT<1, i32>]>;
  25
  26 //===----------------------------------------------------------------------===//
  27 // MBlaze specific nodes
  28 //===----------------------------------------------------------------------===//
  29
  30 def MBlazeRet     : SDNode<"MBlazeISD::Ret", SDT_MBlazeRet,
  31                            [SDNPHasChain, SDNPOptInFlag]>;
  32 def MBlazeIRet    : SDNode<"MBlazeISD::IRet", SDT_MBlazeIRet,
  33                            [SDNPHasChain, SDNPOptInFlag]>;
  34
  35 def MBlazeJmpLink : SDNode<"MBlazeISD::JmpLink",SDT_MBlazeJmpLink,
  36                            [SDNPHasChain,SDNPOptInFlag,SDNPOutFlag,
  37                             SDNPVariadic]>;
  38
  39 def MBWrapper   : SDNode<"MBlazeISD::Wrap", SDTIntUnaryOp>;
  40
  41 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_MBCallSeqStart,
  42                            [SDNPHasChain, SDNPOutFlag]>;
  43
  44 def callseq_end   : SDNode<"ISD::CALLSEQ_END", SDT_MBCallSeqEnd,
  45                            [SDNPHasChain, SDNPOptInFlag, SDNPOutFlag]>;
  46
  47 //===----------------------------------------------------------------------===//
  48 // MBlaze Instruction Predicate Definitions.
  49 //===----------------------------------------------------------------------===//
  50 def HasPipe3     : Predicate<"Subtarget.hasPipe3()">;
  51 def HasBarrel    : Predicate<"Subtarget.hasBarrel()">;
  52 def NoBarrel     : Predicate<"!Subtarget.hasBarrel()">;
  53 def HasDiv       : Predicate<"Subtarget.hasDiv()">;
  54 def HasMul       : Predicate<"Subtarget.hasMul()">;
  55 def HasFSL       : Predicate<"Subtarget.hasFSL()">;
  56 def HasEFSL      : Predicate<"Subtarget.hasEFSL()">;
  57 def HasMSRSet    : Predicate<"Subtarget.hasMSRSet()">;
  58 def HasException : Predicate<"Subtarget.hasException()">;
  59 def HasPatCmp    : Predicate<"Subtarget.hasPatCmp()">;
  60 def HasFPU       : Predicate<"Subtarget.hasFPU()">;
  61 def HasESR       : Predicate<"Subtarget.hasESR()">;
  62 def HasPVR       : Predicate<"Subtarget.hasPVR()">;
  63 def HasMul64     : Predicate<"Subtarget.hasMul64()">;
  64 def HasSqrt      : Predicate<"Subtarget.hasSqrt()">;
  65 def HasMMU       : Predicate<"Subtarget.hasMMU()">;
  66
  67 //===----------------------------------------------------------------------===//
  68 // MBlaze Operand, Complex Patterns and Transformations Definitions.
  69 //===----------------------------------------------------------------------===//
  70
  71 def MBlazeMemAsmOperand : AsmOperandClass {
  72   let Name = "Mem";
  73   let SuperClasses = [];
  74 }
  75
  76 def MBlazeFslAsmOperand : AsmOperandClass {
  77   let Name = "Fsl";
  78   let SuperClasses = [];
  79 }
  80
  81 // Instruction operand types
  82 def brtarget    : Operand<OtherVT>;
  83 def calltarget  : Operand<i32>;
  84 def simm16      : Operand<i32>;
  85 def uimm5       : Operand<i32>;
  86 def uimm15      : Operand<i32>;
  87 def fimm        : Operand<f32>;
  88
  89 // Unsigned Operand
  90 def uimm16      : Operand<i32> {
  91   let PrintMethod = "printUnsignedImm";
  92 }
  93
  94 // FSL Operand
  95 def fslimm      : Operand<i32> {
  96   let PrintMethod = "printFSLImm";
  97   let ParserMatchClass = MBlazeFslAsmOperand;
  98 }
  99
 100 // Address operand
 101 def memri : Operand<i32> {
 102   let PrintMethod = "printMemOperand";
 103   let MIOperandInfo = (ops GPR, simm16);
 104   let ParserMatchClass = MBlazeMemAsmOperand;
 105 }
 106
 107 def memrr : Operand<i32> {
 108   let PrintMethod = "printMemOperand";
 109   let MIOperandInfo = (ops GPR, GPR);
 110   let ParserMatchClass = MBlazeMemAsmOperand;
 111 }
 112
 113 // Node immediate fits as 16-bit sign extended on target immediate.
 114 def immSExt16  : PatLeaf<(imm), [{
 115   return (N->getZExtValue() >> 16) == 0;
 116 }]>;
 117
 118 // Node immediate fits as 16-bit zero extended on target immediate.
 119 // The LO16 param means that only the lower 16 bits of the node
 120 // immediate are caught.
 121 // e.g. addiu, sltiu
 122 def immZExt16  : PatLeaf<(imm), [{
 123   return (N->getZExtValue() >> 16) == 0;
 124 }]>;
 125
 126 // FSL immediate field must fit in 4 bits.
 127 def immZExt4 : PatLeaf<(imm), [{
 128   return N->getZExtValue() == ((N->getZExtValue()) & 0xf) ;
 129 }]>;
 130
 131 // shamt field must fit in 5 bits.
 132 def immZExt5 : PatLeaf<(imm), [{
 133   return N->getZExtValue() == ((N->getZExtValue()) & 0x1f) ;
 134 }]>;
 135
 136 // MBlaze Address Mode. SDNode frameindex could possibily be a match
 137 // since load and store instructions from stack used it.
 138 def iaddr : ComplexPattern<i32, 2, "SelectAddrRegImm", [frameindex], []>;
 139 def xaddr : ComplexPattern<i32, 2, "SelectAddrRegReg", [], []>;
 140
 141 //===----------------------------------------------------------------------===//
 142 // Pseudo instructions
 143 //===----------------------------------------------------------------------===//
 144
 145 // As stack alignment is always done with addiu, we need a 16-bit immediate
 146 let Defs = [R1], Uses = [R1] in {
 147 def ADJCALLSTACKDOWN : MBlazePseudo<(outs), (ins simm16:$amt),
 148                                   "#ADJCALLSTACKDOWN $amt",
 149                                   [(callseq_start timm:$amt)]>;
 150 def ADJCALLSTACKUP   : MBlazePseudo<(outs),
 151                                   (ins uimm16:$amt1, simm16:$amt2),
 152                                   "#ADJCALLSTACKUP $amt1",
 153                                   [(callseq_end timm:$amt1, timm:$amt2)]>;
 154 }
 155
 156 //===----------------------------------------------------------------------===//
 157 // Instructions specific format
 158 //===----------------------------------------------------------------------===//
 159
 160 //===----------------------------------------------------------------------===//
 161 // Arithmetic Instructions
 162 //===----------------------------------------------------------------------===//
 163 class Arith<bits<6> op, bits<11> flags, string instr_asm, SDNode OpNode,
 164             InstrItinClass itin> :
 165             TA<op, flags, (outs GPR:$dst), (ins GPR:$b, GPR:$c),
 166                !strconcat(instr_asm, "   $dst, $b, $c"),
 167                [(set GPR:$dst, (OpNode GPR:$b, GPR:$c))], itin>;
 168
 169 class ArithI<bits<6> op, string instr_asm, SDNode OpNode,
 170              Operand Od, PatLeaf imm_type> :
 171              TB<op, (outs GPR:$dst), (ins GPR:$b, Od:$c),
 172                 !strconcat(instr_asm, "   $dst, $b, $c"),
 173                 [(set GPR:$dst, (OpNode GPR:$b, imm_type:$c))], IIAlu>;
 174
 175 class ArithI32<bits<6> op, string instr_asm,Operand Od, PatLeaf imm_type> :
 176                TB<op, (outs GPR:$dst), (ins GPR:$b, Od:$c),
 177                   !strconcat(instr_asm, "   $dst, $b, $c"),
 178                   [], IIAlu>;
 179
 180 class ShiftI<bits<6> op, bits<2> flags, string instr_asm, SDNode OpNode,
 181              Operand Od, PatLeaf imm_type> :
 182              SHT<op, flags, (outs GPR:$dst), (ins GPR:$b, Od:$c),
 183                  !strconcat(instr_asm, "   $dst, $b, $c"),
 184                  [(set GPR:$dst, (OpNode GPR:$b, imm_type:$c))], IIAlu>;
 185
 186 class ArithR<bits<6> op, bits<11> flags, string instr_asm, SDNode OpNode,
 187             InstrItinClass itin> :
 188             TAR<op, flags, (outs GPR:$dst), (ins GPR:$b, GPR:$c),
 189                 !strconcat(instr_asm, "   $dst, $c, $b"),
 190                 [(set GPR:$dst, (OpNode GPR:$b, GPR:$c))], itin>;
 191
 192 class ArithRI<bits<6> op, string instr_asm, SDNode OpNode,
 193              Operand Od, PatLeaf imm_type> :
 194              TBR<op, (outs GPR:$dst), (ins Od:$b, GPR:$c),
 195                  !strconcat(instr_asm, "   $dst, $c, $b"),
 196                  [(set GPR:$dst, (OpNode imm_type:$b, GPR:$c))], IIAlu>;
 197
 198 class ArithN<bits<6> op, bits<11> flags, string instr_asm,
 199             InstrItinClass itin> :
 200             TA<op, flags, (outs GPR:$dst), (ins GPR:$b, GPR:$c),
 201                !strconcat(instr_asm, "   $dst, $b, $c"),
 202                [], itin>;
 203
 204 class ArithNI<bits<6> op, string instr_asm,Operand Od, PatLeaf imm_type> :
 205              TB<op, (outs GPR:$dst), (ins GPR:$b, Od:$c),
 206                 !strconcat(instr_asm, "   $dst, $b, $c"),
 207                 [], IIAlu>;
 208
 209 class ArithRN<bits<6> op, bits<11> flags, string instr_asm,
 210             InstrItinClass itin> :
 211             TAR<op, flags, (outs GPR:$dst), (ins GPR:$c, GPR:$b),
 212                 !strconcat(instr_asm, "   $dst, $b, $c"),
 213                 [], itin>;
 214
 215 class ArithRNI<bits<6> op, string instr_asm,Operand Od, PatLeaf imm_type> :
 216              TBR<op, (outs GPR:$dst), (ins Od:$c, GPR:$b),
 217                  !strconcat(instr_asm, "   $dst, $b, $c"),
 218                  [], IIAlu>;
 219
 220 //===----------------------------------------------------------------------===//
 221 // Misc Arithmetic Instructions
 222 //===----------------------------------------------------------------------===//
 223
 224 class Logic<bits<6> op, bits<11> flags, string instr_asm, SDNode OpNode> :
 225             TA<op, flags, (outs GPR:$dst), (ins GPR:$b, GPR:$c),
 226                !strconcat(instr_asm, "   $dst, $b, $c"),
 227                [(set GPR:$dst, (OpNode GPR:$b, GPR:$c))], IIAlu>;
 228
 229 class LogicI<bits<6> op, string instr_asm, SDNode OpNode> :
 230              TB<op, (outs GPR:$dst), (ins GPR:$b, uimm16:$c),
 231                 !strconcat(instr_asm, "   $dst, $b, $c"),
 232                 [(set GPR:$dst, (OpNode GPR:$b, immZExt16:$c))],
 233                 IIAlu>;
 234
 235 class LogicI32<bits<6> op, string instr_asm> :
 236                TB<op, (outs GPR:$dst), (ins GPR:$b, uimm16:$c),
 237                   !strconcat(instr_asm, "   $dst, $b, $c"),
 238                   [], IIAlu>;
 239
 240 class PatCmp<bits<6> op, bits<11> flags, string instr_asm> :
 241              TA<op, flags, (outs GPR:$dst), (ins GPR:$b, GPR:$c),
 242                 !strconcat(instr_asm, "   $dst, $b, $c"),
 243                  [], IIAlu>;
 244
 245 //===----------------------------------------------------------------------===//
 246 // Memory Access Instructions
 247 //===----------------------------------------------------------------------===//
 248 class LoadM<bits<6> op, bits<11> flags, string instr_asm> :
 249             TA<op, flags, (outs GPR:$dst), (ins memrr:$addr),
 250                !strconcat(instr_asm, "   $dst, $addr"),
 251                [], IILoad>;
 252
 253 class LoadMI<bits<6> op, string instr_asm, PatFrag OpNode> :
 254              TB<op, (outs GPR:$dst), (ins memri:$addr),
 255                 !strconcat(instr_asm, "   $dst, $addr"),
 256                 [(set (i32 GPR:$dst), (OpNode iaddr:$addr))], IILoad>;
 257
 258 class StoreM<bits<6> op, bits<11> flags, string instr_asm> :
 259              TA<op, flags, (outs), (ins GPR:$dst, memrr:$addr),
 260                 !strconcat(instr_asm, "   $dst, $addr"),
 261                 [], IIStore>;
 262
 263 class StoreMI<bits<6> op, string instr_asm, PatFrag OpNode> :
 264               TB<op, (outs), (ins GPR:$dst, memri:$addr),
 265                  !strconcat(instr_asm, "   $dst, $addr"),
 266                  [(OpNode (i32 GPR:$dst), iaddr:$addr)], IIStore>;
 267
 268 //===----------------------------------------------------------------------===//
 269 // Branch Instructions
 270 //===----------------------------------------------------------------------===//
 271 class Branch<bits<6> op, bits<5> br, bits<11> flags, string instr_asm> :
 272              TA<op, flags, (outs), (ins GPR:$target),
 273                 !strconcat(instr_asm, "   $target"),
 274                 [], IIBranch> {
 275   let rd = 0x0;
 276   let ra = br;
 277   let Form = FCCR;
 278 }
 279
 280 class BranchI<bits<6> op, bits<5> br, string instr_asm> :
 281               TB<op, (outs), (ins brtarget:$target),
 282                  !strconcat(instr_asm, "   $target"),
 283                  [], IIBranch> {
 284   let rd = 0;
 285   let ra = br;
 286   let Form = FCCI;
 287 }
 288
 289 //===----------------------------------------------------------------------===//
 290 // Branch and Link Instructions
 291 //===----------------------------------------------------------------------===//
 292 class BranchL<bits<6> op, bits<5> br, bits<11> flags, string instr_asm> :
 293               TA<op, flags, (outs), (ins GPR:$link, GPR:$target, variable_ops),
 294                  !strconcat(instr_asm, "   $link, $target"),
 295                  [], IIBranch> {
 296   let ra = br;
 297   let Form = FRCR;
 298 }
 299
 300 class BranchLI<bits<6> op, bits<5> br, string instr_asm> :
 301                TB<op, (outs), (ins GPR:$link, calltarget:$target, variable_ops),
 302                   !strconcat(instr_asm, "   $link, $target"),
 303                   [], IIBranch> {
 304   let ra = br;
 305   let Form = FRCI;
 306 }
 307
 308 //===----------------------------------------------------------------------===//
 309 // Conditional Branch Instructions
 310 //===----------------------------------------------------------------------===//
 311 class BranchC<bits<6> op, bits<5> br, bits<11> flags, string instr_asm> :
 312               TA<op, flags, (outs),
 313                  (ins GPR:$a, GPR:$b),
 314                  !strconcat(instr_asm, "   $a, $b"),
 315                  [], IIBranch> {
 316   let rd = br;
 317   let Form = FCRR;
 318 }
 319
 320 class BranchCI<bits<6> op, bits<5> br, string instr_asm> :
 321                TB<op, (outs), (ins GPR:$a, brtarget:$offset),
 322                   !strconcat(instr_asm, "   $a, $offset"),
 323                   [], IIBranch> {
 324   let rd = br;
 325   let Form = FCRI;
 326 }
 327
 328 //===----------------------------------------------------------------------===//
 329 // MBlaze arithmetic instructions
 330 //===----------------------------------------------------------------------===//
 331
 332 let isCommutable = 1, isAsCheapAsAMove = 1 in {
 333   def ADDK   :  Arith<0x04, 0x000, "addk   ", add,  IIAlu>;
 334   def AND    :  Logic<0x21, 0x000, "and    ", and>;
 335   def OR     :  Logic<0x20, 0x000, "or     ", or>;
 336   def XOR    :  Logic<0x22, 0x000, "xor    ", xor>;
 337   def PCMPBF : PatCmp<0x20, 0x400, "pcmpbf ">;
 338   def PCMPEQ : PatCmp<0x22, 0x400, "pcmpeq ">;
 339   def PCMPNE : PatCmp<0x23, 0x400, "pcmpne ">;
 340
 341   let Defs = [CARRY] in {
 342     def ADD    :  Arith<0x00, 0x000, "add    ", addc, IIAlu>;
 343
 344     let Uses = [CARRY] in {
 345       def ADDC   :  Arith<0x02, 0x000, "addc   ", adde, IIAlu>;
 346     }
 347   }
 348
 349   let Uses = [CARRY] in {
 350     def ADDKC  : ArithN<0x06, 0x000, "addkc  ", IIAlu>;
 351   }
 352 }
 353
 354 let isAsCheapAsAMove = 1 in {
 355   def ANDN   :  ArithN<0x23, 0x000, "andn   ", IIAlu>;
 356   def CMP    :  ArithN<0x05, 0x001, "cmp    ", IIAlu>;
 357   def CMPU   :  ArithN<0x05, 0x003, "cmpu   ", IIAlu>;
 358   def RSUBK  :  ArithR<0x05, 0x000, "rsubk  ", sub,  IIAlu>;
 359
 360   let Defs = [CARRY] in {
 361     def RSUB   :  ArithR<0x01, 0x000, "rsub   ", subc, IIAlu>;
 362
 363     let Uses = [CARRY] in {
 364       def RSUBC  :  ArithR<0x03, 0x000, "rsubc  ", sube, IIAlu>;
 365     }
 366   }
 367
 368   let Uses = [CARRY] in {
 369     def RSUBKC : ArithRN<0x07, 0x000, "rsubkc ", IIAlu>;
 370   }
 371 }
 372
 373 let isCommutable = 1, Predicates=[HasMul] in {
 374   def MUL    : Arith<0x10, 0x000, "mul    ", mul,   IIAlu>;
 375 }
 376
 377 let isCommutable = 1, Predicates=[HasMul,HasMul64] in {
 378   def MULH   : Arith<0x10, 0x001, "mulh   ", mulhs, IIAlu>;
 379   def MULHU  : Arith<0x10, 0x003, "mulhu  ", mulhu, IIAlu>;
 380 }
 381
 382 let Predicates=[HasMul,HasMul64] in {
 383   def MULHSU : ArithN<0x10, 0x002, "mulhsu ", IIAlu>;
 384 }
 385
 386 let Predicates=[HasBarrel] in {
 387   def BSRL   :   Arith<0x11, 0x000, "bsrl   ", srl, IIAlu>;
 388   def BSRA   :   Arith<0x11, 0x200, "bsra   ", sra, IIAlu>;
 389   def BSLL   :   Arith<0x11, 0x400, "bsll   ", shl, IIAlu>;
 390   def BSRLI  :  ShiftI<0x19, 0x0, "bsrli  ", srl, uimm5, immZExt5>;
 391   def BSRAI  :  ShiftI<0x19, 0x1, "bsrai  ", sra, uimm5, immZExt5>;
 392   def BSLLI  :  ShiftI<0x19, 0x2, "bslli  ", shl, uimm5, immZExt5>;
 393 }
 394
 395 let Predicates=[HasDiv] in {
 396   def IDIV   :  ArithR<0x12, 0x000, "idiv   ", sdiv, IIAlu>;
 397   def IDIVU  :  ArithR<0x12, 0x002, "idivu  ", udiv, IIAlu>;
 398 }
 399
 400 //===----------------------------------------------------------------------===//
 401 // MBlaze immediate mode arithmetic instructions
 402 //===----------------------------------------------------------------------===//
 403
 404 let isAsCheapAsAMove = 1 in {
 405   def ADDIK   :   ArithI<0x0C, "addik  ", add,  simm16, immSExt16>;
 406   def RSUBIK  :  ArithRI<0x0D, "rsubik ", sub, simm16, immSExt16>;
 407   def ANDNI   :  ArithNI<0x2B, "andni  ", uimm16, immZExt16>;
 408   def ANDI    :   LogicI<0x29, "andi   ", and>;
 409   def ORI     :   LogicI<0x28, "ori    ", or>;
 410   def XORI    :   LogicI<0x2A, "xori   ", xor>;
 411
 412   let Defs = [CARRY] in {
 413     def ADDI    :   ArithI<0x08, "addi   ", addc, simm16, immSExt16>;
 414     def RSUBI   :  ArithRI<0x09, "rsubi  ", subc,  simm16, immSExt16>;
 415
 416     let Uses = [CARRY] in {
 417       def ADDIC   :   ArithI<0x0A, "addic  ", adde, simm16, immSExt16>;
 418       def RSUBIC  :  ArithRI<0x0B, "rsubic ", sube, simm16, immSExt16>;
 419     }
 420   }
 421
 422   let Uses = [CARRY] in {
 423     def ADDIKC  :  ArithNI<0x0E, "addikc ", simm16, immSExt16>;
 424     def RSUBIKC : ArithRNI<0x0F, "rsubikc", simm16, immSExt16>;
 425   }
 426 }
 427
 428 let Predicates=[HasMul] in {
 429   def MULI    :   ArithI<0x18, "muli   ", mul, simm16, immSExt16>;
 430 }
 431
 432 //===----------------------------------------------------------------------===//
 433 // MBlaze memory access instructions
 434 //===----------------------------------------------------------------------===//
 435
 436 let canFoldAsLoad = 1, isReMaterializable = 1 in {
 437   def LBU  :  LoadM<0x30, 0x000, "lbu    ">;
 438   def LBUR :  LoadM<0x30, 0x200, "lbur   ">;
 439
 440   def LHU  :  LoadM<0x31, 0x000, "lhu    ">;
 441   def LHUR :  LoadM<0x31, 0x200, "lhur   ">;
 442
 443   def LW   :  LoadM<0x32, 0x000, "lw     ">;
 444   def LWR  :  LoadM<0x32, 0x200, "lwr    ">;
 445
 446   let Defs = [CARRY] in {
 447     def LWX  :  LoadM<0x32, 0x400, "lwx    ">;
 448   }
 449
 450   def LBUI : LoadMI<0x38, "lbui   ", zextloadi8>;
 451   def LHUI : LoadMI<0x39, "lhui   ", zextloadi16>;
 452   def LWI  : LoadMI<0x3A, "lwi    ", load>;
 453 }
 454
 455 def SB  :  StoreM<0x34, 0x000, "sb     ">;
 456 def SBR :  StoreM<0x34, 0x200, "sbr    ">;
 457
 458 def SH  :  StoreM<0x35, 0x000, "sh     ">;
 459 def SHR :  StoreM<0x35, 0x200, "shr    ">;
 460
 461 def SW  :  StoreM<0x36, 0x000, "sw     ">;
 462 def SWR :  StoreM<0x36, 0x200, "swr    ">;
 463
 464 let Defs = [CARRY] in {
 465   def SWX :  StoreM<0x36, 0x400, "swx    ">;
 466 }
 467
 468 def SBI : StoreMI<0x3C, "sbi    ", truncstorei8>;
 469 def SHI : StoreMI<0x3D, "shi    ", truncstorei16>;
 470 def SWI : StoreMI<0x3E, "swi    ", store>;
 471
 472 //===----------------------------------------------------------------------===//
 473 // MBlaze branch instructions
 474 //===----------------------------------------------------------------------===//
 475
 476 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, isBarrier = 1 in {
 477   def BRI    :  BranchI<0x2E, 0x00, "bri    ">;
 478   def BRAI   :  BranchI<0x2E, 0x08, "brai   ">;
 479 }
 480
 481 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
 482   def BEQI   : BranchCI<0x2F, 0x00, "beqi   ">;
 483   def BNEI   : BranchCI<0x2F, 0x01, "bnei   ">;
 484   def BLTI   : BranchCI<0x2F, 0x02, "blti   ">;
 485   def BLEI   : BranchCI<0x2F, 0x03, "blei   ">;
 486   def BGTI   : BranchCI<0x2F, 0x04, "bgti   ">;
 487   def BGEI   : BranchCI<0x2F, 0x05, "bgei   ">;
 488 }
 489
 490 let isBranch = 1, isIndirectBranch = 1, isTerminator = 1, hasCtrlDep = 1,
 491     isBarrier = 1 in {
 492   def BR     :   Branch<0x26, 0x00, 0x000, "br     ">;
 493   def BRA    :   Branch<0x26, 0x08, 0x000, "bra    ">;
 494 }
 495
 496 let isBranch = 1, isIndirectBranch = 1, isTerminator = 1, hasCtrlDep = 1 in {
 497   def BEQ    :  BranchC<0x27, 0x00, 0x000, "beq    ">;
 498   def BNE    :  BranchC<0x27, 0x01, 0x000, "bne    ">;
 499   def BLT    :  BranchC<0x27, 0x02, 0x000, "blt    ">;
 500   def BLE    :  BranchC<0x27, 0x03, 0x000, "ble    ">;
 501   def BGT    :  BranchC<0x27, 0x04, 0x000, "bgt    ">;
 502   def BGE    :  BranchC<0x27, 0x05, 0x000, "bge    ">;
 503 }
 504
 505 let isBranch = 1, isTerminator = 1, hasDelaySlot = 1, hasCtrlDep = 1,
 506     isBarrier = 1 in {
 507   def BRID   :  BranchI<0x2E, 0x10, "brid   ">;
 508   def BRAID  :  BranchI<0x2E, 0x18, "braid  ">;
 509 }
 510
 511 let isBranch = 1, isTerminator = 1, hasDelaySlot = 1, hasCtrlDep = 1 in {
 512   def BEQID  : BranchCI<0x2F, 0x10, "beqid  ">;
 513   def BNEID  : BranchCI<0x2F, 0x11, "bneid  ">;
 514   def BLTID  : BranchCI<0x2F, 0x12, "bltid  ">;
 515   def BLEID  : BranchCI<0x2F, 0x13, "bleid  ">;
 516   def BGTID  : BranchCI<0x2F, 0x14, "bgtid  ">;
 517   def BGEID  : BranchCI<0x2F, 0x15, "bgeid  ">;
 518 }
 519
 520 let isBranch = 1, isIndirectBranch = 1, isTerminator = 1,
 521     hasDelaySlot = 1, hasCtrlDep = 1, isBarrier = 1 in {
 522   def BRD    :   Branch<0x26, 0x10, 0x000, "brd    ">;
 523   def BRAD   :   Branch<0x26, 0x18, 0x000, "brad   ">;
 524 }
 525
 526 let isBranch = 1, isIndirectBranch = 1, isTerminator = 1,
 527     hasDelaySlot = 1, hasCtrlDep = 1 in {
 528   def BEQD   :  BranchC<0x27, 0x10, 0x000, "beqd   ">;
 529   def BNED   :  BranchC<0x27, 0x11, 0x000, "bned   ">;
 530   def BLTD   :  BranchC<0x27, 0x12, 0x000, "bltd   ">;
 531   def BLED   :  BranchC<0x27, 0x13, 0x000, "bled   ">;
 532   def BGTD   :  BranchC<0x27, 0x14, 0x000, "bgtd   ">;
 533   def BGED   :  BranchC<0x27, 0x15, 0x000, "bged   ">;
 534 }
 535
 536 let isCall =1, hasDelaySlot = 1,
 537     Defs = [R3,R4,R5,R6,R7,R8,R9,R10,R11,R12,CARRY],
 538     Uses = [R1] in {
 539   def BRLID  : BranchLI<0x2E, 0x14, "brlid  ">;
 540   def BRALID : BranchLI<0x2E, 0x1C, "bralid ">;
 541 }
 542
 543 let isCall = 1, hasDelaySlot = 1,
 544     Defs = [R3,R4,R5,R6,R7,R8,R9,R10,R11,R12,CARRY],
 545     Uses = [R1] in {
 546   def BRLD   : BranchL<0x26, 0x14, 0x000, "brld   ">;
 547   def BRALD  : BranchL<0x26, 0x1C, 0x000, "brald  ">;
 548 }
 549
 550 let isReturn=1, isTerminator=1, hasDelaySlot=1, isBarrier=1,
 551     rd=0x10, Form=FCRI in {
 552   def RTSD   : TB<0x2D, (outs), (ins GPR:$target, simm16:$imm),
 553                   "rtsd      $target, $imm",
 554                   [],
 555                   IIBranch>;
 556 }
 557
 558 let isReturn=1, isTerminator=1, hasDelaySlot=1, isBarrier=1,
 559     rd=0x11, Form=FCRI in {
 560   def RTID   : TB<0x2D, (outs), (ins GPR:$target, simm16:$imm),
 561                   "rtid      $target, $imm",
 562                   [],
 563                   IIBranch>;
 564 }
 565
 566 let isReturn=1, isTerminator=1, hasDelaySlot=1, isBarrier=1,
 567     rd=0x12, Form=FCRI in {
 568   def RTBD   : TB<0x2D, (outs), (ins GPR:$target, simm16:$imm),
 569                   "rtbd      $target, $imm",
 570                   [],
 571                   IIBranch>;
 572 }
 573
 574 let isReturn=1, isTerminator=1, hasDelaySlot=1, isBarrier=1,
 575     rd=0x14, Form=FCRI in {
 576   def RTED   : TB<0x2D, (outs), (ins GPR:$target, simm16:$imm),
 577                   "rted      $target, $imm",
 578                   [],
 579                   IIBranch>;
 580 }
 581
 582 //===----------------------------------------------------------------------===//
 583 // MBlaze misc instructions
 584 //===----------------------------------------------------------------------===//
 585
 586 let neverHasSideEffects = 1 in {
 587   def NOP :  MBlazeInst< 0x20, FC, (outs), (ins), "nop    ", [], IIAlu>;
 588 }
 589
 590 let usesCustomInserter = 1 in {
 591   def Select_CC : MBlazePseudo<(outs GPR:$dst),
 592     (ins GPR:$T, GPR:$F, GPR:$CMP, i32imm:$CC), // F T reversed
 593     "; SELECT_CC PSEUDO!",
 594     []>;
 595
 596   def ShiftL : MBlazePseudo<(outs GPR:$dst),
 597     (ins GPR:$L, GPR:$R),
 598     "; ShiftL PSEUDO!",
 599     []>;
 600
 601   def ShiftRA : MBlazePseudo<(outs GPR:$dst),
 602     (ins GPR:$L, GPR:$R),
 603     "; ShiftRA PSEUDO!",
 604     []>;
 605
 606   def ShiftRL : MBlazePseudo<(outs GPR:$dst),
 607     (ins GPR:$L, GPR:$R),
 608     "; ShiftRL PSEUDO!",
 609     []>;
 610 }
 611
 612 let rb = 0 in {
 613   def SEXT16 : TA<0x24, 0x061, (outs GPR:$dst), (ins GPR:$src),
 614                   "sext16    $dst, $src", [], IIAlu>;
 615   def SEXT8  : TA<0x24, 0x060, (outs GPR:$dst), (ins GPR:$src),
 616                   "sext8     $dst, $src", [], IIAlu>;
 617   let Defs = [CARRY] in {
 618     def SRL    : TA<0x24, 0x041, (outs GPR:$dst), (ins GPR:$src),
 619                     "srl       $dst, $src", [], IIAlu>;
 620     def SRA    : TA<0x24, 0x001, (outs GPR:$dst), (ins GPR:$src),
 621                     "sra       $dst, $src", [], IIAlu>;
 622     let Uses = [CARRY] in {
 623       def SRC    : TA<0x24, 0x021, (outs GPR:$dst), (ins GPR:$src),
 624                       "src       $dst, $src", [], IIAlu>;
 625     }
 626   }
 627 }
 628
 629 let isCodeGenOnly=1 in {
 630   def ADDIK32 : ArithI32<0x08, "addik  ", simm16, immSExt16>;
 631   def ORI32   : LogicI32<0x28, "ori    ">;
 632   def BRLID32 : BranchLI<0x2E, 0x14, "brlid  ">;
 633 }
 634
 635 //===----------------------------------------------------------------------===//
 636 // Misc. instructions
 637 //===----------------------------------------------------------------------===//
 638 let Form=FRCS in {
 639   def MFS : SPC<0x25, 0x2, (outs GPR:$dst), (ins SPR:$src),
 640                 "mfs       $dst, $src", [], IIAlu>;
 641 }
 642
 643 let Form=FCRCS in {
 644   def MTS : SPC<0x25, 0x3, (outs SPR:$dst), (ins GPR:$src),
 645                 "mts       $dst, $src", [], IIAlu>;
 646 }
 647
 648 def MSRSET : MSR<0x25, 0x20, (outs GPR:$dst), (ins uimm15:$set),
 649                  "msrset    $dst, $set", [], IIAlu>;
 650
 651 def MSRCLR : MSR<0x25, 0x22, (outs GPR:$dst), (ins uimm15:$clr),
 652                  "msrclr    $dst, $clr", [], IIAlu>;
 653
 654 let rd=0x0, Form=FCRR in {
 655   def WDC  : TA<0x24, 0x64, (outs), (ins GPR:$a, GPR:$b),
 656                 "wdc       $a, $b", [], IIAlu>;
 657   def WDCF : TA<0x24, 0x74, (outs), (ins GPR:$a, GPR:$b),
 658                 "wdc.flush $a, $b", [], IIAlu>;
 659   def WDCC : TA<0x24, 0x66, (outs), (ins GPR:$a, GPR:$b),
 660                 "wdc.clear $a, $b", [], IIAlu>;
 661   def WIC  : TA<0x24, 0x68, (outs), (ins GPR:$a, GPR:$b),
 662                 "wic       $a, $b", [], IIAlu>;
 663 }
 664
 665 def BRK  :  BranchL<0x26, 0x0C, 0x000, "brk    ">;
 666 def BRKI : BranchLI<0x2E, 0x0C, "brki   ">;
 667
 668 def IMM : MBlazeInst<0x2C, FCCI, (outs), (ins simm16:$imm),
 669                      "imm       $imm", [], IIAlu>;
 670
 671 //===----------------------------------------------------------------------===//
 672 // Pseudo instructions for atomic operations
 673 //===----------------------------------------------------------------------===//
 674 let usesCustomInserter=1 in {
 675   def CAS32 : MBlazePseudo<(outs GPR:$dst), (ins GPR:$ptr, GPR:$cmp, GPR:$swp),
 676     "# atomic compare and swap",
 677     [(set GPR:$dst, (atomic_cmp_swap_32 GPR:$ptr, GPR:$cmp, GPR:$swp))]>;
 678
 679   def SWP32 : MBlazePseudo<(outs GPR:$dst), (ins GPR:$ptr, GPR:$swp),
 680     "# atomic swap",
 681     [(set GPR:$dst, (atomic_swap_32 GPR:$ptr, GPR:$swp))]>;
 682
 683   def LAA32 : MBlazePseudo<(outs GPR:$dst), (ins GPR:$ptr, GPR:$val),
 684     "# atomic load and add",
 685     [(set GPR:$dst, (atomic_load_add_32 GPR:$ptr, GPR:$val))]>;
 686
 687   def LAS32 : MBlazePseudo<(outs GPR:$dst), (ins GPR:$ptr, GPR:$val),
 688     "# atomic load and sub",
 689     [(set GPR:$dst, (atomic_load_sub_32 GPR:$ptr, GPR:$val))]>;
 690
 691   def LAD32 : MBlazePseudo<(outs GPR:$dst), (ins GPR:$ptr, GPR:$val),
 692     "# atomic load and and",
 693     [(set GPR:$dst, (atomic_load_and_32 GPR:$ptr, GPR:$val))]>;
 694
 695   def LAO32 : MBlazePseudo<(outs GPR:$dst), (ins GPR:$ptr, GPR:$val),
 696     "# atomic load and or",
 697     [(set GPR:$dst, (atomic_load_or_32 GPR:$ptr, GPR:$val))]>;
 698
 699   def LAX32 : MBlazePseudo<(outs GPR:$dst), (ins GPR:$ptr, GPR:$val),
 700     "# atomic load and xor",
 701     [(set GPR:$dst, (atomic_load_xor_32 GPR:$ptr, GPR:$val))]>;
 702
 703   def LAN32 : MBlazePseudo<(outs GPR:$dst), (ins GPR:$ptr, GPR:$val),
 704     "# atomic load and nand",
 705     [(set GPR:$dst, (atomic_load_nand_32 GPR:$ptr, GPR:$val))]>;
 706
 707   def MEMBARRIER : MBlazePseudo<(outs), (ins),
 708     "# memory barrier",
 709     [(membarrier (i32 imm), (i32 imm), (i32 imm), (i32 imm), (i32 imm))]>;
 710 }
 711
 712 //===----------------------------------------------------------------------===//
 713 //  Arbitrary patterns that map to one or more instructions
 714 //===----------------------------------------------------------------------===//
 715
 716 // Small immediates
 717 def : Pat<(i32 0), (ADD (i32 R0), (i32 R0))>;
 718 def : Pat<(i32 immSExt16:$imm), (ADDIK (i32 R0), imm:$imm)>;
 719 def : Pat<(i32 immZExt16:$imm), (ORI (i32 R0), imm:$imm)>;
 720
 721 // Arbitrary immediates
 722 def : Pat<(i32 imm:$imm), (ADDIK (i32 R0), imm:$imm)>;
 723
 724 // In register sign extension
 725 def : Pat<(sext_inreg GPR:$src, i16), (SEXT16 GPR:$src)>;
 726 def : Pat<(sext_inreg GPR:$src, i8),  (SEXT8 GPR:$src)>;
 727
 728 // Call
 729 def : Pat<(MBlazeJmpLink (i32 tglobaladdr:$dst)),
 730           (BRLID (i32 R15), tglobaladdr:$dst)>;
 731
 732 def : Pat<(MBlazeJmpLink (i32 texternalsym:$dst)),
 733           (BRLID (i32 R15), texternalsym:$dst)>;
 734
 735 def : Pat<(MBlazeJmpLink GPR:$dst),
 736           (BRALD (i32 R15), GPR:$dst)>;
 737
 738 // Shift Instructions
 739 def : Pat<(shl GPR:$L, GPR:$R), (ShiftL GPR:$L, GPR:$R)>;
 740 def : Pat<(sra GPR:$L, GPR:$R), (ShiftRA GPR:$L, GPR:$R)>;
 741 def : Pat<(srl GPR:$L, GPR:$R), (ShiftRL GPR:$L, GPR:$R)>;
 742
 743 // SET_CC operations
 744 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETEQ),
 745           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 746                      (CMP GPR:$R, GPR:$L), 1)>;
 747 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETNE),
 748           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 749                      (CMP GPR:$R, GPR:$L), 2)>;
 750 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETGT),
 751           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 752                      (CMP GPR:$R, GPR:$L), 3)>;
 753 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETLT),
 754           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 755                      (CMP GPR:$R, GPR:$L), 4)>;
 756 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETGE),
 757           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 758                      (CMP GPR:$R, GPR:$L), 5)>;
 759 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETLE),
 760           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 761                      (CMP GPR:$R, GPR:$L), 6)>;
 762 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETUGT),
 763           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 764                      (CMPU GPR:$R, GPR:$L), 3)>;
 765 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETULT),
 766           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 767                      (CMPU GPR:$R, GPR:$L), 4)>;
 768 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETUGE),
 769           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 770                      (CMPU GPR:$R, GPR:$L), 5)>;
 771 def : Pat<(setcc (i32 GPR:$L), (i32 GPR:$R), SETULE),
 772           (Select_CC (ADDIK (i32 R0), 1), (ADDIK (i32 R0), 0),
 773                      (CMPU GPR:$R, GPR:$L), 6)>;
 774
 775 // SELECT operations
 776 def : Pat<(select (i32 GPR:$C), (i32 GPR:$T), (i32 GPR:$F)),
 777           (Select_CC GPR:$T, GPR:$F, GPR:$C, 2)>;
 778
 779 // SELECT_CC
 780 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 781                     (i32 GPR:$T), (i32 GPR:$F), SETEQ),
 782           (Select_CC GPR:$T, GPR:$F, (CMP GPR:$R, GPR:$L), 1)>;
 783 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 784                     (i32 GPR:$T), (i32 GPR:$F), SETNE),
 785           (Select_CC GPR:$T, GPR:$F, (CMP GPR:$R, GPR:$L), 2)>;
 786 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 787                     (i32 GPR:$T), (i32 GPR:$F), SETGT),
 788           (Select_CC GPR:$T, GPR:$F, (CMP GPR:$R, GPR:$L), 3)>;
 789 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 790                     (i32 GPR:$T), (i32 GPR:$F), SETLT),
 791           (Select_CC GPR:$T, GPR:$F, (CMP GPR:$R, GPR:$L), 4)>;
 792 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 793                     (i32 GPR:$T), (i32 GPR:$F), SETGE),
 794           (Select_CC GPR:$T, GPR:$F, (CMP GPR:$R, GPR:$L), 5)>;
 795 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 796                     (i32 GPR:$T), (i32 GPR:$F), SETLE),
 797           (Select_CC GPR:$T, GPR:$F, (CMP GPR:$R, GPR:$L), 6)>;
 798 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 799                     (i32 GPR:$T), (i32 GPR:$F), SETUGT),
 800           (Select_CC GPR:$T, GPR:$F, (CMPU GPR:$R, GPR:$L), 3)>;
 801 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 802                     (i32 GPR:$T), (i32 GPR:$F), SETULT),
 803           (Select_CC GPR:$T, GPR:$F, (CMPU GPR:$R, GPR:$L), 4)>;
 804 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 805                     (i32 GPR:$T), (i32 GPR:$F), SETUGE),
 806           (Select_CC GPR:$T, GPR:$F, (CMPU GPR:$R, GPR:$L), 5)>;
 807 def : Pat<(selectcc (i32 GPR:$L), (i32 GPR:$R),
 808                     (i32 GPR:$T), (i32 GPR:$F), SETULE),
 809           (Select_CC GPR:$T, GPR:$F, (CMPU GPR:$R, GPR:$L), 6)>;
 810
 811 // Ret instructions
 812 def : Pat<(MBlazeRet GPR:$target), (RTSD GPR:$target, 0x8)>;
 813 def : Pat<(MBlazeIRet GPR:$target), (RTID GPR:$target, 0x0)>;
 814
 815 // BR instructions
 816 def : Pat<(br bb:$T), (BRID bb:$T)>;
 817 def : Pat<(brind GPR:$T), (BRAD GPR:$T)>;
 818
 819 // BRCOND instructions
 820 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETEQ), bb:$T),
 821           (BEQID (CMP GPR:$R, GPR:$L), bb:$T)>;
 822 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETNE), bb:$T),
 823           (BNEID (CMP GPR:$R, GPR:$L), bb:$T)>;
 824 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETGT), bb:$T),
 825           (BGTID (CMP GPR:$R, GPR:$L), bb:$T)>;
 826 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETLT), bb:$T),
 827           (BLTID (CMP GPR:$R, GPR:$L), bb:$T)>;
 828 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETGE), bb:$T),
 829           (BGEID (CMP GPR:$R, GPR:$L), bb:$T)>;
 830 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETLE), bb:$T),
 831           (BLEID (CMP GPR:$R, GPR:$L), bb:$T)>;
 832 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETUGT), bb:$T),
 833           (BGTID (CMPU GPR:$R, GPR:$L), bb:$T)>;
 834 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETULT), bb:$T),
 835           (BLTID (CMPU GPR:$R, GPR:$L), bb:$T)>;
 836 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETUGE), bb:$T),
 837           (BGEID (CMPU GPR:$R, GPR:$L), bb:$T)>;
 838 def : Pat<(brcond (setcc (i32 GPR:$L), (i32 GPR:$R), SETULE), bb:$T),
 839           (BLEID (CMPU GPR:$R, GPR:$L), bb:$T)>;
 840 def : Pat<(brcond (i32 GPR:$C), bb:$T),
 841           (BNEID GPR:$C, bb:$T)>;
 842
 843 // Jump tables, global addresses, and constant pools
 844 def : Pat<(MBWrapper tglobaladdr:$in), (ORI (i32 R0), tglobaladdr:$in)>;
 845 def : Pat<(MBWrapper tjumptable:$in),  (ORI (i32 R0), tjumptable:$in)>;
 846 def : Pat<(MBWrapper tconstpool:$in),  (ORI (i32 R0), tconstpool:$in)>;
 847
 848 // Misc instructions
 849 def : Pat<(and (i32 GPR:$lh), (not (i32 GPR:$rh))),(ANDN GPR:$lh, GPR:$rh)>;
 850
 851 // Arithmetic with immediates
 852 def : Pat<(add (i32 GPR:$in), imm:$imm),(ADDIK GPR:$in, imm:$imm)>;
 853 def : Pat<(or (i32 GPR:$in), imm:$imm),(ORI GPR:$in, imm:$imm)>;
 854 def : Pat<(xor (i32 GPR:$in), imm:$imm),(XORI GPR:$in, imm:$imm)>;
 855
 856 // Convert any extend loads into zero extend loads
 857 def : Pat<(extloadi8  iaddr:$src), (i32 (LBUI iaddr:$src))>;
 858 def : Pat<(extloadi16 iaddr:$src), (i32 (LHUI iaddr:$src))>;
 859 def : Pat<(extloadi8  xaddr:$src), (i32 (LBU xaddr:$src))>;
 860 def : Pat<(extloadi16 xaddr:$src), (i32 (LHU xaddr:$src))>;
 861
 862 // 32-bit load and store
 863 def : Pat<(store (i32 GPR:$dst), xaddr:$addr), (SW GPR:$dst, xaddr:$addr)>;
 864 def : Pat<(load xaddr:$addr), (i32 (LW xaddr:$addr))>;
 865
 866 // 16-bit load and store
 867 def : Pat<(truncstorei16 (i32 GPR:$dst), xaddr:$addr), (SH GPR:$dst, xaddr:$addr)>;
 868 def : Pat<(zextloadi16 xaddr:$addr), (i32 (LHU xaddr:$addr))>;
 869
 870 // 8-bit load and store
 871 def : Pat<(truncstorei8 (i32 GPR:$dst), xaddr:$addr), (SB GPR:$dst, xaddr:$addr)>;
 872 def : Pat<(zextloadi8 xaddr:$addr), (i32 (LBU xaddr:$addr))>;
 873
 874 // Peepholes
 875 def : Pat<(store (i32 0), iaddr:$dst), (SWI (i32 R0), iaddr:$dst)>;
 876
 877 //===----------------------------------------------------------------------===//
 878 // Floating Point Support
 879 //===----------------------------------------------------------------------===//
 880 include "MBlazeInstrFSL.td"
 881 include "MBlazeInstrFPU.td"