lib/Target/PowerPC/PPCCallingConv.td

   1 //===- PPCCallingConv.td - Calling Conventions for PowerPC -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This describes the calling conventions for the PowerPC 32- and 64-bit
  11 // architectures.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  16 class CCIfSubtarget<string F, CCAction A>
  17  : CCIf<!strconcat("State.getTarget().getSubtarget<PPCSubtarget>().", F), A>;
  18
  19 //===----------------------------------------------------------------------===//
  20 // Return Value Calling Convention
  21 //===----------------------------------------------------------------------===//
  22
  23 // Return-value convention for PowerPC
  24 def RetCC_PPC : CallingConv<[
  25   // On PPC64, integer return values are always promoted to i64
  26   CCIfType<[i32], CCIfSubtarget<"isPPC64()", CCPromoteToType<i64>>>,
  27
  28   CCIfType<[i32], CCAssignToReg<[R3, R4, R5, R6, R7, R8, R9, R10]>>,
  29   CCIfType<[i64], CCAssignToReg<[X3, X4, X5, X6]>>,
  30   CCIfType<[i128], CCAssignToReg<[X3, X4, X5, X6]>>,
  31
  32   CCIfType<[f32], CCAssignToReg<[F1, F2]>>,
  33   CCIfType<[f64], CCAssignToReg<[F1, F2, F3, F4]>>,
  34
  35   // Vector types are always returned in V2.
  36   CCIfType<[v16i8, v8i16, v4i32, v4f32], CCAssignToReg<[V2]>>
  37 ]>;
  38
  39
  40 // Note that we don't currently have calling conventions for 64-bit
  41 // PowerPC, but handle all the complexities of the ABI in the lowering
  42 // logic.  FIXME: See if the logic can be simplified with use of CCs.
  43 // This may require some extensions to current table generation.
  44
  45 // Simple return-value convention for 64-bit ELF PowerPC fast isel.
  46 // All small ints are promoted to i64.  Vector types, quadword ints,
  47 // and multiple register returns are "supported" to avoid compile
  48 // errors, but none are handled by the fast selector.
  49 def RetCC_PPC64_ELF_FIS : CallingConv<[
  50   CCIfType<[i8],   CCPromoteToType<i64>>,
  51   CCIfType<[i16],  CCPromoteToType<i64>>,
  52   CCIfType<[i32],  CCPromoteToType<i64>>,
  53   CCIfType<[i64],  CCAssignToReg<[X3, X4]>>,
  54   CCIfType<[i128], CCAssignToReg<[X3, X4, X5, X6]>>,
  55   CCIfType<[f32],  CCAssignToReg<[F1, F2]>>,
  56   CCIfType<[f64],  CCAssignToReg<[F1, F2, F3, F4]>>,
  57   CCIfType<[v16i8, v8i16, v4i32, v4f32], CCAssignToReg<[V2]>>
  58 ]>;
  59
  60 //===----------------------------------------------------------------------===//
  61 // PowerPC System V Release 4 32-bit ABI
  62 //===----------------------------------------------------------------------===//
  63
  64 def CC_PPC32_SVR4_Common : CallingConv<[
  65   // The ABI requires i64 to be passed in two adjacent registers with the first
  66   // register having an odd register number.
  67   CCIfType<[i32], CCIfSplit<CCCustom<"CC_PPC32_SVR4_Custom_AlignArgRegs">>>,
  68
  69   // The first 8 integer arguments are passed in integer registers.
  70   CCIfType<[i32], CCAssignToReg<[R3, R4, R5, R6, R7, R8, R9, R10]>>,
  71
  72   // Make sure the i64 words from a long double are either both passed in
  73   // registers or both passed on the stack.
  74   CCIfType<[f64], CCIfSplit<CCCustom<"CC_PPC32_SVR4_Custom_AlignFPArgRegs">>>,
  75
  76   // FP values are passed in F1 - F8.
  77   CCIfType<[f32, f64], CCAssignToReg<[F1, F2, F3, F4, F5, F6, F7, F8]>>,
  78
  79   // Split arguments have an alignment of 8 bytes on the stack.
  80   CCIfType<[i32], CCIfSplit<CCAssignToStack<4, 8>>>,
  81
  82   CCIfType<[i32], CCAssignToStack<4, 4>>,
  83
  84   // Floats are stored in double precision format, thus they have the same
  85   // alignment and size as doubles.
  86   CCIfType<[f32,f64], CCAssignToStack<8, 8>>,
  87
  88   // Vectors get 16-byte stack slots that are 16-byte aligned.
  89   CCIfType<[v16i8, v8i16, v4i32, v4f32], CCAssignToStack<16, 16>>
  90 ]>;
  91
  92 // This calling convention puts vector arguments always on the stack. It is used
  93 // to assign vector arguments which belong to the variable portion of the
  94 // parameter list of a variable argument function.
  95 def CC_PPC32_SVR4_VarArg : CallingConv<[
  96   CCDelegateTo<CC_PPC32_SVR4_Common>
  97 ]>;
  98
  99 // In contrast to CC_PPC32_SVR4_VarArg, this calling convention first tries to
 100 // put vector arguments in vector registers before putting them on the stack.
 101 def CC_PPC32_SVR4 : CallingConv<[
 102   // The first 12 Vector arguments are passed in AltiVec registers.
 103   CCIfType<[v16i8, v8i16, v4i32, v4f32],
 104            CCAssignToReg<[V2, V3, V4, V5, V6, V7, V8, V9, V10, V11, V12, V13]>>,
 105
 106   CCDelegateTo<CC_PPC32_SVR4_Common>
 107 ]>;
 108
 109 // Helper "calling convention" to handle aggregate by value arguments.
 110 // Aggregate by value arguments are always placed in the local variable space
 111 // of the caller. This calling convention is only used to assign those stack
 112 // offsets in the callers stack frame.
 113 //
 114 // Still, the address of the aggregate copy in the callers stack frame is passed
 115 // in a GPR (or in the parameter list area if all GPRs are allocated) from the
 116 // caller to the callee. The location for the address argument is assigned by
 117 // the CC_PPC32_SVR4 calling convention.
 118 //
 119 // The only purpose of CC_PPC32_SVR4_Custom_Dummy is to skip arguments which are
 120 // not passed by value.
 121
 122 def CC_PPC32_SVR4_ByVal : CallingConv<[
 123   CCIfByVal<CCPassByVal<4, 4>>,
 124
 125   CCCustom<"CC_PPC32_SVR4_Custom_Dummy">
 126 ]>;
 127
 128 def CSR_Altivec : CalleeSavedRegs<(add V20, V21, V22, V23, V24, V25, V26, V27,
 129                                        V28, V29, V30, V31)>;
 130
 131 def CSR_Darwin32 : CalleeSavedRegs<(add R13, R14, R15, R16, R17, R18, R19, R20,
 132                                         R21, R22, R23, R24, R25, R26, R27, R28,
 133                                         R29, R30, R31, F14, F15, F16, F17, F18,
 134                                         F19, F20, F21, F22, F23, F24, F25, F26,
 135                                         F27, F28, F29, F30, F31, CR2, CR3, CR4
 136                                    )>;
 137
 138 def CSR_Darwin32_Altivec : CalleeSavedRegs<(add CSR_Darwin32, CSR_Altivec)>;
 139
 140 def CSR_SVR432   : CalleeSavedRegs<(add R14, R15, R16, R17, R18, R19, R20,
 141                                         R21, R22, R23, R24, R25, R26, R27, R28,
 142                                         R29, R30, R31, F14, F15, F16, F17, F18,
 143                                         F19, F20, F21, F22, F23, F24, F25, F26,
 144                                         F27, F28, F29, F30, F31, CR2, CR3, CR4
 145                                    )>;
 146
 147 def CSR_SVR432_Altivec : CalleeSavedRegs<(add CSR_SVR432, CSR_Altivec)>;
 148
 149 def CSR_Darwin64 : CalleeSavedRegs<(add X13, X14, X15, X16, X17, X18, X19, X20,
 150                                         X21, X22, X23, X24, X25, X26, X27, X28,
 151                                         X29, X30, X31, F14, F15, F16, F17, F18,
 152                                         F19, F20, F21, F22, F23, F24, F25, F26,
 153                                         F27, F28, F29, F30, F31, CR2, CR3, CR4
 154                                    )>;
 155
 156 def CSR_Darwin64_Altivec : CalleeSavedRegs<(add CSR_Darwin64, CSR_Altivec)>;
 157
 158 def CSR_SVR464   : CalleeSavedRegs<(add X14, X15, X16, X17, X18, X19, X20,
 159                                         X21, X22, X23, X24, X25, X26, X27, X28,
 160                                         X29, X30, X31, F14, F15, F16, F17, F18,
 161                                         F19, F20, F21, F22, F23, F24, F25, F26,
 162                                         F27, F28, F29, F30, F31, CR2, CR3, CR4
 163                                    )>;
 164
 165
 166 def CSR_SVR464_Altivec : CalleeSavedRegs<(add CSR_SVR464, CSR_Altivec)>;
 167
 168 def CSR_NoRegs : CalleeSavedRegs<(add)>;
 169