lib/Target/Mips/MipsInstrFPU.td

   1 //===- MipsInstrFPU.td - Mips FPU Instruction Information -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===---------------------------------------------------------------------===//
   9 //
  10 // This file contains the Mips implementation of the TargetInstrInfo class.
  11 //
  12 //===---------------------------------------------------------------------===//
  13
  14 //===---------------------------------------------------------------------===//
  15 // Floating Point Instructions
  16 // ------------------------
  17 // * 64bit fp:
  18 //    - 32 64-bit registers (default mode)
  19 //    - 16 even 32-bit registers (32-bit compatible mode) for
  20 //      single and double access.
  21 // * 32bit fp:
  22 //    - 16 even 32-bit registers - single and double (aliased)
  23 //    - 32 32-bit registers (within single-only mode)
  24 //===---------------------------------------------------------------------===//
  25
  26 // Floating Point Compare and Branch
  27 def SDT_MipsFPBrcond : SDTypeProfile<0, 2, [SDTCisInt<0>,
  28                                             SDTCisVT<1, OtherVT>]>;
  29 def SDT_MipsFPCmp : SDTypeProfile<0, 3, [SDTCisSameAs<0, 1>, SDTCisFP<1>,
  30                                          SDTCisInt<2>]>;
  31 def SDT_MipsCMovFP : SDTypeProfile<1, 2, [SDTCisSameAs<0, 1>,
  32                                           SDTCisSameAs<1, 2>]>;
  33 def SDT_MipsBuildPairF64 : SDTypeProfile<1, 2, [SDTCisVT<0, f64>,
  34                                                 SDTCisVT<1, i32>,
  35                                                 SDTCisSameAs<1, 2>]>;
  36 def SDT_MipsExtractElementF64 : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
  37                                                      SDTCisVT<1, f64>,
  38                                                      SDTCisVT<0, i32>]>;
  39
  40 def MipsFPCmp : SDNode<"MipsISD::FPCmp", SDT_MipsFPCmp, [SDNPOutGlue]>;
  41 def MipsCMovFP_T : SDNode<"MipsISD::CMovFP_T", SDT_MipsCMovFP, [SDNPInGlue]>;
  42 def MipsCMovFP_F : SDNode<"MipsISD::CMovFP_F", SDT_MipsCMovFP, [SDNPInGlue]>;
  43 def MipsFPRound : SDNode<"MipsISD::FPRound", SDTFPRoundOp, [SDNPOptInGlue]>;
  44 def MipsFPBrcond : SDNode<"MipsISD::FPBrcond", SDT_MipsFPBrcond,
  45                           [SDNPHasChain, SDNPOptInGlue]>;
  46 def MipsBuildPairF64 : SDNode<"MipsISD::BuildPairF64", SDT_MipsBuildPairF64>;
  47 def MipsExtractElementF64 : SDNode<"MipsISD::ExtractElementF64",
  48                                    SDT_MipsExtractElementF64>;
  49
  50 // Operand for printing out a condition code.
  51 let PrintMethod = "printFCCOperand" in
  52   def condcode : Operand<i32>;
  53
  54 //===---------------------------------------------------------------------===//
  55 // Feature predicates.
  56 //===---------------------------------------------------------------------===//
  57
  58 def In32BitMode      : Predicate<"!Subtarget.isFP64bit()">;
  59 def IsSingleFloat    : Predicate<"Subtarget.isSingleFloat()">;
  60 def IsNotSingleFloat : Predicate<"!Subtarget.isSingleFloat()">;
  61 def IsNotMipsI       : Predicate<"!Subtarget.isMips1()">;
  62
  63 //===---------------------------------------------------------------------===//
  64 // Instruction Class Templates
  65 //
  66 // A set of multiclasses is used to address the register usage.
  67 //
  68 // S32 - single precision in 16 32bit even fp registers
  69 //       single precision in 32 32bit fp registers in SingleOnly mode
  70 // S64 - single precision in 32 64bit fp registers (In64BitMode)
  71 // D32 - double precision in 16 32bit even fp registers
  72 // D64 - double precision in 32 64bit fp registers (In64BitMode)
  73 //
  74 // Only S32 and D32 are supported right now.
  75 //===---------------------------------------------------------------------===//
  76
  77 multiclass FFR1_1<bits<6> funct, string asmstr>
  78 {
  79   def _S32 : FFR<0x11, funct, 0x0, (outs FGR32:$fd), (ins FGR32:$fs),
  80       !strconcat(asmstr, ".s $fd, $fs"), []>;
  81
  82   def _D32  : FFR<0x11, funct, 0x1, (outs FGR32:$fd), (ins AFGR64:$fs),
  83       !strconcat(asmstr, ".d $fd, $fs"), []>, Requires<[In32BitMode]>;
  84 }
  85
  86 multiclass FFR1_2<bits<6> funct, string asmstr, SDNode FOp>
  87 {
  88   def _S32 : FFR<0x11, funct, 0x0, (outs FGR32:$fd), (ins FGR32:$fs),
  89                  !strconcat(asmstr, ".s $fd, $fs"),
  90                  [(set FGR32:$fd, (FOp FGR32:$fs))]>;
  91
  92   def _D32  : FFR<0x11, funct, 0x1, (outs AFGR64:$fd), (ins AFGR64:$fs),
  93                  !strconcat(asmstr, ".d $fd, $fs"),
  94                  [(set AFGR64:$fd, (FOp AFGR64:$fs))]>,
  95                  Requires<[In32BitMode]>;
  96 }
  97
  98 class FFR1_3<bits<6> funct, bits<5> fmt, RegisterClass RcSrc,
  99               RegisterClass RcDst, string asmstr>:
 100   FFR<0x11, funct, fmt, (outs RcSrc:$fd), (ins RcDst:$fs),
 101       !strconcat(asmstr, " $fd, $fs"), []>;
 102
 103
 104 multiclass FFR1_4<bits<6> funct, string asmstr, SDNode FOp> {
 105   def _S32 : FFR<0x11, funct, 0x0, (outs FGR32:$fd),
 106                  (ins FGR32:$fs, FGR32:$ft),
 107                  !strconcat(asmstr, ".s $fd, $fs, $ft"),
 108                  [(set FGR32:$fd, (FOp FGR32:$fs, FGR32:$ft))]>;
 109
 110   def _D32 : FFR<0x11, funct, 0x1, (outs AFGR64:$fd),
 111                  (ins AFGR64:$fs, AFGR64:$ft),
 112                  !strconcat(asmstr, ".d $fd, $fs, $ft"),
 113                  [(set AFGR64:$fd, (FOp AFGR64:$fs, AFGR64:$ft))]>,
 114                  Requires<[In32BitMode]>;
 115 }
 116
 117 //===---------------------------------------------------------------------===//
 118 // Floating Point Instructions
 119 //===---------------------------------------------------------------------===//
 120
 121 let ft = 0 in {
 122   defm FLOOR_W : FFR1_1<0b001111, "floor.w">;
 123   defm CEIL_W  : FFR1_1<0b001110, "ceil.w">;
 124   defm ROUND_W : FFR1_1<0b001100, "round.w">;
 125   defm TRUNC_W : FFR1_1<0b001101, "trunc.w">;
 126   defm CVTW    : FFR1_1<0b100100, "cvt.w">;
 127
 128   defm FABS    : FFR1_2<0b000101, "abs",  fabs>;
 129   defm FNEG    : FFR1_2<0b000111, "neg",  fneg>;
 130   defm FSQRT   : FFR1_2<0b000100, "sqrt", fsqrt>;
 131
 132   /// Convert to Single Precison
 133   def CVTS_W32 : FFR1_3<0b100000, 0x2, FGR32,  FGR32,  "cvt.s.w">;
 134
 135   let Predicates = [IsNotSingleFloat] in {
 136     /// Ceil to long signed integer
 137     def CEIL_LS   : FFR1_3<0b001010, 0x0, FGR32, FGR32, "ceil.l">;
 138     def CEIL_LD   : FFR1_3<0b001010, 0x1, AFGR64, AFGR64, "ceil.l">;
 139
 140     /// Round to long signed integer
 141     def ROUND_LS  : FFR1_3<0b001000, 0x0, FGR32, FGR32, "round.l">;
 142     def ROUND_LD  : FFR1_3<0b001000, 0x1, AFGR64, AFGR64, "round.l">;
 143
 144     /// Floor to long signed integer
 145     def FLOOR_LS  : FFR1_3<0b001011, 0x0, FGR32, FGR32, "floor.l">;
 146     def FLOOR_LD  : FFR1_3<0b001011, 0x1, AFGR64, AFGR64, "floor.l">;
 147
 148     /// Trunc to long signed integer
 149     def TRUNC_LS  : FFR1_3<0b001001, 0x0, FGR32, FGR32, "trunc.l">;
 150     def TRUNC_LD  : FFR1_3<0b001001, 0x1, AFGR64, AFGR64, "trunc.l">;
 151
 152     /// Convert to long signed integer
 153     def CVTL_S    : FFR1_3<0b100101, 0x0, FGR32, FGR32, "cvt.l">;
 154     def CVTL_D    : FFR1_3<0b100101, 0x1, AFGR64, AFGR64, "cvt.l">;
 155
 156     /// Convert to Double Precison
 157     def CVTD_S32 : FFR1_3<0b100001, 0x0, AFGR64, FGR32, "cvt.d.s">;
 158     def CVTD_W32 : FFR1_3<0b100001, 0x2, AFGR64, FGR32, "cvt.d.w">;
 159     def CVTD_L32 : FFR1_3<0b100001, 0x3, AFGR64, AFGR64, "cvt.d.l">;
 160
 161     /// Convert to Single Precison
 162     def CVTS_D32 : FFR1_3<0b100000, 0x1, FGR32, AFGR64, "cvt.s.d">;
 163     def CVTS_L32 : FFR1_3<0b100000, 0x3, FGR32, AFGR64, "cvt.s.l">;
 164   }
 165 }
 166
 167 // The odd-numbered registers are only referenced when doing loads,
 168 // stores, and moves between floating-point and integer registers.
 169 // When defining instructions, we reference all 32-bit registers,
 170 // regardless of register aliasing.
 171 let fd = 0 in {
 172   /// Move Control Registers From/To CPU Registers
 173   def CFC1  : FFR<0x11, 0x0, 0x2, (outs CPURegs:$rt), (ins CCR:$fs),
 174                   "cfc1 $rt, $fs", []>;
 175
 176   def CTC1  : FFR<0x11, 0x0, 0x6, (outs CCR:$rt), (ins CPURegs:$fs),
 177                   "ctc1 $fs, $rt", []>;
 178
 179   def MFC1  : FFR<0x11, 0x00, 0x00, (outs CPURegs:$rt), (ins FGR32:$fs),
 180                   "mfc1 $rt, $fs", []>;
 181
 182   def MTC1  : FFR<0x11, 0x00, 0x04, (outs FGR32:$fs), (ins CPURegs:$rt),
 183                   "mtc1 $rt, $fs", []>;
 184 }
 185
 186 def FMOV_S32 : FFR<0x11, 0b000110, 0x0, (outs FGR32:$fd), (ins FGR32:$fs),
 187                    "mov.s $fd, $fs", []>;
 188 def FMOV_D32 : FFR<0x11, 0b000110, 0x1, (outs AFGR64:$fd), (ins AFGR64:$fs),
 189                    "mov.d $fd, $fs", []>;
 190
 191 /// Floating Point Memory Instructions
 192 let Predicates = [IsNotSingleFloat, IsNotMipsI] in {
 193   def LDC1 : FFI<0b110101, (outs AFGR64:$ft), (ins mem:$addr),
 194                  "ldc1 $ft, $addr", [(set AFGR64:$ft, (load addr:$addr))]>;
 195
 196   def SDC1 : FFI<0b111101, (outs), (ins AFGR64:$ft, mem:$addr),
 197                  "sdc1 $ft, $addr", [(store AFGR64:$ft, addr:$addr)]>;
 198 }
 199
 200 // LWC1 and SWC1 can always be emitted with odd registers.
 201 def LWC1  : FFI<0b110001, (outs FGR32:$ft), (ins mem:$addr), "lwc1 $ft, $addr",
 202                [(set FGR32:$ft, (load addr:$addr))]>;
 203 def SWC1  : FFI<0b111001, (outs), (ins FGR32:$ft, mem:$addr),
 204                 "swc1 $ft, $addr", [(store FGR32:$ft, addr:$addr)]>;
 205
 206 /// Floating-point Aritmetic
 207 defm FADD : FFR1_4<0x10, "add", fadd>;
 208 defm FDIV : FFR1_4<0x03, "div", fdiv>;
 209 defm FMUL : FFR1_4<0x02, "mul", fmul>;
 210 defm FSUB : FFR1_4<0x01, "sub", fsub>;
 211
 212 //===---------------------------------------------------------------------===//
 213 // Floating Point Branch Codes
 214 //===---------------------------------------------------------------------===//
 215 // Mips branch codes. These correspond to condcode in MipsInstrInfo.h.
 216 // They must be kept in synch.
 217 def MIPS_BRANCH_F  : PatLeaf<(i32 0)>;
 218 def MIPS_BRANCH_T  : PatLeaf<(i32 1)>;
 219 def MIPS_BRANCH_FL : PatLeaf<(i32 2)>;
 220 def MIPS_BRANCH_TL : PatLeaf<(i32 3)>;
 221
 222 /// Floating Point Branch of False/True (Likely)
 223 let isBranch=1, isTerminator=1, hasDelaySlot=1, base=0x8, Uses=[FCR31] in
 224   class FBRANCH<PatLeaf op, string asmstr> : FFI<0x11, (outs),
 225         (ins brtarget:$dst), !strconcat(asmstr, " $dst"),
 226         [(MipsFPBrcond op, bb:$dst)]>;
 227
 228 def BC1F  : FBRANCH<MIPS_BRANCH_F,  "bc1f">;
 229 def BC1T  : FBRANCH<MIPS_BRANCH_T,  "bc1t">;
 230 def BC1FL : FBRANCH<MIPS_BRANCH_FL, "bc1fl">;
 231 def BC1TL : FBRANCH<MIPS_BRANCH_TL, "bc1tl">;
 232
 233 //===---------------------------------------------------------------------===//
 234 // Floating Point Flag Conditions
 235 //===---------------------------------------------------------------------===//
 236 // Mips condition codes. They must correspond to condcode in MipsInstrInfo.h.
 237 // They must be kept in synch.
 238 def MIPS_FCOND_F    : PatLeaf<(i32 0)>;
 239 def MIPS_FCOND_UN   : PatLeaf<(i32 1)>;
 240 def MIPS_FCOND_OEQ  : PatLeaf<(i32 2)>;
 241 def MIPS_FCOND_UEQ  : PatLeaf<(i32 3)>;
 242 def MIPS_FCOND_OLT  : PatLeaf<(i32 4)>;
 243 def MIPS_FCOND_ULT  : PatLeaf<(i32 5)>;
 244 def MIPS_FCOND_OLE  : PatLeaf<(i32 6)>;
 245 def MIPS_FCOND_ULE  : PatLeaf<(i32 7)>;
 246 def MIPS_FCOND_SF   : PatLeaf<(i32 8)>;
 247 def MIPS_FCOND_NGLE : PatLeaf<(i32 9)>;
 248 def MIPS_FCOND_SEQ  : PatLeaf<(i32 10)>;
 249 def MIPS_FCOND_NGL  : PatLeaf<(i32 11)>;
 250 def MIPS_FCOND_LT   : PatLeaf<(i32 12)>;
 251 def MIPS_FCOND_NGE  : PatLeaf<(i32 13)>;
 252 def MIPS_FCOND_LE   : PatLeaf<(i32 14)>;
 253 def MIPS_FCOND_NGT  : PatLeaf<(i32 15)>;
 254
 255 /// Floating Point Compare
 256 let hasDelaySlot = 1, Defs=[FCR31] in {
 257   def FCMP_S32 : FCC<0x0, (outs), (ins FGR32:$fs, FGR32:$ft, condcode:$cc),
 258                      "c.$cc.s $fs, $ft",
 259                      [(MipsFPCmp FGR32:$fs, FGR32:$ft, imm:$cc)]>;
 260
 261   def FCMP_D32 : FCC<0x1, (outs), (ins AFGR64:$fs, AFGR64:$ft, condcode:$cc),
 262                      "c.$cc.d $fs, $ft",
 263                      [(MipsFPCmp AFGR64:$fs, AFGR64:$ft, imm:$cc)]>,
 264                      Requires<[In32BitMode]>;
 265 }
 266
 267
 268 // Conditional moves:
 269 // These instructions are expanded in
 270 // MipsISelLowering::EmitInstrWithCustomInserter if target does not have
 271 // conditional move instructions.
 272 // flag:int, data:float
 273 let usesCustomInserter = 1, Constraints = "$F = $dst" in
 274 class CondMovIntFP<RegisterClass RC, bits<5> fmt, bits<6> func,
 275                    string instr_asm> :
 276   FFR<0x11, func, fmt, (outs RC:$dst), (ins RC:$T, CPURegs:$cond, RC:$F),
 277       !strconcat(instr_asm, "\t$dst, $T, $cond"), []>;
 278
 279 def MOVZ_S : CondMovIntFP<FGR32, 16, 18, "movz.s">;
 280 def MOVN_S : CondMovIntFP<FGR32, 16, 19, "movn.s">;
 281
 282 let Predicates = [In32BitMode] in {
 283   def MOVZ_D : CondMovIntFP<AFGR64, 17, 18, "movz.d">;
 284   def MOVN_D : CondMovIntFP<AFGR64, 17, 19, "movn.d">;
 285 }
 286
 287 defm : MovzPats<FGR32, MOVZ_S>;
 288 defm : MovnPats<FGR32, MOVN_S>;
 289
 290 let Predicates = [In32BitMode] in {
 291   defm : MovzPats<AFGR64, MOVZ_D>;
 292   defm : MovnPats<AFGR64, MOVN_D>;
 293 }
 294
 295 let usesCustomInserter = 1, Uses = [FCR31], Constraints = "$F = $dst" in {
 296 // flag:float, data:int
 297 class CondMovFPInt<SDNode cmov, bits<1> tf, string instr_asm> :
 298   FCMOV<tf, (outs CPURegs:$dst), (ins CPURegs:$T, CPURegs:$F),
 299         !strconcat(instr_asm, "\t$dst, $T, $$fcc0"),
 300         [(set CPURegs:$dst, (cmov CPURegs:$T, CPURegs:$F))]>;
 301
 302 // flag:float, data:float
 303 class CondMovFPFP<RegisterClass RC, SDNode cmov, bits<5> fmt, bits<1> tf,
 304                   string instr_asm> :
 305   FFCMOV<fmt, tf, (outs RC:$dst), (ins RC:$T, RC:$F),
 306          !strconcat(instr_asm, "\t$dst, $T, $$fcc0"),
 307          [(set RC:$dst, (cmov RC:$T, RC:$F))]>;
 308 }
 309
 310 def MOVT : CondMovFPInt<MipsCMovFP_T, 1, "movt">;
 311 def MOVF : CondMovFPInt<MipsCMovFP_F, 0, "movf">;
 312 def MOVT_S : CondMovFPFP<FGR32, MipsCMovFP_T, 16, 1, "movt.s">;
 313 def MOVF_S : CondMovFPFP<FGR32, MipsCMovFP_F, 16, 0, "movf.s">;
 314
 315 let Predicates = [In32BitMode] in {
 316   def MOVT_D : CondMovFPFP<AFGR64, MipsCMovFP_T, 17, 1, "movt.d">;
 317   def MOVF_D : CondMovFPFP<AFGR64, MipsCMovFP_F, 17, 0, "movf.d">;
 318 }
 319
 320 //===---------------------------------------------------------------------===//
 321 // Floating Point Pseudo-Instructions
 322 //===---------------------------------------------------------------------===//
 323 def MOVCCRToCCR : MipsPseudo<(outs CCR:$dst), (ins CCR:$src),
 324                              "# MOVCCRToCCR", []>;
 325
 326 // This pseudo instr gets expanded into 2 mtc1 instrs after register
 327 // allocation.
 328 def BuildPairF64 :
 329   MipsPseudo<(outs AFGR64:$dst),
 330              (ins CPURegs:$lo, CPURegs:$hi), "",
 331              [(set AFGR64:$dst, (MipsBuildPairF64 CPURegs:$lo, CPURegs:$hi))]>;
 332
 333 // This pseudo instr gets expanded into 2 mfc1 instrs after register
 334 // allocation.
 335 // if n is 0, lower part of src is extracted.
 336 // if n is 1, higher part of src is extracted.
 337 def ExtractElementF64 :
 338   MipsPseudo<(outs CPURegs:$dst),
 339              (ins AFGR64:$src, i32imm:$n), "",
 340              [(set CPURegs:$dst,
 341                (MipsExtractElementF64 AFGR64:$src, imm:$n))]>;
 342
 343 //===---------------------------------------------------------------------===//
 344 // Floating Point Patterns
 345 //===---------------------------------------------------------------------===//
 346 def fpimm0 : PatLeaf<(fpimm), [{
 347   return N->isExactlyValue(+0.0);
 348 }]>;
 349
 350 def fpimm0neg : PatLeaf<(fpimm), [{
 351   return N->isExactlyValue(-0.0);
 352 }]>;
 353
 354 def : Pat<(f32 fpimm0), (MTC1 ZERO)>;
 355 def : Pat<(f32 fpimm0neg), (FNEG_S32 (MTC1 ZERO))>;
 356
 357 def : Pat<(f32 (sint_to_fp CPURegs:$src)), (CVTS_W32 (MTC1 CPURegs:$src))>;
 358 def : Pat<(f64 (sint_to_fp CPURegs:$src)), (CVTD_W32 (MTC1 CPURegs:$src))>;
 359
 360 def : Pat<(i32 (fp_to_sint FGR32:$src)), (MFC1 (TRUNC_W_S32 FGR32:$src))>;
 361
 362 def : Pat<(i32 (bitconvert FGR32:$src)),  (MFC1 FGR32:$src)>;
 363 def : Pat<(f32 (bitconvert CPURegs:$src)), (MTC1 CPURegs:$src)>;
 364
 365 let Predicates = [In32BitMode] in {
 366   def : Pat<(f32 (fround AFGR64:$src)), (CVTS_D32 AFGR64:$src)>;
 367   def : Pat<(f64 (fextend FGR32:$src)), (CVTD_S32 FGR32:$src)>;
 368 }
 369
 370 // MipsFPRound is only emitted for MipsI targets.
 371 def : Pat<(f32 (MipsFPRound AFGR64:$src)), (CVTW_D32 AFGR64:$src)>;
 372