lib/Target/PowerPC/PPCInstrAltivec.td

   1 //===-- PPCInstrAltivec.td - The PowerPC Altivec Extension -*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the Altivec extension to the PowerPC instruction set.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 //===----------------------------------------------------------------------===//
  15 // Altivec transformation functions and pattern fragments.
  16 //
  17
  18 // Since we canonicalize buildvectors to v16i8, all vnots "-1" operands will be
  19 // of that type.
  20 def vnot_ppc : PatFrag<(ops node:$in),
  21                        (xor node:$in, (bitconvert (v16i8 immAllOnesV)))>;
  22
  23 def vpkuhum_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  24                               (vector_shuffle node:$lhs, node:$rhs), [{
  25   return PPC::isVPKUHUMShuffleMask(cast<ShuffleVectorSDNode>(N), false);
  26 }]>;
  27 def vpkuwum_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  28                               (vector_shuffle node:$lhs, node:$rhs), [{
  29   return PPC::isVPKUWUMShuffleMask(cast<ShuffleVectorSDNode>(N), false);
  30 }]>;
  31 def vpkuhum_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  32                                     (vector_shuffle node:$lhs, node:$rhs), [{
  33   return PPC::isVPKUHUMShuffleMask(cast<ShuffleVectorSDNode>(N), true);
  34 }]>;
  35 def vpkuwum_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  36                                     (vector_shuffle node:$lhs, node:$rhs), [{
  37   return PPC::isVPKUWUMShuffleMask(cast<ShuffleVectorSDNode>(N), true);
  38 }]>;
  39
  40
  41 def vmrglb_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  42                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  43   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 1, false);
  44 }]>;
  45 def vmrglh_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  46                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  47   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 2, false);
  48 }]>;
  49 def vmrglw_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  50                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  51   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 4, false);
  52 }]>;
  53 def vmrghb_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  54                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  55   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 1, false);
  56 }]>;
  57 def vmrghh_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  58                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  59   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 2, false);
  60 }]>;
  61 def vmrghw_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  62                              (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  63   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 4, false);
  64 }]>;
  65
  66
  67 def vmrglb_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  68                                (vector_shuffle (v16i8 node:$lhs), node:$rhs), [{
  69   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 1, true);
  70 }]>;
  71 def vmrglh_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  72                                    (vector_shuffle node:$lhs, node:$rhs), [{
  73   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 2, true);
  74 }]>;
  75 def vmrglw_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  76                                    (vector_shuffle node:$lhs, node:$rhs), [{
  77   return PPC::isVMRGLShuffleMask(cast<ShuffleVectorSDNode>(N), 4, true);
  78 }]>;
  79 def vmrghb_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  80                                    (vector_shuffle node:$lhs, node:$rhs), [{
  81   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 1, true);
  82 }]>;
  83 def vmrghh_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  84                                    (vector_shuffle node:$lhs, node:$rhs), [{
  85   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 2, true);
  86 }]>;
  87 def vmrghw_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  88                                    (vector_shuffle node:$lhs, node:$rhs), [{
  89   return PPC::isVMRGHShuffleMask(cast<ShuffleVectorSDNode>(N), 4, true);
  90 }]>;
  91
  92
  93 def VSLDOI_get_imm : SDNodeXForm<vector_shuffle, [{
  94   return getI32Imm(PPC::isVSLDOIShuffleMask(N, false));
  95 }]>;
  96 def vsldoi_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
  97                              (vector_shuffle node:$lhs, node:$rhs), [{
  98   return PPC::isVSLDOIShuffleMask(N, false) != -1;
  99 }], VSLDOI_get_imm>;
 100
 101
 102 /// VSLDOI_unary* - These are used to match vsldoi(X,X), which is turned into
 103 /// vector_shuffle(X,undef,mask) by the dag combiner.
 104 def VSLDOI_unary_get_imm : SDNodeXForm<vector_shuffle, [{
 105   return getI32Imm(PPC::isVSLDOIShuffleMask(N, true));
 106 }]>;
 107 def vsldoi_unary_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 108                                    (vector_shuffle node:$lhs, node:$rhs), [{
 109   return PPC::isVSLDOIShuffleMask(N, true) != -1;
 110 }], VSLDOI_unary_get_imm>;
 111
 112
 113 // VSPLT*_get_imm xform function: convert vector_shuffle mask to VSPLT* imm.
 114 def VSPLTB_get_imm : SDNodeXForm<vector_shuffle, [{
 115   return getI32Imm(PPC::getVSPLTImmediate(N, 1));
 116 }]>;
 117 def vspltb_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 118                              (vector_shuffle node:$lhs, node:$rhs), [{
 119   return PPC::isSplatShuffleMask(cast<ShuffleVectorSDNode>(N), 1);
 120 }], VSPLTB_get_imm>;
 121 def VSPLTH_get_imm : SDNodeXForm<vector_shuffle, [{
 122   return getI32Imm(PPC::getVSPLTImmediate(N, 2));
 123 }]>;
 124 def vsplth_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 125                              (vector_shuffle node:$lhs, node:$rhs), [{
 126   return PPC::isSplatShuffleMask(cast<ShuffleVectorSDNode>(N), 2);
 127 }], VSPLTH_get_imm>;
 128 def VSPLTW_get_imm : SDNodeXForm<vector_shuffle, [{
 129   return getI32Imm(PPC::getVSPLTImmediate(N, 4));
 130 }]>;
 131 def vspltw_shuffle : PatFrag<(ops node:$lhs, node:$rhs),
 132                              (vector_shuffle node:$lhs, node:$rhs), [{
 133   return PPC::isSplatShuffleMask(cast<ShuffleVectorSDNode>(N), 4);
 134 }], VSPLTW_get_imm>;
 135
 136
 137 // VSPLTISB_get_imm xform function: convert build_vector to VSPLTISB imm.
 138 def VSPLTISB_get_imm : SDNodeXForm<build_vector, [{
 139   return PPC::get_VSPLTI_elt(N, 1, *CurDAG);
 140 }]>;
 141 def vecspltisb : PatLeaf<(build_vector), [{
 142   return PPC::get_VSPLTI_elt(N, 1, *CurDAG).getNode() != 0;
 143 }], VSPLTISB_get_imm>;
 144
 145 // VSPLTISH_get_imm xform function: convert build_vector to VSPLTISH imm.
 146 def VSPLTISH_get_imm : SDNodeXForm<build_vector, [{
 147   return PPC::get_VSPLTI_elt(N, 2, *CurDAG);
 148 }]>;
 149 def vecspltish : PatLeaf<(build_vector), [{
 150   return PPC::get_VSPLTI_elt(N, 2, *CurDAG).getNode() != 0;
 151 }], VSPLTISH_get_imm>;
 152
 153 // VSPLTISW_get_imm xform function: convert build_vector to VSPLTISW imm.
 154 def VSPLTISW_get_imm : SDNodeXForm<build_vector, [{
 155   return PPC::get_VSPLTI_elt(N, 4, *CurDAG);
 156 }]>;
 157 def vecspltisw : PatLeaf<(build_vector), [{
 158   return PPC::get_VSPLTI_elt(N, 4, *CurDAG).getNode() != 0;
 159 }], VSPLTISW_get_imm>;
 160
 161 //===----------------------------------------------------------------------===//
 162 // Helpers for defining instructions that directly correspond to intrinsics.
 163
 164 // VA1a_Int - A VAForm_1a intrinsic definition.
 165 class VA1a_Int<bits<6> xo, string opc, Intrinsic IntID>
 166   : VAForm_1a<xo, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB, VRRC:$vC),
 167               !strconcat(opc, " $vD, $vA, $vB, $vC"), VecFP,
 168                        [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB, VRRC:$vC))]>;
 169
 170 // VX1_Int - A VXForm_1 intrinsic definition.
 171 class VX1_Int<bits<11> xo, string opc, Intrinsic IntID>
 172   : VXForm_1<xo, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 173              !strconcat(opc, " $vD, $vA, $vB"), VecFP,
 174              [(set VRRC:$vD, (IntID VRRC:$vA, VRRC:$vB))]>;
 175
 176 // VX2_Int - A VXForm_2 intrinsic definition.
 177 class VX2_Int<bits<11> xo, string opc, Intrinsic IntID>
 178   : VXForm_2<xo, (outs VRRC:$vD), (ins VRRC:$vB),
 179              !strconcat(opc, " $vD, $vB"), VecFP,
 180              [(set VRRC:$vD, (IntID VRRC:$vB))]>;
 181
 182 //===----------------------------------------------------------------------===//
 183 // Instruction Definitions.
 184
 185 def DSS      : DSS_Form<822, (outs),
 186                         (ins u5imm:$ZERO0, u5imm:$STRM,u5imm:$ZERO1,u5imm:$ZERO2),
 187                         "dss $STRM", LdStLoad /*FIXME*/, []>;
 188 def DSSALL   : DSS_Form<822, (outs),
 189                         (ins u5imm:$ONE, u5imm:$ZERO0,u5imm:$ZERO1,u5imm:$ZERO2),
 190                         "dssall", LdStLoad /*FIXME*/, []>;
 191 def DST      : DSS_Form<342, (outs),
 192                         (ins u5imm:$ZERO, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 193                         "dst $rA, $rB, $STRM", LdStLoad /*FIXME*/, []>;
 194 def DSTT     : DSS_Form<342, (outs),
 195                         (ins u5imm:$ONE, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 196                         "dstt $rA, $rB, $STRM", LdStLoad /*FIXME*/, []>;
 197 def DSTST    : DSS_Form<374, (outs),
 198                         (ins u5imm:$ZERO, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 199                         "dstst $rA, $rB, $STRM", LdStLoad /*FIXME*/, []>;
 200 def DSTSTT   : DSS_Form<374, (outs),
 201                         (ins u5imm:$ONE, u5imm:$STRM, GPRC:$rA, GPRC:$rB),
 202                         "dststt $rA, $rB, $STRM", LdStLoad /*FIXME*/, []>;
 203
 204 def DST64    : DSS_Form<342, (outs),
 205                         (ins u5imm:$ZERO, u5imm:$STRM, G8RC:$rA, GPRC:$rB),
 206                         "dst $rA, $rB, $STRM", LdStLoad /*FIXME*/, []>;
 207 def DSTT64   : DSS_Form<342, (outs),
 208                         (ins u5imm:$ONE, u5imm:$STRM, G8RC:$rA, GPRC:$rB),
 209                         "dstt $rA, $rB, $STRM", LdStLoad /*FIXME*/, []>;
 210 def DSTST64  : DSS_Form<374, (outs),
 211                         (ins u5imm:$ZERO, u5imm:$STRM, G8RC:$rA, GPRC:$rB),
 212                         "dstst $rA, $rB, $STRM", LdStLoad /*FIXME*/, []>;
 213 def DSTSTT64 : DSS_Form<374, (outs),
 214                         (ins u5imm:$ONE, u5imm:$STRM, G8RC:$rA, GPRC:$rB),
 215                         "dststt $rA, $rB, $STRM", LdStLoad /*FIXME*/, []>;
 216
 217 def MFVSCR : VXForm_4<1540, (outs VRRC:$vD), (ins),
 218                       "mfvscr $vD", LdStStore,
 219                       [(set VRRC:$vD, (int_ppc_altivec_mfvscr))]>;
 220 def MTVSCR : VXForm_5<1604, (outs), (ins VRRC:$vB),
 221                       "mtvscr $vB", LdStLoad,
 222                       [(int_ppc_altivec_mtvscr VRRC:$vB)]>;
 223
 224 let canFoldAsLoad = 1, PPC970_Unit = 2 in {  // Loads.
 225 def LVEBX: XForm_1<31,   7, (outs VRRC:$vD), (ins memrr:$src),
 226                    "lvebx $vD, $src", LdStLoad,
 227                    [(set VRRC:$vD, (int_ppc_altivec_lvebx xoaddr:$src))]>;
 228 def LVEHX: XForm_1<31,  39, (outs VRRC:$vD), (ins memrr:$src),
 229                    "lvehx $vD, $src", LdStLoad,
 230                    [(set VRRC:$vD, (int_ppc_altivec_lvehx xoaddr:$src))]>;
 231 def LVEWX: XForm_1<31,  71, (outs VRRC:$vD), (ins memrr:$src),
 232                    "lvewx $vD, $src", LdStLoad,
 233                    [(set VRRC:$vD, (int_ppc_altivec_lvewx xoaddr:$src))]>;
 234 def LVX  : XForm_1<31, 103, (outs VRRC:$vD), (ins memrr:$src),
 235                    "lvx $vD, $src", LdStLoad,
 236                    [(set VRRC:$vD, (int_ppc_altivec_lvx xoaddr:$src))]>;
 237 def LVXL : XForm_1<31, 359, (outs VRRC:$vD), (ins memrr:$src),
 238                    "lvxl $vD, $src", LdStLoad,
 239                    [(set VRRC:$vD, (int_ppc_altivec_lvxl xoaddr:$src))]>;
 240 }
 241
 242 def LVSL : XForm_1<31,   6, (outs VRRC:$vD), (ins memrr:$src),
 243                    "lvsl $vD, $src", LdStLoad,
 244                    [(set VRRC:$vD, (int_ppc_altivec_lvsl xoaddr:$src))]>,
 245                    PPC970_Unit_LSU;
 246 def LVSR : XForm_1<31,  38, (outs VRRC:$vD), (ins memrr:$src),
 247                    "lvsr $vD, $src", LdStLoad,
 248                    [(set VRRC:$vD, (int_ppc_altivec_lvsr xoaddr:$src))]>,
 249                    PPC970_Unit_LSU;
 250
 251 let PPC970_Unit = 2 in {   // Stores.
 252 def STVEBX: XForm_8<31, 135, (outs), (ins VRRC:$rS, memrr:$dst),
 253                    "stvebx $rS, $dst", LdStStore,
 254                    [(int_ppc_altivec_stvebx VRRC:$rS, xoaddr:$dst)]>;
 255 def STVEHX: XForm_8<31, 167, (outs), (ins VRRC:$rS, memrr:$dst),
 256                    "stvehx $rS, $dst", LdStStore,
 257                    [(int_ppc_altivec_stvehx VRRC:$rS, xoaddr:$dst)]>;
 258 def STVEWX: XForm_8<31, 199, (outs), (ins VRRC:$rS, memrr:$dst),
 259                    "stvewx $rS, $dst", LdStStore,
 260                    [(int_ppc_altivec_stvewx VRRC:$rS, xoaddr:$dst)]>;
 261 def STVX  : XForm_8<31, 231, (outs), (ins VRRC:$rS, memrr:$dst),
 262                    "stvx $rS, $dst", LdStStore,
 263                    [(int_ppc_altivec_stvx VRRC:$rS, xoaddr:$dst)]>;
 264 def STVXL : XForm_8<31, 487, (outs), (ins VRRC:$rS, memrr:$dst),
 265                    "stvxl $rS, $dst", LdStStore,
 266                    [(int_ppc_altivec_stvxl VRRC:$rS, xoaddr:$dst)]>;
 267 }
 268
 269 let PPC970_Unit = 5 in {  // VALU Operations.
 270 // VA-Form instructions.  3-input AltiVec ops.
 271 def VMADDFP : VAForm_1<46, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vC, VRRC:$vB),
 272                        "vmaddfp $vD, $vA, $vC, $vB", VecFP,
 273                        [(set VRRC:$vD, (fma VRRC:$vA, VRRC:$vC, VRRC:$vB))]>;
 274 def VNMSUBFP: VAForm_1<47, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vC, VRRC:$vB),
 275                        "vnmsubfp $vD, $vA, $vC, $vB", VecFP,
 276                        [(set VRRC:$vD, (fneg (fma VRRC:$vA, VRRC:$vC,
 277                                                   (fneg VRRC:$vB))))]>;
 278
 279 def VMHADDSHS  : VA1a_Int<32, "vmhaddshs",  int_ppc_altivec_vmhaddshs>;
 280 def VMHRADDSHS : VA1a_Int<33, "vmhraddshs", int_ppc_altivec_vmhraddshs>;
 281 def VMLADDUHM  : VA1a_Int<34, "vmladduhm",  int_ppc_altivec_vmladduhm>;
 282 def VPERM      : VA1a_Int<43, "vperm",      int_ppc_altivec_vperm>;
 283 def VSEL       : VA1a_Int<42, "vsel",       int_ppc_altivec_vsel>;
 284
 285 // Shuffles.
 286 def VSLDOI  : VAForm_2<44, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB, u5imm:$SH),
 287                        "vsldoi $vD, $vA, $vB, $SH", VecFP,
 288                        [(set VRRC:$vD,
 289                          (vsldoi_shuffle:$SH (v16i8 VRRC:$vA), VRRC:$vB))]>;
 290
 291 // VX-Form instructions.  AltiVec arithmetic ops.
 292 def VADDFP : VXForm_1<10, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 293                       "vaddfp $vD, $vA, $vB", VecFP,
 294                       [(set VRRC:$vD, (fadd VRRC:$vA, VRRC:$vB))]>;
 295
 296 def VADDUBM : VXForm_1<0, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 297                       "vaddubm $vD, $vA, $vB", VecGeneral,
 298                       [(set VRRC:$vD, (add (v16i8 VRRC:$vA), VRRC:$vB))]>;
 299 def VADDUHM : VXForm_1<64, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 300                       "vadduhm $vD, $vA, $vB", VecGeneral,
 301                       [(set VRRC:$vD, (add (v8i16 VRRC:$vA), VRRC:$vB))]>;
 302 def VADDUWM : VXForm_1<128, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 303                       "vadduwm $vD, $vA, $vB", VecGeneral,
 304                       [(set VRRC:$vD, (add (v4i32 VRRC:$vA), VRRC:$vB))]>;
 305
 306 def VADDCUW : VX1_Int<384, "vaddcuw", int_ppc_altivec_vaddcuw>;
 307 def VADDSBS : VX1_Int<768, "vaddsbs", int_ppc_altivec_vaddsbs>;
 308 def VADDSHS : VX1_Int<832, "vaddshs", int_ppc_altivec_vaddshs>;
 309 def VADDSWS : VX1_Int<896, "vaddsws", int_ppc_altivec_vaddsws>;
 310 def VADDUBS : VX1_Int<512, "vaddubs", int_ppc_altivec_vaddubs>;
 311 def VADDUHS : VX1_Int<576, "vadduhs", int_ppc_altivec_vadduhs>;
 312 def VADDUWS : VX1_Int<640, "vadduws", int_ppc_altivec_vadduws>;
 313
 314
 315 def VAND : VXForm_1<1028, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 316                     "vand $vD, $vA, $vB", VecFP,
 317                     [(set VRRC:$vD, (and (v4i32 VRRC:$vA), VRRC:$vB))]>;
 318 def VANDC : VXForm_1<1092, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 319                      "vandc $vD, $vA, $vB", VecFP,
 320                      [(set VRRC:$vD, (and (v4i32 VRRC:$vA),
 321                                           (vnot_ppc VRRC:$vB)))]>;
 322
 323 def VCFSX  : VXForm_1<842, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 324                       "vcfsx $vD, $vB, $UIMM", VecFP,
 325                       [(set VRRC:$vD,
 326                              (int_ppc_altivec_vcfsx VRRC:$vB, imm:$UIMM))]>;
 327 def VCFUX  : VXForm_1<778, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 328                       "vcfux $vD, $vB, $UIMM", VecFP,
 329                       [(set VRRC:$vD,
 330                              (int_ppc_altivec_vcfux VRRC:$vB, imm:$UIMM))]>;
 331 def VCTSXS : VXForm_1<970, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 332                       "vctsxs $vD, $vB, $UIMM", VecFP,
 333                       [(set VRRC:$vD,
 334                              (int_ppc_altivec_vctsxs VRRC:$vB, imm:$UIMM))]>;
 335 def VCTUXS : VXForm_1<906, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 336                       "vctuxs $vD, $vB, $UIMM", VecFP,
 337                       [(set VRRC:$vD,
 338                              (int_ppc_altivec_vctuxs VRRC:$vB, imm:$UIMM))]>;
 339
 340 // Defines with the UIM field set to 0 for floating-point
 341 // to integer (fp_to_sint/fp_to_uint) conversions and integer
 342 // to floating-point (sint_to_fp/uint_to_fp) conversions.
 343 let VA = 0 in {
 344 def VCFSX_0 : VXForm_1<842, (outs VRRC:$vD), (ins VRRC:$vB),
 345                        "vcfsx $vD, $vB, 0", VecFP,
 346                        [(set VRRC:$vD,
 347                              (int_ppc_altivec_vcfsx VRRC:$vB, 0))]>;
 348 def VCTUXS_0 : VXForm_1<906, (outs VRRC:$vD), (ins VRRC:$vB),
 349                         "vctuxs $vD, $vB, 0", VecFP,
 350                         [(set VRRC:$vD,
 351                                (int_ppc_altivec_vctuxs VRRC:$vB, 0))]>;
 352 def VCFUX_0 : VXForm_1<778, (outs VRRC:$vD), (ins VRRC:$vB),
 353                        "vcfux $vD, $vB, 0", VecFP,
 354                        [(set VRRC:$vD,
 355                                (int_ppc_altivec_vcfux VRRC:$vB, 0))]>;
 356 def VCTSXS_0 : VXForm_1<970, (outs VRRC:$vD), (ins VRRC:$vB),
 357                       "vctsxs $vD, $vB, 0", VecFP,
 358                       [(set VRRC:$vD,
 359                              (int_ppc_altivec_vctsxs VRRC:$vB, 0))]>;
 360 }
 361 def VEXPTEFP : VX2_Int<394, "vexptefp", int_ppc_altivec_vexptefp>;
 362 def VLOGEFP  : VX2_Int<458, "vlogefp",  int_ppc_altivec_vlogefp>;
 363
 364 def VAVGSB : VX1_Int<1282, "vavgsb", int_ppc_altivec_vavgsb>;
 365 def VAVGSH : VX1_Int<1346, "vavgsh", int_ppc_altivec_vavgsh>;
 366 def VAVGSW : VX1_Int<1410, "vavgsw", int_ppc_altivec_vavgsw>;
 367 def VAVGUB : VX1_Int<1026, "vavgub", int_ppc_altivec_vavgub>;
 368 def VAVGUH : VX1_Int<1090, "vavguh", int_ppc_altivec_vavguh>;
 369 def VAVGUW : VX1_Int<1154, "vavguw", int_ppc_altivec_vavguw>;
 370
 371 def VMAXFP : VX1_Int<1034, "vmaxfp", int_ppc_altivec_vmaxfp>;
 372 def VMAXSB : VX1_Int< 258, "vmaxsb", int_ppc_altivec_vmaxsb>;
 373 def VMAXSH : VX1_Int< 322, "vmaxsh", int_ppc_altivec_vmaxsh>;
 374 def VMAXSW : VX1_Int< 386, "vmaxsw", int_ppc_altivec_vmaxsw>;
 375 def VMAXUB : VX1_Int<   2, "vmaxub", int_ppc_altivec_vmaxub>;
 376 def VMAXUH : VX1_Int<  66, "vmaxuh", int_ppc_altivec_vmaxuh>;
 377 def VMAXUW : VX1_Int< 130, "vmaxuw", int_ppc_altivec_vmaxuw>;
 378 def VMINFP : VX1_Int<1098, "vminfp", int_ppc_altivec_vminfp>;
 379 def VMINSB : VX1_Int< 770, "vminsb", int_ppc_altivec_vminsb>;
 380 def VMINSH : VX1_Int< 834, "vminsh", int_ppc_altivec_vminsh>;
 381 def VMINSW : VX1_Int< 898, "vminsw", int_ppc_altivec_vminsw>;
 382 def VMINUB : VX1_Int< 514, "vminub", int_ppc_altivec_vminub>;
 383 def VMINUH : VX1_Int< 578, "vminuh", int_ppc_altivec_vminuh>;
 384 def VMINUW : VX1_Int< 642, "vminuw", int_ppc_altivec_vminuw>;
 385
 386 def VMRGHB : VXForm_1< 12, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 387                       "vmrghb $vD, $vA, $vB", VecFP,
 388                       [(set VRRC:$vD, (vmrghb_shuffle VRRC:$vA, VRRC:$vB))]>;
 389 def VMRGHH : VXForm_1< 76, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 390                       "vmrghh $vD, $vA, $vB", VecFP,
 391                       [(set VRRC:$vD, (vmrghh_shuffle VRRC:$vA, VRRC:$vB))]>;
 392 def VMRGHW : VXForm_1<140, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 393                       "vmrghw $vD, $vA, $vB", VecFP,
 394                       [(set VRRC:$vD, (vmrghw_shuffle VRRC:$vA, VRRC:$vB))]>;
 395 def VMRGLB : VXForm_1<268, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 396                       "vmrglb $vD, $vA, $vB", VecFP,
 397                       [(set VRRC:$vD, (vmrglb_shuffle VRRC:$vA, VRRC:$vB))]>;
 398 def VMRGLH : VXForm_1<332, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 399                       "vmrglh $vD, $vA, $vB", VecFP,
 400                       [(set VRRC:$vD, (vmrglh_shuffle VRRC:$vA, VRRC:$vB))]>;
 401 def VMRGLW : VXForm_1<396, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 402                       "vmrglw $vD, $vA, $vB", VecFP,
 403                       [(set VRRC:$vD, (vmrglw_shuffle VRRC:$vA, VRRC:$vB))]>;
 404
 405 def VMSUMMBM : VA1a_Int<37, "vmsummbm", int_ppc_altivec_vmsummbm>;
 406 def VMSUMSHM : VA1a_Int<40, "vmsumshm", int_ppc_altivec_vmsumshm>;
 407 def VMSUMSHS : VA1a_Int<41, "vmsumshs", int_ppc_altivec_vmsumshs>;
 408 def VMSUMUBM : VA1a_Int<36, "vmsumubm", int_ppc_altivec_vmsumubm>;
 409 def VMSUMUHM : VA1a_Int<38, "vmsumuhm", int_ppc_altivec_vmsumuhm>;
 410 def VMSUMUHS : VA1a_Int<39, "vmsumuhs", int_ppc_altivec_vmsumuhs>;
 411
 412 def VMULESB : VX1_Int<776, "vmulesb", int_ppc_altivec_vmulesb>;
 413 def VMULESH : VX1_Int<840, "vmulesh", int_ppc_altivec_vmulesh>;
 414 def VMULEUB : VX1_Int<520, "vmuleub", int_ppc_altivec_vmuleub>;
 415 def VMULEUH : VX1_Int<584, "vmuleuh", int_ppc_altivec_vmuleuh>;
 416 def VMULOSB : VX1_Int<264, "vmulosb", int_ppc_altivec_vmulosb>;
 417 def VMULOSH : VX1_Int<328, "vmulosh", int_ppc_altivec_vmulosh>;
 418 def VMULOUB : VX1_Int<  8, "vmuloub", int_ppc_altivec_vmuloub>;
 419 def VMULOUH : VX1_Int< 72, "vmulouh", int_ppc_altivec_vmulouh>;
 420
 421 def VREFP     : VX2_Int<266, "vrefp",     int_ppc_altivec_vrefp>;
 422 def VRFIM     : VX2_Int<714, "vrfim",     int_ppc_altivec_vrfim>;
 423 def VRFIN     : VX2_Int<522, "vrfin",     int_ppc_altivec_vrfin>;
 424 def VRFIP     : VX2_Int<650, "vrfip",     int_ppc_altivec_vrfip>;
 425 def VRFIZ     : VX2_Int<586, "vrfiz",     int_ppc_altivec_vrfiz>;
 426 def VRSQRTEFP : VX2_Int<330, "vrsqrtefp", int_ppc_altivec_vrsqrtefp>;
 427
 428 def VSUBCUW : VX1_Int<74, "vsubcuw", int_ppc_altivec_vsubcuw>;
 429
 430 def VSUBFP  : VXForm_1<74, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 431                       "vsubfp $vD, $vA, $vB", VecGeneral,
 432                       [(set VRRC:$vD, (fsub VRRC:$vA, VRRC:$vB))]>;
 433 def VSUBUBM : VXForm_1<1024, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 434                       "vsububm $vD, $vA, $vB", VecGeneral,
 435                       [(set VRRC:$vD, (sub (v16i8 VRRC:$vA), VRRC:$vB))]>;
 436 def VSUBUHM : VXForm_1<1088, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 437                       "vsubuhm $vD, $vA, $vB", VecGeneral,
 438                       [(set VRRC:$vD, (sub (v8i16 VRRC:$vA), VRRC:$vB))]>;
 439 def VSUBUWM : VXForm_1<1152, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 440                       "vsubuwm $vD, $vA, $vB", VecGeneral,
 441                       [(set VRRC:$vD, (sub (v4i32 VRRC:$vA), VRRC:$vB))]>;
 442
 443 def VSUBSBS : VX1_Int<1792, "vsubsbs" , int_ppc_altivec_vsubsbs>;
 444 def VSUBSHS : VX1_Int<1856, "vsubshs" , int_ppc_altivec_vsubshs>;
 445 def VSUBSWS : VX1_Int<1920, "vsubsws" , int_ppc_altivec_vsubsws>;
 446 def VSUBUBS : VX1_Int<1536, "vsububs" , int_ppc_altivec_vsububs>;
 447 def VSUBUHS : VX1_Int<1600, "vsubuhs" , int_ppc_altivec_vsubuhs>;
 448 def VSUBUWS : VX1_Int<1664, "vsubuws" , int_ppc_altivec_vsubuws>;
 449 def VSUMSWS : VX1_Int<1928, "vsumsws" , int_ppc_altivec_vsumsws>;
 450 def VSUM2SWS: VX1_Int<1672, "vsum2sws", int_ppc_altivec_vsum2sws>;
 451 def VSUM4SBS: VX1_Int<1672, "vsum4sbs", int_ppc_altivec_vsum4sbs>;
 452 def VSUM4SHS: VX1_Int<1608, "vsum4shs", int_ppc_altivec_vsum4shs>;
 453 def VSUM4UBS: VX1_Int<1544, "vsum4ubs", int_ppc_altivec_vsum4ubs>;
 454
 455 def VNOR : VXForm_1<1284, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 456                     "vnor $vD, $vA, $vB", VecFP,
 457                     [(set VRRC:$vD, (vnot_ppc (or (v4i32 VRRC:$vA),
 458                                                   VRRC:$vB)))]>;
 459 def VOR : VXForm_1<1156, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 460                       "vor $vD, $vA, $vB", VecFP,
 461                       [(set VRRC:$vD, (or (v4i32 VRRC:$vA), VRRC:$vB))]>;
 462 def VXOR : VXForm_1<1220, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 463                       "vxor $vD, $vA, $vB", VecFP,
 464                       [(set VRRC:$vD, (xor (v4i32 VRRC:$vA), VRRC:$vB))]>;
 465
 466 def VRLB   : VX1_Int<   4, "vrlb", int_ppc_altivec_vrlb>;
 467 def VRLH   : VX1_Int<  68, "vrlh", int_ppc_altivec_vrlh>;
 468 def VRLW   : VX1_Int< 132, "vrlw", int_ppc_altivec_vrlw>;
 469
 470 def VSL    : VX1_Int< 452, "vsl" , int_ppc_altivec_vsl >;
 471 def VSLO   : VX1_Int<1036, "vslo", int_ppc_altivec_vslo>;
 472 def VSLB   : VX1_Int< 260, "vslb", int_ppc_altivec_vslb>;
 473 def VSLH   : VX1_Int< 324, "vslh", int_ppc_altivec_vslh>;
 474 def VSLW   : VX1_Int< 388, "vslw", int_ppc_altivec_vslw>;
 475
 476 def VSPLTB : VXForm_1<524, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 477                       "vspltb $vD, $vB, $UIMM", VecPerm,
 478                       [(set VRRC:$vD,
 479                         (vspltb_shuffle:$UIMM (v16i8 VRRC:$vB), (undef)))]>;
 480 def VSPLTH : VXForm_1<588, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 481                       "vsplth $vD, $vB, $UIMM", VecPerm,
 482                       [(set VRRC:$vD,
 483                         (vsplth_shuffle:$UIMM (v16i8 VRRC:$vB), (undef)))]>;
 484 def VSPLTW : VXForm_1<652, (outs VRRC:$vD), (ins u5imm:$UIMM, VRRC:$vB),
 485                       "vspltw $vD, $vB, $UIMM", VecPerm,
 486                       [(set VRRC:$vD,
 487                         (vspltw_shuffle:$UIMM (v16i8 VRRC:$vB), (undef)))]>;
 488
 489 def VSR    : VX1_Int< 708, "vsr"  , int_ppc_altivec_vsr>;
 490 def VSRO   : VX1_Int<1100, "vsro" , int_ppc_altivec_vsro>;
 491 def VSRAB  : VX1_Int< 772, "vsrab", int_ppc_altivec_vsrab>;
 492 def VSRAH  : VX1_Int< 836, "vsrah", int_ppc_altivec_vsrah>;
 493 def VSRAW  : VX1_Int< 900, "vsraw", int_ppc_altivec_vsraw>;
 494 def VSRB   : VX1_Int< 516, "vsrb" , int_ppc_altivec_vsrb>;
 495 def VSRH   : VX1_Int< 580, "vsrh" , int_ppc_altivec_vsrh>;
 496 def VSRW   : VX1_Int< 644, "vsrw" , int_ppc_altivec_vsrw>;
 497
 498
 499 def VSPLTISB : VXForm_3<780, (outs VRRC:$vD), (ins s5imm:$SIMM),
 500                        "vspltisb $vD, $SIMM", VecPerm,
 501                        [(set VRRC:$vD, (v16i8 vecspltisb:$SIMM))]>;
 502 def VSPLTISH : VXForm_3<844, (outs VRRC:$vD), (ins s5imm:$SIMM),
 503                        "vspltish $vD, $SIMM", VecPerm,
 504                        [(set VRRC:$vD, (v8i16 vecspltish:$SIMM))]>;
 505 def VSPLTISW : VXForm_3<908, (outs VRRC:$vD), (ins s5imm:$SIMM),
 506                        "vspltisw $vD, $SIMM", VecPerm,
 507                        [(set VRRC:$vD, (v4i32 vecspltisw:$SIMM))]>;
 508
 509 // Vector Pack.
 510 def VPKPX   : VX1_Int<782, "vpkpx", int_ppc_altivec_vpkpx>;
 511 def VPKSHSS : VX1_Int<398, "vpkshss", int_ppc_altivec_vpkshss>;
 512 def VPKSHUS : VX1_Int<270, "vpkshus", int_ppc_altivec_vpkshus>;
 513 def VPKSWSS : VX1_Int<462, "vpkswss", int_ppc_altivec_vpkswss>;
 514 def VPKSWUS : VX1_Int<334, "vpkswus", int_ppc_altivec_vpkswus>;
 515 def VPKUHUM : VXForm_1<14, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 516                        "vpkuhum $vD, $vA, $vB", VecFP,
 517                        [(set VRRC:$vD,
 518                          (vpkuhum_shuffle (v16i8 VRRC:$vA), VRRC:$vB))]>;
 519 def VPKUHUS : VX1_Int<142, "vpkuhus", int_ppc_altivec_vpkuhus>;
 520 def VPKUWUM : VXForm_1<78, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),
 521                        "vpkuwum $vD, $vA, $vB", VecFP,
 522                        [(set VRRC:$vD,
 523                          (vpkuwum_shuffle (v16i8 VRRC:$vA), VRRC:$vB))]>;
 524 def VPKUWUS : VX1_Int<206, "vpkuwus", int_ppc_altivec_vpkuwus>;
 525
 526 // Vector Unpack.
 527 def VUPKHPX : VX2_Int<846, "vupkhpx", int_ppc_altivec_vupkhpx>;
 528 def VUPKHSB : VX2_Int<526, "vupkhsb", int_ppc_altivec_vupkhsb>;
 529 def VUPKHSH : VX2_Int<590, "vupkhsh", int_ppc_altivec_vupkhsh>;
 530 def VUPKLPX : VX2_Int<974, "vupklpx", int_ppc_altivec_vupklpx>;
 531 def VUPKLSB : VX2_Int<654, "vupklsb", int_ppc_altivec_vupklsb>;
 532 def VUPKLSH : VX2_Int<718, "vupklsh", int_ppc_altivec_vupklsh>;
 533
 534
 535 // Altivec Comparisons.
 536
 537 class VCMP<bits<10> xo, string asmstr, ValueType Ty>
 538   : VXRForm_1<xo, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),asmstr,VecFPCompare,
 539               [(set VRRC:$vD, (Ty (PPCvcmp VRRC:$vA, VRRC:$vB, xo)))]>;
 540 class VCMPo<bits<10> xo, string asmstr, ValueType Ty>
 541   : VXRForm_1<xo, (outs VRRC:$vD), (ins VRRC:$vA, VRRC:$vB),asmstr,VecFPCompare,
 542               [(set VRRC:$vD, (Ty (PPCvcmp_o VRRC:$vA, VRRC:$vB, xo)))]> {
 543   let Defs = [CR6];
 544   let RC = 1;
 545 }
 546
 547 // f32 element comparisons.0
 548 def VCMPBFP   : VCMP <966, "vcmpbfp $vD, $vA, $vB"  , v4f32>;
 549 def VCMPBFPo  : VCMPo<966, "vcmpbfp. $vD, $vA, $vB" , v4f32>;
 550 def VCMPEQFP  : VCMP <198, "vcmpeqfp $vD, $vA, $vB" , v4f32>;
 551 def VCMPEQFPo : VCMPo<198, "vcmpeqfp. $vD, $vA, $vB", v4f32>;
 552 def VCMPGEFP  : VCMP <454, "vcmpgefp $vD, $vA, $vB" , v4f32>;
 553 def VCMPGEFPo : VCMPo<454, "vcmpgefp. $vD, $vA, $vB", v4f32>;
 554 def VCMPGTFP  : VCMP <710, "vcmpgtfp $vD, $vA, $vB" , v4f32>;
 555 def VCMPGTFPo : VCMPo<710, "vcmpgtfp. $vD, $vA, $vB", v4f32>;
 556
 557 // i8 element comparisons.
 558 def VCMPEQUB  : VCMP <  6, "vcmpequb $vD, $vA, $vB" , v16i8>;
 559 def VCMPEQUBo : VCMPo<  6, "vcmpequb. $vD, $vA, $vB", v16i8>;
 560 def VCMPGTSB  : VCMP <774, "vcmpgtsb $vD, $vA, $vB" , v16i8>;
 561 def VCMPGTSBo : VCMPo<774, "vcmpgtsb. $vD, $vA, $vB", v16i8>;
 562 def VCMPGTUB  : VCMP <518, "vcmpgtub $vD, $vA, $vB" , v16i8>;
 563 def VCMPGTUBo : VCMPo<518, "vcmpgtub. $vD, $vA, $vB", v16i8>;
 564
 565 // i16 element comparisons.
 566 def VCMPEQUH  : VCMP < 70, "vcmpequh $vD, $vA, $vB" , v8i16>;
 567 def VCMPEQUHo : VCMPo< 70, "vcmpequh. $vD, $vA, $vB", v8i16>;
 568 def VCMPGTSH  : VCMP <838, "vcmpgtsh $vD, $vA, $vB" , v8i16>;
 569 def VCMPGTSHo : VCMPo<838, "vcmpgtsh. $vD, $vA, $vB", v8i16>;
 570 def VCMPGTUH  : VCMP <582, "vcmpgtuh $vD, $vA, $vB" , v8i16>;
 571 def VCMPGTUHo : VCMPo<582, "vcmpgtuh. $vD, $vA, $vB", v8i16>;
 572
 573 // i32 element comparisons.
 574 def VCMPEQUW  : VCMP <134, "vcmpequw $vD, $vA, $vB" , v4i32>;
 575 def VCMPEQUWo : VCMPo<134, "vcmpequw. $vD, $vA, $vB", v4i32>;
 576 def VCMPGTSW  : VCMP <902, "vcmpgtsw $vD, $vA, $vB" , v4i32>;
 577 def VCMPGTSWo : VCMPo<902, "vcmpgtsw. $vD, $vA, $vB", v4i32>;
 578 def VCMPGTUW  : VCMP <646, "vcmpgtuw $vD, $vA, $vB" , v4i32>;
 579 def VCMPGTUWo : VCMPo<646, "vcmpgtuw. $vD, $vA, $vB", v4i32>;
 580
 581 def V_SET0 : VXForm_setzero<1220, (outs VRRC:$vD), (ins),
 582                       "vxor $vD, $vD, $vD", VecFP,
 583                       [(set VRRC:$vD, (v4i32 immAllZerosV))]>;
 584 let IMM=-1 in {
 585 def V_SETALLONES : VXForm_3<908, (outs VRRC:$vD), (ins),
 586                       "vspltisw $vD, -1", VecFP,
 587                       [(set VRRC:$vD, (v4i32 immAllOnesV))]>;
 588 }
 589 } // VALU Operations.
 590
 591 //===----------------------------------------------------------------------===//
 592 // Additional Altivec Patterns
 593 //
 594
 595 // DS* intrinsics
 596 def : Pat<(int_ppc_altivec_dssall), (DSSALL 1, 0, 0, 0)>;
 597 def : Pat<(int_ppc_altivec_dss imm:$STRM), (DSS 0, imm:$STRM, 0, 0)>;
 598
 599 //  * 32-bit
 600 def : Pat<(int_ppc_altivec_dst GPRC:$rA, GPRC:$rB, imm:$STRM),
 601           (DST 0, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 602 def : Pat<(int_ppc_altivec_dstt GPRC:$rA, GPRC:$rB, imm:$STRM),
 603           (DSTT 1, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 604 def : Pat<(int_ppc_altivec_dstst GPRC:$rA, GPRC:$rB, imm:$STRM),
 605           (DSTST 0, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 606 def : Pat<(int_ppc_altivec_dststt GPRC:$rA, GPRC:$rB, imm:$STRM),
 607           (DSTSTT 1, imm:$STRM, GPRC:$rA, GPRC:$rB)>;
 608
 609 //  * 64-bit
 610 def : Pat<(int_ppc_altivec_dst G8RC:$rA, GPRC:$rB, imm:$STRM),
 611           (DST64 0, imm:$STRM, (i64 G8RC:$rA), GPRC:$rB)>;
 612 def : Pat<(int_ppc_altivec_dstt G8RC:$rA, GPRC:$rB, imm:$STRM),
 613           (DSTT64 1, imm:$STRM, (i64 G8RC:$rA), GPRC:$rB)>;
 614 def : Pat<(int_ppc_altivec_dstst G8RC:$rA, GPRC:$rB, imm:$STRM),
 615           (DSTST64 0, imm:$STRM, (i64 G8RC:$rA), GPRC:$rB)>;
 616 def : Pat<(int_ppc_altivec_dststt G8RC:$rA, GPRC:$rB, imm:$STRM),
 617           (DSTSTT64 1, imm:$STRM, (i64 G8RC:$rA), GPRC:$rB)>;
 618
 619 // Loads.
 620 def : Pat<(v4i32 (load xoaddr:$src)), (LVX xoaddr:$src)>;
 621
 622 // Stores.
 623 def : Pat<(store (v4i32 VRRC:$rS), xoaddr:$dst),
 624           (STVX (v4i32 VRRC:$rS), xoaddr:$dst)>;
 625
 626 // Bit conversions.
 627 def : Pat<(v16i8 (bitconvert (v8i16 VRRC:$src))), (v16i8 VRRC:$src)>;
 628 def : Pat<(v16i8 (bitconvert (v4i32 VRRC:$src))), (v16i8 VRRC:$src)>;
 629 def : Pat<(v16i8 (bitconvert (v4f32 VRRC:$src))), (v16i8 VRRC:$src)>;
 630
 631 def : Pat<(v8i16 (bitconvert (v16i8 VRRC:$src))), (v8i16 VRRC:$src)>;
 632 def : Pat<(v8i16 (bitconvert (v4i32 VRRC:$src))), (v8i16 VRRC:$src)>;
 633 def : Pat<(v8i16 (bitconvert (v4f32 VRRC:$src))), (v8i16 VRRC:$src)>;
 634
 635 def : Pat<(v4i32 (bitconvert (v16i8 VRRC:$src))), (v4i32 VRRC:$src)>;
 636 def : Pat<(v4i32 (bitconvert (v8i16 VRRC:$src))), (v4i32 VRRC:$src)>;
 637 def : Pat<(v4i32 (bitconvert (v4f32 VRRC:$src))), (v4i32 VRRC:$src)>;
 638
 639 def : Pat<(v4f32 (bitconvert (v16i8 VRRC:$src))), (v4f32 VRRC:$src)>;
 640 def : Pat<(v4f32 (bitconvert (v8i16 VRRC:$src))), (v4f32 VRRC:$src)>;
 641 def : Pat<(v4f32 (bitconvert (v4i32 VRRC:$src))), (v4f32 VRRC:$src)>;
 642
 643 // Shuffles.
 644
 645 // Match vsldoi(x,x), vpkuwum(x,x), vpkuhum(x,x)
 646 def:Pat<(vsldoi_unary_shuffle:$in (v16i8 VRRC:$vA), undef),
 647         (VSLDOI VRRC:$vA, VRRC:$vA, (VSLDOI_unary_get_imm VRRC:$in))>;
 648 def:Pat<(vpkuwum_unary_shuffle (v16i8 VRRC:$vA), undef),
 649         (VPKUWUM VRRC:$vA, VRRC:$vA)>;
 650 def:Pat<(vpkuhum_unary_shuffle (v16i8 VRRC:$vA), undef),
 651         (VPKUHUM VRRC:$vA, VRRC:$vA)>;
 652
 653 // Match vmrg*(x,x)
 654 def:Pat<(vmrglb_unary_shuffle (v16i8 VRRC:$vA), undef),
 655         (VMRGLB VRRC:$vA, VRRC:$vA)>;
 656 def:Pat<(vmrglh_unary_shuffle (v16i8 VRRC:$vA), undef),
 657         (VMRGLH VRRC:$vA, VRRC:$vA)>;
 658 def:Pat<(vmrglw_unary_shuffle (v16i8 VRRC:$vA), undef),
 659         (VMRGLW VRRC:$vA, VRRC:$vA)>;
 660 def:Pat<(vmrghb_unary_shuffle (v16i8 VRRC:$vA), undef),
 661         (VMRGHB VRRC:$vA, VRRC:$vA)>;
 662 def:Pat<(vmrghh_unary_shuffle (v16i8 VRRC:$vA), undef),
 663         (VMRGHH VRRC:$vA, VRRC:$vA)>;
 664 def:Pat<(vmrghw_unary_shuffle (v16i8 VRRC:$vA), undef),
 665         (VMRGHW VRRC:$vA, VRRC:$vA)>;
 666
 667 // Logical Operations
 668 def : Pat<(v4i32 (vnot_ppc VRRC:$vA)), (VNOR VRRC:$vA, VRRC:$vA)>;
 669
 670 def : Pat<(v4i32 (vnot_ppc (or VRRC:$A, VRRC:$B))),
 671           (VNOR VRRC:$A, VRRC:$B)>;
 672 def : Pat<(v4i32 (and VRRC:$A, (vnot_ppc VRRC:$B))),
 673           (VANDC VRRC:$A, VRRC:$B)>;
 674
 675 def : Pat<(fmul VRRC:$vA, VRRC:$vB),
 676           (VMADDFP VRRC:$vA, VRRC:$vB,
 677              (v4i32 (VSLW (V_SETALLONES), (V_SETALLONES))))>;
 678
 679 // Fused multiply add and multiply sub for packed float.  These are represented
 680 // separately from the real instructions above, for operations that must have
 681 // the additional precision, such as Newton-Rhapson (used by divide, sqrt)
 682 def : Pat<(PPCvmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 683           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 684 def : Pat<(PPCvnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 685           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 686
 687 def : Pat<(int_ppc_altivec_vmaddfp VRRC:$A, VRRC:$B, VRRC:$C),
 688           (VMADDFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 689 def : Pat<(int_ppc_altivec_vnmsubfp VRRC:$A, VRRC:$B, VRRC:$C),
 690           (VNMSUBFP VRRC:$A, VRRC:$B, VRRC:$C)>;
 691
 692 def : Pat<(PPCvperm (v16i8 VRRC:$vA), VRRC:$vB, VRRC:$vC),
 693           (VPERM VRRC:$vA, VRRC:$vB, VRRC:$vC)>;
 694
 695 // Vector shifts
 696 def : Pat<(v16i8 (shl (v16i8 VRRC:$vA), (v16i8 VRRC:$vB))),
 697           (v16i8 (VSLB VRRC:$vA, VRRC:$vB))>;
 698 def : Pat<(v8i16 (shl (v8i16 VRRC:$vA), (v8i16 VRRC:$vB))),
 699           (v8i16 (VSLH VRRC:$vA, VRRC:$vB))>;
 700 def : Pat<(v4i32 (shl (v4i32 VRRC:$vA), (v4i32 VRRC:$vB))),
 701           (v4i32 (VSLW VRRC:$vA, VRRC:$vB))>;
 702
 703 def : Pat<(v16i8 (srl (v16i8 VRRC:$vA), (v16i8 VRRC:$vB))),
 704           (v16i8 (VSRB VRRC:$vA, VRRC:$vB))>;
 705 def : Pat<(v8i16 (srl (v8i16 VRRC:$vA), (v8i16 VRRC:$vB))),
 706           (v8i16 (VSRH VRRC:$vA, VRRC:$vB))>;
 707 def : Pat<(v4i32 (srl (v4i32 VRRC:$vA), (v4i32 VRRC:$vB))),
 708           (v4i32 (VSRW VRRC:$vA, VRRC:$vB))>;
 709
 710 def : Pat<(v16i8 (sra (v16i8 VRRC:$vA), (v16i8 VRRC:$vB))),
 711           (v16i8 (VSRAB VRRC:$vA, VRRC:$vB))>;
 712 def : Pat<(v8i16 (sra (v8i16 VRRC:$vA), (v8i16 VRRC:$vB))),
 713           (v8i16 (VSRAH VRRC:$vA, VRRC:$vB))>;
 714 def : Pat<(v4i32 (sra (v4i32 VRRC:$vA), (v4i32 VRRC:$vB))),
 715           (v4i32 (VSRAW VRRC:$vA, VRRC:$vB))>;
 716
 717 // Float to integer and integer to float conversions
 718 def : Pat<(v4i32 (fp_to_sint (v4f32 VRRC:$vA))),
 719            (VCTSXS_0 VRRC:$vA)>;
 720 def : Pat<(v4i32 (fp_to_uint (v4f32 VRRC:$vA))),
 721            (VCTUXS_0 VRRC:$vA)>;
 722 def : Pat<(v4f32 (sint_to_fp (v4i32 VRRC:$vA))),
 723            (VCFSX_0 VRRC:$vA)>;
 724 def : Pat<(v4f32 (uint_to_fp (v4i32 VRRC:$vA))),
 725            (VCFUX_0 VRRC:$vA)>;
 726
 727 // Floating-point rounding
 728 def : Pat<(v4f32 (ffloor (v4f32 VRRC:$vA))),
 729           (VRFIM VRRC:$vA)>;
 730 def : Pat<(v4f32 (fceil (v4f32 VRRC:$vA))),
 731           (VRFIP VRRC:$vA)>;
 732 def : Pat<(v4f32 (ftrunc (v4f32 VRRC:$vA))),
 733           (VRFIZ VRRC:$vA)>;
 734 def : Pat<(v4f32 (fnearbyint (v4f32 VRRC:$vA))),
 735           (VRFIN VRRC:$vA)>;