lib/Target/Mips/MipsInstrFPU.td

   1 //===-- MipsInstrFPU.td - Mips FPU Instruction Information -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Mips FPU instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Floating Point Instructions
  16 // ------------------------
  17 // * 64bit fp:
  18 //    - 32 64-bit registers (default mode)
  19 //    - 16 even 32-bit registers (32-bit compatible mode) for
  20 //      single and double access.
  21 // * 32bit fp:
  22 //    - 16 even 32-bit registers - single and double (aliased)
  23 //    - 32 32-bit registers (within single-only mode)
  24 //===----------------------------------------------------------------------===//
  25
  26 // Floating Point Compare and Branch
  27 def SDT_MipsFPBrcond : SDTypeProfile<0, 2, [SDTCisInt<0>,
  28                                             SDTCisVT<1, OtherVT>]>;
  29 def SDT_MipsFPCmp : SDTypeProfile<0, 3, [SDTCisSameAs<0, 1>, SDTCisFP<1>,
  30                                          SDTCisVT<2, i32>]>;
  31 def SDT_MipsCMovFP : SDTypeProfile<1, 2, [SDTCisSameAs<0, 1>,
  32                                           SDTCisSameAs<1, 2>]>;
  33 def SDT_MipsBuildPairF64 : SDTypeProfile<1, 2, [SDTCisVT<0, f64>,
  34                                                 SDTCisVT<1, i32>,
  35                                                 SDTCisSameAs<1, 2>]>;
  36 def SDT_MipsExtractElementF64 : SDTypeProfile<1, 2, [SDTCisVT<0, i32>,
  37                                                      SDTCisVT<1, f64>,
  38                                                      SDTCisVT<2, i32>]>;
  39
  40 def MipsFPCmp : SDNode<"MipsISD::FPCmp", SDT_MipsFPCmp, [SDNPOutGlue]>;
  41 def MipsCMovFP_T : SDNode<"MipsISD::CMovFP_T", SDT_MipsCMovFP, [SDNPInGlue]>;
  42 def MipsCMovFP_F : SDNode<"MipsISD::CMovFP_F", SDT_MipsCMovFP, [SDNPInGlue]>;
  43 def MipsFPBrcond : SDNode<"MipsISD::FPBrcond", SDT_MipsFPBrcond,
  44                           [SDNPHasChain, SDNPOptInGlue]>;
  45 def MipsBuildPairF64 : SDNode<"MipsISD::BuildPairF64", SDT_MipsBuildPairF64>;
  46 def MipsExtractElementF64 : SDNode<"MipsISD::ExtractElementF64",
  47                                    SDT_MipsExtractElementF64>;
  48
  49 // Operand for printing out a condition code.
  50 let PrintMethod = "printFCCOperand", DecoderMethod = "DecodeCondCode" in
  51   def condcode : Operand<i32>;
  52
  53 //===----------------------------------------------------------------------===//
  54 // Feature predicates.
  55 //===----------------------------------------------------------------------===//
  56
  57 def IsFP64bit        : Predicate<"Subtarget.isFP64bit()">,
  58                        AssemblerPredicate<"FeatureFP64Bit">;
  59 def NotFP64bit       : Predicate<"!Subtarget.isFP64bit()">,
  60                        AssemblerPredicate<"!FeatureFP64Bit">;
  61 def IsSingleFloat    : Predicate<"Subtarget.isSingleFloat()">,
  62                        AssemblerPredicate<"FeatureSingleFloat">;
  63 def IsNotSingleFloat : Predicate<"!Subtarget.isSingleFloat()">,
  64                        AssemblerPredicate<"!FeatureSingleFloat">;
  65
  66 // FP immediate patterns.
  67 def fpimm0 : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(+0.0);
  69 }]>;
  70
  71 def fpimm0neg : PatLeaf<(fpimm), [{
  72   return N->isExactlyValue(-0.0);
  73 }]>;
  74
  75 //===----------------------------------------------------------------------===//
  76 // Instruction Class Templates
  77 //
  78 // A set of multiclasses is used to address the register usage.
  79 //
  80 // S32 - single precision in 16 32bit even fp registers
  81 //       single precision in 32 32bit fp registers in SingleOnly mode
  82 // S64 - single precision in 32 64bit fp registers (In64BitMode)
  83 // D32 - double precision in 16 32bit even fp registers
  84 // D64 - double precision in 32 64bit fp registers (In64BitMode)
  85 //
  86 // Only S32 and D32 are supported right now.
  87 //===----------------------------------------------------------------------===//
  88
  89 // FP unary instructions without patterns.
  90 class FFR1<bits<6> funct, bits<5> fmt, string opstr, RegisterClass DstRC,
  91            RegisterClass SrcRC> :
  92   FFR<0x11, funct, fmt, (outs DstRC:$fd), (ins SrcRC:$fs),
  93       !strconcat(opstr, "\t$fd, $fs"), []> {
  94   let ft = 0;
  95 }
  96
  97 // FP unary instructions with patterns.
  98 class FFR1P<bits<6> funct, bits<5> fmt, string opstr, RegisterClass DstRC,
  99             RegisterClass SrcRC, SDNode OpNode> :
 100   FFR<0x11, funct, fmt, (outs DstRC:$fd), (ins SrcRC:$fs),
 101       !strconcat(opstr, "\t$fd, $fs"),
 102       [(set DstRC:$fd, (OpNode SrcRC:$fs))]> {
 103   let ft = 0;
 104 }
 105
 106 class FFR2P<bits<6> funct, bits<5> fmt, string opstr, RegisterClass RC,
 107             SDNode OpNode> :
 108   FFR<0x11, funct, fmt, (outs RC:$fd), (ins RC:$fs, RC:$ft),
 109       !strconcat(opstr, "\t$fd, $fs, $ft"),
 110       [(set RC:$fd, (OpNode RC:$fs, RC:$ft))]>;
 111
 112 // FP load.
 113 let DecoderMethod = "DecodeFMem" in {
 114 class FPLoad<bits<6> op, string opstr, RegisterClass RC, Operand MemOpnd>:
 115   FMem<op, (outs RC:$ft), (ins MemOpnd:$addr),
 116       !strconcat(opstr, "\t$ft, $addr"), [(set RC:$ft, (load addr:$addr))],
 117       IILoad>;
 118
 119 // FP store.
 120 class FPStore<bits<6> op, string opstr, RegisterClass RC, Operand MemOpnd>:
 121   FMem<op, (outs), (ins RC:$ft, MemOpnd:$addr),
 122       !strconcat(opstr, "\t$ft, $addr"), [(store RC:$ft, addr:$addr)],
 123       IIStore>;
 124 }
 125 // FP indexed load.
 126 class FPIdxLoad<bits<6> funct, string opstr, RegisterClass DRC,
 127                 RegisterClass PRC, SDPatternOperator FOp = null_frag>:
 128   FFMemIdx<funct, (outs DRC:$fd), (ins PRC:$base, PRC:$index),
 129            !strconcat(opstr, "\t$fd, ${index}(${base})"),
 130            [(set DRC:$fd, (FOp (add PRC:$base, PRC:$index)))]> {
 131   let fs = 0;
 132 }
 133
 134 // FP indexed store.
 135 class FPIdxStore<bits<6> funct, string opstr, RegisterClass DRC,
 136                  RegisterClass PRC, SDPatternOperator FOp= null_frag>:
 137   FFMemIdx<funct, (outs), (ins DRC:$fs, PRC:$base, PRC:$index),
 138            !strconcat(opstr, "\t$fs, ${index}(${base})"),
 139            [(FOp DRC:$fs, (add PRC:$base, PRC:$index))]> {
 140   let fd = 0;
 141 }
 142
 143 // Instructions that convert an FP value to 32-bit fixed point.
 144 multiclass FFR1_W_M<bits<6> funct, string opstr> {
 145   def _D32 : FFR1<funct, 17, opstr, FGR32, AFGR64>,
 146              Requires<[NotFP64bit, HasStdEnc]>;
 147   def _D64 : FFR1<funct, 17, opstr, FGR32, FGR64>,
 148              Requires<[IsFP64bit, HasStdEnc]> {
 149     let DecoderNamespace = "Mips64";
 150   }
 151 }
 152
 153 // FP-to-FP conversion instructions.
 154 multiclass FFR1P_M<bits<6> funct, string opstr, SDNode OpNode> {
 155   def _D32 : FFR1P<funct, 17, opstr, AFGR64, AFGR64, OpNode>,
 156              Requires<[NotFP64bit, HasStdEnc]>;
 157   def _D64 : FFR1P<funct, 17, opstr, FGR64, FGR64, OpNode>,
 158              Requires<[IsFP64bit, HasStdEnc]> {
 159     let DecoderNamespace = "Mips64";
 160   }
 161 }
 162
 163 multiclass FFR2P_M<bits<6> funct, string opstr, SDNode OpNode> {
 164   def _D32 : FFR2P<funct, 17, opstr, AFGR64, OpNode>,
 165              Requires<[NotFP64bit, HasStdEnc]>;
 166   def _D64 : FFR2P<funct, 17, opstr, FGR64, OpNode>,
 167              Requires<[IsFP64bit, HasStdEnc]> {
 168     let DecoderNamespace = "Mips64";
 169   }
 170 }
 171
 172 // FP madd/msub/nmadd/nmsub instruction classes.
 173 class FMADDSUB<bits<3> funct, bits<3> fmt, string opstr,
 174                SDNode OpNode, RegisterClass RC> :
 175   FFMADDSUB<funct, fmt, (outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 176             !strconcat(opstr, "\t$fd, $fr, $fs, $ft"),
 177             [(set RC:$fd, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr))]>;
 178
 179 class FNMADDSUB<bits<3> funct, bits<3> fmt, string opstr,
 180                 SDNode OpNode, RegisterClass RC> :
 181   FFMADDSUB<funct, fmt, (outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 182             !strconcat(opstr, "\t$fd, $fr, $fs, $ft"),
 183             [(set RC:$fd, (fsub fpimm0, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr)))]>;
 184
 185 class ADDS_FT<string opstr, RegisterClass RC, InstrItinClass Itin, bit IsComm,
 186               SDPatternOperator OpNode= null_frag> :
 187   InstSE<(outs RC:$fd), (ins RC:$fs, RC:$ft),
 188          !strconcat(opstr, "\t$fd, $fs, $ft"),
 189          [(set RC:$fd, (OpNode RC:$fs, RC:$ft))], Itin, FrmFR> {
 190   let isCommutable = IsComm;
 191 }
 192
 193 multiclass ADDS_M<string opstr, InstrItinClass Itin, bit IsComm,
 194                   SDPatternOperator OpNode = null_frag> {
 195   def _D32 : ADDS_FT<opstr, AFGR64, Itin, IsComm, OpNode>,
 196              Requires<[NotFP64bit, HasStdEnc]>;
 197   def _D64 : ADDS_FT<opstr, FGR64, Itin, IsComm, OpNode>,
 198              Requires<[IsFP64bit, HasStdEnc]> {
 199     string DecoderNamespace = "Mips64";
 200   }
 201 }
 202
 203 class ABSS_FT<string opstr, RegisterClass DstRC, RegisterClass SrcRC,
 204               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 205   InstSE<(outs DstRC:$fd), (ins SrcRC:$fs), !strconcat(opstr, "\t$fd, $fs"),
 206          [(set DstRC:$fd, (OpNode SrcRC:$fs))], Itin, FrmFR>;
 207
 208 multiclass ABSS_M<string opstr, InstrItinClass Itin,
 209                   SDPatternOperator OpNode= null_frag> {
 210   def _D32 : ABSS_FT<opstr, AFGR64, AFGR64, Itin, OpNode>,
 211              Requires<[NotFP64bit, HasStdEnc]>;
 212   def _D64 : ABSS_FT<opstr, FGR64, FGR64, Itin, OpNode>,
 213              Requires<[IsFP64bit, HasStdEnc]> {
 214     string DecoderNamespace = "Mips64";
 215   }
 216 }
 217
 218 multiclass ROUND_M<string opstr, InstrItinClass Itin> {
 219   def _D32 : ABSS_FT<opstr, FGR32, AFGR64, Itin>,
 220              Requires<[NotFP64bit, HasStdEnc]>;
 221   def _D64 : ABSS_FT<opstr, FGR32, FGR64, Itin>,
 222              Requires<[IsFP64bit, HasStdEnc]> {
 223     let DecoderNamespace = "Mips64";
 224   }
 225 }
 226
 227 class MFC1_FT<string opstr, RegisterClass DstRC, RegisterClass SrcRC,
 228               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 229   InstSE<(outs DstRC:$rt), (ins SrcRC:$fs), !strconcat(opstr, "\t$rt, $fs"),
 230          [(set DstRC:$rt, (OpNode SrcRC:$fs))], Itin, FrmFR>;
 231
 232 class MTC1_FT<string opstr, RegisterClass DstRC, RegisterClass SrcRC,
 233               InstrItinClass Itin, SDPatternOperator OpNode= null_frag> :
 234   InstSE<(outs DstRC:$fs), (ins SrcRC:$rt), !strconcat(opstr, "\t$rt, $fs"),
 235          [(set DstRC:$fs, (OpNode SrcRC:$rt))], Itin, FrmFR>;
 236
 237 class LW_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
 238             Operand MemOpnd, SDPatternOperator OpNode= null_frag> :
 239   InstSE<(outs RC:$rt), (ins MemOpnd:$addr), !strconcat(opstr, "\t$rt, $addr"),
 240          [(set RC:$rt, (OpNode addr:$addr))], Itin, FrmFI> {
 241   let DecoderMethod = "DecodeFMem";
 242 }
 243
 244 class SW_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
 245             Operand MemOpnd, SDPatternOperator OpNode= null_frag> :
 246   InstSE<(outs), (ins RC:$rt, MemOpnd:$addr), !strconcat(opstr, "\t$rt, $addr"),
 247          [(OpNode RC:$rt, addr:$addr)], Itin, FrmFI> {
 248   let DecoderMethod = "DecodeFMem";
 249 }
 250
 251 class MADDS_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
 252                SDPatternOperator OpNode = null_frag> :
 253   InstSE<(outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 254          !strconcat(opstr, "\t$fd, $fr, $fs, $ft"),
 255          [(set RC:$fd, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr))], Itin, FrmFR>;
 256
 257 class NMADDS_FT<string opstr, RegisterClass RC, InstrItinClass Itin,
 258                 SDPatternOperator OpNode = null_frag> :
 259   InstSE<(outs RC:$fd), (ins RC:$fr, RC:$fs, RC:$ft),
 260          !strconcat(opstr, "\t$fd, $fr, $fs, $ft"),
 261          [(set RC:$fd, (fsub fpimm0, (OpNode (fmul RC:$fs, RC:$ft), RC:$fr)))],
 262          Itin, FrmFR>;
 263
 264 //===----------------------------------------------------------------------===//
 265 // Floating Point Instructions
 266 //===----------------------------------------------------------------------===//
 267 def ROUND_W_S  : ABSS_FT<"round.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0xc, 16>;
 268 def TRUNC_W_S  : ABSS_FT<"trunc.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0xd, 16>;
 269 def CEIL_W_S   : ABSS_FT<"ceil.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0xe, 16>;
 270 def FLOOR_W_S  : ABSS_FT<"floor.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0xf, 16>;
 271 def CVT_W_S    : ABSS_FT<"cvt.w.s", FGR32, FGR32, IIFcvt>, ABSS_FM<0x24, 16>,
 272                  NeverHasSideEffects;
 273
 274 defm ROUND_W : ROUND_M<"round.w.d", IIFcvt>, ABSS_FM<0xc, 17>;
 275 defm TRUNC_W : ROUND_M<"trunc.w.d", IIFcvt>, ABSS_FM<0xd, 17>;
 276 defm CEIL_W  : ROUND_M<"ceil.w.d", IIFcvt>, ABSS_FM<0xe, 17>;
 277 defm FLOOR_W : ROUND_M<"floor.w.d", IIFcvt>, ABSS_FM<0xf, 17>;
 278 defm CVT_W   : ROUND_M<"cvt.w.d", IIFcvt>, ABSS_FM<0x24, 17>,
 279                NeverHasSideEffects;
 280
 281 let Predicates = [IsFP64bit, HasStdEnc], DecoderNamespace = "Mips64" in {
 282   def ROUND_L_S : ABSS_FT<"round.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0x8, 16>;
 283   def ROUND_L_D64 : ABSS_FT<"round.l.d", FGR64, FGR64, IIFcvt>,
 284                     ABSS_FM<0x8, 17>;
 285   def TRUNC_L_S : ABSS_FT<"trunc.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0x9, 16>;
 286   def TRUNC_L_D64 : ABSS_FT<"trunc.l.d", FGR64, FGR64, IIFcvt>,
 287                     ABSS_FM<0x9, 17>;
 288   def CEIL_L_S  : ABSS_FT<"ceil.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0xa, 16>;
 289   def CEIL_L_D64 : ABSS_FT<"ceil.l.d", FGR64, FGR64, IIFcvt>, ABSS_FM<0xa, 17>;
 290   def FLOOR_L_S : ABSS_FT<"floor.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0xb, 16>;
 291   def FLOOR_L_D64 : ABSS_FT<"floor.l.d", FGR64, FGR64, IIFcvt>,
 292                     ABSS_FM<0xb, 17>;
 293 }
 294
 295 def CVT_S_W : ABSS_FT<"cvt.s.w", FGR32, FGR32, IIFcvt>, ABSS_FM<0x20, 20>;
 296 def CVT_L_S : ABSS_FT<"cvt.l.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0x25, 16>,
 297               NeverHasSideEffects;
 298 def CVT_L_D64: ABSS_FT<"cvt.l.d", FGR64, FGR64, IIFcvt>, ABSS_FM<0x25, 17>,
 299                NeverHasSideEffects;
 300
 301 let Predicates = [NotFP64bit, HasStdEnc], neverHasSideEffects = 1 in {
 302   def CVT_S_D32 : ABSS_FT<"cvt.s.d", FGR32, AFGR64, IIFcvt>, ABSS_FM<0x20, 17>;
 303   def CVT_D32_W : ABSS_FT<"cvt.d.w", AFGR64, FGR32, IIFcvt>, ABSS_FM<0x21, 20>;
 304   def CVT_D32_S : ABSS_FT<"cvt.d.s", AFGR64, FGR32, IIFcvt>, ABSS_FM<0x21, 16>;
 305 }
 306
 307 let Predicates = [IsFP64bit, HasStdEnc], DecoderNamespace = "Mips64",
 308     neverHasSideEffects = 1 in {
 309  def CVT_S_D64 : ABSS_FT<"cvt.s.d", FGR32, FGR64, IIFcvt>, ABSS_FM<0x20, 17>;
 310  def CVT_S_L   : ABSS_FT<"cvt.s.l", FGR32, FGR64, IIFcvt>, ABSS_FM<0x20, 21>;
 311  def CVT_D64_W : ABSS_FT<"cvt.d.w", FGR64, FGR32, IIFcvt>, ABSS_FM<0x21, 20>;
 312  def CVT_D64_S : ABSS_FT<"cvt.d.s", FGR64, FGR32, IIFcvt>, ABSS_FM<0x21, 16>;
 313  def CVT_D64_L : ABSS_FT<"cvt.d.l", FGR64, FGR64, IIFcvt>, ABSS_FM<0x21, 21>;
 314 }
 315
 316 let Predicates = [NoNaNsFPMath, HasStdEnc] in {
 317   def FABS_S : ABSS_FT<"abs.s", FGR32, FGR32, IIFcvt, fabs>, ABSS_FM<0x5, 16>;
 318   def FNEG_S : ABSS_FT<"neg.s", FGR32, FGR32, IIFcvt, fneg>, ABSS_FM<0x7, 16>;
 319   defm FABS : ABSS_M<"abs.d", IIFcvt, fabs>, ABSS_FM<0x5, 17>;
 320   defm FNEG : ABSS_M<"neg.d", IIFcvt, fneg>, ABSS_FM<0x7, 17>;
 321 }
 322
 323 def  FSQRT_S : ABSS_FT<"sqrt.s", FGR32, FGR32, IIFsqrtSingle, fsqrt>,
 324                ABSS_FM<0x4, 16>;
 325 defm FSQRT : ABSS_M<"sqrt.d", IIFsqrtDouble, fsqrt>, ABSS_FM<0x4, 17>;
 326
 327 // The odd-numbered registers are only referenced when doing loads,
 328 // stores, and moves between floating-point and integer registers.
 329 // When defining instructions, we reference all 32-bit registers,
 330 // regardless of register aliasing.
 331
 332 class FFRGPR<bits<5> _fmt, dag outs, dag ins, string asmstr, list<dag> pattern>:
 333              FFR<0x11, 0x0, _fmt, outs, ins, asmstr, pattern> {
 334   bits<5> rt;
 335   let ft = rt;
 336   let fd = 0;
 337 }
 338
 339 /// Move Control Registers From/To CPU Registers
 340 def CFC1 : MFC1_FT<"cfc1", CPURegs, CCR, IIFmove>, MFC1_FM<2>;
 341 def CTC1 : MTC1_FT<"ctc1", CCR, CPURegs, IIFmove>, MFC1_FM<6>;
 342 def MFC1 : MFC1_FT<"mfc1", CPURegs, FGR32, IIFmove, bitconvert>, MFC1_FM<0>;
 343 def MTC1 : MTC1_FT<"mtc1", FGR32, CPURegs, IIFmove, bitconvert>, MFC1_FM<4>;
 344 def DMFC1 : MFC1_FT<"dmfc1", CPU64Regs, FGR64, IIFmove, bitconvert>, MFC1_FM<1>;
 345 def DMTC1 : MTC1_FT<"dmtc1", FGR64, CPU64Regs, IIFmove, bitconvert>, MFC1_FM<5>;
 346
 347 def FMOV_S   : ABSS_FT<"mov.s", FGR32, FGR32, IIFmove>, ABSS_FM<0x6, 16>;
 348 def FMOV_D32 : ABSS_FT<"mov.d", AFGR64, AFGR64, IIFmove>, ABSS_FM<0x6, 17>,
 349                Requires<[NotFP64bit, HasStdEnc]>;
 350 def FMOV_D64 : ABSS_FT<"mov.d", FGR64, FGR64, IIFmove>, ABSS_FM<0x6, 17>,
 351                Requires<[IsFP64bit, HasStdEnc]> {
 352   let DecoderNamespace = "Mips64";
 353 }
 354
 355 /// Floating Point Memory Instructions
 356 let Predicates = [IsN64, HasStdEnc], DecoderNamespace = "Mips64" in {
 357   def LWC1_P8 : LW_FT<"lwc1", FGR32, IILoad, mem64, load>, LW_FM<0x31>;
 358   def SWC1_P8 : SW_FT<"swc1", FGR32, IIStore, mem64, store>, LW_FM<0x39>;
 359   def LDC164_P8 : LW_FT<"ldc1", FGR64, IILoad, mem64, load>, LW_FM<0x35> {
 360     let isCodeGenOnly =1;
 361   }
 362   def SDC164_P8 : SW_FT<"sdc1", FGR64, IIStore, mem64, store>, LW_FM<0x3d> {
 363     let isCodeGenOnly =1;
 364   }
 365 }
 366
 367 let Predicates = [NotN64, HasStdEnc] in {
 368   def LWC1 : LW_FT<"lwc1", FGR32, IILoad, mem, load>, LW_FM<0x31>;
 369   def SWC1 : SW_FT<"swc1", FGR32, IIStore, mem, store>, LW_FM<0x39>;
 370 }
 371
 372 let Predicates = [NotN64, HasMips64, HasStdEnc],
 373   DecoderNamespace = "Mips64" in {
 374   def LDC164 : LW_FT<"ldc1", FGR64, IILoad, mem, load>, LW_FM<0x35>;
 375   def SDC164 : SW_FT<"sdc1", FGR64, IIStore, mem, store>, LW_FM<0x3d>;
 376 }
 377
 378 let Predicates = [NotN64, NotMips64, HasStdEnc] in {
 379   def LDC1 : LW_FT<"ldc1", AFGR64, IILoad, mem, load>, LW_FM<0x35>;
 380   def SDC1 : SW_FT<"sdc1", AFGR64, IIStore, mem, store>, LW_FM<0x3d>;
 381 }
 382
 383 // Indexed loads and stores.
 384 let Predicates = [HasFPIdx, HasStdEnc] in {
 385   def LWXC1 : FPIdxLoad<0x0, "lwxc1", FGR32, CPURegs, load>;
 386   def SWXC1 : FPIdxStore<0x8, "swxc1", FGR32, CPURegs, store>;
 387 }
 388
 389 let Predicates = [HasMips32r2, NotMips64, HasStdEnc] in {
 390   def LDXC1 : FPIdxLoad<0x1, "ldxc1", AFGR64, CPURegs, load>;
 391   def SDXC1 : FPIdxStore<0x9, "sdxc1", AFGR64, CPURegs, store>;
 392 }
 393
 394 let Predicates = [HasMips64, NotN64, HasStdEnc], DecoderNamespace="Mips64" in {
 395   def LDXC164 : FPIdxLoad<0x1, "ldxc1", FGR64, CPURegs, load>;
 396   def SDXC164 : FPIdxStore<0x9, "sdxc1", FGR64, CPURegs, store>;
 397 }
 398
 399 // n64
 400 let Predicates = [IsN64, HasStdEnc], isCodeGenOnly=1 in {
 401   def LWXC1_P8   : FPIdxLoad<0x0, "lwxc1", FGR32, CPU64Regs, load>;
 402   def LDXC164_P8 : FPIdxLoad<0x1, "ldxc1", FGR64, CPU64Regs, load>;
 403   def SWXC1_P8   : FPIdxStore<0x8, "swxc1", FGR32, CPU64Regs, store>;
 404   def SDXC164_P8 : FPIdxStore<0x9, "sdxc1", FGR64, CPU64Regs, store>;
 405 }
 406
 407 // Load/store doubleword indexed unaligned.
 408 let Predicates = [NotMips64, HasStdEnc] in {
 409   def LUXC1 : FPIdxLoad<0x5, "luxc1", AFGR64, CPURegs>;
 410   def SUXC1 : FPIdxStore<0xd, "suxc1", AFGR64, CPURegs>;
 411 }
 412
 413 let Predicates = [HasMips64, HasStdEnc],
 414   DecoderNamespace="Mips64" in {
 415   def LUXC164 : FPIdxLoad<0x5, "luxc1", FGR64, CPURegs>;
 416   def SUXC164 : FPIdxStore<0xd, "suxc1", FGR64, CPURegs>;
 417 }
 418
 419 /// Floating-point Aritmetic
 420 def FADD_S : ADDS_FT<"add.s", FGR32, IIFadd, 1, fadd>, ADDS_FM<0x00, 16>;
 421 defm FADD : ADDS_M<"add.d", IIFadd, 1, fadd>, ADDS_FM<0x00, 17>;
 422 def FDIV_S : ADDS_FT<"div.s", FGR32, IIFdivSingle, 0, fdiv>, ADDS_FM<0x03, 16>;
 423 defm FDIV : ADDS_M<"div.d", IIFdivDouble, 0, fdiv>, ADDS_FM<0x03, 17>;
 424 def FMUL_S : ADDS_FT<"mul.s", FGR32, IIFmulSingle, 1, fmul>, ADDS_FM<0x02, 16>;
 425 defm FMUL : ADDS_M<"mul.d", IIFmulDouble, 1, fmul>, ADDS_FM<0x02, 17>;
 426 def FSUB_S : ADDS_FT<"sub.s", FGR32, IIFadd, 0, fsub>, ADDS_FM<0x01, 16>;
 427 defm FSUB : ADDS_M<"sub.d", IIFadd, 0, fsub>, ADDS_FM<0x01, 17>;
 428
 429 let Predicates = [HasMips32r2, HasStdEnc] in {
 430   def MADD_S : MADDS_FT<"madd.s", FGR32, IIFmulSingle, fadd>, MADDS_FM<4, 0>;
 431   def MSUB_S : MADDS_FT<"msub.s", FGR32, IIFmulSingle, fsub>, MADDS_FM<5, 0>;
 432 }
 433
 434 let Predicates = [HasMips32r2, NoNaNsFPMath, HasStdEnc] in {
 435   def NMADD_S : NMADDS_FT<"nmadd.s", FGR32, IIFmulSingle, fadd>, MADDS_FM<6, 0>;
 436   def NMSUB_S : NMADDS_FT<"nmsub.s", FGR32, IIFmulSingle, fsub>, MADDS_FM<7, 0>;
 437 }
 438
 439 let Predicates = [HasMips32r2, NotFP64bit, HasStdEnc] in {
 440   def MADD_D32 : MADDS_FT<"madd.d", AFGR64, IIFmulDouble, fadd>, MADDS_FM<4, 1>;
 441   def MSUB_D32 : MADDS_FT<"msub.d", AFGR64, IIFmulDouble, fsub>, MADDS_FM<5, 1>;
 442 }
 443
 444 let Predicates = [HasMips32r2, NotFP64bit, NoNaNsFPMath, HasStdEnc] in {
 445   def NMADD_D32 : NMADDS_FT<"nmadd.d", AFGR64, IIFmulDouble, fadd>,
 446                   MADDS_FM<6, 1>;
 447   def NMSUB_D32 : NMADDS_FT<"nmsub.d", AFGR64, IIFmulDouble, fsub>,
 448                   MADDS_FM<7, 1>;
 449 }
 450
 451 let Predicates = [HasMips32r2, IsFP64bit, HasStdEnc], isCodeGenOnly=1 in {
 452   def MADD_D64 : MADDS_FT<"madd.d", FGR64, IIFmulDouble, fadd>, MADDS_FM<4, 1>;
 453   def MSUB_D64 : MADDS_FT<"msub.d", FGR64, IIFmulDouble, fsub>, MADDS_FM<5, 1>;
 454 }
 455
 456 let Predicates = [HasMips32r2, IsFP64bit, NoNaNsFPMath, HasStdEnc],
 457     isCodeGenOnly=1 in {
 458   def NMADD_D64 : NMADDS_FT<"nmadd.d", FGR64, IIFmulDouble, fadd>,
 459                   MADDS_FM<6, 1>;
 460   def NMSUB_D64 : NMADDS_FT<"nmsub.d", FGR64, IIFmulDouble, fsub>,
 461                   MADDS_FM<7, 1>;
 462 }
 463
 464 //===----------------------------------------------------------------------===//
 465 // Floating Point Branch Codes
 466 //===----------------------------------------------------------------------===//
 467 // Mips branch codes. These correspond to condcode in MipsInstrInfo.h.
 468 // They must be kept in synch.
 469 def MIPS_BRANCH_F  : PatLeaf<(i32 0)>;
 470 def MIPS_BRANCH_T  : PatLeaf<(i32 1)>;
 471
 472 /// Floating Point Branch of False/True (Likely)
 473 let isBranch=1, isTerminator=1, hasDelaySlot=1, base=0x8, Uses=[FCR31] in
 474   class FBRANCH<bits<1> nd, bits<1> tf, PatLeaf op, string asmstr> :
 475       FFI<0x11, (outs), (ins brtarget:$dst), !strconcat(asmstr, "\t$dst"),
 476         [(MipsFPBrcond op, bb:$dst)]> {
 477   let Inst{20-18} = 0;
 478   let Inst{17} = nd;
 479   let Inst{16} = tf;
 480 }
 481
 482 let DecoderMethod = "DecodeBC1" in {
 483 def BC1F  : FBRANCH<0, 0, MIPS_BRANCH_F,  "bc1f">;
 484 def BC1T  : FBRANCH<0, 1, MIPS_BRANCH_T,  "bc1t">;
 485 }
 486 //===----------------------------------------------------------------------===//
 487 // Floating Point Flag Conditions
 488 //===----------------------------------------------------------------------===//
 489 // Mips condition codes. They must correspond to condcode in MipsInstrInfo.h.
 490 // They must be kept in synch.
 491 def MIPS_FCOND_F    : PatLeaf<(i32 0)>;
 492 def MIPS_FCOND_UN   : PatLeaf<(i32 1)>;
 493 def MIPS_FCOND_OEQ  : PatLeaf<(i32 2)>;
 494 def MIPS_FCOND_UEQ  : PatLeaf<(i32 3)>;
 495 def MIPS_FCOND_OLT  : PatLeaf<(i32 4)>;
 496 def MIPS_FCOND_ULT  : PatLeaf<(i32 5)>;
 497 def MIPS_FCOND_OLE  : PatLeaf<(i32 6)>;
 498 def MIPS_FCOND_ULE  : PatLeaf<(i32 7)>;
 499 def MIPS_FCOND_SF   : PatLeaf<(i32 8)>;
 500 def MIPS_FCOND_NGLE : PatLeaf<(i32 9)>;
 501 def MIPS_FCOND_SEQ  : PatLeaf<(i32 10)>;
 502 def MIPS_FCOND_NGL  : PatLeaf<(i32 11)>;
 503 def MIPS_FCOND_LT   : PatLeaf<(i32 12)>;
 504 def MIPS_FCOND_NGE  : PatLeaf<(i32 13)>;
 505 def MIPS_FCOND_LE   : PatLeaf<(i32 14)>;
 506 def MIPS_FCOND_NGT  : PatLeaf<(i32 15)>;
 507
 508 class FCMP<bits<5> fmt, RegisterClass RC, string typestr> :
 509   FCC<fmt, (outs), (ins RC:$fs, RC:$ft, condcode:$cc),
 510       !strconcat("c.$cc.", typestr, "\t$fs, $ft"),
 511       [(MipsFPCmp RC:$fs, RC:$ft, imm:$cc)]>;
 512
 513 /// Floating Point Compare
 514 let Defs=[FCR31] in {
 515   def FCMP_S32 : FCMP<0x10, FGR32, "s">;
 516   def FCMP_D32 : FCMP<0x11, AFGR64, "d">,
 517       Requires<[NotFP64bit, HasStdEnc]>;
 518   def FCMP_D64 : FCMP<0x11, FGR64, "d">,
 519       Requires<[IsFP64bit, HasStdEnc]> {
 520     let DecoderNamespace = "Mips64";
 521   }
 522 }
 523
 524 //===----------------------------------------------------------------------===//
 525 // Floating Point Pseudo-Instructions
 526 //===----------------------------------------------------------------------===//
 527 def MOVCCRToCCR : PseudoSE<(outs CCR:$dst), (ins CCR:$src),
 528                            "# MOVCCRToCCR", []>;
 529
 530 // This pseudo instr gets expanded into 2 mtc1 instrs after register
 531 // allocation.
 532 def BuildPairF64 :
 533   PseudoSE<(outs AFGR64:$dst),
 534            (ins CPURegs:$lo, CPURegs:$hi), "",
 535            [(set AFGR64:$dst, (MipsBuildPairF64 CPURegs:$lo, CPURegs:$hi))]>;
 536
 537 // This pseudo instr gets expanded into 2 mfc1 instrs after register
 538 // allocation.
 539 // if n is 0, lower part of src is extracted.
 540 // if n is 1, higher part of src is extracted.
 541 def ExtractElementF64 :
 542   PseudoSE<(outs CPURegs:$dst), (ins AFGR64:$src, i32imm:$n), "",
 543            [(set CPURegs:$dst, (MipsExtractElementF64 AFGR64:$src, imm:$n))]>;
 544
 545 //===----------------------------------------------------------------------===//
 546 // Floating Point Patterns
 547 //===----------------------------------------------------------------------===//
 548 def : MipsPat<(f32 fpimm0), (MTC1 ZERO)>;
 549 def : MipsPat<(f32 fpimm0neg), (FNEG_S (MTC1 ZERO))>;
 550
 551 def : MipsPat<(f32 (sint_to_fp CPURegs:$src)), (CVT_S_W (MTC1 CPURegs:$src))>;
 552 def : MipsPat<(i32 (fp_to_sint FGR32:$src)), (MFC1 (TRUNC_W_S FGR32:$src))>;
 553
 554 let Predicates = [NotFP64bit, HasStdEnc] in {
 555   def : MipsPat<(f64 (sint_to_fp CPURegs:$src)),
 556                 (CVT_D32_W (MTC1 CPURegs:$src))>;
 557   def : MipsPat<(i32 (fp_to_sint AFGR64:$src)),
 558                 (MFC1 (TRUNC_W_D32 AFGR64:$src))>;
 559   def : MipsPat<(f32 (fround AFGR64:$src)), (CVT_S_D32 AFGR64:$src)>;
 560   def : MipsPat<(f64 (fextend FGR32:$src)), (CVT_D32_S FGR32:$src)>;
 561 }
 562
 563 let Predicates = [IsFP64bit, HasStdEnc] in {
 564   def : MipsPat<(f64 fpimm0), (DMTC1 ZERO_64)>;
 565   def : MipsPat<(f64 fpimm0neg), (FNEG_D64 (DMTC1 ZERO_64))>;
 566
 567   def : MipsPat<(f64 (sint_to_fp CPURegs:$src)),
 568                 (CVT_D64_W (MTC1 CPURegs:$src))>;
 569   def : MipsPat<(f32 (sint_to_fp CPU64Regs:$src)),
 570                 (CVT_S_L (DMTC1 CPU64Regs:$src))>;
 571   def : MipsPat<(f64 (sint_to_fp CPU64Regs:$src)),
 572                 (CVT_D64_L (DMTC1 CPU64Regs:$src))>;
 573
 574   def : MipsPat<(i32 (fp_to_sint FGR64:$src)),
 575                 (MFC1 (TRUNC_W_D64 FGR64:$src))>;
 576   def : MipsPat<(i64 (fp_to_sint FGR32:$src)), (DMFC1 (TRUNC_L_S FGR32:$src))>;
 577   def : MipsPat<(i64 (fp_to_sint FGR64:$src)),
 578                 (DMFC1 (TRUNC_L_D64 FGR64:$src))>;
 579
 580   def : MipsPat<(f32 (fround FGR64:$src)), (CVT_S_D64 FGR64:$src)>;
 581   def : MipsPat<(f64 (fextend FGR32:$src)), (CVT_D64_S FGR32:$src)>;
 582 }