lib/Target/Mips/MipsInstrFPU.td

   1 //===-- MipsInstrFPU.td - Mips FPU Instruction Information -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Mips FPU instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Floating Point Instructions
  16 // ------------------------
  17 // * 64bit fp:
  18 //    - 32 64-bit registers (default mode)
  19 //    - 16 even 32-bit registers (32-bit compatible mode) for
  20 //      single and double access.
  21 // * 32bit fp:
  22 //    - 16 even 32-bit registers - single and double (aliased)
  23 //    - 32 32-bit registers (within single-only mode)
  24 //===----------------------------------------------------------------------===//
  25
  26 // Floating Point Compare and Branch
  27 def SDT_MipsFPBrcond : SDTypeProfile<0, 2, [SDTCisInt<0>,
  28                                             SDTCisVT<1, OtherVT>]>;
  29 def SDT_MipsFPCmp : SDTypeProfile<0, 3, [SDTCisSameAs<0, 1>, SDTCisFP<1>,
  30                                          SDTCisVT<2, i32>]>;
  31 def SDT_MipsCMovFP : SDTypeProfile<1, 2, [SDTCisSameAs<0, 1>,
  32                                           SDTCisSameAs<1, 2>]>;
  33 def SDT_MipsBuildPairF64 : SDTypeProfile<1, 2, [SDTCisVT<0, f64>,
  34                                                 SDTCisVT<1, i32>,
  35                                                 SDTCisSameAs<1, 2>]>;
  36 def SDT_MipsExtractElementF64 : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
  37                                                      SDTCisVT<1, f64>,
  38                                                      SDTCisVT<2, i32>]>;
  39
  40 def MipsFPCmp : SDNode<"MipsISD::FPCmp", SDT_MipsFPCmp, [SDNPOutGlue]>;
  41 def MipsCMovFP_T : SDNode<"MipsISD::CMovFP_T", SDT_MipsCMovFP, [SDNPInGlue]>;
  42 def MipsCMovFP_F : SDNode<"MipsISD::CMovFP_F", SDT_MipsCMovFP, [SDNPInGlue]>;
  43 def MipsFPBrcond : SDNode<"MipsISD::FPBrcond", SDT_MipsFPBrcond,
  44                           [SDNPHasChain, SDNPOptInGlue]>;
  45 def MipsBuildPairF64 : SDNode<"MipsISD::BuildPairF64", SDT_MipsBuildPairF64>;
  46 def MipsExtractElementF64 : SDNode<"MipsISD::ExtractElementF64",
  47                                    SDT_MipsExtractElementF64>;
  48
  49 // Operand for printing out a condition code.
  50 let PrintMethod = "printFCCOperand", DecoderMethod = "DecodeCondCode" in
  51   def condcode : Operand<i32>;
  52
  53 //===----------------------------------------------------------------------===//
  54 // Feature predicates.
  55 //===----------------------------------------------------------------------===//
  56
  57 def IsFP64bit        : Predicate<"Subtarget.isFP64bit()">, AssemblerPredicate<"FeatureFP64Bit">;
  58 def NotFP64bit       : Predicate<"!Subtarget.isFP64bit()">, AssemblerPredicate<"!FeatureFP64Bit">;
  59 def IsSingleFloat    : Predicate<"Subtarget.isSingleFloat()">, AssemblerPredicate<"FeatureSingleFloat">;
  60 def IsNotSingleFloat : Predicate<"!Subtarget.isSingleFloat()">, AssemblerPredicate<"!FeatureSingleFloat">;
  61
  62 // FP immediate patterns.
  63 def fpimm0 : PatLeaf<(fpimm), [{
  64   return N->isExactlyValue(+0.0);
  65 }]>;
  66
  67 def fpimm0neg : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(-0.0);
  69 }]>;
  70
  71 //===----------------------------------------------------------------------===//
  72 // Instruction Class Templates
  73 //
  74 // A set of multiclasses is used to address the register usage.
  75 //
  76 // S32 - single precision in 16 32bit even fp registers
  77 //       single precision in 32 32bit fp registers in SingleOnly mode
  78 // S64 - single precision in 32 64bit fp registers (In64BitMode)
  79 // D32 - double precision in 16 32bit even fp registers
  80 // D64 - double precision in 32 64bit fp registers (In64BitMode)
  81 //
  82 // Only S32 and D32 are supported right now.
  83 //===----------------------------------------------------------------------===//
  84
  85 // FP load.
  86 let DecoderMethod = "DecodeFMem" in {
  87 class FPLoad<bits<6> op, string opstr, RegisterClass RC, Operand MemOpnd>:
  88   FMem<op, (outs RC:$ft), (ins MemOpnd:$addr),
  89       !strconcat(opstr, "\t$ft, $addr"), [(set RC:$ft, (load_a addr:$addr))],
  90       IILoad>;
  91
  92 // FP store.
  93 class FPStore<bits<6> op, string opstr, RegisterClass RC, Operand MemOpnd>:
  94   FMem<op, (outs), (ins RC:$ft, MemOpnd:$addr),
  95       !strconcat(opstr, "\t$ft, $addr"), [(store_a RC:$ft, addr:$addr)],
  96       IIStore>;
  97 }
  98 // FP indexed load.
  99 class FPIdxLoad<bits<6> funct, string opstr, RegisterClass DRC,
 100                 RegisterClass PRC, PatFrag FOp>:
 101   FFMemIdx<funct, (outs DRC:$fd), (ins PRC:$base, PRC:$index),
 102            !strconcat(opstr, "\t$fd, $index($base)"),
 103            [(set DRC:$fd, (FOp (add PRC:$base, PRC:$index)))]> {
 104   let fs = 0;
 105 }
 106
 107 // FP indexed store.
 108 class FPIdxStore<bits<6> funct, string opstr, RegisterClass DRC,
 109                  RegisterClass PRC, PatFrag FOp>:
 110   FFMemIdx<funct, (outs), (ins DRC:$fs, PRC:$base, PRC:$index),
 111            !strconcat(opstr, "\t$fs, $index($base)"),
 112            [(FOp DRC:$fs, (add PRC:$base, PRC:$index))]> {
 113   let fd = 0;
 114 }
 115
 116 // Instructions that convert an FP value to 32-bit fixed point.
 117 multiclass FFR1_W_M<bits<6> funct, string opstr> {
 118   def _S   : FFR1<funct, 16, opstr, "w.s", FGR32, FGR32>;
 119   def _D32 : FFR1<funct, 17, opstr, "w.d", FGR32, AFGR64>,
 120              Requires<[NotFP64bit, HasStandardEncoding]>;
 121   def _D64 : FFR1<funct, 17, opstr, "w.d", FGR32, FGR64>,
 122              Requires<[IsFP64bit, HasStandardEncoding]> {
 123     let DecoderNamespace = "Mips64";
 124   }
 125 }
 126
 127 // Instructions that convert an FP value to 64-bit fixed point.
 128 let Predicates = [IsFP64bit, HasStandardEncoding], DecoderNamespace = "Mips64" in
 129 multiclass FFR1_L_M<bits<6> funct, string opstr> {
 130   def _S   : FFR1<funct, 16, opstr, "l.s", FGR64, FGR32>;
 131   def _D64 : FFR1<funct, 17, opstr, "l.d", FGR64, FGR64>;
 132 }
 133
 134 // FP-to-FP conversion instructions.
 135 multiclass FFR1P_M<bits<6> funct, string opstr, SDNode OpNode> {
 136   def _S   : FFR1P<funct, 16, opstr, "s", FGR32, FGR32, OpNode>;
 137   def _D32 : FFR1P<funct, 17, opstr, "d", AFGR64, AFGR64, OpNode>,
 138              Requires<[NotFP64bit, HasStandardEncoding]>;
 139   def _D64 : FFR1P<funct, 17, opstr, "d", FGR64, FGR64, OpNode>,
 140              Requires<[IsFP64bit, HasStandardEncoding]> {
 141     let DecoderNamespace = "Mips64";
 142   }
 143 }
 144
 145 multiclass FFR2P_M<bits<6> funct, string opstr, SDNode OpNode, bit isComm = 0> {
 146   let isCommutable = isComm in {
 147   def _S   : FFR2P<funct, 16, opstr, "s", FGR32, OpNode>;
 148   def _D32 : FFR2P<funct, 17, opstr, "d", AFGR64, OpNode>,
 149              Requires<[NotFP64bit, HasStandardEncoding]>;
 150   def _D64 : FFR2P<funct, 17, opstr, "d", FGR64, OpNode>,
 151              Requires<[IsFP64bit, HasStandardEncoding]> {
 152     let DecoderNamespace = "Mips64";
 153   }
 154 }
 155 }
 156
 157 // FP madd/msub/nmadd/nmsub instruction classes.
 158 class FMADDSUB<bits<3> funct, bits<3> fmt, string opstr, string fmtstr,
 159                SDNode OpNode, RegisterClass RC> :
 160   FFMADDSUB<funct, fmt, (outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 161             !strconcat(opstr, ".", fmtstr, "\t$fd, $fr, $fs, $ft"),
 162             [(set RC:$fd, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr))]>;
 163
 164 class FNMADDSUB<bits<3> funct, bits<3> fmt, string opstr, string fmtstr,
 165                 SDNode OpNode, RegisterClass RC> :
 166   FFMADDSUB<funct, fmt, (outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 167             !strconcat(opstr, ".", fmtstr, "\t$fd, $fr, $fs, $ft"),
 168             [(set RC:$fd, (fsub fpimm0, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr)))]>;
 169
 170 //===----------------------------------------------------------------------===//
 171 // Floating Point Instructions
 172 //===----------------------------------------------------------------------===//
 173 defm ROUND_W : FFR1_W_M<0xc, "round">;
 174 defm ROUND_L : FFR1_L_M<0x8, "round">;
 175 defm TRUNC_W : FFR1_W_M<0xd, "trunc">;
 176 defm TRUNC_L : FFR1_L_M<0x9, "trunc">;
 177 defm CEIL_W  : FFR1_W_M<0xe, "ceil">;
 178 defm CEIL_L  : FFR1_L_M<0xa, "ceil">;
 179 defm FLOOR_W : FFR1_W_M<0xf, "floor">;
 180 defm FLOOR_L : FFR1_L_M<0xb, "floor">;
 181 defm CVT_W   : FFR1_W_M<0x24, "cvt">;
 182 //defm CVT_L   : FFR1_L_M<0x25, "cvt">;
 183
 184 def CVT_S_W : FFR1<0x20, 20, "cvt", "s.w", FGR32, FGR32>;
 185 def CVT_L_S : FFR1<0x25, 16, "cvt", "l.s", FGR64, FGR32>;
 186 def CVT_L_D64: FFR1<0x25, 17, "cvt", "l.d", FGR64, FGR64>;
 187
 188 let Predicates = [NotFP64bit, HasStandardEncoding] in {
 189   def CVT_S_D32 : FFR1<0x20, 17, "cvt", "s.d", FGR32, AFGR64>;
 190   def CVT_D32_W : FFR1<0x21, 20, "cvt", "d.w", AFGR64, FGR32>;
 191   def CVT_D32_S : FFR1<0x21, 16, "cvt", "d.s", AFGR64, FGR32>;
 192 }
 193
 194 let Predicates = [IsFP64bit, HasStandardEncoding], DecoderNamespace = "Mips64" in {
 195  def CVT_S_D64 : FFR1<0x20, 17, "cvt", "s.d", FGR32, FGR64>;
 196  def CVT_S_L   : FFR1<0x20, 21, "cvt", "s.l", FGR32, FGR64>;
 197  def CVT_D64_W : FFR1<0x21, 20, "cvt", "d.w", FGR64, FGR32>;
 198  def CVT_D64_S : FFR1<0x21, 16, "cvt", "d.s", FGR64, FGR32>;
 199  def CVT_D64_L : FFR1<0x21, 21, "cvt", "d.l", FGR64, FGR64>;
 200 }
 201
 202 let Predicates = [NoNaNsFPMath, HasStandardEncoding] in {
 203   defm FABS    : FFR1P_M<0x5, "abs",  fabs>;
 204   defm FNEG    : FFR1P_M<0x7, "neg",  fneg>;
 205 }
 206 defm FSQRT   : FFR1P_M<0x4, "sqrt", fsqrt>;
 207
 208 // The odd-numbered registers are only referenced when doing loads,
 209 // stores, and moves between floating-point and integer registers.
 210 // When defining instructions, we reference all 32-bit registers,
 211 // regardless of register aliasing.
 212
 213 class FFRGPR<bits<5> _fmt, dag outs, dag ins, string asmstr, list<dag> pattern>:
 214              FFR<0x11, 0x0, _fmt, outs, ins, asmstr, pattern> {
 215   bits<5> rt;
 216   let ft = rt;
 217   let fd = 0;
 218 }
 219
 220 /// Move Control Registers From/To CPU Registers
 221 def CFC1  : FFRGPR<0x2, (outs CPURegs:$rt), (ins CCR:$fs),
 222                   "cfc1\t$rt, $fs", []>;
 223
 224 def CTC1  : FFRGPR<0x6, (outs CCR:$fs), (ins CPURegs:$rt),
 225                   "ctc1\t$rt, $fs", []>;
 226
 227 def MFC1  : FFRGPR<0x00, (outs CPURegs:$rt), (ins FGR32:$fs),
 228                   "mfc1\t$rt, $fs",
 229                   [(set CPURegs:$rt, (bitconvert FGR32:$fs))]>;
 230
 231 def MTC1  : FFRGPR<0x04, (outs FGR32:$fs), (ins CPURegs:$rt),
 232                   "mtc1\t$rt, $fs",
 233                   [(set FGR32:$fs, (bitconvert CPURegs:$rt))]>;
 234
 235 def DMFC1 : FFRGPR<0x01, (outs CPU64Regs:$rt), (ins FGR64:$fs),
 236                   "dmfc1\t$rt, $fs",
 237                   [(set CPU64Regs:$rt, (bitconvert FGR64:$fs))]>;
 238
 239 def DMTC1 : FFRGPR<0x05, (outs FGR64:$fs), (ins CPU64Regs:$rt),
 240                   "dmtc1\t$rt, $fs",
 241                   [(set FGR64:$fs, (bitconvert CPU64Regs:$rt))]>;
 242
 243 def FMOV_S   : FFR1<0x6, 16, "mov", "s", FGR32, FGR32>;
 244 def FMOV_D32 : FFR1<0x6, 17, "mov", "d", AFGR64, AFGR64>,
 245                Requires<[NotFP64bit, HasStandardEncoding]>;
 246 def FMOV_D64 : FFR1<0x6, 17, "mov", "d", FGR64, FGR64>,
 247                Requires<[IsFP64bit, HasStandardEncoding]> {
 248   let DecoderNamespace = "Mips64";
 249 }
 250
 251 /// Floating Point Memory Instructions
 252 let Predicates = [IsN64, HasStandardEncoding], DecoderNamespace = "Mips64" in {
 253   def LWC1_P8   : FPLoad<0x31, "lwc1", FGR32, mem64>;
 254   def SWC1_P8   : FPStore<0x39, "swc1", FGR32, mem64>;
 255   def LDC164_P8 : FPLoad<0x35, "ldc1", FGR64, mem64> {
 256     let isCodeGenOnly =1;
 257   }
 258   def SDC164_P8 : FPStore<0x3d, "sdc1", FGR64, mem64> {
 259     let isCodeGenOnly =1;
 260   }
 261 }
 262
 263 let Predicates = [NotN64, HasStandardEncoding] in {
 264   def LWC1   : FPLoad<0x31, "lwc1", FGR32, mem>;
 265   def SWC1   : FPStore<0x39, "swc1", FGR32, mem>;
 266 }
 267
 268 let Predicates = [NotN64, HasMips64, HasStandardEncoding],
 269     DecoderNamespace = "Mips64" in {
 270   def LDC164 : FPLoad<0x35, "ldc1", FGR64, mem>;
 271   def SDC164 : FPStore<0x3d, "sdc1", FGR64, mem>;
 272 }
 273
 274 let Predicates = [NotN64, NotMips64, HasStandardEncoding] in {
 275   def LDC1   : FPLoad<0x35, "ldc1", AFGR64, mem>;
 276   def SDC1   : FPStore<0x3d, "sdc1", AFGR64, mem>;
 277 }
 278
 279 // Indexed loads and stores.
 280 let Predicates = [HasMips32r2Or64, HasStandardEncoding] in {
 281   def LWXC1 : FPIdxLoad<0x0, "lwxc1", FGR32, CPURegs, load_a>;
 282   def LUXC1 : FPIdxLoad<0x5, "luxc1", FGR32, CPURegs, load_u>;
 283   def SWXC1 : FPIdxStore<0x8, "swxc1", FGR32, CPURegs, store_a>;
 284   def SUXC1 : FPIdxStore<0xd, "suxc1", FGR32, CPURegs, store_u>;
 285 }
 286
 287 let Predicates = [HasMips32r2, NotMips64, HasStandardEncoding] in {
 288   def LDXC1 : FPIdxLoad<0x1, "ldxc1", AFGR64, CPURegs, load_a>;
 289   def SDXC1 : FPIdxStore<0x9, "sdxc1", AFGR64, CPURegs, store_a>;
 290 }
 291
 292 let Predicates = [HasMips64, NotN64, HasStandardEncoding], DecoderNamespace="Mips64" in {
 293   def LDXC164 : FPIdxLoad<0x1, "ldxc1", FGR64, CPURegs, load_a>;
 294   def SDXC164 : FPIdxStore<0x9, "sdxc1", FGR64, CPURegs, store_a>;
 295 }
 296
 297 // n64
 298 let Predicates = [IsN64, HasStandardEncoding], isCodeGenOnly=1 in {
 299   def LWXC1_P8   : FPIdxLoad<0x0, "lwxc1", FGR32, CPU64Regs, load_a>;
 300   def LUXC1_P8   : FPIdxLoad<0x5, "luxc1", FGR32, CPU64Regs, load_u>;
 301   def LDXC164_P8 : FPIdxLoad<0x1, "ldxc1", FGR64, CPU64Regs, load_a>;
 302   def SWXC1_P8   : FPIdxStore<0x8, "swxc1", FGR32, CPU64Regs, store_a>;
 303   def SUXC1_P8   : FPIdxStore<0xd, "suxc1", FGR32, CPU64Regs, store_u>;
 304   def SDXC164_P8 : FPIdxStore<0x9, "sdxc1", FGR64, CPU64Regs, store_a>;
 305 }
 306
 307 /// Floating-point Aritmetic
 308 defm FADD : FFR2P_M<0x00, "add", fadd, 1>;
 309 defm FDIV : FFR2P_M<0x03, "div", fdiv>;
 310 defm FMUL : FFR2P_M<0x02, "mul", fmul, 1>;
 311 defm FSUB : FFR2P_M<0x01, "sub", fsub>;
 312
 313 let Predicates = [HasMips32r2, HasStandardEncoding] in {
 314   def MADD_S : FMADDSUB<0x4, 0, "madd", "s", fadd, FGR32>;
 315   def MSUB_S : FMADDSUB<0x5, 0, "msub", "s", fsub, FGR32>;
 316 }
 317
 318 let Predicates = [HasMips32r2, NoNaNsFPMath, HasStandardEncoding] in {
 319   def NMADD_S : FNMADDSUB<0x6, 0, "nmadd", "s", fadd, FGR32>;
 320   def NMSUB_S : FNMADDSUB<0x7, 0, "nmsub", "s", fsub, FGR32>;
 321 }
 322
 323 let Predicates = [HasMips32r2, NotFP64bit, HasStandardEncoding] in {
 324   def MADD_D32 : FMADDSUB<0x4, 1, "madd", "d", fadd, AFGR64>;
 325   def MSUB_D32 : FMADDSUB<0x5, 1, "msub", "d", fsub, AFGR64>;
 326 }
 327
 328 let Predicates = [HasMips32r2, NotFP64bit, NoNaNsFPMath, HasStandardEncoding] in {
 329   def NMADD_D32 : FNMADDSUB<0x6, 1, "nmadd", "d", fadd, AFGR64>;
 330   def NMSUB_D32 : FNMADDSUB<0x7, 1, "nmsub", "d", fsub, AFGR64>;
 331 }
 332
 333 let Predicates = [HasMips32r2, IsFP64bit, HasStandardEncoding], isCodeGenOnly=1 in {
 334   def MADD_D64 : FMADDSUB<0x4, 1, "madd", "d", fadd, FGR64>;
 335   def MSUB_D64 : FMADDSUB<0x5, 1, "msub", "d", fsub, FGR64>;
 336 }
 337
 338 let Predicates = [HasMips32r2, IsFP64bit, NoNaNsFPMath, HasStandardEncoding],
 339     isCodeGenOnly=1 in {
 340   def NMADD_D64 : FNMADDSUB<0x6, 1, "nmadd", "d", fadd, FGR64>;
 341   def NMSUB_D64 : FNMADDSUB<0x7, 1, "nmsub", "d", fsub, FGR64>;
 342 }
 343
 344 //===----------------------------------------------------------------------===//
 345 // Floating Point Branch Codes
 346 //===----------------------------------------------------------------------===//
 347 // Mips branch codes. These correspond to condcode in MipsInstrInfo.h.
 348 // They must be kept in synch.
 349 def MIPS_BRANCH_F  : PatLeaf<(i32 0)>;
 350 def MIPS_BRANCH_T  : PatLeaf<(i32 1)>;
 351
 352 /// Floating Point Branch of False/True (Likely)
 353 let isBranch=1, isTerminator=1, hasDelaySlot=1, base=0x8, Uses=[FCR31] in
 354   class FBRANCH<bits<1> nd, bits<1> tf, PatLeaf op, string asmstr> :
 355       FFI<0x11, (outs), (ins brtarget:$dst), !strconcat(asmstr, "\t$dst"),
 356         [(MipsFPBrcond op, bb:$dst)]> {
 357   let Inst{20-18} = 0;
 358   let Inst{17} = nd;
 359   let Inst{16} = tf;
 360 }
 361
 362 let DecoderMethod = "DecodeBC1" in {
 363 def BC1F  : FBRANCH<0, 0, MIPS_BRANCH_F,  "bc1f">;
 364 def BC1T  : FBRANCH<0, 1, MIPS_BRANCH_T,  "bc1t">;
 365 }
 366 //===----------------------------------------------------------------------===//
 367 // Floating Point Flag Conditions
 368 //===----------------------------------------------------------------------===//
 369 // Mips condition codes. They must correspond to condcode in MipsInstrInfo.h.
 370 // They must be kept in synch.
 371 def MIPS_FCOND_F    : PatLeaf<(i32 0)>;
 372 def MIPS_FCOND_UN   : PatLeaf<(i32 1)>;
 373 def MIPS_FCOND_OEQ  : PatLeaf<(i32 2)>;
 374 def MIPS_FCOND_UEQ  : PatLeaf<(i32 3)>;
 375 def MIPS_FCOND_OLT  : PatLeaf<(i32 4)>;
 376 def MIPS_FCOND_ULT  : PatLeaf<(i32 5)>;
 377 def MIPS_FCOND_OLE  : PatLeaf<(i32 6)>;
 378 def MIPS_FCOND_ULE  : PatLeaf<(i32 7)>;
 379 def MIPS_FCOND_SF   : PatLeaf<(i32 8)>;
 380 def MIPS_FCOND_NGLE : PatLeaf<(i32 9)>;
 381 def MIPS_FCOND_SEQ  : PatLeaf<(i32 10)>;
 382 def MIPS_FCOND_NGL  : PatLeaf<(i32 11)>;
 383 def MIPS_FCOND_LT   : PatLeaf<(i32 12)>;
 384 def MIPS_FCOND_NGE  : PatLeaf<(i32 13)>;
 385 def MIPS_FCOND_LE   : PatLeaf<(i32 14)>;
 386 def MIPS_FCOND_NGT  : PatLeaf<(i32 15)>;
 387
 388 class FCMP<bits<5> fmt, RegisterClass RC, string typestr> :
 389   FCC<fmt, (outs), (ins RC:$fs, RC:$ft, condcode:$cc),
 390       !strconcat("c.$cc.", typestr, "\t$fs, $ft"),
 391       [(MipsFPCmp RC:$fs, RC:$ft, imm:$cc)]>;
 392
 393 /// Floating Point Compare
 394 let Defs=[FCR31] in {
 395   def FCMP_S32 : FCMP<0x10, FGR32, "s">;
 396   def FCMP_D32 : FCMP<0x11, AFGR64, "d">,
 397       Requires<[NotFP64bit, HasStandardEncoding]>;
 398   def FCMP_D64 : FCMP<0x11, FGR64, "d">,
 399       Requires<[IsFP64bit, HasStandardEncoding]> {
 400     let DecoderNamespace = "Mips64";
 401   }
 402 }
 403
 404 //===----------------------------------------------------------------------===//
 405 // Floating Point Pseudo-Instructions
 406 //===----------------------------------------------------------------------===//
 407 def MOVCCRToCCR : MipsPseudo<(outs CCR:$dst), (ins CCR:$src),
 408                              "# MOVCCRToCCR", []>;
 409
 410 // This pseudo instr gets expanded into 2 mtc1 instrs after register
 411 // allocation.
 412 def BuildPairF64 :
 413   MipsPseudo<(outs AFGR64:$dst),
 414              (ins CPURegs:$lo, CPURegs:$hi), "",
 415              [(set AFGR64:$dst, (MipsBuildPairF64 CPURegs:$lo, CPURegs:$hi))]>;
 416
 417 // This pseudo instr gets expanded into 2 mfc1 instrs after register
 418 // allocation.
 419 // if n is 0, lower part of src is extracted.
 420 // if n is 1, higher part of src is extracted.
 421 def ExtractElementF64 :
 422   MipsPseudo<(outs CPURegs:$dst),
 423              (ins AFGR64:$src, i32imm:$n), "",
 424              [(set CPURegs:$dst,
 425                (MipsExtractElementF64 AFGR64:$src, imm:$n))]>;
 426
 427 //===----------------------------------------------------------------------===//
 428 // Floating Point Patterns
 429 //===----------------------------------------------------------------------===//
 430 def : Pat<(f32 fpimm0), (MTC1 ZERO)>;
 431 def : Pat<(f32 fpimm0neg), (FNEG_S (MTC1 ZERO))>;
 432
 433 def : Pat<(f32 (sint_to_fp CPURegs:$src)), (CVT_S_W (MTC1 CPURegs:$src))>;
 434 def : Pat<(i32 (fp_to_sint FGR32:$src)), (MFC1 (TRUNC_W_S FGR32:$src))>;
 435
 436 let Predicates = [NotFP64bit, HasStandardEncoding] in {
 437   def : Pat<(f64 (sint_to_fp CPURegs:$src)), (CVT_D32_W (MTC1 CPURegs:$src))>;
 438   def : Pat<(i32 (fp_to_sint AFGR64:$src)), (MFC1 (TRUNC_W_D32 AFGR64:$src))>;
 439   def : Pat<(f32 (fround AFGR64:$src)), (CVT_S_D32 AFGR64:$src)>;
 440   def : Pat<(f64 (fextend FGR32:$src)), (CVT_D32_S FGR32:$src)>;
 441 }
 442
 443 let Predicates = [IsFP64bit, HasStandardEncoding] in {
 444   def : Pat<(f64 fpimm0), (DMTC1 ZERO_64)>;
 445   def : Pat<(f64 fpimm0neg), (FNEG_D64 (DMTC1 ZERO_64))>;
 446
 447   def : Pat<(f64 (sint_to_fp CPURegs:$src)), (CVT_D64_W (MTC1 CPURegs:$src))>;
 448   def : Pat<(f32 (sint_to_fp CPU64Regs:$src)),
 449             (CVT_S_L (DMTC1 CPU64Regs:$src))>;
 450   def : Pat<(f64 (sint_to_fp CPU64Regs:$src)),
 451             (CVT_D64_L (DMTC1 CPU64Regs:$src))>;
 452
 453   def : Pat<(i32 (fp_to_sint FGR64:$src)), (MFC1 (TRUNC_W_D64 FGR64:$src))>;
 454   def : Pat<(i64 (fp_to_sint FGR32:$src)), (DMFC1 (TRUNC_L_S FGR32:$src))>;
 455   def : Pat<(i64 (fp_to_sint FGR64:$src)), (DMFC1 (TRUNC_L_D64 FGR64:$src))>;
 456
 457   def : Pat<(f32 (fround FGR64:$src)), (CVT_S_D64 FGR64:$src)>;
 458   def : Pat<(f64 (fextend FGR32:$src)), (CVT_D64_S FGR32:$src)>;
 459 }
 460
 461 // Patterns for unaligned floating point loads and stores.
 462 let Predicates = [HasMips32r2Or64, NotN64, HasStandardEncoding] in {
 463   def : Pat<(f32 (load_u CPURegs:$addr)), (LUXC1 CPURegs:$addr, ZERO)>;
 464   def : Pat<(store_u FGR32:$src, CPURegs:$addr),
 465             (SUXC1 FGR32:$src, CPURegs:$addr, ZERO)>;
 466 }
 467
 468 let Predicates = [IsN64, HasStandardEncoding] in {
 469   def : Pat<(f32 (load_u CPU64Regs:$addr)), (LUXC1_P8 CPU64Regs:$addr, ZERO_64)>;
 470   def : Pat<(store_u FGR32:$src, CPU64Regs:$addr),
 471             (SUXC1_P8 FGR32:$src, CPU64Regs:$addr, ZERO_64)>;
 472 }