lib/Target/PowerPC/PPCInstrFormats.td

   1 //===- PowerPCInstrFormats.td - PowerPC Instruction Formats --*- tablegen -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 //
  11 //===----------------------------------------------------------------------===//
  12
  13 class Format<bits<5> val> {
  14   bits<5> Value = val;
  15 }
  16
  17 def Pseudo: Format<0>;
  18 def Gpr : Format<1>;
  19 def Gpr0 : Format<2>;
  20 def Simm16 : Format<3>;
  21 def PCRelimm24 : Format<5>;
  22 def Imm24 : Format<6>;
  23 def Imm5 : Format<7>;
  24 def PCRelimm14 : Format<8>;
  25 def Imm14 : Format<9>;
  26 def Imm2 : Format<10>;
  27 def Crf : Format<11>;
  28 def Imm3 : Format<12>;
  29 def Imm1 : Format<13>;
  30 def Fpr : Format<14>;
  31 def Imm4 : Format<15>;
  32 def Imm8 : Format<16>;
  33 def Disimm16 : Format<17>;
  34 def Disimm14 : Format<18>;
  35 def Spr : Format<19>;
  36 def Sgr : Format<20>;
  37 def Imm15 : Format<21>;
  38 def Vpr : Format<22>;
  39 def Imm6 : Format<23>;
  40
  41 //===----------------------------------------------------------------------===//
  42 //
  43 // PowerPC instruction formats
  44
  45 class I<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
  46   : Instruction {
  47   field bits<32> Inst;
  48
  49   bit PPC64 = ppc64;
  50   bit VMX = vmx;
  51
  52   let Name = "";
  53   let Namespace = "PPC";
  54   let Inst{0-5} = opcode;
  55   let OperandList = OL;
  56   let AsmString = asmstr;
  57 }
  58
  59 // 1.7.1 I-Form
  60 class IForm<bits<6> opcode, bit aa, bit lk, bit ppc64, bit vmx,
  61             dag OL, string asmstr> : I<opcode, ppc64, vmx, OL, asmstr> {
  62   bits<24> LI;
  63
  64   let Inst{6-29}  = LI;
  65   let Inst{30}    = aa;
  66   let Inst{31}    = lk;
  67 }
  68
  69 // 1.7.2 B-Form
  70 class BForm<bits<6> opcode, bit aa, bit lk, bit ppc64, bit vmx,
  71             dag OL, string asmstr> : I<opcode, ppc64, vmx, OL, asmstr> {
  72   bits<5>  BO;
  73   bits<3>  CRNum;
  74   bits<2>  BICode;
  75   bits<14> BD;
  76
  77   let Inst{6-10}  = BO;
  78   let Inst{11-13} = CRNum;
  79   let Inst{14-15} = BICode;
  80   let Inst{16-29} = BD;
  81   let Inst{30}    = aa;
  82   let Inst{31}    = lk;
  83 }
  84
  85 class BForm_ext<bits<6> opcode, bit aa, bit lk, bits<5> bo, bits<2> bicode,
  86                 bit ppc64, bit vmx, dag OL, string asmstr>
  87   : BForm<opcode, aa, lk, ppc64, vmx, OL, asmstr> {
  88   let BO = bo;
  89   let BICode = bicode;
  90 }
  91
  92 // 1.7.4 D-Form
  93 class DForm_base<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
  94   : I<opcode, ppc64, vmx, OL, asmstr> {
  95   bits<5>  A;
  96   bits<5>  B;
  97   bits<16> C;
  98
  99   let Inst{6-10}  = A;
 100   let Inst{11-15} = B;
 101   let Inst{16-31} = C;
 102 }
 103
 104 class DForm_1<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 105   : I<opcode, ppc64, vmx, OL, asmstr> {
 106   bits<5>  A;
 107   bits<16> C;
 108   bits<5>  B;
 109
 110   let Inst{6-10}  = A;
 111   let Inst{11-15} = B;
 112   let Inst{16-31} = C;
 113 }
 114
 115 class DForm_2<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 116   : DForm_base<opcode, ppc64, vmx, OL, asmstr>;
 117
 118 class DForm_2_r0<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 119   : I<opcode, ppc64, vmx, OL, asmstr> {
 120   bits<5>  A;
 121   bits<16> B;
 122
 123   let Inst{6-10}  = A;
 124   let Inst{11-15} = 0;
 125   let Inst{16-31} = B;
 126 }
 127
 128 // Currently we make the use/def reg distinction in ISel, not tablegen
 129 class DForm_3<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 130   : DForm_1<opcode, ppc64, vmx, OL, asmstr>;
 131
 132 class DForm_4<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 133   : I<opcode, ppc64, vmx, OL, asmstr> {
 134   bits<5>  B;
 135   bits<5>  A;
 136   bits<16> C;
 137
 138   let Inst{6-10}  = A;
 139   let Inst{11-15} = B;
 140   let Inst{16-31} = C;
 141 }
 142
 143 class DForm_4_zero<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 144   : DForm_1<opcode, ppc64, vmx, OL, asmstr> {
 145   let A = 0;
 146   let B = 0;
 147   let C = 0;
 148 }
 149
 150 class DForm_5<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 151   : I<opcode, ppc64, vmx, OL, asmstr> {
 152   bits<3>  BF;
 153   bits<1>  L;
 154   bits<5>  RA;
 155   bits<16> I;
 156
 157   let Inst{6-8}   = BF;
 158   let Inst{9}     = 0;
 159   let Inst{10}    = L;
 160   let Inst{11-15} = RA;
 161   let Inst{16-31} = I;
 162 }
 163
 164 class DForm_5_ext<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 165   : DForm_5<opcode, ppc64, vmx, OL, asmstr> {
 166   let L = ppc64;
 167 }
 168
 169 class DForm_6<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 170   : DForm_5<opcode, ppc64, vmx, OL, asmstr>;
 171
 172 class DForm_6_ext<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 173   : DForm_6<opcode, ppc64, vmx, OL, asmstr> {
 174   let L = ppc64;
 175 }
 176
 177 class DForm_8<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 178   : DForm_1<opcode, ppc64, vmx, OL, asmstr> {
 179 }
 180
 181 class DForm_9<bits<6> opcode, bit ppc64, bit vmx, dag OL, string asmstr>
 182   : DForm_1<opcode, ppc64, vmx, OL, asmstr> {
 183 }
 184
 185 // 1.7.5 DS-Form
 186 class DSForm_1<bits<6> opcode, bits<2> xo, bit ppc64, bit vmx,
 187                dag OL, string asmstr> : I<opcode, ppc64, vmx, OL, asmstr> {
 188   bits<5>  RST;
 189   bits<14> DS;
 190   bits<5>  RA;
 191
 192   let Inst{6-10}  = RST;
 193   let Inst{11-15} = RA;
 194   let Inst{16-29} = DS;
 195   let Inst{30-31} = xo;
 196 }
 197
 198 class DSForm_2<bits<6> opcode, bits<2> xo, bit ppc64, bit vmx,
 199                dag OL, string asmstr>
 200   : DSForm_1<opcode, xo, ppc64, vmx, OL, asmstr>;
 201
 202 // 1.7.6 X-Form
 203 class XForm_base_r3xo<bits<6> opcode, bits<10> xo, bit rc,
 204                       dag OL, string asmstr>
 205   : I<opcode, 0, 0, OL, asmstr> {
 206   bits<5> RST;
 207   bits<5> A;
 208   bits<5> B;
 209
 210   let Inst{6-10}  = RST;
 211   let Inst{11-15} = A;
 212   let Inst{16-20} = B;
 213   let Inst{21-30} = xo;
 214   let Inst{31}    = rc;
 215 }
 216
 217 // This is the same as XForm_base_r3xo, but the first two operands are swapped
 218 // when code is emitted.
 219 class XForm_base_r3xo_swapped
 220         <bits<6> opcode, bits<10> xo, bit rc, dag OL, string asmstr>
 221   : I<opcode, 0, 0, OL, asmstr> {
 222   bits<5> A;
 223   bits<5> RST;
 224   bits<5> B;
 225
 226   let Inst{6-10}  = RST;
 227   let Inst{11-15} = A;
 228   let Inst{16-20} = B;
 229   let Inst{21-30} = xo;
 230   let Inst{31}    = rc;
 231 }
 232
 233
 234 class XForm_1<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 235   : XForm_base_r3xo<opcode, xo, 0, OL, asmstr>;
 236
 237 class XForm_6<bits<6> opcode, bits<10> xo, bit rc, dag OL, string asmstr>
 238   : XForm_base_r3xo_swapped<opcode, xo, rc, OL, asmstr>;
 239
 240 class XForm_8<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 241   : XForm_base_r3xo<opcode, xo, 0, OL, asmstr>;
 242
 243 class XForm_10<bits<6> opcode, bits<10> xo, bit rc, dag OL, string asmstr>
 244   : XForm_base_r3xo_swapped<opcode, xo, rc, OL, asmstr> {
 245 }
 246
 247 class XForm_11<bits<6> opcode, bits<10> xo, bit rc, dag OL, string asmstr>
 248   : XForm_base_r3xo_swapped<opcode, xo, rc, OL, asmstr> {
 249   let B = 0;
 250 }
 251
 252 class XForm_16<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 253          : I<opcode, 0, 0, OL, asmstr> {
 254   bits<3> BF;
 255   bits<1> L;
 256   bits<5> RA;
 257   bits<5> RB;
 258
 259   let Inst{6-8}   = BF;
 260   let Inst{9}     = 0;
 261   let Inst{10}    = L;
 262   let Inst{11-15} = RA;
 263   let Inst{16-20} = RB;
 264   let Inst{21-30} = xo;
 265   let Inst{31}    = 0;
 266 }
 267
 268 class XForm_16_ext<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 269   : XForm_16<opcode, xo, OL, asmstr> {
 270   let L = PPC64;
 271 }
 272
 273 class XForm_17<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 274          : I<opcode, 0, 0, OL, asmstr> {
 275   bits<3> BF;
 276   bits<5> FRA;
 277   bits<5> FRB;
 278
 279   let Inst{6-8}   = BF;
 280   let Inst{9-10}  = 0;
 281   let Inst{11-15} = FRA;
 282   let Inst{16-20} = FRB;
 283   let Inst{21-30} = xo;
 284   let Inst{31}    = 0;
 285 }
 286
 287 class XForm_25<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 288   : XForm_base_r3xo<opcode, xo, 0, OL, asmstr> {
 289 }
 290
 291 class XForm_26<bits<6> opcode, bits<10> xo, bit rc, dag OL, string asmstr>
 292   : XForm_base_r3xo<opcode, xo, rc, OL, asmstr> {
 293   let A = 0;
 294 }
 295
 296 class XForm_28<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 297   : XForm_base_r3xo<opcode, xo, 0, OL, asmstr> {
 298 }
 299
 300 // 1.7.7 XL-Form
 301 class XLForm_1<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 302          : I<opcode, 0, 0, OL, asmstr> {
 303   bits<3> CRD;
 304   bits<2> CRDb;
 305   bits<3> CRA;
 306   bits<2> CRAb;
 307   bits<3> CRB;
 308   bits<2> CRBb;
 309
 310   let Inst{6-8}   = CRD;
 311   let Inst{9-10}  = CRDb;
 312   let Inst{11-13} = CRA;
 313   let Inst{14-15} = CRAb;
 314   let Inst{16-18} = CRB;
 315   let Inst{19-20} = CRBb;
 316   let Inst{21-30} = xo;
 317   let Inst{31}    = 0;
 318 }
 319
 320 class XLForm_2<bits<6> opcode, bits<10> xo, bit lk,
 321                dag OL, string asmstr> : I<opcode, 0, 0, OL, asmstr> {
 322   bits<5> BO;
 323   bits<5> BI;
 324   bits<2> BH;
 325
 326   let Inst{6-10}  = BO;
 327   let Inst{11-15} = BI;
 328   let Inst{16-18} = 0;
 329   let Inst{19-20} = BH;
 330   let Inst{21-30} = xo;
 331   let Inst{31}    = lk;
 332 }
 333
 334 class XLForm_2_ext<bits<6> opcode, bits<10> xo, bits<5> bo,
 335                    bits<5> bi, bit lk, dag OL, string asmstr>
 336   : XLForm_2<opcode, xo, lk, OL, asmstr> {
 337   let BO = bo;
 338   let BI = bi;
 339   let BH = 0;
 340 }
 341
 342 class XLForm_3<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 343          : I<opcode, 0, 0, OL, asmstr> {
 344   bits<3> BF;
 345   bits<3> BFA;
 346
 347   let Inst{6-8}   = BF;
 348   let Inst{9-10}  = 0;
 349   let Inst{11-13} = BFA;
 350   let Inst{14-15} = 0;
 351   let Inst{16-20} = 0;
 352   let Inst{21-30} = xo;
 353   let Inst{31}    = 0;
 354 }
 355
 356 // 1.7.8 XFX-Form
 357 class XFXForm_1<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 358          : I<opcode, 0, 0, OL, asmstr> {
 359   bits<5>  RT;
 360   bits<10> SPR;
 361
 362   let Inst{6-10}  = RT;
 363   let Inst{11-20} = SPR;
 364   let Inst{21-30} = xo;
 365   let Inst{31}    = 0;
 366 }
 367
 368 class XFXForm_1_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 369                    dag OL, string asmstr>
 370   : XFXForm_1<opcode, xo, OL, asmstr> {
 371   let SPR = spr;
 372 }
 373
 374 class XFXForm_3<bits<6> opcode, bits<10> xo,
 375                 dag OL, string asmstr> : I<opcode, 0, 0, OL, asmstr> {
 376   bits<5>  RT;
 377
 378   let Inst{6-10}  = RT;
 379   let Inst{11-20} = 0;
 380   let Inst{21-30} = xo;
 381   let Inst{31}    = 0;
 382 }
 383
 384 class XFXForm_5<bits<6> opcode, bit mfcrf, bits<10> xo,
 385                 dag OL, string asmstr> : I<opcode, 0, 0, OL, asmstr> {
 386   bits<8>  FXM;
 387   bits<5>  ST;
 388
 389   let Inst{6-10}  = ST;
 390   let Inst{11}    = mfcrf;
 391   let Inst{12-19} = FXM;
 392   let Inst{20}    = 0;
 393   let Inst{21-30} = xo;
 394   let Inst{31}    = 0;
 395 }
 396
 397 class XFXForm_7<bits<6> opcode, bits<10> xo, dag OL, string asmstr>
 398   : XFXForm_1<opcode, xo, OL, asmstr>;
 399
 400 class XFXForm_7_ext<bits<6> opcode, bits<10> xo, bits<10> spr,
 401                     dag OL, string asmstr>
 402   : XFXForm_7<opcode, xo, OL, asmstr> {
 403   let SPR = spr;
 404 }
 405
 406 // 1.7.10 XS-Form
 407 class XSForm_1<bits<6> opcode, bits<9> xo, bit rc,
 408                dag OL, string asmstr> : I<opcode, 0, 0, OL, asmstr> {
 409   bits<5> RS;
 410   bits<5> A;
 411   bits<6> SH;
 412
 413   let Inst{6-10}  = RS;
 414   let Inst{11-15} = A;
 415   let Inst{16-20} = SH{1-5};
 416   let Inst{21-29} = xo;
 417   let Inst{30}    = SH{0};
 418   let Inst{31}    = rc;
 419 }
 420
 421 // 1.7.11 XO-Form
 422 class XOForm_1<bits<6> opcode, bits<9> xo, bit oe, bit rc,
 423                dag OL, string asmstr> : I<opcode, 0, 0, OL, asmstr> {
 424   bits<5> RT;
 425   bits<5> RA;
 426   bits<5> RB;
 427
 428   let Inst{6-10}  = RT;
 429   let Inst{11-15} = RA;
 430   let Inst{16-20} = RB;
 431   let Inst{21}    = oe;
 432   let Inst{22-30} = xo;
 433   let Inst{31}    = rc;
 434 }
 435
 436 class XOForm_1r<bits<6> opcode, bits<9> xo, bit oe, bit rc,
 437                dag OL, string asmstr>
 438   : XOForm_1<opcode, xo, oe, rc, OL, asmstr> {
 439   let Inst{11-15} = RB;
 440   let Inst{16-20} = RA;
 441 }
 442
 443 class XOForm_3<bits<6> opcode, bits<9> xo, bit oe, bit rc,
 444                dag OL, string asmstr>
 445   : XOForm_1<opcode, xo, oe, rc, OL, asmstr> {
 446   let RB = 0;
 447 }
 448
 449 // 1.7.12 A-Form
 450 class AForm_1<bits<6> opcode, bits<5> xo, bit rc, dag OL, string asmstr>
 451          : I<opcode, 0, 0, OL, asmstr> {
 452   bits<5> FRT;
 453   bits<5> FRA;
 454   bits<5> FRC;
 455   bits<5> FRB;
 456
 457   let Inst{6-10}  = FRT;
 458   let Inst{11-15} = FRA;
 459   let Inst{16-20} = FRB;
 460   let Inst{21-25} = FRC;
 461   let Inst{26-30} = xo;
 462   let Inst{31}    = rc;
 463 }
 464
 465 class AForm_2<bits<6> opcode, bits<5> xo, bit rc, dag OL, string asmstr>
 466   : AForm_1<opcode, xo, rc, OL, asmstr> {
 467   let FRC = 0;
 468 }
 469
 470 class AForm_3<bits<6> opcode, bits<5> xo, bit rc, dag OL,
 471               string asmstr>
 472   : AForm_1<opcode, xo, rc, OL, asmstr> {
 473   let FRB = 0;
 474 }
 475
 476 // 1.7.13 M-Form
 477 class MForm_1<bits<6> opcode, bit rc, dag OL, string asmstr>
 478          : I<opcode, 0, 0, OL, asmstr> {
 479   bits<5> RA;
 480   bits<5> RS;
 481   bits<5> RB;
 482   bits<5> MB;
 483   bits<5> ME;
 484
 485   let Inst{6-10}  = RS;
 486   let Inst{11-15} = RA;
 487   let Inst{16-20} = RB;
 488   let Inst{21-25} = MB;
 489   let Inst{26-30} = ME;
 490   let Inst{31}    = rc;
 491 }
 492
 493 class MForm_2<bits<6> opcode, bit rc, dag OL, string asmstr>
 494   : MForm_1<opcode, rc, OL, asmstr> {
 495 }
 496
 497 // 1.7.14 MD-Form
 498 class MDForm_1<bits<6> opcode, bits<3> xo, bit rc,
 499                dag OL, string asmstr> : I<opcode, 0, 0, OL, asmstr> {
 500   bits<5> RS;
 501   bits<5> RA;
 502   bits<6> SH;
 503   bits<6> MBE;
 504
 505   let Inst{6-10}  = RS;
 506   let Inst{11-15} = RA;
 507   let Inst{16-20} = SH{1-5};
 508   let Inst{21-26} = MBE;
 509   let Inst{27-29} = xo;
 510   let Inst{30}    = SH{0};
 511   let Inst{31}    = rc;
 512 }
 513
 514 //===----------------------------------------------------------------------===//
 515
 516 class Pseudo<dag OL, string asmstr> : I<0, 0, 0, OL, asmstr> {
 517   let PPC64 = 0;
 518   let VMX = 0;
 519
 520   let Inst{31-0} = 0;
 521 }