lib/Target/Mips/MipsInstrFormats.td

   1 //===-- MipsInstrFormats.td - Mips Instruction Formats -----*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 //  Describe MIPS instructions format
  12 //
  13 //  CPU INSTRUCTION FORMATS
  14 //
  15 //  opcode  - operation code.
  16 //  rs      - src reg.
  17 //  rt      - dst reg (on a 2 regs instr) or src reg (on a 3 reg instr).
  18 //  rd      - dst reg, only used on 3 regs instr.
  19 //  shamt   - only used on shift instructions, contains the shift amount.
  20 //  funct   - combined with opcode field give us an operation code.
  21 //
  22 //===----------------------------------------------------------------------===//
  23
  24 // Format specifies the encoding used by the instruction.  This is part of the
  25 // ad-hoc solution used to emit machine instruction encodings by our machine
  26 // code emitter.
  27 class Format<bits<4> val> {
  28   bits<4> Value = val;
  29 }
  30
  31 def Pseudo    : Format<0>;
  32 def FrmR      : Format<1>;
  33 def FrmI      : Format<2>;
  34 def FrmJ      : Format<3>;
  35 def FrmFR     : Format<4>;
  36 def FrmFI     : Format<5>;
  37 def FrmOther  : Format<6>; // Instruction w/ a custom format
  38
  39 // Generic Mips Format
  40 class MipsInst<dag outs, dag ins, string asmstr, list<dag> pattern,
  41                InstrItinClass itin, Format f>: Instruction
  42 {
  43   field bits<32> Inst;
  44   Format Form = f;
  45
  46   let Namespace = "Mips";
  47
  48   let Size = 4;
  49
  50   bits<6> Opcode = 0;
  51
  52   // Top 6 bits are the 'opcode' field
  53   let Inst{31-26} = Opcode;
  54
  55   let OutOperandList = outs;
  56   let InOperandList  = ins;
  57
  58   let AsmString   = asmstr;
  59   let Pattern     = pattern;
  60   let Itinerary   = itin;
  61
  62   //
  63   // Attributes specific to Mips instructions...
  64   //
  65   bits<4> FormBits = Form.Value;
  66
  67   // TSFlags layout should be kept in sync with MipsInstrInfo.h.
  68   let TSFlags{3-0}   = FormBits;
  69
  70   let DecoderNamespace = "Mips";
  71
  72   field bits<32> SoftFail = 0;
  73 }
  74
  75 // Mips32/64 Instruction Format
  76 class InstSE<dag outs, dag ins, string asmstr, list<dag> pattern,
  77              InstrItinClass itin, Format f>:
  78   MipsInst<outs, ins, asmstr, pattern, itin, f> {
  79   let Predicates = [HasStdEnc];
  80 }
  81
  82 // Mips Pseudo Instructions Format
  83 class MipsPseudo<dag outs, dag ins, string asmstr, list<dag> pattern>:
  84   MipsInst<outs, ins, asmstr, pattern, IIPseudo, Pseudo> {
  85   let isCodeGenOnly = 1;
  86   let isPseudo = 1;
  87 }
  88
  89 // Mips32/64 Pseudo Instruction Format
  90 class PseudoSE<dag outs, dag ins, string asmstr, list<dag> pattern>:
  91   MipsPseudo<outs, ins, asmstr, pattern> {
  92   let Predicates = [HasStdEnc];
  93 }
  94
  95 // Pseudo-instructions for alternate assembly syntax (never used by codegen).
  96 // These are aliases that require C++ handling to convert to the target
  97 // instruction, while InstAliases can be handled directly by tblgen.
  98 class MipsAsmPseudoInst<dag outs, dag ins, string asmstr>:
  99   MipsInst<outs, ins, asmstr, [], IIPseudo, Pseudo> {
 100   let isPseudo = 1;
 101   let Pattern = [];
 102 }
 103 //===----------------------------------------------------------------------===//
 104 // Format R instruction class in Mips : <|opcode|rs|rt|rd|shamt|funct|>
 105 //===----------------------------------------------------------------------===//
 106
 107 class FR<bits<6> op, bits<6> _funct, dag outs, dag ins, string asmstr,
 108          list<dag> pattern, InstrItinClass itin>:
 109   InstSE<outs, ins, asmstr, pattern, itin, FrmR>
 110 {
 111   bits<5>  rd;
 112   bits<5>  rs;
 113   bits<5>  rt;
 114   bits<5>  shamt;
 115   bits<6>  funct;
 116
 117   let Opcode = op;
 118   let funct  = _funct;
 119
 120   let Inst{25-21} = rs;
 121   let Inst{20-16} = rt;
 122   let Inst{15-11} = rd;
 123   let Inst{10-6}  = shamt;
 124   let Inst{5-0}   = funct;
 125 }
 126
 127 //===----------------------------------------------------------------------===//
 128 // Format I instruction class in Mips : <|opcode|rs|rt|immediate|>
 129 //===----------------------------------------------------------------------===//
 130
 131 class FI<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
 132          InstrItinClass itin>: InstSE<outs, ins, asmstr, pattern, itin, FrmI>
 133 {
 134   bits<5>  rt;
 135   bits<5>  rs;
 136   bits<16> imm16;
 137
 138   let Opcode = op;
 139
 140   let Inst{25-21} = rs;
 141   let Inst{20-16} = rt;
 142   let Inst{15-0}  = imm16;
 143 }
 144
 145 class BranchBase<bits<6> op, dag outs, dag ins, string asmstr,
 146                   list<dag> pattern, InstrItinClass itin>:
 147   InstSE<outs, ins, asmstr, pattern, itin, FrmI>
 148 {
 149   bits<5>  rs;
 150   bits<5>  rt;
 151   bits<16> imm16;
 152
 153   let Opcode = op;
 154
 155   let Inst{25-21} = rs;
 156   let Inst{20-16} = rt;
 157   let Inst{15-0}  = imm16;
 158 }
 159
 160 //===----------------------------------------------------------------------===//
 161 // Format J instruction class in Mips : <|opcode|address|>
 162 //===----------------------------------------------------------------------===//
 163
 164 class FJ<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern,
 165          InstrItinClass itin>: InstSE<outs, ins, asmstr, pattern, itin, FrmJ>
 166 {
 167   bits<26> addr;
 168
 169   let Opcode = op;
 170
 171   let Inst{25-0} = addr;
 172 }
 173
 174  //===----------------------------------------------------------------------===//
 175 // MFC instruction class in Mips : <|op|mf|rt|rd|0000000|sel|>
 176 //===----------------------------------------------------------------------===//
 177 class MFC3OP<bits<6> op, bits<5> _mfmt, dag outs, dag ins, string asmstr>:
 178   InstSE<outs, ins, asmstr, [], NoItinerary, FrmFR>
 179 {
 180   bits<5> mfmt;
 181   bits<5> rt;
 182   bits<5> rd;
 183   bits<3> sel;
 184
 185   let Opcode = op;
 186   let mfmt = _mfmt;
 187
 188   let Inst{25-21} = mfmt;
 189   let Inst{20-16} = rt;
 190   let Inst{15-11} = rd;
 191   let Inst{10-3}  = 0;
 192   let Inst{2-0}   = sel;
 193 }
 194
 195 class ADD_FM<bits<6> op, bits<6> funct> {
 196   bits<5> rd;
 197   bits<5> rs;
 198   bits<5> rt;
 199
 200   bits<32> Inst;
 201
 202   let Inst{31-26} = op;
 203   let Inst{25-21} = rs;
 204   let Inst{20-16} = rt;
 205   let Inst{15-11} = rd;
 206   let Inst{10-6}  = 0;
 207   let Inst{5-0}   = funct;
 208 }
 209
 210 class ADDI_FM<bits<6> op> {
 211   bits<5>  rs;
 212   bits<5>  rt;
 213   bits<16> imm16;
 214
 215   bits<32> Inst;
 216
 217   let Inst{31-26} = op;
 218   let Inst{25-21} = rs;
 219   let Inst{20-16} = rt;
 220   let Inst{15-0}  = imm16;
 221 }
 222
 223 class SRA_FM<bits<6> funct, bit rotate> {
 224   bits<5> rd;
 225   bits<5> rt;
 226   bits<5> shamt;
 227
 228   bits<32> Inst;
 229
 230   let Inst{31-26} = 0;
 231   let Inst{25-22} = 0;
 232   let Inst{21}    = rotate;
 233   let Inst{20-16} = rt;
 234   let Inst{15-11} = rd;
 235   let Inst{10-6}  = shamt;
 236   let Inst{5-0}   = funct;
 237 }
 238
 239 class SRLV_FM<bits<6> funct, bit rotate> {
 240   bits<5> rd;
 241   bits<5> rt;
 242   bits<5> rs;
 243
 244   bits<32> Inst;
 245
 246   let Inst{31-26} = 0;
 247   let Inst{25-21} = rs;
 248   let Inst{20-16} = rt;
 249   let Inst{15-11} = rd;
 250   let Inst{10-7}  = 0;
 251   let Inst{6}     = rotate;
 252   let Inst{5-0}   = funct;
 253 }
 254
 255 //===----------------------------------------------------------------------===//
 256 //
 257 //  FLOATING POINT INSTRUCTION FORMATS
 258 //
 259 //  opcode  - operation code.
 260 //  fs      - src reg.
 261 //  ft      - dst reg (on a 2 regs instr) or src reg (on a 3 reg instr).
 262 //  fd      - dst reg, only used on 3 regs instr.
 263 //  fmt     - double or single precision.
 264 //  funct   - combined with opcode field give us an operation code.
 265 //
 266 //===----------------------------------------------------------------------===//
 267
 268 //===----------------------------------------------------------------------===//
 269 // Format FI instruction class in Mips : <|opcode|base|ft|immediate|>
 270 //===----------------------------------------------------------------------===//
 271
 272 class FFI<bits<6> op, dag outs, dag ins, string asmstr, list<dag> pattern>:
 273   InstSE<outs, ins, asmstr, pattern, NoItinerary, FrmFI>
 274 {
 275   bits<5>  ft;
 276   bits<5>  base;
 277   bits<16> imm16;
 278
 279   let Opcode = op;
 280
 281   let Inst{25-21} = base;
 282   let Inst{20-16} = ft;
 283   let Inst{15-0}  = imm16;
 284 }
 285
 286 class ADDS_FM<bits<6> funct, bits<5> fmt> {
 287   bits<5> fd;
 288   bits<5> fs;
 289   bits<5> ft;
 290
 291   bits<32> Inst;
 292
 293   let Inst{31-26} = 0x11;
 294   let Inst{25-21} = fmt;
 295   let Inst{20-16} = ft;
 296   let Inst{15-11} = fs;
 297   let Inst{10-6}  = fd;
 298   let Inst{5-0}   = funct;
 299 }
 300
 301 class ABSS_FM<bits<6> funct, bits<5> fmt> {
 302   bits<5> fd;
 303   bits<5> fs;
 304
 305   bits<32> Inst;
 306
 307   let Inst{31-26} = 0x11;
 308   let Inst{25-21} = fmt;
 309   let Inst{20-16} = 0;
 310   let Inst{15-11} = fs;
 311   let Inst{10-6}  = fd;
 312   let Inst{5-0}   = funct;
 313 }
 314
 315 class MFC1_FM<bits<5> funct> {
 316   bits<5> rt;
 317   bits<5> fs;
 318
 319   bits<32> Inst;
 320
 321   let Inst{31-26} = 0x11;
 322   let Inst{25-21} = funct;
 323   let Inst{20-16} = rt;
 324   let Inst{15-11} = fs;
 325   let Inst{10-0}  = 0;
 326 }
 327
 328 class LW_FM<bits<6> op> {
 329   bits<5> rt;
 330   bits<21> addr;
 331
 332   bits<32> Inst;
 333
 334   let Inst{31-26} = op;
 335   let Inst{25-21} = addr{20-16};
 336   let Inst{20-16} = rt;
 337   let Inst{15-0}  = addr{15-0};
 338 }
 339
 340 class MADDS_FM<bits<3> funct, bits<3> fmt> {
 341   bits<5> fd;
 342   bits<5> fr;
 343   bits<5> fs;
 344   bits<5> ft;
 345
 346   bits<32> Inst;
 347
 348   let Inst{31-26} = 0x13;
 349   let Inst{25-21} = fr;
 350   let Inst{20-16} = ft;
 351   let Inst{15-11} = fs;
 352   let Inst{10-6}  = fd;
 353   let Inst{5-3}   = funct;
 354   let Inst{2-0}   = fmt;
 355 }
 356
 357 class LWXC1_FM<bits<6> funct> {
 358   bits<5> fd;
 359   bits<5> base;
 360   bits<5> index;
 361
 362   bits<32> Inst;
 363
 364   let Inst{31-26} = 0x13;
 365   let Inst{25-21} = base;
 366   let Inst{20-16} = index;
 367   let Inst{15-11} = 0;
 368   let Inst{10-6}  = fd;
 369   let Inst{5-0}   = funct;
 370 }
 371
 372 class SWXC1_FM<bits<6> funct> {
 373   bits<5> fs;
 374   bits<5> base;
 375   bits<5> index;
 376
 377   bits<32> Inst;
 378
 379   let Inst{31-26} = 0x13;
 380   let Inst{25-21} = base;
 381   let Inst{20-16} = index;
 382   let Inst{15-11} = fs;
 383   let Inst{10-6}  = 0;
 384   let Inst{5-0}   = funct;
 385 }
 386
 387 class BC1F_FM<bit nd, bit tf> {
 388   bits<16> offset;
 389
 390   bits<32> Inst;
 391
 392   let Inst{31-26} = 0x11;
 393   let Inst{25-21} = 0x8;
 394   let Inst{20-18} = 0; // cc
 395   let Inst{17} = nd;
 396   let Inst{16} = tf;
 397   let Inst{15-0} = offset;
 398 }
 399
 400 class CEQS_FM<bits<5> fmt> {
 401   bits<5> fs;
 402   bits<5> ft;
 403   bits<4> cond;
 404
 405   bits<32> Inst;
 406
 407   let Inst{31-26} = 0x11;
 408   let Inst{25-21} = fmt;
 409   let Inst{20-16} = ft;
 410   let Inst{15-11} = fs;
 411   let Inst{10-8} = 0; // cc
 412   let Inst{7-4} = 0x3;
 413   let Inst{3-0} = cond;
 414 }
 415
 416 class CMov_I_F_FM<bits<6> funct, bits<5> fmt> {
 417   bits<5> fd;
 418   bits<5> fs;
 419   bits<5> rt;
 420
 421   bits<32> Inst;
 422
 423   let Inst{31-26} = 0x11;
 424   let Inst{25-21} = fmt;
 425   let Inst{20-16} = rt;
 426   let Inst{15-11} = fs;
 427   let Inst{10-6} = fd;
 428   let Inst{5-0} = funct;
 429 }
 430
 431 class CMov_F_I_FM<bit tf> {
 432   bits<5> rd;
 433   bits<5> rs;
 434
 435   bits<32> Inst;
 436
 437   let Inst{31-26} = 0;
 438   let Inst{25-21} = rs;
 439   let Inst{20-18} = 0; // cc
 440   let Inst{17} = 0;
 441   let Inst{16} = tf;
 442   let Inst{15-11} = rd;
 443   let Inst{10-6} = 0;
 444   let Inst{5-0} = 1;
 445 }
 446
 447 class CMov_F_F_FM<bits<5> fmt, bit tf> {
 448   bits<5> fd;
 449   bits<5> fs;
 450
 451   bits<32> Inst;
 452
 453   let Inst{31-26} = 0x11;
 454   let Inst{25-21} = fmt;
 455   let Inst{20-18} = 0; // cc
 456   let Inst{17} = 0;
 457   let Inst{16} = tf;
 458   let Inst{15-11} = fs;
 459   let Inst{10-6} = fd;
 460   let Inst{5-0} = 0x11;
 461 }