lib/Target/Mips/MipsCondMov.td

   1 //===-- MipsCondMov.td - Describe Mips Conditional Moves --*- tablegen -*--===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This is the Conditional Moves implementation.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 // Conditional moves:
  15 // These instructions are expanded in
  16 // MipsISelLowering::EmitInstrWithCustomInserter if target does not have
  17 // conditional move instructions.
  18 // cond:int, data:int
  19 class CMov_I_I_FT<string opstr, RegisterClass CRC, RegisterClass DRC,
  20                   InstrItinClass Itin> :
  21   InstSE<(outs DRC:$rd), (ins DRC:$rs, CRC:$rt, DRC:$F),
  22          !strconcat(opstr, "\t$rd, $rs, $rt"), [], Itin, FrmFR> {
  23   let Constraints = "$F = $rd";
  24 }
  25
  26 // cond:int, data:float
  27 class CMov_I_F_FT<string opstr, RegisterClass CRC, RegisterClass DRC,
  28                   InstrItinClass Itin> :
  29   InstSE<(outs DRC:$fd), (ins DRC:$fs, CRC:$rt, DRC:$F),
  30          !strconcat(opstr, "\t$fd, $fs, $rt"), [], Itin, FrmFR> {
  31   let Constraints = "$F = $fd";
  32 }
  33
  34 // cond:float, data:int
  35 class CMov_F_I_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
  36                   SDPatternOperator OpNode = null_frag> :
  37   InstSE<(outs RC:$rd), (ins RC:$rs, RC:$F),
  38          !strconcat(opstr, "\t$rd, $rs, $$fcc0"),
  39          [(set RC:$rd, (OpNode RC:$rs, RC:$F))], Itin, FrmFR> {
  40   let Uses = [FCR31];
  41   let Constraints = "$F = $rd";
  42 }
  43
  44 // cond:float, data:float
  45 class CMov_F_F_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
  46                   SDPatternOperator OpNode = null_frag> :
  47   InstSE<(outs RC:$fd), (ins RC:$fs, RC:$F),
  48          !strconcat(opstr, "\t$fd, $fs, $$fcc0"),
  49          [(set RC:$fd, (OpNode RC:$fs, RC:$F))], Itin, FrmFR> {
  50   let Uses = [FCR31];
  51   let Constraints = "$F = $fd";
  52 }
  53
  54 // select patterns
  55 multiclass MovzPats0<RegisterClass CRC, RegisterClass DRC,
  56                      Instruction MOVZInst, Instruction SLTOp,
  57                      Instruction SLTuOp, Instruction SLTiOp,
  58                      Instruction SLTiuOp> {
  59   def : MipsPat<(select (i32 (setge CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  60                 (MOVZInst DRC:$T, (SLTOp CRC:$lhs, CRC:$rhs), DRC:$F)>;
  61   def : MipsPat<(select (i32 (setuge CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  62                 (MOVZInst DRC:$T, (SLTuOp CRC:$lhs, CRC:$rhs), DRC:$F)>;
  63   def : MipsPat<(select (i32 (setge CRC:$lhs, immSExt16:$rhs)), DRC:$T, DRC:$F),
  64                 (MOVZInst DRC:$T, (SLTiOp CRC:$lhs, immSExt16:$rhs), DRC:$F)>;
  65   def : MipsPat<(select (i32 (setuge CRC:$lh, immSExt16:$rh)), DRC:$T, DRC:$F),
  66                 (MOVZInst DRC:$T, (SLTiuOp CRC:$lh, immSExt16:$rh), DRC:$F)>;
  67   def : MipsPat<(select (i32 (setle CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  68                 (MOVZInst DRC:$T, (SLTOp CRC:$rhs, CRC:$lhs), DRC:$F)>;
  69   def : MipsPat<(select (i32 (setule CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  70                 (MOVZInst DRC:$T, (SLTuOp CRC:$rhs, CRC:$lhs), DRC:$F)>;
  71 }
  72
  73 multiclass MovzPats1<RegisterClass CRC, RegisterClass DRC,
  74                      Instruction MOVZInst, Instruction XOROp> {
  75   def : MipsPat<(select (i32 (seteq CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  76                 (MOVZInst DRC:$T, (XOROp CRC:$lhs, CRC:$rhs), DRC:$F)>;
  77   def : MipsPat<(select (i32 (seteq CRC:$lhs, 0)), DRC:$T, DRC:$F),
  78                 (MOVZInst DRC:$T, CRC:$lhs, DRC:$F)>;
  79 }
  80
  81 multiclass MovzPats2<RegisterClass CRC, RegisterClass DRC,
  82                      Instruction MOVZInst, Instruction XORiOp> {
  83   def : MipsPat<
  84             (select (i32 (seteq CRC:$lhs, immZExt16:$uimm16)), DRC:$T, DRC:$F),
  85             (MOVZInst DRC:$T, (XORiOp CRC:$lhs, immZExt16:$uimm16), DRC:$F)>;
  86 }
  87
  88 multiclass MovnPats<RegisterClass CRC, RegisterClass DRC, Instruction MOVNInst,
  89                     Instruction XOROp> {
  90   def : MipsPat<(select (i32 (setne CRC:$lhs, CRC:$rhs)), DRC:$T, DRC:$F),
  91                 (MOVNInst DRC:$T, (XOROp CRC:$lhs, CRC:$rhs), DRC:$F)>;
  92   def : MipsPat<(select CRC:$cond, DRC:$T, DRC:$F),
  93                 (MOVNInst DRC:$T, CRC:$cond, DRC:$F)>;
  94   def : MipsPat<(select (i32 (setne CRC:$lhs, 0)),DRC:$T, DRC:$F),
  95                 (MOVNInst DRC:$T, CRC:$lhs, DRC:$F)>;
  96 }
  97
  98 // Instantiation of instructions.
  99 def MOVZ_I_I : CMov_I_I_FT<"movz", CPURegs, CPURegs, NoItinerary>,
 100                ADD_FM<0, 0xa>;
 101 let Predicates = [HasStdEnc],
 102                   DecoderNamespace = "Mips64" in {
 103   def MOVZ_I_I64   : CMov_I_I_FT<"movz", CPURegs, CPU64Regs, NoItinerary>,
 104                      ADD_FM<0, 0xa>;
 105   def MOVZ_I64_I   : CMov_I_I_FT<"movz", CPU64Regs, CPURegs, NoItinerary>,
 106                      ADD_FM<0, 0xa> {
 107     let isCodeGenOnly = 1;
 108   }
 109   def MOVZ_I64_I64 : CMov_I_I_FT<"movz", CPU64Regs, CPU64Regs, NoItinerary>,
 110                      ADD_FM<0, 0xa> {
 111     let isCodeGenOnly = 1;
 112   }
 113 }
 114
 115 def MOVN_I_I       : CMov_I_I_FT<"movn", CPURegs, CPURegs, NoItinerary>,
 116                      ADD_FM<0, 0xb>;
 117 let Predicates = [HasStdEnc],
 118                   DecoderNamespace = "Mips64" in {
 119   def MOVN_I_I64   : CMov_I_I_FT<"movn", CPURegs, CPU64Regs, NoItinerary>,
 120                      ADD_FM<0, 0xb>;
 121   def MOVN_I64_I   : CMov_I_I_FT<"movn", CPU64Regs, CPURegs, NoItinerary>,
 122                      ADD_FM<0, 0xb> {
 123     let isCodeGenOnly = 1;
 124   }
 125   def MOVN_I64_I64 : CMov_I_I_FT<"movn", CPU64Regs, CPU64Regs, NoItinerary>,
 126                      ADD_FM<0, 0xb> {
 127     let isCodeGenOnly = 1;
 128   }
 129 }
 130
 131 def MOVZ_I_S : CMov_I_F_FT<"movz.s", CPURegs, FGR32, IIFmove>,
 132                CMov_I_F_FM<18, 16>;
 133 def MOVZ_I64_S : CMov_I_F_FT<"movz.s", CPU64Regs, FGR32, IIFmove>,
 134                  CMov_I_F_FM<18, 16>, Requires<[HasMips64, HasStdEnc]> {
 135   let DecoderNamespace = "Mips64";
 136 }
 137
 138 def MOVN_I_S : CMov_I_F_FT<"movn.s", CPURegs, FGR32, IIFmove>,
 139                CMov_I_F_FM<19, 16>;
 140 def MOVN_I64_S : CMov_I_F_FT<"movn.s", CPU64Regs, FGR32, IIFmove>,
 141                  CMov_I_F_FM<19, 16>, Requires<[HasMips64, HasStdEnc]> {
 142   let DecoderNamespace = "Mips64";
 143 }
 144
 145 let Predicates = [NotFP64bit, HasStdEnc] in {
 146   def MOVZ_I_D32 : CMov_I_F_FT<"movz.d", CPURegs, AFGR64, IIFmove>,
 147                    CMov_I_F_FM<18, 17>;
 148   def MOVN_I_D32 : CMov_I_F_FT<"movn.d", CPURegs, AFGR64, IIFmove>,
 149                    CMov_I_F_FM<19, 17>;
 150 }
 151 let Predicates = [IsFP64bit, HasStdEnc],
 152                   DecoderNamespace = "Mips64" in {
 153   def MOVZ_I_D64 : CMov_I_F_FT<"movz.d", CPURegs, FGR64, IIFmove>,
 154                    CMov_I_F_FM<18, 17>;
 155   def MOVZ_I64_D64 : CMov_I_F_FT<"movz.d", CPU64Regs, FGR64, IIFmove>,
 156                      CMov_I_F_FM<18, 17> {
 157     let isCodeGenOnly = 1;
 158   }
 159   def MOVN_I_D64 : CMov_I_F_FT<"movn.d", CPURegs, FGR64, IIFmove>,
 160                    CMov_I_F_FM<19, 17>;
 161   def MOVN_I64_D64 : CMov_I_F_FT<"movn.d", CPU64Regs, FGR64, IIFmove>,
 162                      CMov_I_F_FM<19, 17> {
 163     let isCodeGenOnly = 1;
 164   }
 165 }
 166
 167 def MOVT_I : CMov_F_I_FT<"movt", CPURegs, IIAlu, MipsCMovFP_T>, CMov_F_I_FM<1>;
 168 def MOVT_I64 : CMov_F_I_FT<"movt", CPU64Regs, IIAlu, MipsCMovFP_T>,
 169                CMov_F_I_FM<1>, Requires<[HasMips64, HasStdEnc]> {
 170   let DecoderNamespace = "Mips64";
 171 }
 172
 173 def MOVF_I : CMov_F_I_FT<"movf", CPURegs, IIAlu, MipsCMovFP_F>, CMov_F_I_FM<0>;
 174 def MOVF_I64 : CMov_F_I_FT<"movf", CPU64Regs, IIAlu, MipsCMovFP_F>,
 175                CMov_F_I_FM<0>, Requires<[HasMips64, HasStdEnc]> {
 176   let DecoderNamespace = "Mips64";
 177 }
 178
 179 def MOVT_S : CMov_F_F_FT<"movt.s", FGR32, IIFmove, MipsCMovFP_T>,
 180              CMov_F_F_FM<16, 1>;
 181 def MOVF_S : CMov_F_F_FT<"movf.s", FGR32, IIFmove, MipsCMovFP_F>,
 182              CMov_F_F_FM<16, 0>;
 183
 184 let Predicates = [NotFP64bit, HasStdEnc] in {
 185   def MOVT_D32 : CMov_F_F_FT<"movt.d", AFGR64, IIFmove, MipsCMovFP_T>,
 186                  CMov_F_F_FM<17, 1>;
 187   def MOVF_D32 : CMov_F_F_FT<"movf.d", AFGR64, IIFmove, MipsCMovFP_F>,
 188                  CMov_F_F_FM<17, 0>;
 189 }
 190 let Predicates = [IsFP64bit, HasStdEnc],
 191     DecoderNamespace = "Mips64" in {
 192   def MOVT_D64 : CMov_F_F_FT<"movt.d", FGR64, IIFmove, MipsCMovFP_T>,
 193                  CMov_F_F_FM<17, 1>;
 194   def MOVF_D64 : CMov_F_F_FT<"movf.d", FGR64, IIFmove, MipsCMovFP_F>,
 195                  CMov_F_F_FM<17, 0>;
 196 }
 197
 198 // Instantiation of conditional move patterns.
 199 defm : MovzPats0<CPURegs, CPURegs, MOVZ_I_I, SLT, SLTu, SLTi, SLTiu>;
 200 defm : MovzPats1<CPURegs, CPURegs, MOVZ_I_I, XOR>;
 201 defm : MovzPats2<CPURegs, CPURegs, MOVZ_I_I, XORi>;
 202 let Predicates = [HasMips64, HasStdEnc] in {
 203   defm : MovzPats0<CPURegs, CPU64Regs, MOVZ_I_I64, SLT, SLTu, SLTi, SLTiu>;
 204   defm : MovzPats0<CPU64Regs, CPURegs, MOVZ_I_I, SLT64, SLTu64, SLTi64,
 205                    SLTiu64>;
 206   defm : MovzPats0<CPU64Regs, CPU64Regs, MOVZ_I_I64, SLT64, SLTu64, SLTi64,
 207                    SLTiu64>;
 208   defm : MovzPats1<CPURegs, CPU64Regs, MOVZ_I_I64, XOR>;
 209   defm : MovzPats1<CPU64Regs, CPURegs, MOVZ_I64_I, XOR64>;
 210   defm : MovzPats1<CPU64Regs, CPU64Regs, MOVZ_I64_I64, XOR64>;
 211   defm : MovzPats2<CPURegs, CPU64Regs, MOVZ_I_I64, XORi>;
 212   defm : MovzPats2<CPU64Regs, CPURegs, MOVZ_I64_I, XORi64>;
 213   defm : MovzPats2<CPU64Regs, CPU64Regs, MOVZ_I64_I64, XORi64>;
 214 }
 215
 216 defm : MovnPats<CPURegs, CPURegs, MOVN_I_I, XOR>;
 217 let Predicates = [HasMips64, HasStdEnc] in {
 218   defm : MovnPats<CPURegs, CPU64Regs, MOVN_I_I64, XOR>;
 219   defm : MovnPats<CPU64Regs, CPURegs, MOVN_I64_I, XOR64>;
 220   defm : MovnPats<CPU64Regs, CPU64Regs, MOVN_I64_I64, XOR64>;
 221 }
 222
 223 defm : MovzPats0<CPURegs, FGR32, MOVZ_I_S, SLT, SLTu, SLTi, SLTiu>;
 224 defm : MovzPats1<CPURegs, FGR32, MOVZ_I_S, XOR>;
 225 defm : MovnPats<CPURegs, FGR32, MOVN_I_S, XOR>;
 226 let Predicates = [HasMips64, HasStdEnc] in {
 227   defm : MovzPats0<CPU64Regs, FGR32, MOVZ_I_S, SLT64, SLTu64, SLTi64,
 228                    SLTiu64>;
 229   defm : MovzPats1<CPU64Regs, FGR32, MOVZ_I64_S, XOR64>;
 230   defm : MovnPats<CPU64Regs, FGR32, MOVN_I64_S, XOR64>;
 231 }
 232
 233 let Predicates = [NotFP64bit, HasStdEnc] in {
 234   defm : MovzPats0<CPURegs, AFGR64, MOVZ_I_D32, SLT, SLTu, SLTi, SLTiu>;
 235   defm : MovzPats1<CPURegs, AFGR64, MOVZ_I_D32, XOR>;
 236   defm : MovnPats<CPURegs, AFGR64, MOVN_I_D32, XOR>;
 237 }
 238 let Predicates = [IsFP64bit, HasStdEnc] in {
 239   defm : MovzPats0<CPURegs, FGR64, MOVZ_I_D64, SLT, SLTu, SLTi, SLTiu>;
 240   defm : MovzPats0<CPU64Regs, FGR64, MOVZ_I_D64, SLT64, SLTu64, SLTi64,
 241                    SLTiu64>;
 242   defm : MovzPats1<CPURegs, FGR64, MOVZ_I_D64, XOR>;
 243   defm : MovzPats1<CPU64Regs, FGR64, MOVZ_I64_D64, XOR64>;
 244   defm : MovnPats<CPURegs, FGR64, MOVN_I_D64, XOR>;
 245   defm : MovnPats<CPU64Regs, FGR64, MOVN_I64_D64, XOR64>;
 246 }