lib/Target/Mips/MipsInstrFormats.td

   1 //===-- MipsInstrFormats.td - Mips Instruction Formats -----*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //  Describe MIPS instructions format
  12 //
  13 //  CPU INSTRUCTION FORMATS
  14 //
  15 //  opcode  - operation code.
  16 //  rs      - src reg.
  17 //  rt      - dst reg (on a 2 regs instr) or src reg (on a 3 reg instr).
  18 //  rd      - dst reg, only used on 3 regs instr.
  19 //  shamt   - only used on shift instructions, contains the shift amount.
  20 //  funct   - combined with opcode field give us an operation code.
  21 //
  22 //===----------------------------------------------------------------------===//
  23
  24 // Format specifies the encoding used by the instruction.  This is part of the
  25 // ad-hoc solution used to emit machine instruction encodings by our machine
  26 // code emitter.
  27 class Format<bits<4> val> {
  28   bits<4> Value = val;
  29 }
  30
  31 def Pseudo    : Format<0>;
  32 def FrmR      : Format<1>;
  33 def FrmI      : Format<2>;
  34 def FrmJ      : Format<3>;
  35 def FrmFR     : Format<4>;
  36 def FrmFI     : Format<5>;
  37 def FrmOther  : Format<6>; // Instruction w/ a custom format
  38
  39 // Generic Mips Format
  40 class MipsInst<dag outs, dag ins, string asmstr, list<dag> pattern,
  41                InstrItinClass itin, Format f>: Instruction
  42 {
  43   field bits<32> Inst;
  44   Format Form = f;
  45
  46   let Namespace = "Mips";
  47
  48   let Size = 4;
  49
  50   bits<6> Opcode = 0;
  51
  52   // Top 6 bits are the 'opcode' field
  53   let Inst{31-26} = Opcode;
  54
  55   let OutOperandList = outs;
  56   let InOperandList  = ins;
  57
  58   let AsmString   = asmstr;
  59   let Pattern     = pattern;
  60   let Itinerary   = itin;
  61
  62   //
  63   // Attributes specific to Mips instructions...
  64   //
  65   bits<4> FormBits = Form.Value;
  66
  67   // TSFlags layout should be kept in sync with MipsInstrInfo.h.
  68   let TSFlags{3-0}   = FormBits;
  69
  70   let DecoderNamespace = "Mips";
  71
  72   field bits<32> SoftFail = 0;
  73 }
  74
  75 // Mips32/64 Instruction Format
  76 class InstSE<dag outs, dag ins, string asmstr, list<dag> pattern,
  77              InstrItinClass itin, Format f>:
  78   MipsInst<outs, ins, asmstr, pattern, itin, f> {
  79   let Predicates = [HasStdEnc];
  80 }
  81
  82 // Mips Pseudo Instructions Format
  83 class MipsPseudo<dag outs, dag ins, list<dag> pattern,
  84                  InstrItinClass itin = IIPseudo> :
  85   MipsInst<outs, ins, "", pattern, itin, Pseudo> {
  86   let isCodeGenOnly = 1;
  87   let isPseudo = 1;
  88 }
  89
  90 // Mips32/64 Pseudo Instruction Format
  91 class PseudoSE<dag outs, dag ins, list<dag> pattern,
  92                InstrItinClass itin = IIPseudo>:
  93   MipsPseudo<outs, ins, pattern, itin> {
  94   let Predicates = [HasStdEnc];
  95 }
  96
  97 // Pseudo-instructions for alternate assembly syntax (never used by codegen).
  98 // These are aliases that require C++ handling to convert to the target
  99 // instruction, while InstAliases can be handled directly by tblgen.
 100 class MipsAsmPseudoInst<dag outs, dag ins, string asmstr>:
 101   MipsInst<outs, ins, asmstr, [], IIPseudo, Pseudo> {
 102   let isPseudo = 1;
 103   let Pattern = [];
 104 }
 105 //===----------------------------------------------------------------------===//
 106 // Format R instruction class in Mips : <|opcode|rs|rt|rd|shamt|funct|>
 107 //===----------------------------------------------------------------------===//
 108
 109 class FR<bits<6> op, bits<6> _funct, dag outs, dag ins, string asmstr,
 110          list<dag> pattern, InstrItinClass itin>:
 111   InstSE<outs, ins, asmstr, pattern, itin, FrmR>
 112 {
 113   bits<5>  rd;
 114   bits<5>  rs;
 115   bits<5>  rt;
 116   bits<5>  shamt;
 117   bits<6>  funct;
 118
 119   let Opcode = op;
 120   let funct  = _funct;
 121
 122   let Inst{25-21} = rs;
 123   let Inst{20-16} = rt;
 124   let Inst{15-11} = rd;
 125   let Inst{10-6}  = shamt;
 126   let Inst{5-0}   = funct;
 127 }
 128
 129 //===----------------------------------------------------------------------===//
 130 // Format I instruction class in Mips : <|opcode|rs|rt|immediate|>
 131 //===----------------------------------------------------------------------===//
 132
 133 class FI<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
 134          InstrItinClass itin>: InstSE<outs, ins, asmstr, pattern, itin, FrmI>
 135 {
 136   bits<5>  rt;
 137   bits<5>  rs;
 138   bits<16> imm16;
 139
 140   let Opcode = op;
 141
 142   let Inst{25-21} = rs;
 143   let Inst{20-16} = rt;
 144   let Inst{15-0}  = imm16;
 145 }
 146
 147 class BranchBase<bits<6> op, dag outs, dag ins, string asmstr,
 148                   list<dag> pattern, InstrItinClass itin>:
 149   InstSE<outs, ins, asmstr, pattern, itin, FrmI>
 150 {
 151   bits<5>  rs;
 152   bits<5>  rt;
 153   bits<16> imm16;
 154
 155   let Opcode = op;
 156
 157   let Inst{25-21} = rs;
 158   let Inst{20-16} = rt;
 159   let Inst{15-0}  = imm16;
 160 }
 161
 162 //===----------------------------------------------------------------------===//
 163 // Format J instruction class in Mips : <|opcode|address|>
 164 //===----------------------------------------------------------------------===//
 165
 166 class FJ<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
 167          InstrItinClass itin>: InstSE<outs, ins, asmstr, pattern, itin, FrmJ>
 168 {
 169   bits<26> addr;
 170
 171   let Opcode = op;
 172
 173   let Inst{25-0} = addr;
 174 }
 175
 176  //===----------------------------------------------------------------------===//
 177 // MFC instruction class in Mips : <|op|mf|rt|rd|0000000|sel|>
 178 //===----------------------------------------------------------------------===//
 179 class MFC3OP<bits<6> op, bits<5> _mfmt, dag outs, dag ins, string asmstr>:
 180   InstSE<outs, ins, asmstr, [], NoItinerary, FrmFR>
 181 {
 182   bits<5> mfmt;
 183   bits<5> rt;
 184   bits<5> rd;
 185   bits<3> sel;
 186
 187   let Opcode = op;
 188   let mfmt = _mfmt;
 189
 190   let Inst{25-21} = mfmt;
 191   let Inst{20-16} = rt;
 192   let Inst{15-11} = rd;
 193   let Inst{10-3}  = 0;
 194   let Inst{2-0}   = sel;
 195 }
 196
 197 class ADD_FM<bits<6> op, bits<6> funct> {
 198   bits<5> rd;
 199   bits<5> rs;
 200   bits<5> rt;
 201
 202   bits<32> Inst;
 203
 204   let Inst{31-26} = op;
 205   let Inst{25-21} = rs;
 206   let Inst{20-16} = rt;
 207   let Inst{15-11} = rd;
 208   let Inst{10-6}  = 0;
 209   let Inst{5-0}   = funct;
 210 }
 211
 212 class ADDI_FM<bits<6> op> {
 213   bits<5>  rs;
 214   bits<5>  rt;
 215   bits<16> imm16;
 216
 217   bits<32> Inst;
 218
 219   let Inst{31-26} = op;
 220   let Inst{25-21} = rs;
 221   let Inst{20-16} = rt;
 222   let Inst{15-0}  = imm16;
 223 }
 224
 225 class SRA_FM<bits<6> funct, bit rotate> {
 226   bits<5> rd;
 227   bits<5> rt;
 228   bits<5> shamt;
 229
 230   bits<32> Inst;
 231
 232   let Inst{31-26} = 0;
 233   let Inst{25-22} = 0;
 234   let Inst{21}    = rotate;
 235   let Inst{20-16} = rt;
 236   let Inst{15-11} = rd;
 237   let Inst{10-6}  = shamt;
 238   let Inst{5-0}   = funct;
 239 }
 240
 241 class SRLV_FM<bits<6> funct, bit rotate> {
 242   bits<5> rd;
 243   bits<5> rt;
 244   bits<5> rs;
 245
 246   bits<32> Inst;
 247
 248   let Inst{31-26} = 0;
 249   let Inst{25-21} = rs;
 250   let Inst{20-16} = rt;
 251   let Inst{15-11} = rd;
 252   let Inst{10-7}  = 0;
 253   let Inst{6}     = rotate;
 254   let Inst{5-0}   = funct;
 255 }
 256
 257 class BEQ_FM<bits<6> op> {
 258   bits<5>  rs;
 259   bits<5>  rt;
 260   bits<16> offset;
 261
 262   bits<32> Inst;
 263
 264   let Inst{31-26} = op;
 265   let Inst{25-21} = rs;
 266   let Inst{20-16} = rt;
 267   let Inst{15-0}  = offset;
 268 }
 269
 270 class BGEZ_FM<bits<6> op, bits<5> funct> {
 271   bits<5>  rs;
 272   bits<16> offset;
 273
 274   bits<32> Inst;
 275
 276   let Inst{31-26} = op;
 277   let Inst{25-21} = rs;
 278   let Inst{20-16} = funct;
 279   let Inst{15-0}  = offset;
 280 }
 281
 282 class B_FM {
 283   bits<16> offset;
 284
 285   bits<32> Inst;
 286
 287   let Inst{31-26} = 4;
 288   let Inst{25-21} = 0;
 289   let Inst{20-16} = 0;
 290   let Inst{15-0}  = offset;
 291 }
 292
 293 class SLTI_FM<bits<6> op> {
 294   bits<5> rt;
 295   bits<5> rs;
 296   bits<16> imm16;
 297
 298   bits<32> Inst;
 299
 300   let Inst{31-26} = op;
 301   let Inst{25-21} = rs;
 302   let Inst{20-16} = rt;
 303   let Inst{15-0}  = imm16;
 304 }
 305
 306 //===----------------------------------------------------------------------===//
 307 //
 308 //  FLOATING POINT INSTRUCTION FORMATS
 309 //
 310 //  opcode  - operation code.
 311 //  fs      - src reg.
 312 //  ft      - dst reg (on a 2 regs instr) or src reg (on a 3 reg instr).
 313 //  fd      - dst reg, only used on 3 regs instr.
 314 //  fmt     - double or single precision.
 315 //  funct   - combined with opcode field give us an operation code.
 316 //
 317 //===----------------------------------------------------------------------===//
 318
 319 //===----------------------------------------------------------------------===//
 320 // Format FI instruction class in Mips : <|opcode|base|ft|immediate|>
 321 //===----------------------------------------------------------------------===//
 322
 323 class FFI<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern>:
 324   InstSE<outs, ins, asmstr, pattern, NoItinerary, FrmFI>
 325 {
 326   bits<5>  ft;
 327   bits<5>  base;
 328   bits<16> imm16;
 329
 330   let Opcode = op;
 331
 332   let Inst{25-21} = base;
 333   let Inst{20-16} = ft;
 334   let Inst{15-0}  = imm16;
 335 }
 336
 337 class ADDS_FM<bits<6> funct, bits<5> fmt> {
 338   bits<5> fd;
 339   bits<5> fs;
 340   bits<5> ft;
 341
 342   bits<32> Inst;
 343
 344   let Inst{31-26} = 0x11;
 345   let Inst{25-21} = fmt;
 346   let Inst{20-16} = ft;
 347   let Inst{15-11} = fs;
 348   let Inst{10-6}  = fd;
 349   let Inst{5-0}   = funct;
 350 }
 351
 352 class ABSS_FM<bits<6> funct, bits<5> fmt> {
 353   bits<5> fd;
 354   bits<5> fs;
 355
 356   bits<32> Inst;
 357
 358   let Inst{31-26} = 0x11;
 359   let Inst{25-21} = fmt;
 360   let Inst{20-16} = 0;
 361   let Inst{15-11} = fs;
 362   let Inst{10-6}  = fd;
 363   let Inst{5-0}   = funct;
 364 }
 365
 366 class MFC1_FM<bits<5> funct> {
 367   bits<5> rt;
 368   bits<5> fs;
 369
 370   bits<32> Inst;
 371
 372   let Inst{31-26} = 0x11;
 373   let Inst{25-21} = funct;
 374   let Inst{20-16} = rt;
 375   let Inst{15-11} = fs;
 376   let Inst{10-0}  = 0;
 377 }
 378
 379 class LW_FM<bits<6> op> {
 380   bits<5> rt;
 381   bits<21> addr;
 382
 383   bits<32> Inst;
 384
 385   let Inst{31-26} = op;
 386   let Inst{25-21} = addr{20-16};
 387   let Inst{20-16} = rt;
 388   let Inst{15-0}  = addr{15-0};
 389 }
 390
 391 class MADDS_FM<bits<3> funct, bits<3> fmt> {
 392   bits<5> fd;
 393   bits<5> fr;
 394   bits<5> fs;
 395   bits<5> ft;
 396
 397   bits<32> Inst;
 398
 399   let Inst{31-26} = 0x13;
 400   let Inst{25-21} = fr;
 401   let Inst{20-16} = ft;
 402   let Inst{15-11} = fs;
 403   let Inst{10-6}  = fd;
 404   let Inst{5-3}   = funct;
 405   let Inst{2-0}   = fmt;
 406 }
 407
 408 class LWXC1_FM<bits<6> funct> {
 409   bits<5> fd;
 410   bits<5> base;
 411   bits<5> index;
 412
 413   bits<32> Inst;
 414
 415   let Inst{31-26} = 0x13;
 416   let Inst{25-21} = base;
 417   let Inst{20-16} = index;
 418   let Inst{15-11} = 0;
 419   let Inst{10-6}  = fd;
 420   let Inst{5-0}   = funct;
 421 }
 422
 423 class SWXC1_FM<bits<6> funct> {
 424   bits<5> fs;
 425   bits<5> base;
 426   bits<5> index;
 427
 428   bits<32> Inst;
 429
 430   let Inst{31-26} = 0x13;
 431   let Inst{25-21} = base;
 432   let Inst{20-16} = index;
 433   let Inst{15-11} = fs;
 434   let Inst{10-6}  = 0;
 435   let Inst{5-0}   = funct;
 436 }
 437
 438 class BC1F_FM<bit nd, bit tf> {
 439   bits<16> offset;
 440
 441   bits<32> Inst;
 442
 443   let Inst{31-26} = 0x11;
 444   let Inst{25-21} = 0x8;
 445   let Inst{20-18} = 0; // cc
 446   let Inst{17} = nd;
 447   let Inst{16} = tf;
 448   let Inst{15-0} = offset;
 449 }
 450
 451 class CEQS_FM<bits<5> fmt> {
 452   bits<5> fs;
 453   bits<5> ft;
 454   bits<4> cond;
 455
 456   bits<32> Inst;
 457
 458   let Inst{31-26} = 0x11;
 459   let Inst{25-21} = fmt;
 460   let Inst{20-16} = ft;
 461   let Inst{15-11} = fs;
 462   let Inst{10-8} = 0; // cc
 463   let Inst{7-4} = 0x3;
 464   let Inst{3-0} = cond;
 465 }
 466
 467 class CMov_I_F_FM<bits<6> funct, bits<5> fmt> {
 468   bits<5> fd;
 469   bits<5> fs;
 470   bits<5> rt;
 471
 472   bits<32> Inst;
 473
 474   let Inst{31-26} = 0x11;
 475   let Inst{25-21} = fmt;
 476   let Inst{20-16} = rt;
 477   let Inst{15-11} = fs;
 478   let Inst{10-6} = fd;
 479   let Inst{5-0} = funct;
 480 }
 481
 482 class CMov_F_I_FM<bit tf> {
 483   bits<5> rd;
 484   bits<5> rs;
 485
 486   bits<32> Inst;
 487
 488   let Inst{31-26} = 0;
 489   let Inst{25-21} = rs;
 490   let Inst{20-18} = 0; // cc
 491   let Inst{17} = 0;
 492   let Inst{16} = tf;
 493   let Inst{15-11} = rd;
 494   let Inst{10-6} = 0;
 495   let Inst{5-0} = 1;
 496 }
 497
 498 class CMov_F_F_FM<bits<5> fmt, bit tf> {
 499   bits<5> fd;
 500   bits<5> fs;
 501
 502   bits<32> Inst;
 503
 504   let Inst{31-26} = 0x11;
 505   let Inst{25-21} = fmt;
 506   let Inst{20-18} = 0; // cc
 507   let Inst{17} = 0;
 508   let Inst{16} = tf;
 509   let Inst{15-11} = fs;
 510   let Inst{10-6} = fd;
 511   let Inst{5-0} = 0x11;
 512 }