lib/Target/PowerPC/PPCInstr64Bit.td

   1 //===- PPCInstr64Bit.td - The PowerPC 64-bit Support -------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by Chris Lattner and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the PowerPC 64-bit instructions.  These patterns are used
  11 // both when in ppc64 mode and when in "use 64-bit extensions in 32-bit" mode.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // 64-bit operands.
  17 //
  18 def s16imm64 : Operand<i64> {
  19   let PrintMethod = "printS16ImmOperand";
  20 }
  21 def u16imm64 : Operand<i64> {
  22   let PrintMethod = "printU16ImmOperand";
  23 }
  24 def symbolHi64 : Operand<i64> {
  25   let PrintMethod = "printSymbolHi";
  26 }
  27 def symbolLo64 : Operand<i64> {
  28   let PrintMethod = "printSymbolLo";
  29 }
  30
  31 //===----------------------------------------------------------------------===//
  32 // 64-bit transformation functions.
  33 //
  34
  35 def SHL64 : SDNodeXForm<imm, [{
  36   // Transformation function: 63 - imm
  37   return getI32Imm(63 - N->getValue());
  38 }]>;
  39
  40 def SRL64 : SDNodeXForm<imm, [{
  41   // Transformation function: 64 - imm
  42   return N->getValue() ? getI32Imm(64 - N->getValue()) : getI32Imm(0);
  43 }]>;
  44
  45 def HI32_48 : SDNodeXForm<imm, [{
  46   // Transformation function: shift the immediate value down into the low bits.
  47   return getI32Imm((unsigned short)(N->getValue() >> 32));
  48 }]>;
  49
  50 def HI48_64 : SDNodeXForm<imm, [{
  51   // Transformation function: shift the immediate value down into the low bits.
  52   return getI32Imm((unsigned short)(N->getValue() >> 48));
  53 }]>;
  54
  55
  56 //===----------------------------------------------------------------------===//
  57 // Pseudo instructions.
  58 //
  59
  60 def IMPLICIT_DEF_G8RC : Pseudo<(ops G8RC:$rD), "; IMPLICIT_DEF_G8RC $rD",
  61                               [(set G8RC:$rD, (undef))]>;
  62
  63
  64 //===----------------------------------------------------------------------===//
  65 // Calls.
  66 //
  67
  68 let Defs = [LR8] in
  69   def MovePCtoLR8 : Pseudo<(ops piclabel:$label), "bl $label", []>,
  70                     PPC970_Unit_BRU;
  71
  72 // Macho ABI Calls.
  73 let isCall = 1, noResults = 1, PPC970_Unit = 7,
  74   // All calls clobber the PPC64 non-callee saved registers.
  75   Defs = [X0,X2,X3,X4,X5,X6,X7,X8,X9,X10,X11,X12,
  76           F0,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12,F13,
  77           V0,V1,V2,V3,V4,V5,V6,V7,V8,V9,V10,V11,V12,V13,V14,V15,V16,V17,V18,V19,
  78           LR8,CTR8,
  79           CR0,CR1,CR5,CR6,CR7] in {
  80   // Convenient aliases for call instructions
  81   def BL8_Macho  : IForm<18, 0, 1,
  82                          (ops calltarget:$func, variable_ops),
  83                          "bl $func", BrB, []>;  // See Pat patterns below.
  84
  85   def BLA8_Macho : IForm<18, 1, 1,
  86                          (ops aaddr:$func, variable_ops),
  87                          "bla $func", BrB, [(PPCcall_Macho (i64 imm:$func))]>;
  88 }
  89
  90 // ELF 64 ABI Calls = Macho ABI Calls
  91 // Used to define BL8_ELF and BLA8_ELF
  92 let isCall = 1, noResults = 1, PPC970_Unit = 7,
  93   // All calls clobber the PPC64 non-callee saved registers.
  94   Defs = [X0,X2,X3,X4,X5,X6,X7,X8,X9,X10,X11,X12,
  95           F0,F1,F2,F3,F4,F5,F6,F7,F8,F9,F10,F11,F12,F13,
  96           V0,V1,V2,V3,V4,V5,V6,V7,V8,V9,V10,V11,V12,V13,V14,V15,V16,V17,V18,V19,
  97           LR8,CTR8,
  98           CR0,CR1,CR5,CR6,CR7] in {
  99   // Convenient aliases for call instructions
 100   def BL8_ELF  : IForm<18, 0, 1,
 101                        (ops calltarget:$func, variable_ops),
 102                        "bl $func", BrB, []>;  // See Pat patterns below.
 103
 104   def BLA8_ELF : IForm<18, 1, 1,
 105                        (ops aaddr:$func, variable_ops),
 106                        "bla $func", BrB, [(PPCcall_ELF (i64 imm:$func))]>;
 107 }
 108
 109
 110 // Calls
 111 def : Pat<(PPCcall_Macho (i64 tglobaladdr:$dst)),
 112           (BL8_Macho tglobaladdr:$dst)>;
 113 def : Pat<(PPCcall_Macho (i64 texternalsym:$dst)),
 114           (BL8_Macho texternalsym:$dst)>;
 115
 116 def : Pat<(PPCcall_ELF (i64 tglobaladdr:$dst)),
 117           (BL8_ELF tglobaladdr:$dst)>;
 118 def : Pat<(PPCcall_ELF (i64 texternalsym:$dst)),
 119           (BL8_ELF texternalsym:$dst)>;
 120
 121 //===----------------------------------------------------------------------===//
 122 // 64-bit SPR manipulation instrs.
 123
 124 def MFCTR8 : XFXForm_1_ext<31, 339, 9, (ops G8RC:$rT), "mfctr $rT", SprMFSPR>,
 125              PPC970_DGroup_First, PPC970_Unit_FXU;
 126 let Pattern = [(PPCmtctr G8RC:$rS)] in {
 127 def MTCTR8 : XFXForm_7_ext<31, 467, 9, (ops G8RC:$rS), "mtctr $rS", SprMTSPR>,
 128              PPC970_DGroup_First, PPC970_Unit_FXU;
 129 }
 130
 131 def DYNALLOC8 : Pseudo<(ops G8RC:$result, G8RC:$negsize, memri:$fpsi),
 132                        "${:comment} DYNALLOC8 $result, $negsize, $fpsi",
 133                        [(set G8RC:$result,
 134                              (PPCdynalloc G8RC:$negsize, iaddr:$fpsi))]>,
 135                         Imp<[X1],[X1]>;
 136
 137 def MTLR8  : XFXForm_7_ext<31, 467, 8, (ops G8RC:$rS), "mtlr $rS", SprMTSPR>,
 138              PPC970_DGroup_First, PPC970_Unit_FXU;
 139 def MFLR8  : XFXForm_1_ext<31, 339, 8, (ops G8RC:$rT), "mflr $rT", SprMFSPR>,
 140              PPC970_DGroup_First, PPC970_Unit_FXU;
 141
 142
 143 //===----------------------------------------------------------------------===//
 144 // Fixed point instructions.
 145 //
 146
 147 let PPC970_Unit = 1 in {  // FXU Operations.
 148
 149 // Copies, extends, truncates.
 150 def OR4To8  : XForm_6<31, 444, (ops G8RC:$rA, GPRC:$rS, GPRC:$rB),
 151                    "or $rA, $rS, $rB", IntGeneral,
 152                    []>;
 153 def OR8To4  : XForm_6<31, 444, (ops GPRC:$rA, G8RC:$rS, G8RC:$rB),
 154                    "or $rA, $rS, $rB", IntGeneral,
 155                    []>;
 156
 157 def LI8  : DForm_2_r0<14, (ops G8RC:$rD, symbolLo64:$imm),
 158                       "li $rD, $imm", IntGeneral,
 159                       [(set G8RC:$rD, immSExt16:$imm)]>;
 160 def LIS8 : DForm_2_r0<15, (ops G8RC:$rD, symbolHi64:$imm),
 161                       "lis $rD, $imm", IntGeneral,
 162                       [(set G8RC:$rD, imm16ShiftedSExt:$imm)]>;
 163
 164 // Logical ops.
 165 def NAND8: XForm_6<31, 476, (ops G8RC:$rA, G8RC:$rS, G8RC:$rB),
 166                    "nand $rA, $rS, $rB", IntGeneral,
 167                    [(set G8RC:$rA, (not (and G8RC:$rS, G8RC:$rB)))]>;
 168 def AND8 : XForm_6<31,  28, (ops G8RC:$rA, G8RC:$rS, G8RC:$rB),
 169                    "and $rA, $rS, $rB", IntGeneral,
 170                    [(set G8RC:$rA, (and G8RC:$rS, G8RC:$rB))]>;
 171 def ANDC8: XForm_6<31,  60, (ops G8RC:$rA, G8RC:$rS, G8RC:$rB),
 172                    "andc $rA, $rS, $rB", IntGeneral,
 173                    [(set G8RC:$rA, (and G8RC:$rS, (not G8RC:$rB)))]>;
 174 def OR8  : XForm_6<31, 444, (ops G8RC:$rA, G8RC:$rS, G8RC:$rB),
 175                    "or $rA, $rS, $rB", IntGeneral,
 176                    [(set G8RC:$rA, (or G8RC:$rS, G8RC:$rB))]>;
 177 def NOR8 : XForm_6<31, 124, (ops G8RC:$rA, G8RC:$rS, G8RC:$rB),
 178                    "nor $rA, $rS, $rB", IntGeneral,
 179                    [(set G8RC:$rA, (not (or G8RC:$rS, G8RC:$rB)))]>;
 180 def ORC8 : XForm_6<31, 412, (ops G8RC:$rA, G8RC:$rS, G8RC:$rB),
 181                    "orc $rA, $rS, $rB", IntGeneral,
 182                    [(set G8RC:$rA, (or G8RC:$rS, (not G8RC:$rB)))]>;
 183 def EQV8 : XForm_6<31, 284, (ops G8RC:$rA, G8RC:$rS, G8RC:$rB),
 184                    "eqv $rA, $rS, $rB", IntGeneral,
 185                    [(set G8RC:$rA, (not (xor G8RC:$rS, G8RC:$rB)))]>;
 186 def XOR8 : XForm_6<31, 316, (ops G8RC:$rA, G8RC:$rS, G8RC:$rB),
 187                    "xor $rA, $rS, $rB", IntGeneral,
 188                    [(set G8RC:$rA, (xor G8RC:$rS, G8RC:$rB))]>;
 189
 190 // Logical ops with immediate.
 191 def ANDIo8  : DForm_4<28, (ops G8RC:$dst, G8RC:$src1, u16imm:$src2),
 192                       "andi. $dst, $src1, $src2", IntGeneral,
 193                       [(set G8RC:$dst, (and G8RC:$src1, immZExt16:$src2))]>,
 194                       isDOT;
 195 def ANDISo8 : DForm_4<29, (ops G8RC:$dst, G8RC:$src1, u16imm:$src2),
 196                      "andis. $dst, $src1, $src2", IntGeneral,
 197                     [(set G8RC:$dst, (and G8RC:$src1,imm16ShiftedZExt:$src2))]>,
 198                      isDOT;
 199 def ORI8    : DForm_4<24, (ops G8RC:$dst, G8RC:$src1, u16imm:$src2),
 200                       "ori $dst, $src1, $src2", IntGeneral,
 201                       [(set G8RC:$dst, (or G8RC:$src1, immZExt16:$src2))]>;
 202 def ORIS8   : DForm_4<25, (ops G8RC:$dst, G8RC:$src1, u16imm:$src2),
 203                       "oris $dst, $src1, $src2", IntGeneral,
 204                     [(set G8RC:$dst, (or G8RC:$src1, imm16ShiftedZExt:$src2))]>;
 205 def XORI8   : DForm_4<26, (ops G8RC:$dst, G8RC:$src1, u16imm:$src2),
 206                       "xori $dst, $src1, $src2", IntGeneral,
 207                       [(set G8RC:$dst, (xor G8RC:$src1, immZExt16:$src2))]>;
 208 def XORIS8  : DForm_4<27, (ops G8RC:$dst, G8RC:$src1, u16imm:$src2),
 209                       "xoris $dst, $src1, $src2", IntGeneral,
 210                    [(set G8RC:$dst, (xor G8RC:$src1, imm16ShiftedZExt:$src2))]>;
 211
 212 def ADD8  : XOForm_1<31, 266, 0, (ops G8RC:$rT, G8RC:$rA, G8RC:$rB),
 213                      "add $rT, $rA, $rB", IntGeneral,
 214                      [(set G8RC:$rT, (add G8RC:$rA, G8RC:$rB))]>;
 215 def ADDI8  : DForm_2<14, (ops G8RC:$rD, G8RC:$rA, s16imm64:$imm),
 216                      "addi $rD, $rA, $imm", IntGeneral,
 217                      [(set G8RC:$rD, (add G8RC:$rA, immSExt16:$imm))]>;
 218 def ADDIS8 : DForm_2<15, (ops G8RC:$rD, G8RC:$rA, symbolHi64:$imm),
 219                      "addis $rD, $rA, $imm", IntGeneral,
 220                      [(set G8RC:$rD, (add G8RC:$rA, imm16ShiftedSExt:$imm))]>;
 221
 222 def SUBFIC8: DForm_2< 8, (ops G8RC:$rD, G8RC:$rA, s16imm64:$imm),
 223                      "subfic $rD, $rA, $imm", IntGeneral,
 224                      [(set G8RC:$rD, (subc immSExt16:$imm, G8RC:$rA))]>;
 225 def SUBF8 : XOForm_1<31, 40, 0, (ops G8RC:$rT, G8RC:$rA, G8RC:$rB),
 226                      "subf $rT, $rA, $rB", IntGeneral,
 227                      [(set G8RC:$rT, (sub G8RC:$rB, G8RC:$rA))]>;
 228
 229
 230 def MULHD : XOForm_1<31, 73, 0, (ops G8RC:$rT, G8RC:$rA, G8RC:$rB),
 231                      "mulhd $rT, $rA, $rB", IntMulHW,
 232                      [(set G8RC:$rT, (mulhs G8RC:$rA, G8RC:$rB))]>;
 233 def MULHDU : XOForm_1<31, 9, 0, (ops G8RC:$rT, G8RC:$rA, G8RC:$rB),
 234                      "mulhdu $rT, $rA, $rB", IntMulHWU,
 235                      [(set G8RC:$rT, (mulhu G8RC:$rA, G8RC:$rB))]>;
 236
 237 def CMPD   : XForm_16_ext<31, 0, (ops CRRC:$crD, G8RC:$rA, G8RC:$rB),
 238                           "cmpd $crD, $rA, $rB", IntCompare>, isPPC64;
 239 def CMPLD  : XForm_16_ext<31, 32, (ops CRRC:$crD, G8RC:$rA, G8RC:$rB),
 240                           "cmpld $crD, $rA, $rB", IntCompare>, isPPC64;
 241 def CMPDI  : DForm_5_ext<11, (ops CRRC:$crD, G8RC:$rA, s16imm:$imm),
 242                          "cmpdi $crD, $rA, $imm", IntCompare>, isPPC64;
 243 def CMPLDI : DForm_6_ext<10, (ops CRRC:$dst, G8RC:$src1, u16imm:$src2),
 244                          "cmpldi $dst, $src1, $src2", IntCompare>, isPPC64;
 245
 246 def SLD  : XForm_6<31,  27, (ops G8RC:$rA, G8RC:$rS, GPRC:$rB),
 247                    "sld $rA, $rS, $rB", IntRotateD,
 248                    [(set G8RC:$rA, (shl G8RC:$rS, GPRC:$rB))]>, isPPC64;
 249 def SRD  : XForm_6<31, 539, (ops G8RC:$rA, G8RC:$rS, GPRC:$rB),
 250                    "srd $rA, $rS, $rB", IntRotateD,
 251                    [(set G8RC:$rA, (srl G8RC:$rS, GPRC:$rB))]>, isPPC64;
 252 def SRAD : XForm_6<31, 794, (ops G8RC:$rA, G8RC:$rS, GPRC:$rB),
 253                    "srad $rA, $rS, $rB", IntRotateD,
 254                    [(set G8RC:$rA, (sra G8RC:$rS, GPRC:$rB))]>, isPPC64;
 255
 256 def EXTSB8 : XForm_11<31, 954, (ops G8RC:$rA, G8RC:$rS),
 257                       "extsb $rA, $rS", IntGeneral,
 258                       [(set G8RC:$rA, (sext_inreg G8RC:$rS, i8))]>;
 259 def EXTSH8 : XForm_11<31, 922, (ops G8RC:$rA, G8RC:$rS),
 260                       "extsh $rA, $rS", IntGeneral,
 261                       [(set G8RC:$rA, (sext_inreg G8RC:$rS, i16))]>;
 262
 263 def EXTSW  : XForm_11<31, 986, (ops G8RC:$rA, G8RC:$rS),
 264                       "extsw $rA, $rS", IntGeneral,
 265                       [(set G8RC:$rA, (sext_inreg G8RC:$rS, i32))]>, isPPC64;
 266 /// EXTSW_32 - Just like EXTSW, but works on '32-bit' registers.
 267 def EXTSW_32 : XForm_11<31, 986, (ops GPRC:$rA, GPRC:$rS),
 268                       "extsw $rA, $rS", IntGeneral,
 269                       [(set GPRC:$rA, (PPCextsw_32 GPRC:$rS))]>, isPPC64;
 270 def EXTSW_32_64 : XForm_11<31, 986, (ops G8RC:$rA, GPRC:$rS),
 271                       "extsw $rA, $rS", IntGeneral,
 272                       [(set G8RC:$rA, (sext GPRC:$rS))]>, isPPC64;
 273
 274 def SRADI  : XSForm_1<31, 413, (ops G8RC:$rA, G8RC:$rS, u6imm:$SH),
 275                       "sradi $rA, $rS, $SH", IntRotateD,
 276                       [(set G8RC:$rA, (sra G8RC:$rS, (i32 imm:$SH)))]>, isPPC64;
 277 def CNTLZD : XForm_11<31, 58, (ops G8RC:$rA, G8RC:$rS),
 278                       "cntlzd $rA, $rS", IntGeneral,
 279                       [(set G8RC:$rA, (ctlz G8RC:$rS))]>;
 280
 281 def DIVD  : XOForm_1<31, 489, 0, (ops G8RC:$rT, G8RC:$rA, G8RC:$rB),
 282                      "divd $rT, $rA, $rB", IntDivD,
 283                      [(set G8RC:$rT, (sdiv G8RC:$rA, G8RC:$rB))]>, isPPC64,
 284                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 285 def DIVDU : XOForm_1<31, 457, 0, (ops G8RC:$rT, G8RC:$rA, G8RC:$rB),
 286                      "divdu $rT, $rA, $rB", IntDivD,
 287                      [(set G8RC:$rT, (udiv G8RC:$rA, G8RC:$rB))]>, isPPC64,
 288                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
 289 def MULLD : XOForm_1<31, 233, 0, (ops G8RC:$rT, G8RC:$rA, G8RC:$rB),
 290                      "mulld $rT, $rA, $rB", IntMulHD,
 291                      [(set G8RC:$rT, (mul G8RC:$rA, G8RC:$rB))]>, isPPC64;
 292
 293
 294 let isCommutable = 1 in {
 295 def RLDIMI : MDForm_1<30, 3,
 296                       (ops G8RC:$rA, G8RC:$rSi, G8RC:$rS, u6imm:$SH, u6imm:$MB),
 297                       "rldimi $rA, $rS, $SH, $MB", IntRotateD,
 298                       []>, isPPC64, RegConstraint<"$rSi = $rA">,
 299                       NoEncode<"$rSi">;
 300 }
 301
 302 // Rotate instructions.
 303 def RLDICL : MDForm_1<30, 0,
 304                       (ops G8RC:$rA, G8RC:$rS, u6imm:$SH, u6imm:$MB),
 305                       "rldicl $rA, $rS, $SH, $MB", IntRotateD,
 306                       []>, isPPC64;
 307 def RLDICR : MDForm_1<30, 1,
 308                       (ops G8RC:$rA, G8RC:$rS, u6imm:$SH, u6imm:$ME),
 309                       "rldicr $rA, $rS, $SH, $ME", IntRotateD,
 310                       []>, isPPC64;
 311 }  // End FXU Operations.
 312
 313
 314 //===----------------------------------------------------------------------===//
 315 // Load/Store instructions.
 316 //
 317
 318
 319 // Sign extending loads.
 320 let isLoad = 1, PPC970_Unit = 2 in {
 321 def LHA8: DForm_1<42, (ops G8RC:$rD, memri:$src),
 322                   "lha $rD, $src", LdStLHA,
 323                   [(set G8RC:$rD, (sextloadi16 iaddr:$src))]>,
 324                   PPC970_DGroup_Cracked;
 325 def LWA  : DSForm_1<58, 2, (ops G8RC:$rD, memrix:$src),
 326                     "lwa $rD, $src", LdStLWA,
 327                     [(set G8RC:$rD, (sextloadi32 ixaddr:$src))]>, isPPC64,
 328                     PPC970_DGroup_Cracked;
 329 def LHAX8: XForm_1<31, 343, (ops G8RC:$rD, memrr:$src),
 330                    "lhax $rD, $src", LdStLHA,
 331                    [(set G8RC:$rD, (sextloadi16 xaddr:$src))]>,
 332                    PPC970_DGroup_Cracked;
 333 def LWAX : XForm_1<31, 341, (ops G8RC:$rD, memrr:$src),
 334                    "lwax $rD, $src", LdStLHA,
 335                    [(set G8RC:$rD, (sextloadi32 xaddr:$src))]>, isPPC64,
 336                    PPC970_DGroup_Cracked;
 337
 338 // Update forms.
 339 def LHAU8 : DForm_1<43, (ops G8RC:$rD, ptr_rc:$ea_result, symbolLo:$disp,
 340                             ptr_rc:$rA),
 341                     "lhau $rD, $disp($rA)", LdStGeneral,
 342                     []>, RegConstraint<"$rA = $ea_result">,
 343                     NoEncode<"$ea_result">;
 344 // NO LWAU!
 345
 346 }
 347
 348 // Zero extending loads.
 349 let isLoad = 1, PPC970_Unit = 2 in {
 350 def LBZ8 : DForm_1<34, (ops G8RC:$rD, memri:$src),
 351                   "lbz $rD, $src", LdStGeneral,
 352                   [(set G8RC:$rD, (zextloadi8 iaddr:$src))]>;
 353 def LHZ8 : DForm_1<40, (ops G8RC:$rD, memri:$src),
 354                   "lhz $rD, $src", LdStGeneral,
 355                   [(set G8RC:$rD, (zextloadi16 iaddr:$src))]>;
 356 def LWZ8 : DForm_1<32, (ops G8RC:$rD, memri:$src),
 357                   "lwz $rD, $src", LdStGeneral,
 358                   [(set G8RC:$rD, (zextloadi32 iaddr:$src))]>, isPPC64;
 359
 360 def LBZX8 : XForm_1<31,  87, (ops G8RC:$rD, memrr:$src),
 361                    "lbzx $rD, $src", LdStGeneral,
 362                    [(set G8RC:$rD, (zextloadi8 xaddr:$src))]>;
 363 def LHZX8 : XForm_1<31, 279, (ops G8RC:$rD, memrr:$src),
 364                    "lhzx $rD, $src", LdStGeneral,
 365                    [(set G8RC:$rD, (zextloadi16 xaddr:$src))]>;
 366 def LWZX8 : XForm_1<31,  23, (ops G8RC:$rD, memrr:$src),
 367                    "lwzx $rD, $src", LdStGeneral,
 368                    [(set G8RC:$rD, (zextloadi32 xaddr:$src))]>;
 369
 370
 371 // Update forms.
 372 def LBZU8 : DForm_1<35, (ops G8RC:$rD, ptr_rc:$ea_result, memri:$addr),
 373                     "lbzu $rD, $addr", LdStGeneral,
 374                     []>, RegConstraint<"$addr.reg = $ea_result">,
 375                     NoEncode<"$ea_result">;
 376 def LHZU8 : DForm_1<41, (ops G8RC:$rD, ptr_rc:$ea_result, memri:$addr),
 377                     "lhzu $rD, $addr", LdStGeneral,
 378                     []>, RegConstraint<"$addr.reg = $ea_result">,
 379                     NoEncode<"$ea_result">;
 380 def LWZU8 : DForm_1<33, (ops G8RC:$rD, ptr_rc:$ea_result, memri:$addr),
 381                     "lwzu $rD, $addr", LdStGeneral,
 382                     []>, RegConstraint<"$addr.reg = $ea_result">,
 383                     NoEncode<"$ea_result">;
 384 }
 385
 386
 387 // Full 8-byte loads.
 388 let isLoad = 1, PPC970_Unit = 2 in {
 389 def LD   : DSForm_1<58, 0, (ops G8RC:$rD, memrix:$src),
 390                     "ld $rD, $src", LdStLD,
 391                     [(set G8RC:$rD, (load ixaddr:$src))]>, isPPC64;
 392 def LDX  : XForm_1<31,  21, (ops G8RC:$rD, memrr:$src),
 393                    "ldx $rD, $src", LdStLD,
 394                    [(set G8RC:$rD, (load xaddr:$src))]>, isPPC64;
 395
 396 def LDU  : DSForm_1<58, 1, (ops G8RC:$rD, ptr_rc:$ea_result, memrix:$addr),
 397                     "ldu $rD, $addr", LdStLD,
 398                     []>, RegConstraint<"$addr.reg = $ea_result">, isPPC64,
 399                     NoEncode<"$ea_result">;
 400
 401 }
 402
 403 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {
 404 // Truncating stores.
 405 def STB8 : DForm_1<38, (ops G8RC:$rS, memri:$src),
 406                    "stb $rS, $src", LdStGeneral,
 407                    [(truncstorei8 G8RC:$rS, iaddr:$src)]>;
 408 def STH8 : DForm_1<44, (ops G8RC:$rS, memri:$src),
 409                    "sth $rS, $src", LdStGeneral,
 410                    [(truncstorei16 G8RC:$rS, iaddr:$src)]>;
 411 def STW8 : DForm_1<36, (ops G8RC:$rS, memri:$src),
 412                    "stw $rS, $src", LdStGeneral,
 413                    [(truncstorei32 G8RC:$rS, iaddr:$src)]>;
 414 def STBX8 : XForm_8<31, 215, (ops G8RC:$rS, memrr:$dst),
 415                    "stbx $rS, $dst", LdStGeneral,
 416                    [(truncstorei8 G8RC:$rS, xaddr:$dst)]>,
 417                    PPC970_DGroup_Cracked;
 418 def STHX8 : XForm_8<31, 407, (ops G8RC:$rS, memrr:$dst),
 419                    "sthx $rS, $dst", LdStGeneral,
 420                    [(truncstorei16 G8RC:$rS, xaddr:$dst)]>,
 421                    PPC970_DGroup_Cracked;
 422 def STWX8 : XForm_8<31, 151, (ops G8RC:$rS, memrr:$dst),
 423                    "stwx $rS, $dst", LdStGeneral,
 424                    [(truncstorei32 G8RC:$rS, xaddr:$dst)]>,
 425                    PPC970_DGroup_Cracked;
 426 // Normal 8-byte stores.
 427 def STD  : DSForm_1<62, 0, (ops G8RC:$rS, memrix:$dst),
 428                     "std $rS, $dst", LdStSTD,
 429                     [(store G8RC:$rS, ixaddr:$dst)]>, isPPC64;
 430 def STDX  : XForm_8<31, 149, (ops G8RC:$rS, memrr:$dst),
 431                    "stdx $rS, $dst", LdStSTD,
 432                    [(store G8RC:$rS, xaddr:$dst)]>, isPPC64,
 433                    PPC970_DGroup_Cracked;
 434 }
 435
 436 let isStore = 1, PPC970_Unit = 2 in {
 437
 438 def STBU8 : DForm_1<38, (ops ptr_rc:$ea_res, G8RC:$rS,
 439                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 440                     "stbu $rS, $ptroff($ptrreg)", LdStGeneral,
 441                     [(set ptr_rc:$ea_res,
 442                           (pre_truncsti8 G8RC:$rS, ptr_rc:$ptrreg,
 443                                          iaddroff:$ptroff))]>,
 444                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 445 def STHU8 : DForm_1<45, (ops ptr_rc:$ea_res, G8RC:$rS,
 446                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 447                     "sthu $rS, $ptroff($ptrreg)", LdStGeneral,
 448                     [(set ptr_rc:$ea_res,
 449                         (pre_truncsti16 G8RC:$rS, ptr_rc:$ptrreg,
 450                                         iaddroff:$ptroff))]>,
 451                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 452 def STWU8 : DForm_1<37, (ops ptr_rc:$ea_res, G8RC:$rS,
 453                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 454                     "stwu $rS, $ptroff($ptrreg)", LdStGeneral,
 455                     [(set ptr_rc:$ea_res, (pre_store G8RC:$rS, ptr_rc:$ptrreg,
 456                                                      iaddroff:$ptroff))]>,
 457                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 458
 459
 460 def STDU : DSForm_1<62, 1, (ops ptr_rc:$ea_res, G8RC:$rS,
 461                                 s16immX4:$ptroff, ptr_rc:$ptrreg),
 462                     "stdu $rS, $ptroff($ptrreg)", LdStSTD,
 463                     [(set ptr_rc:$ea_res, (pre_store G8RC:$rS, ptr_rc:$ptrreg,
 464                                                      iaddroff:$ptroff))]>,
 465                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">,
 466                     isPPC64;
 467
 468 }
 469
 470 let isStore = 1, noResults = 1, PPC970_Unit = 2 in {
 471
 472 def STDUX : XForm_8<31, 181, (ops G8RC:$rS, memrr:$dst),
 473                    "stdux $rS, $dst", LdStSTD,
 474                    []>, isPPC64;
 475
 476
 477 // STD_32/STDX_32 - Just like STD/STDX, but uses a '32-bit' input register.
 478 def STD_32  : DSForm_1<62, 0, (ops GPRC:$rT, memrix:$dst),
 479                        "std $rT, $dst", LdStSTD,
 480                        [(PPCstd_32  GPRC:$rT, ixaddr:$dst)]>, isPPC64;
 481 def STDX_32  : XForm_8<31, 149, (ops GPRC:$rT, memrr:$dst),
 482                        "stdx $rT, $dst", LdStSTD,
 483                        [(PPCstd_32  GPRC:$rT, xaddr:$dst)]>, isPPC64,
 484                        PPC970_DGroup_Cracked;
 485 }
 486
 487
 488
 489 //===----------------------------------------------------------------------===//
 490 // Floating point instructions.
 491 //
 492
 493
 494 let PPC970_Unit = 3 in {  // FPU Operations.
 495 def FCFID  : XForm_26<63, 846, (ops F8RC:$frD, F8RC:$frB),
 496                       "fcfid $frD, $frB", FPGeneral,
 497                       [(set F8RC:$frD, (PPCfcfid F8RC:$frB))]>, isPPC64;
 498 def FCTIDZ : XForm_26<63, 815, (ops F8RC:$frD, F8RC:$frB),
 499                       "fctidz $frD, $frB", FPGeneral,
 500                       [(set F8RC:$frD, (PPCfctidz F8RC:$frB))]>, isPPC64;
 501 }
 502
 503
 504 //===----------------------------------------------------------------------===//
 505 // Instruction Patterns
 506 //
 507
 508 // Extensions and truncates to/from 32-bit regs.
 509 def : Pat<(i64 (zext GPRC:$in)),
 510           (RLDICL (OR4To8 GPRC:$in, GPRC:$in), 0, 32)>;
 511 def : Pat<(i64 (anyext GPRC:$in)),
 512           (OR4To8 GPRC:$in, GPRC:$in)>;
 513 def : Pat<(i32 (trunc G8RC:$in)),
 514           (OR8To4 G8RC:$in, G8RC:$in)>;
 515
 516 // Extending loads with i64 targets.
 517 def : Pat<(zextloadi1 iaddr:$src),
 518           (LBZ8 iaddr:$src)>;
 519 def : Pat<(zextloadi1 xaddr:$src),
 520           (LBZX8 xaddr:$src)>;
 521 def : Pat<(extloadi1 iaddr:$src),
 522           (LBZ8 iaddr:$src)>;
 523 def : Pat<(extloadi1 xaddr:$src),
 524           (LBZX8 xaddr:$src)>;
 525 def : Pat<(extloadi8 iaddr:$src),
 526           (LBZ8 iaddr:$src)>;
 527 def : Pat<(extloadi8 xaddr:$src),
 528           (LBZX8 xaddr:$src)>;
 529 def : Pat<(extloadi16 iaddr:$src),
 530           (LHZ8 iaddr:$src)>;
 531 def : Pat<(extloadi16 xaddr:$src),
 532           (LHZX8 xaddr:$src)>;
 533 def : Pat<(extloadi32 iaddr:$src),
 534           (LWZ8 iaddr:$src)>;
 535 def : Pat<(extloadi32 xaddr:$src),
 536           (LWZX8 xaddr:$src)>;
 537
 538 // SHL/SRL
 539 def : Pat<(shl G8RC:$in, (i32 imm:$imm)),
 540           (RLDICR G8RC:$in, imm:$imm, (SHL64 imm:$imm))>;
 541 def : Pat<(srl G8RC:$in, (i32 imm:$imm)),
 542           (RLDICL G8RC:$in, (SRL64 imm:$imm), imm:$imm)>;
 543
 544 // Hi and Lo for Darwin Global Addresses.
 545 def : Pat<(PPChi tglobaladdr:$in, 0), (LIS8 tglobaladdr:$in)>;
 546 def : Pat<(PPClo tglobaladdr:$in, 0), (LI8  tglobaladdr:$in)>;
 547 def : Pat<(PPChi tconstpool:$in , 0), (LIS8 tconstpool:$in)>;
 548 def : Pat<(PPClo tconstpool:$in , 0), (LI8  tconstpool:$in)>;
 549 def : Pat<(PPChi tjumptable:$in , 0), (LIS8 tjumptable:$in)>;
 550 def : Pat<(PPClo tjumptable:$in , 0), (LI8  tjumptable:$in)>;
 551 def : Pat<(add G8RC:$in, (PPChi tglobaladdr:$g, 0)),
 552           (ADDIS8 G8RC:$in, tglobaladdr:$g)>;
 553 def : Pat<(add G8RC:$in, (PPChi tconstpool:$g, 0)),
 554           (ADDIS8 G8RC:$in, tconstpool:$g)>;
 555 def : Pat<(add G8RC:$in, (PPChi tjumptable:$g, 0)),
 556           (ADDIS8 G8RC:$in, tjumptable:$g)>;