lib/Target/PowerPC/PPCInstrInfo.td

   1 //===-- PPCInstrInfo.td - The PowerPC Instruction Set ------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the subset of the 32-bit PowerPC instruction set, as used
  11 // by the PowerPC instruction selector.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 include "PPCInstrFormats.td"
  16
  17 //===----------------------------------------------------------------------===//
  18 // PowerPC specific type constraints.
  19 //
  20 def SDT_PPCstfiwx : SDTypeProfile<0, 2, [ // stfiwx
  21   SDTCisVT<0, f64>, SDTCisPtrTy<1>
  22 ]>;
  23 def SDT_PPCCallSeqStart : SDCallSeqStart<[ SDTCisVT<0, i32> ]>;
  24 def SDT_PPCCallSeqEnd   : SDCallSeqEnd<[ SDTCisVT<0, i32>,
  25                                          SDTCisVT<1, i32> ]>;
  26 def SDT_PPCvperm   : SDTypeProfile<1, 3, [
  27   SDTCisVT<3, v16i8>, SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>
  28 ]>;
  29
  30 def SDT_PPCvcmp : SDTypeProfile<1, 3, [
  31   SDTCisSameAs<0, 1>, SDTCisSameAs<1, 2>, SDTCisVT<3, i32>
  32 ]>;
  33
  34 def SDT_PPCcondbr : SDTypeProfile<0, 3, [
  35   SDTCisVT<0, i32>, SDTCisVT<2, OtherVT>
  36 ]>;
  37
  38 def SDT_PPClbrx : SDTypeProfile<1, 2, [
  39   SDTCisVT<0, i32>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>
  40 ]>;
  41 def SDT_PPCstbrx : SDTypeProfile<0, 3, [
  42   SDTCisVT<0, i32>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>
  43 ]>;
  44
  45 def SDT_PPClarx : SDTypeProfile<1, 1, [
  46   SDTCisInt<0>, SDTCisPtrTy<1>
  47 ]>;
  48 def SDT_PPCstcx : SDTypeProfile<0, 2, [
  49   SDTCisInt<0>, SDTCisPtrTy<1>
  50 ]>;
  51
  52 def SDT_PPCTC_ret : SDTypeProfile<0, 2, [
  53   SDTCisPtrTy<0>, SDTCisVT<1, i32>
  54 ]>;
  55
  56 def SDT_PPCnop : SDTypeProfile<0, 0, []>;
  57
  58 //===----------------------------------------------------------------------===//
  59 // PowerPC specific DAG Nodes.
  60 //
  61
  62 def PPCfcfid  : SDNode<"PPCISD::FCFID" , SDTFPUnaryOp, []>;
  63 def PPCfctidz : SDNode<"PPCISD::FCTIDZ", SDTFPUnaryOp, []>;
  64 def PPCfctiwz : SDNode<"PPCISD::FCTIWZ", SDTFPUnaryOp, []>;
  65 def PPCstfiwx : SDNode<"PPCISD::STFIWX", SDT_PPCstfiwx,
  66                        [SDNPHasChain, SDNPMayStore]>;
  67
  68 // This sequence is used for long double->int conversions.  It changes the
  69 // bits in the FPSCR which is not modelled.
  70 def PPCmffs   : SDNode<"PPCISD::MFFS", SDTypeProfile<1, 0, [SDTCisVT<0, f64>]>,
  71                         [SDNPOutGlue]>;
  72 def PPCmtfsb0 : SDNode<"PPCISD::MTFSB0", SDTypeProfile<0, 1, [SDTCisInt<0>]>,
  73                        [SDNPInGlue, SDNPOutGlue]>;
  74 def PPCmtfsb1 : SDNode<"PPCISD::MTFSB1", SDTypeProfile<0, 1, [SDTCisInt<0>]>,
  75                        [SDNPInGlue, SDNPOutGlue]>;
  76 def PPCfaddrtz: SDNode<"PPCISD::FADDRTZ", SDTFPBinOp,
  77                        [SDNPInGlue, SDNPOutGlue]>;
  78 def PPCmtfsf  : SDNode<"PPCISD::MTFSF", SDTypeProfile<1, 3,
  79                        [SDTCisVT<0, f64>, SDTCisInt<1>, SDTCisVT<2, f64>,
  80                         SDTCisVT<3, f64>]>,
  81                        [SDNPInGlue]>;
  82
  83 def PPCfsel   : SDNode<"PPCISD::FSEL",
  84    // Type constraint for fsel.
  85    SDTypeProfile<1, 3, [SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>,
  86                         SDTCisFP<0>, SDTCisVT<1, f64>]>, []>;
  87
  88 def PPChi       : SDNode<"PPCISD::Hi", SDTIntBinOp, []>;
  89 def PPClo       : SDNode<"PPCISD::Lo", SDTIntBinOp, []>;
  90 def PPCtoc_entry: SDNode<"PPCISD::TOC_ENTRY", SDTIntBinOp, [SDNPMayLoad]>;
  91 def PPCvmaddfp  : SDNode<"PPCISD::VMADDFP", SDTFPTernaryOp, []>;
  92 def PPCvnmsubfp : SDNode<"PPCISD::VNMSUBFP", SDTFPTernaryOp, []>;
  93
  94 def PPCvperm    : SDNode<"PPCISD::VPERM", SDT_PPCvperm, []>;
  95
  96 // These nodes represent the 32-bit PPC shifts that operate on 6-bit shift
  97 // amounts.  These nodes are generated by the multi-precision shift code.
  98 def PPCsrl        : SDNode<"PPCISD::SRL"       , SDTIntShiftOp>;
  99 def PPCsra        : SDNode<"PPCISD::SRA"       , SDTIntShiftOp>;
 100 def PPCshl        : SDNode<"PPCISD::SHL"       , SDTIntShiftOp>;
 101
 102 def PPCextsw_32   : SDNode<"PPCISD::EXTSW_32"  , SDTIntUnaryOp>;
 103 def PPCstd_32     : SDNode<"PPCISD::STD_32"    , SDTStore,
 104                            [SDNPHasChain, SDNPMayStore]>;
 105
 106 // These are target-independent nodes, but have target-specific formats.
 107 def callseq_start : SDNode<"ISD::CALLSEQ_START", SDT_PPCCallSeqStart,
 108                            [SDNPHasChain, SDNPOutGlue]>;
 109 def callseq_end   : SDNode<"ISD::CALLSEQ_END",   SDT_PPCCallSeqEnd,
 110                            [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 111
 112 def SDT_PPCCall   : SDTypeProfile<0, -1, [SDTCisInt<0>]>;
 113 def PPCcall_Darwin : SDNode<"PPCISD::CALL_Darwin", SDT_PPCCall,
 114                             [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 115                              SDNPVariadic]>;
 116 def PPCcall_SVR4  : SDNode<"PPCISD::CALL_SVR4", SDT_PPCCall,
 117                            [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 118                             SDNPVariadic]>;
 119 def PPCcall_nop_SVR4  : SDNode<"PPCISD::CALL_NOP_SVR4", SDT_PPCCall,
 120                                [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 121                                 SDNPVariadic]>;
 122 def PPCnop : SDNode<"PPCISD::NOP", SDT_PPCnop, [SDNPInGlue, SDNPOutGlue]>;
 123 def PPCload   : SDNode<"PPCISD::LOAD", SDTypeProfile<1, 1, []>,
 124                        [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 125 def PPCload_toc : SDNode<"PPCISD::LOAD_TOC", SDTypeProfile<0, 1, []>,
 126                           [SDNPHasChain, SDNPInGlue, SDNPOutGlue]>;
 127 def PPCtoc_restore : SDNode<"PPCISD::TOC_RESTORE", SDTypeProfile<0, 0, []>,
 128                             [SDNPHasChain, SDNPInGlue, SDNPOutGlue]>;
 129 def PPCmtctr      : SDNode<"PPCISD::MTCTR", SDT_PPCCall,
 130                            [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue]>;
 131 def PPCbctrl_Darwin  : SDNode<"PPCISD::BCTRL_Darwin", SDTNone,
 132                               [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 133                                SDNPVariadic]>;
 134
 135 def PPCbctrl_SVR4  : SDNode<"PPCISD::BCTRL_SVR4", SDTNone,
 136                             [SDNPHasChain, SDNPOptInGlue, SDNPOutGlue,
 137                              SDNPVariadic]>;
 138
 139 def retflag       : SDNode<"PPCISD::RET_FLAG", SDTNone,
 140                            [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
 141
 142 def PPCtc_return : SDNode<"PPCISD::TC_RETURN", SDT_PPCTC_ret,
 143                         [SDNPHasChain,  SDNPOptInGlue, SDNPVariadic]>;
 144
 145 def PPCvcmp       : SDNode<"PPCISD::VCMP" , SDT_PPCvcmp, []>;
 146 def PPCvcmp_o     : SDNode<"PPCISD::VCMPo", SDT_PPCvcmp, [SDNPOutGlue]>;
 147
 148 def PPCcondbranch : SDNode<"PPCISD::COND_BRANCH", SDT_PPCcondbr,
 149                            [SDNPHasChain, SDNPOptInGlue]>;
 150
 151 def PPClbrx       : SDNode<"PPCISD::LBRX", SDT_PPClbrx,
 152                            [SDNPHasChain, SDNPMayLoad]>;
 153 def PPCstbrx      : SDNode<"PPCISD::STBRX", SDT_PPCstbrx,
 154                            [SDNPHasChain, SDNPMayStore]>;
 155
 156 // Instructions to support atomic operations
 157 def PPClarx      : SDNode<"PPCISD::LARX", SDT_PPClarx,
 158                           [SDNPHasChain, SDNPMayLoad]>;
 159 def PPCstcx      : SDNode<"PPCISD::STCX", SDT_PPCstcx,
 160                           [SDNPHasChain, SDNPMayStore]>;
 161
 162 // Instructions to support dynamic alloca.
 163 def SDTDynOp  : SDTypeProfile<1, 2, []>;
 164 def PPCdynalloc   : SDNode<"PPCISD::DYNALLOC", SDTDynOp, [SDNPHasChain]>;
 165
 166 //===----------------------------------------------------------------------===//
 167 // PowerPC specific transformation functions and pattern fragments.
 168 //
 169
 170 def SHL32 : SDNodeXForm<imm, [{
 171   // Transformation function: 31 - imm
 172   return getI32Imm(31 - N->getZExtValue());
 173 }]>;
 174
 175 def SRL32 : SDNodeXForm<imm, [{
 176   // Transformation function: 32 - imm
 177   return N->getZExtValue() ? getI32Imm(32 - N->getZExtValue()) : getI32Imm(0);
 178 }]>;
 179
 180 def LO16 : SDNodeXForm<imm, [{
 181   // Transformation function: get the low 16 bits.
 182   return getI32Imm((unsigned short)N->getZExtValue());
 183 }]>;
 184
 185 def HI16 : SDNodeXForm<imm, [{
 186   // Transformation function: shift the immediate value down into the low bits.
 187   return getI32Imm((unsigned)N->getZExtValue() >> 16);
 188 }]>;
 189
 190 def HA16 : SDNodeXForm<imm, [{
 191   // Transformation function: shift the immediate value down into the low bits.
 192   signed int Val = N->getZExtValue();
 193   return getI32Imm((Val - (signed short)Val) >> 16);
 194 }]>;
 195 def MB : SDNodeXForm<imm, [{
 196   // Transformation function: get the start bit of a mask
 197   unsigned mb = 0, me;
 198   (void)isRunOfOnes((unsigned)N->getZExtValue(), mb, me);
 199   return getI32Imm(mb);
 200 }]>;
 201
 202 def ME : SDNodeXForm<imm, [{
 203   // Transformation function: get the end bit of a mask
 204   unsigned mb, me = 0;
 205   (void)isRunOfOnes((unsigned)N->getZExtValue(), mb, me);
 206   return getI32Imm(me);
 207 }]>;
 208 def maskimm32 : PatLeaf<(imm), [{
 209   // maskImm predicate - True if immediate is a run of ones.
 210   unsigned mb, me;
 211   if (N->getValueType(0) == MVT::i32)
 212     return isRunOfOnes((unsigned)N->getZExtValue(), mb, me);
 213   else
 214     return false;
 215 }]>;
 216
 217 def immSExt16  : PatLeaf<(imm), [{
 218   // immSExt16 predicate - True if the immediate fits in a 16-bit sign extended
 219   // field.  Used by instructions like 'addi'.
 220   if (N->getValueType(0) == MVT::i32)
 221     return (int32_t)N->getZExtValue() == (short)N->getZExtValue();
 222   else
 223     return (int64_t)N->getZExtValue() == (short)N->getZExtValue();
 224 }]>;
 225 def immZExt16  : PatLeaf<(imm), [{
 226   // immZExt16 predicate - True if the immediate fits in a 16-bit zero extended
 227   // field.  Used by instructions like 'ori'.
 228   return (uint64_t)N->getZExtValue() == (unsigned short)N->getZExtValue();
 229 }], LO16>;
 230
 231 // imm16Shifted* - These match immediates where the low 16-bits are zero.  There
 232 // are two forms: imm16ShiftedSExt and imm16ShiftedZExt.  These two forms are
 233 // identical in 32-bit mode, but in 64-bit mode, they return true if the
 234 // immediate fits into a sign/zero extended 32-bit immediate (with the low bits
 235 // clear).
 236 def imm16ShiftedZExt : PatLeaf<(imm), [{
 237   // imm16ShiftedZExt predicate - True if only bits in the top 16-bits of the
 238   // immediate are set.  Used by instructions like 'xoris'.
 239   return (N->getZExtValue() & ~uint64_t(0xFFFF0000)) == 0;
 240 }], HI16>;
 241
 242 def imm16ShiftedSExt : PatLeaf<(imm), [{
 243   // imm16ShiftedSExt predicate - True if only bits in the top 16-bits of the
 244   // immediate are set.  Used by instructions like 'addis'.  Identical to
 245   // imm16ShiftedZExt in 32-bit mode.
 246   if (N->getZExtValue() & 0xFFFF) return false;
 247   if (N->getValueType(0) == MVT::i32)
 248     return true;
 249   // For 64-bit, make sure it is sext right.
 250   return N->getZExtValue() == (uint64_t)(int)N->getZExtValue();
 251 }], HI16>;
 252
 253
 254 //===----------------------------------------------------------------------===//
 255 // PowerPC Flag Definitions.
 256
 257 class isPPC64 { bit PPC64 = 1; }
 258 class isDOT   {
 259   list<Register> Defs = [CR0];
 260   bit RC  = 1;
 261 }
 262
 263 class RegConstraint<string C> {
 264   string Constraints = C;
 265 }
 266 class NoEncode<string E> {
 267   string DisableEncoding = E;
 268 }
 269
 270
 271 //===----------------------------------------------------------------------===//
 272 // PowerPC Operand Definitions.
 273
 274 def s5imm   : Operand<i32> {
 275   let PrintMethod = "printS5ImmOperand";
 276 }
 277 def u5imm   : Operand<i32> {
 278   let PrintMethod = "printU5ImmOperand";
 279 }
 280 def u6imm   : Operand<i32> {
 281   let PrintMethod = "printU6ImmOperand";
 282 }
 283 def s16imm  : Operand<i32> {
 284   let PrintMethod = "printS16ImmOperand";
 285 }
 286 def u16imm  : Operand<i32> {
 287   let PrintMethod = "printU16ImmOperand";
 288 }
 289 def s16immX4  : Operand<i32> {   // Multiply imm by 4 before printing.
 290   let PrintMethod = "printS16X4ImmOperand";
 291 }
 292 def directbrtarget : Operand<OtherVT> {
 293   let PrintMethod = "printBranchOperand";
 294   let EncoderMethod = "getDirectBrEncoding";
 295 }
 296 def condbrtarget : Operand<OtherVT> {
 297   let PrintMethod = "printBranchOperand";
 298   let EncoderMethod = "getCondBrEncoding";
 299 }
 300 def calltarget : Operand<iPTR> {
 301   let EncoderMethod = "getDirectBrEncoding";
 302 }
 303 def aaddr : Operand<iPTR> {
 304   let PrintMethod = "printAbsAddrOperand";
 305 }
 306 def symbolHi: Operand<i32> {
 307   let PrintMethod = "printSymbolHi";
 308   let EncoderMethod = "getHA16Encoding";
 309 }
 310 def symbolLo: Operand<i32> {
 311   let PrintMethod = "printSymbolLo";
 312   let EncoderMethod = "getLO16Encoding";
 313 }
 314 def crbitm: Operand<i8> {
 315   let PrintMethod = "printcrbitm";
 316   let EncoderMethod = "get_crbitm_encoding";
 317 }
 318 // Address operands
 319 def memri : Operand<iPTR> {
 320   let PrintMethod = "printMemRegImm";
 321   let MIOperandInfo = (ops i32imm:$imm, ptr_rc:$reg);
 322   let EncoderMethod = "getMemRIEncoding";
 323 }
 324 def memrr : Operand<iPTR> {
 325   let PrintMethod = "printMemRegReg";
 326   let MIOperandInfo = (ops ptr_rc:$offreg, ptr_rc:$ptrreg);
 327 }
 328 def memrix : Operand<iPTR> {   // memri where the imm is shifted 2 bits.
 329   let PrintMethod = "printMemRegImmShifted";
 330   let MIOperandInfo = (ops i32imm:$imm, ptr_rc:$reg);
 331   let EncoderMethod = "getMemRIXEncoding";
 332 }
 333 def tocentry : Operand<iPTR> {
 334   let MIOperandInfo = (ops i32imm:$imm);
 335 }
 336
 337 // PowerPC Predicate operand.  20 = (0<<5)|20 = always, CR0 is a dummy reg
 338 // that doesn't matter.
 339 def pred : PredicateOperand<OtherVT, (ops imm, CRRC),
 340                                      (ops (i32 20), (i32 zero_reg))> {
 341   let PrintMethod = "printPredicateOperand";
 342 }
 343
 344 // Define PowerPC specific addressing mode.
 345 def iaddr  : ComplexPattern<iPTR, 2, "SelectAddrImm",    [], []>;
 346 def xaddr  : ComplexPattern<iPTR, 2, "SelectAddrIdx",    [], []>;
 347 def xoaddr : ComplexPattern<iPTR, 2, "SelectAddrIdxOnly",[], []>;
 348 def ixaddr : ComplexPattern<iPTR, 2, "SelectAddrImmShift", [], []>; // "std"
 349
 350 /// This is just the offset part of iaddr, used for preinc.
 351 def iaddroff : ComplexPattern<iPTR, 1, "SelectAddrImmOffs", [], []>;
 352 def xaddroff : ComplexPattern<iPTR, 1, "SelectAddrIdxOffs", [], []>;
 353
 354 //===----------------------------------------------------------------------===//
 355 // PowerPC Instruction Predicate Definitions.
 356 def FPContractions : Predicate<"TM.Options.AllowExcessFPPrecision">;
 357 def In32BitMode  : Predicate<"!PPCSubTarget.isPPC64()">;
 358 def In64BitMode  : Predicate<"PPCSubTarget.isPPC64()">;
 359 def IsBookE  : Predicate<"PPCSubTarget.isBookE()">;
 360
 361 //===----------------------------------------------------------------------===//
 362 // PowerPC Instruction Definitions.
 363
 364 // Pseudo-instructions:
 365
 366 let hasCtrlDep = 1 in {
 367 let Defs = [R1], Uses = [R1] in {
 368 def ADJCALLSTACKDOWN : Pseudo<(outs), (ins u16imm:$amt), "",
 369                               [(callseq_start timm:$amt)]>;
 370 def ADJCALLSTACKUP   : Pseudo<(outs), (ins u16imm:$amt1, u16imm:$amt2), "",
 371                               [(callseq_end timm:$amt1, timm:$amt2)]>;
 372 }
 373
 374 def UPDATE_VRSAVE    : Pseudo<(outs GPRC:$rD), (ins GPRC:$rS),
 375                               "UPDATE_VRSAVE $rD, $rS", []>;
 376 }
 377
 378 let Defs = [R1], Uses = [R1] in
 379 def DYNALLOC : Pseudo<(outs GPRC:$result), (ins GPRC:$negsize, memri:$fpsi), "",
 380                        [(set GPRC:$result,
 381                              (PPCdynalloc GPRC:$negsize, iaddr:$fpsi))]>;
 382
 383 // SELECT_CC_* - Used to implement the SELECT_CC DAG operation.  Expanded after
 384 // instruction selection into a branch sequence.
 385 let usesCustomInserter = 1,    // Expanded after instruction selection.
 386     PPC970_Single = 1 in {
 387   def SELECT_CC_I4 : Pseudo<(outs GPRC:$dst), (ins CRRC:$cond, GPRC:$T, GPRC:$F,
 388                               i32imm:$BROPC), "",
 389                               []>;
 390   def SELECT_CC_I8 : Pseudo<(outs G8RC:$dst), (ins CRRC:$cond, G8RC:$T, G8RC:$F,
 391                               i32imm:$BROPC), "",
 392                               []>;
 393   def SELECT_CC_F4  : Pseudo<(outs F4RC:$dst), (ins CRRC:$cond, F4RC:$T, F4RC:$F,
 394                               i32imm:$BROPC), "",
 395                               []>;
 396   def SELECT_CC_F8  : Pseudo<(outs F8RC:$dst), (ins CRRC:$cond, F8RC:$T, F8RC:$F,
 397                               i32imm:$BROPC), "",
 398                               []>;
 399   def SELECT_CC_VRRC: Pseudo<(outs VRRC:$dst), (ins CRRC:$cond, VRRC:$T, VRRC:$F,
 400                               i32imm:$BROPC), "",
 401                               []>;
 402 }
 403
 404 // SPILL_CR - Indicate that we're dumping the CR register, so we'll need to
 405 // scavenge a register for it.
 406 let mayStore = 1 in
 407 def SPILL_CR : Pseudo<(outs), (ins CRRC:$cond, memri:$F),
 408                      "", []>;
 409
 410 // RESTORE_CR - Indicate that we're restoring the CR register (previously
 411 // spilled), so we'll need to scavenge a register for it.
 412 let mayLoad = 1 in
 413 def RESTORE_CR : Pseudo<(outs CRRC:$cond), (ins memri:$F),
 414                      "", []>;
 415
 416 let isTerminator = 1, isBarrier = 1, PPC970_Unit = 7 in {
 417   let isReturn = 1, Uses = [LR, RM] in
 418     def BLR : XLForm_2_br<19, 16, 0, (outs), (ins pred:$p),
 419                           "b${p:cc}lr ${p:reg}", BrB,
 420                           [(retflag)]>;
 421   let isBranch = 1, isIndirectBranch = 1, Uses = [CTR] in
 422     def BCTR : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", BrB, []>;
 423 }
 424
 425 let Defs = [LR] in
 426   def MovePCtoLR : Pseudo<(outs), (ins), "", []>,
 427                    PPC970_Unit_BRU;
 428
 429 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7 in {
 430   let isBarrier = 1 in {
 431   def B   : IForm<18, 0, 0, (outs), (ins directbrtarget:$dst),
 432                   "b $dst", BrB,
 433                   [(br bb:$dst)]>;
 434   }
 435
 436   // BCC represents an arbitrary conditional branch on a predicate.
 437   // FIXME: should be able to write a pattern for PPCcondbranch, but can't use
 438   // a two-value operand where a dag node expects two operands. :(
 439   def BCC : BForm<16, 0, 0, (outs), (ins pred:$cond, condbrtarget:$dst),
 440                   "b${cond:cc} ${cond:reg}, $dst"
 441                   /*[(PPCcondbranch CRRC:$crS, imm:$opc, bb:$dst)]*/>;
 442
 443   let Defs = [CTR], Uses = [CTR] in {
 444     def BDZ  : IForm_ext<16, 18, 0, 0, (outs), (ins condbrtarget:$dst),
 445                          "bdz $dst",  BrB, []>;
 446     def BDNZ : IForm_ext<16, 16, 0, 0, (outs), (ins condbrtarget:$dst),
 447                          "bdnz $dst", BrB, []>;
 448   }
 449 }
 450
 451 // Darwin ABI Calls.
 452 let isCall = 1, PPC970_Unit = 7, Defs = [LR] in {
 453   // Convenient aliases for call instructions
 454   let Uses = [RM] in {
 455     def BL_Darwin  : IForm<18, 0, 1,
 456                            (outs), (ins calltarget:$func, variable_ops),
 457                            "bl $func", BrB, []>;  // See Pat patterns below.
 458     def BLA_Darwin : IForm<18, 1, 1,
 459                           (outs), (ins aaddr:$func, variable_ops),
 460                           "bla $func", BrB, [(PPCcall_Darwin (i32 imm:$func))]>;
 461   }
 462   let Uses = [CTR, RM] in {
 463     def BCTRL_Darwin : XLForm_2_ext<19, 528, 20, 0, 1,
 464                                   (outs), (ins variable_ops),
 465                                   "bctrl", BrB,
 466                                   [(PPCbctrl_Darwin)]>, Requires<[In32BitMode]>;
 467   }
 468 }
 469
 470 // SVR4 ABI Calls.
 471 let isCall = 1, PPC970_Unit = 7, Defs = [LR] in {
 472   // Convenient aliases for call instructions
 473   let Uses = [RM] in {
 474     def BL_SVR4  : IForm<18, 0, 1,
 475                         (outs), (ins calltarget:$func, variable_ops),
 476                         "bl $func", BrB, []>;  // See Pat patterns below.
 477     def BLA_SVR4 : IForm<18, 1, 1,
 478                         (outs), (ins aaddr:$func, variable_ops),
 479                         "bla $func", BrB,
 480                         [(PPCcall_SVR4 (i32 imm:$func))]>;
 481   }
 482   let Uses = [CTR, RM] in {
 483     def BCTRL_SVR4 : XLForm_2_ext<19, 528, 20, 0, 1,
 484                                 (outs), (ins variable_ops),
 485                                 "bctrl", BrB,
 486                                 [(PPCbctrl_SVR4)]>, Requires<[In32BitMode]>;
 487   }
 488 }
 489
 490
 491 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 492 def TCRETURNdi :Pseudo< (outs),
 493                         (ins calltarget:$dst, i32imm:$offset, variable_ops),
 494                  "#TC_RETURNd $dst $offset",
 495                  []>;
 496
 497
 498 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 499 def TCRETURNai :Pseudo<(outs), (ins aaddr:$func, i32imm:$offset, variable_ops),
 500                  "#TC_RETURNa $func $offset",
 501                  [(PPCtc_return (i32 imm:$func), imm:$offset)]>;
 502
 503 let isCall = 1, isTerminator = 1, isReturn = 1, isBarrier = 1, Uses = [RM] in
 504 def TCRETURNri : Pseudo<(outs), (ins CTRRC:$dst, i32imm:$offset, variable_ops),
 505                  "#TC_RETURNr $dst $offset",
 506                  []>;
 507
 508
 509 let isTerminator = 1, isBarrier = 1, PPC970_Unit = 7, isBranch = 1,
 510     isIndirectBranch = 1, isCall = 1, isReturn = 1, Uses = [CTR, RM]  in
 511 def TAILBCTR : XLForm_2_ext<19, 528, 20, 0, 0, (outs), (ins), "bctr", BrB, []>,
 512      Requires<[In32BitMode]>;
 513
 514
 515
 516 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
 517     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
 518 def TAILB   : IForm<18, 0, 0, (outs), (ins calltarget:$dst),
 519                   "b $dst", BrB,
 520                   []>;
 521
 522
 523 let isBranch = 1, isTerminator = 1, hasCtrlDep = 1, PPC970_Unit = 7,
 524     isBarrier = 1, isCall = 1, isReturn = 1, Uses = [RM] in
 525 def TAILBA   : IForm<18, 0, 0, (outs), (ins aaddr:$dst),
 526                   "ba $dst", BrB,
 527                   []>;
 528
 529
 530 // DCB* instructions.
 531 def DCBA   : DCB_Form<758, 0, (outs), (ins memrr:$dst),
 532                       "dcba $dst", LdStDCBF, [(int_ppc_dcba xoaddr:$dst)]>,
 533                       PPC970_DGroup_Single;
 534 def DCBF   : DCB_Form<86, 0, (outs), (ins memrr:$dst),
 535                       "dcbf $dst", LdStDCBF, [(int_ppc_dcbf xoaddr:$dst)]>,
 536                       PPC970_DGroup_Single;
 537 def DCBI   : DCB_Form<470, 0, (outs), (ins memrr:$dst),
 538                       "dcbi $dst", LdStDCBF, [(int_ppc_dcbi xoaddr:$dst)]>,
 539                       PPC970_DGroup_Single;
 540 def DCBST  : DCB_Form<54, 0, (outs), (ins memrr:$dst),
 541                       "dcbst $dst", LdStDCBF, [(int_ppc_dcbst xoaddr:$dst)]>,
 542                       PPC970_DGroup_Single;
 543 def DCBT   : DCB_Form<278, 0, (outs), (ins memrr:$dst),
 544                       "dcbt $dst", LdStDCBF, [(int_ppc_dcbt xoaddr:$dst)]>,
 545                       PPC970_DGroup_Single;
 546 def DCBTST : DCB_Form<246, 0, (outs), (ins memrr:$dst),
 547                       "dcbtst $dst", LdStDCBF, [(int_ppc_dcbtst xoaddr:$dst)]>,
 548                       PPC970_DGroup_Single;
 549 def DCBZ   : DCB_Form<1014, 0, (outs), (ins memrr:$dst),
 550                       "dcbz $dst", LdStDCBF, [(int_ppc_dcbz xoaddr:$dst)]>,
 551                       PPC970_DGroup_Single;
 552 def DCBZL  : DCB_Form<1014, 1, (outs), (ins memrr:$dst),
 553                       "dcbzl $dst", LdStDCBF, [(int_ppc_dcbzl xoaddr:$dst)]>,
 554                       PPC970_DGroup_Single;
 555
 556 def : Pat<(prefetch xoaddr:$dst, (i32 0), imm, (i32 1)),
 557           (DCBT xoaddr:$dst)>;
 558
 559 // Atomic operations
 560 let usesCustomInserter = 1 in {
 561   let Defs = [CR0] in {
 562     def ATOMIC_LOAD_ADD_I8 : Pseudo<
 563       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 564       [(set GPRC:$dst, (atomic_load_add_8 xoaddr:$ptr, GPRC:$incr))]>;
 565     def ATOMIC_LOAD_SUB_I8 : Pseudo<
 566       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 567       [(set GPRC:$dst, (atomic_load_sub_8 xoaddr:$ptr, GPRC:$incr))]>;
 568     def ATOMIC_LOAD_AND_I8 : Pseudo<
 569       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 570       [(set GPRC:$dst, (atomic_load_and_8 xoaddr:$ptr, GPRC:$incr))]>;
 571     def ATOMIC_LOAD_OR_I8 : Pseudo<
 572       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 573       [(set GPRC:$dst, (atomic_load_or_8 xoaddr:$ptr, GPRC:$incr))]>;
 574     def ATOMIC_LOAD_XOR_I8 : Pseudo<
 575       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 576       [(set GPRC:$dst, (atomic_load_xor_8 xoaddr:$ptr, GPRC:$incr))]>;
 577     def ATOMIC_LOAD_NAND_I8 : Pseudo<
 578       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 579       [(set GPRC:$dst, (atomic_load_nand_8 xoaddr:$ptr, GPRC:$incr))]>;
 580     def ATOMIC_LOAD_ADD_I16 : Pseudo<
 581       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 582       [(set GPRC:$dst, (atomic_load_add_16 xoaddr:$ptr, GPRC:$incr))]>;
 583     def ATOMIC_LOAD_SUB_I16 : Pseudo<
 584       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 585       [(set GPRC:$dst, (atomic_load_sub_16 xoaddr:$ptr, GPRC:$incr))]>;
 586     def ATOMIC_LOAD_AND_I16 : Pseudo<
 587       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 588       [(set GPRC:$dst, (atomic_load_and_16 xoaddr:$ptr, GPRC:$incr))]>;
 589     def ATOMIC_LOAD_OR_I16 : Pseudo<
 590       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 591       [(set GPRC:$dst, (atomic_load_or_16 xoaddr:$ptr, GPRC:$incr))]>;
 592     def ATOMIC_LOAD_XOR_I16 : Pseudo<
 593       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 594       [(set GPRC:$dst, (atomic_load_xor_16 xoaddr:$ptr, GPRC:$incr))]>;
 595     def ATOMIC_LOAD_NAND_I16 : Pseudo<
 596       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 597       [(set GPRC:$dst, (atomic_load_nand_16 xoaddr:$ptr, GPRC:$incr))]>;
 598     def ATOMIC_LOAD_ADD_I32 : Pseudo<
 599       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 600       [(set GPRC:$dst, (atomic_load_add_32 xoaddr:$ptr, GPRC:$incr))]>;
 601     def ATOMIC_LOAD_SUB_I32 : Pseudo<
 602       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 603       [(set GPRC:$dst, (atomic_load_sub_32 xoaddr:$ptr, GPRC:$incr))]>;
 604     def ATOMIC_LOAD_AND_I32 : Pseudo<
 605       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 606       [(set GPRC:$dst, (atomic_load_and_32 xoaddr:$ptr, GPRC:$incr))]>;
 607     def ATOMIC_LOAD_OR_I32 : Pseudo<
 608       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 609       [(set GPRC:$dst, (atomic_load_or_32 xoaddr:$ptr, GPRC:$incr))]>;
 610     def ATOMIC_LOAD_XOR_I32 : Pseudo<
 611       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 612       [(set GPRC:$dst, (atomic_load_xor_32 xoaddr:$ptr, GPRC:$incr))]>;
 613     def ATOMIC_LOAD_NAND_I32 : Pseudo<
 614       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$incr), "",
 615       [(set GPRC:$dst, (atomic_load_nand_32 xoaddr:$ptr, GPRC:$incr))]>;
 616
 617     def ATOMIC_CMP_SWAP_I8 : Pseudo<
 618       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$old, GPRC:$new), "",
 619       [(set GPRC:$dst,
 620                     (atomic_cmp_swap_8 xoaddr:$ptr, GPRC:$old, GPRC:$new))]>;
 621     def ATOMIC_CMP_SWAP_I16 : Pseudo<
 622       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$old, GPRC:$new), "",
 623       [(set GPRC:$dst,
 624                     (atomic_cmp_swap_16 xoaddr:$ptr, GPRC:$old, GPRC:$new))]>;
 625     def ATOMIC_CMP_SWAP_I32 : Pseudo<
 626       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$old, GPRC:$new), "",
 627       [(set GPRC:$dst,
 628                     (atomic_cmp_swap_32 xoaddr:$ptr, GPRC:$old, GPRC:$new))]>;
 629
 630     def ATOMIC_SWAP_I8 : Pseudo<
 631       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$new), "",
 632       [(set GPRC:$dst, (atomic_swap_8 xoaddr:$ptr, GPRC:$new))]>;
 633     def ATOMIC_SWAP_I16 : Pseudo<
 634       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$new), "",
 635       [(set GPRC:$dst, (atomic_swap_16 xoaddr:$ptr, GPRC:$new))]>;
 636     def ATOMIC_SWAP_I32 : Pseudo<
 637       (outs GPRC:$dst), (ins memrr:$ptr, GPRC:$new), "",
 638       [(set GPRC:$dst, (atomic_swap_32 xoaddr:$ptr, GPRC:$new))]>;
 639   }
 640 }
 641
 642 // Instructions to support atomic operations
 643 def LWARX : XForm_1<31,  20, (outs GPRC:$rD), (ins memrr:$src),
 644                    "lwarx $rD, $src", LdStLWARX,
 645                    [(set GPRC:$rD, (PPClarx xoaddr:$src))]>;
 646
 647 let Defs = [CR0] in
 648 def STWCX : XForm_1<31, 150, (outs), (ins GPRC:$rS, memrr:$dst),
 649                    "stwcx. $rS, $dst", LdStSTWCX,
 650                    [(PPCstcx GPRC:$rS, xoaddr:$dst)]>,
 651                    isDOT;
 652
 653 let isTerminator = 1, isBarrier = 1, hasCtrlDep = 1 in
 654 def TRAP  : XForm_24<31, 4, (outs), (ins), "trap", LdStLoad, [(trap)]>;
 655
 656 //===----------------------------------------------------------------------===//
 657 // PPC32 Load Instructions.
 658 //
 659
 660 // Unindexed (r+i) Loads.
 661 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 662 def LBZ : DForm_1<34, (outs GPRC:$rD), (ins memri:$src),
 663                   "lbz $rD, $src", LdStLoad,
 664                   [(set GPRC:$rD, (zextloadi8 iaddr:$src))]>;
 665 def LHA : DForm_1<42, (outs GPRC:$rD), (ins memri:$src),
 666                   "lha $rD, $src", LdStLHA,
 667                   [(set GPRC:$rD, (sextloadi16 iaddr:$src))]>,
 668                   PPC970_DGroup_Cracked;
 669 def LHZ : DForm_1<40, (outs GPRC:$rD), (ins memri:$src),
 670                   "lhz $rD, $src", LdStLoad,
 671                   [(set GPRC:$rD, (zextloadi16 iaddr:$src))]>;
 672 def LWZ : DForm_1<32, (outs GPRC:$rD), (ins memri:$src),
 673                   "lwz $rD, $src", LdStLoad,
 674                   [(set GPRC:$rD, (load iaddr:$src))]>;
 675
 676 def LFS : DForm_1<48, (outs F4RC:$rD), (ins memri:$src),
 677                   "lfs $rD, $src", LdStLFDU,
 678                   [(set F4RC:$rD, (load iaddr:$src))]>;
 679 def LFD : DForm_1<50, (outs F8RC:$rD), (ins memri:$src),
 680                   "lfd $rD, $src", LdStLFD,
 681                   [(set F8RC:$rD, (load iaddr:$src))]>;
 682
 683
 684 // Unindexed (r+i) Loads with Update (preinc).
 685 let mayLoad = 1 in {
 686 def LBZU : DForm_1<35, (outs GPRC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 687                    "lbzu $rD, $addr", LdStLoad,
 688                    []>, RegConstraint<"$addr.reg = $ea_result">,
 689                    NoEncode<"$ea_result">;
 690
 691 def LHAU : DForm_1<43, (outs GPRC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 692                    "lhau $rD, $addr", LdStLoad,
 693                    []>, RegConstraint<"$addr.reg = $ea_result">,
 694                    NoEncode<"$ea_result">;
 695
 696 def LHZU : DForm_1<41, (outs GPRC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 697                    "lhzu $rD, $addr", LdStLoad,
 698                    []>, RegConstraint<"$addr.reg = $ea_result">,
 699                    NoEncode<"$ea_result">;
 700
 701 def LWZU : DForm_1<33, (outs GPRC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 702                    "lwzu $rD, $addr", LdStLoad,
 703                    []>, RegConstraint<"$addr.reg = $ea_result">,
 704                    NoEncode<"$ea_result">;
 705
 706 def LFSU : DForm_1<49, (outs F4RC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 707                   "lfs $rD, $addr", LdStLFDU,
 708                   []>, RegConstraint<"$addr.reg = $ea_result">,
 709                    NoEncode<"$ea_result">;
 710
 711 def LFDU : DForm_1<51, (outs F8RC:$rD, ptr_rc:$ea_result), (ins memri:$addr),
 712                   "lfd $rD, $addr", LdStLFD,
 713                   []>, RegConstraint<"$addr.reg = $ea_result">,
 714                    NoEncode<"$ea_result">;
 715
 716
 717 // Indexed (r+r) Loads with Update (preinc).
 718 def LBZUX : XForm_1<31, 119, (outs GPRC:$rD, ptr_rc:$ea_result),
 719                    (ins memrr:$addr),
 720                    "lbzux $rD, $addr", LdStLoad,
 721                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 722                    NoEncode<"$ea_result">;
 723
 724 def LHAUX : XForm_1<31, 375, (outs GPRC:$rD, ptr_rc:$ea_result),
 725                    (ins memrr:$addr),
 726                    "lhaux $rD, $addr", LdStLoad,
 727                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 728                    NoEncode<"$ea_result">;
 729
 730 def LHZUX : XForm_1<31, 331, (outs GPRC:$rD, ptr_rc:$ea_result),
 731                    (ins memrr:$addr),
 732                    "lhzux $rD, $addr", LdStLoad,
 733                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 734                    NoEncode<"$ea_result">;
 735
 736 def LWZUX : XForm_1<31, 55, (outs GPRC:$rD, ptr_rc:$ea_result),
 737                    (ins memrr:$addr),
 738                    "lwzux $rD, $addr", LdStLoad,
 739                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 740                    NoEncode<"$ea_result">;
 741
 742 def LFSUX : XForm_1<31, 567, (outs F4RC:$rD, ptr_rc:$ea_result),
 743                    (ins memrr:$addr),
 744                    "lfsux $rD, $addr", LdStLoad,
 745                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 746                    NoEncode<"$ea_result">;
 747
 748 def LFDUX : XForm_1<31, 631, (outs F8RC:$rD, ptr_rc:$ea_result),
 749                    (ins memrr:$addr),
 750                    "lfdux $rD, $addr", LdStLoad,
 751                    []>, RegConstraint<"$addr.offreg = $ea_result">,
 752                    NoEncode<"$ea_result">;
 753 }
 754 }
 755
 756 // Indexed (r+r) Loads.
 757 //
 758 let canFoldAsLoad = 1, PPC970_Unit = 2 in {
 759 def LBZX : XForm_1<31,  87, (outs GPRC:$rD), (ins memrr:$src),
 760                    "lbzx $rD, $src", LdStLoad,
 761                    [(set GPRC:$rD, (zextloadi8 xaddr:$src))]>;
 762 def LHAX : XForm_1<31, 343, (outs GPRC:$rD), (ins memrr:$src),
 763                    "lhax $rD, $src", LdStLHA,
 764                    [(set GPRC:$rD, (sextloadi16 xaddr:$src))]>,
 765                    PPC970_DGroup_Cracked;
 766 def LHZX : XForm_1<31, 279, (outs GPRC:$rD), (ins memrr:$src),
 767                    "lhzx $rD, $src", LdStLoad,
 768                    [(set GPRC:$rD, (zextloadi16 xaddr:$src))]>;
 769 def LWZX : XForm_1<31,  23, (outs GPRC:$rD), (ins memrr:$src),
 770                    "lwzx $rD, $src", LdStLoad,
 771                    [(set GPRC:$rD, (load xaddr:$src))]>;
 772
 773
 774 def LHBRX : XForm_1<31, 790, (outs GPRC:$rD), (ins memrr:$src),
 775                    "lhbrx $rD, $src", LdStLoad,
 776                    [(set GPRC:$rD, (PPClbrx xoaddr:$src, i16))]>;
 777 def LWBRX : XForm_1<31,  534, (outs GPRC:$rD), (ins memrr:$src),
 778                    "lwbrx $rD, $src", LdStLoad,
 779                    [(set GPRC:$rD, (PPClbrx xoaddr:$src, i32))]>;
 780
 781 def LFSX   : XForm_25<31, 535, (outs F4RC:$frD), (ins memrr:$src),
 782                       "lfsx $frD, $src", LdStLFDU,
 783                       [(set F4RC:$frD, (load xaddr:$src))]>;
 784 def LFDX   : XForm_25<31, 599, (outs F8RC:$frD), (ins memrr:$src),
 785                       "lfdx $frD, $src", LdStLFDU,
 786                       [(set F8RC:$frD, (load xaddr:$src))]>;
 787 }
 788
 789 //===----------------------------------------------------------------------===//
 790 // PPC32 Store Instructions.
 791 //
 792
 793 // Unindexed (r+i) Stores.
 794 let PPC970_Unit = 2 in {
 795 def STB  : DForm_1<38, (outs), (ins GPRC:$rS, memri:$src),
 796                    "stb $rS, $src", LdStStore,
 797                    [(truncstorei8 GPRC:$rS, iaddr:$src)]>;
 798 def STH  : DForm_1<44, (outs), (ins GPRC:$rS, memri:$src),
 799                    "sth $rS, $src", LdStStore,
 800                    [(truncstorei16 GPRC:$rS, iaddr:$src)]>;
 801 def STW  : DForm_1<36, (outs), (ins GPRC:$rS, memri:$src),
 802                    "stw $rS, $src", LdStStore,
 803                    [(store GPRC:$rS, iaddr:$src)]>;
 804 def STFS : DForm_1<52, (outs), (ins F4RC:$rS, memri:$dst),
 805                    "stfs $rS, $dst", LdStUX,
 806                    [(store F4RC:$rS, iaddr:$dst)]>;
 807 def STFD : DForm_1<54, (outs), (ins F8RC:$rS, memri:$dst),
 808                    "stfd $rS, $dst", LdStUX,
 809                    [(store F8RC:$rS, iaddr:$dst)]>;
 810 }
 811
 812 // Unindexed (r+i) Stores with Update (preinc).
 813 let PPC970_Unit = 2 in {
 814 def STBU  : DForm_1a<39, (outs ptr_rc:$ea_res), (ins GPRC:$rS,
 815                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 816                     "stbu $rS, $ptroff($ptrreg)", LdStStore,
 817                     [(set ptr_rc:$ea_res,
 818                           (pre_truncsti8 GPRC:$rS, ptr_rc:$ptrreg,
 819                                          iaddroff:$ptroff))]>,
 820                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 821 def STHU  : DForm_1a<45, (outs ptr_rc:$ea_res), (ins GPRC:$rS,
 822                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 823                     "sthu $rS, $ptroff($ptrreg)", LdStStore,
 824                     [(set ptr_rc:$ea_res,
 825                         (pre_truncsti16 GPRC:$rS, ptr_rc:$ptrreg,
 826                                         iaddroff:$ptroff))]>,
 827                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 828 def STWU  : DForm_1a<37, (outs ptr_rc:$ea_res), (ins GPRC:$rS,
 829                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 830                     "stwu $rS, $ptroff($ptrreg)", LdStStore,
 831                     [(set ptr_rc:$ea_res, (pre_store GPRC:$rS, ptr_rc:$ptrreg,
 832                                                      iaddroff:$ptroff))]>,
 833                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 834 def STFSU : DForm_1a<37, (outs ptr_rc:$ea_res), (ins F4RC:$rS,
 835                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 836                     "stfsu $rS, $ptroff($ptrreg)", LdStStore,
 837                     [(set ptr_rc:$ea_res, (pre_store F4RC:$rS,  ptr_rc:$ptrreg,
 838                                           iaddroff:$ptroff))]>,
 839                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 840 def STFDU : DForm_1a<37, (outs ptr_rc:$ea_res), (ins F8RC:$rS,
 841                              symbolLo:$ptroff, ptr_rc:$ptrreg),
 842                     "stfdu $rS, $ptroff($ptrreg)", LdStStore,
 843                     [(set ptr_rc:$ea_res, (pre_store F8RC:$rS, ptr_rc:$ptrreg,
 844                                           iaddroff:$ptroff))]>,
 845                     RegConstraint<"$ptrreg = $ea_res">, NoEncode<"$ea_res">;
 846 }
 847
 848
 849 // Indexed (r+r) Stores.
 850 //
 851 let PPC970_Unit = 2 in {
 852 def STBX  : XForm_8<31, 215, (outs), (ins GPRC:$rS, memrr:$dst),
 853                    "stbx $rS, $dst", LdStStore,
 854                    [(truncstorei8 GPRC:$rS, xaddr:$dst)]>,
 855                    PPC970_DGroup_Cracked;
 856 def STHX  : XForm_8<31, 407, (outs), (ins GPRC:$rS, memrr:$dst),
 857                    "sthx $rS, $dst", LdStStore,
 858                    [(truncstorei16 GPRC:$rS, xaddr:$dst)]>,
 859                    PPC970_DGroup_Cracked;
 860 def STWX  : XForm_8<31, 151, (outs), (ins GPRC:$rS, memrr:$dst),
 861                    "stwx $rS, $dst", LdStStore,
 862                    [(store GPRC:$rS, xaddr:$dst)]>,
 863                    PPC970_DGroup_Cracked;
 864
 865 def STBUX : XForm_8<31, 247, (outs ptr_rc:$ea_res),
 866                              (ins GPRC:$rS, ptr_rc:$ptroff, ptr_rc:$ptrreg),
 867                    "stbux $rS, $ptroff, $ptrreg", LdStStore,
 868                    [(set ptr_rc:$ea_res,
 869                       (pre_truncsti8 GPRC:$rS,
 870                                      ptr_rc:$ptrreg, xaddroff:$ptroff))]>,
 871                    RegConstraint<"$ptroff = $ea_res">, NoEncode<"$ea_res">,
 872                    PPC970_DGroup_Cracked;
 873
 874 def STHUX : XForm_8<31, 439, (outs ptr_rc:$ea_res),
 875                              (ins GPRC:$rS, ptr_rc:$ptroff, ptr_rc:$ptrreg),
 876                    "sthux $rS, $ptroff, $ptrreg", LdStStore,
 877                    [(set ptr_rc:$ea_res,
 878                       (pre_truncsti16 GPRC:$rS,
 879                                       ptr_rc:$ptrreg, xaddroff:$ptroff))]>,
 880                    RegConstraint<"$ptroff = $ea_res">, NoEncode<"$ea_res">,
 881                    PPC970_DGroup_Cracked;
 882
 883 def STWUX : XForm_8<31, 183, (outs ptr_rc:$ea_res),
 884                              (ins GPRC:$rS, ptr_rc:$ptroff, ptr_rc:$ptrreg),
 885                    "stwux $rS, $ptroff, $ptrreg", LdStStore,
 886                    [(set ptr_rc:$ea_res,
 887                       (pre_store GPRC:$rS, ptr_rc:$ptrreg, xaddroff:$ptroff))]>,
 888                    RegConstraint<"$ptroff = $ea_res">, NoEncode<"$ea_res">,
 889                    PPC970_DGroup_Cracked;
 890
 891 def STFSUX : XForm_8<31, 695, (outs ptr_rc:$ea_res),
 892                               (ins F4RC:$rS, ptr_rc:$ptroff, ptr_rc:$ptrreg),
 893                     "stfsux $rS, $ptroff, $ptrreg", LdStStore,
 894                     [(set ptr_rc:$ea_res,
 895                        (pre_store F4RC:$rS, ptr_rc:$ptrreg, xaddroff:$ptroff))]>,
 896                     RegConstraint<"$ptroff = $ea_res">, NoEncode<"$ea_res">,
 897                     PPC970_DGroup_Cracked;
 898
 899 def STFDUX : XForm_8<31, 759, (outs ptr_rc:$ea_res),
 900                               (ins F8RC:$rS, ptr_rc:$ptroff, ptr_rc:$ptrreg),
 901                     "stfdux $rS, $ptroff, $ptrreg", LdStStore,
 902                     [(set ptr_rc:$ea_res,
 903                        (pre_store F8RC:$rS, ptr_rc:$ptrreg, xaddroff:$ptroff))]>,
 904                     RegConstraint<"$ptroff = $ea_res">, NoEncode<"$ea_res">,
 905                     PPC970_DGroup_Cracked;
 906
 907 def STHBRX: XForm_8<31, 918, (outs), (ins GPRC:$rS, memrr:$dst),
 908                    "sthbrx $rS, $dst", LdStStore,
 909                    [(PPCstbrx GPRC:$rS, xoaddr:$dst, i16)]>,
 910                    PPC970_DGroup_Cracked;
 911 def STWBRX: XForm_8<31, 662, (outs), (ins GPRC:$rS, memrr:$dst),
 912                    "stwbrx $rS, $dst", LdStStore,
 913                    [(PPCstbrx GPRC:$rS, xoaddr:$dst, i32)]>,
 914                    PPC970_DGroup_Cracked;
 915
 916 def STFIWX: XForm_28<31, 983, (outs), (ins F8RC:$frS, memrr:$dst),
 917                      "stfiwx $frS, $dst", LdStUX,
 918                      [(PPCstfiwx F8RC:$frS, xoaddr:$dst)]>;
 919
 920 def STFSX : XForm_28<31, 663, (outs), (ins F4RC:$frS, memrr:$dst),
 921                      "stfsx $frS, $dst", LdStUX,
 922                      [(store F4RC:$frS, xaddr:$dst)]>;
 923 def STFDX : XForm_28<31, 727, (outs), (ins F8RC:$frS, memrr:$dst),
 924                      "stfdx $frS, $dst", LdStUX,
 925                      [(store F8RC:$frS, xaddr:$dst)]>;
 926 }
 927
 928 def SYNC : XForm_24_sync<31, 598, (outs), (ins),
 929                         "sync", LdStSync,
 930                         [(int_ppc_sync)]>;
 931
 932 //===----------------------------------------------------------------------===//
 933 // PPC32 Arithmetic Instructions.
 934 //
 935
 936 let PPC970_Unit = 1 in {  // FXU Operations.
 937 def ADDI   : DForm_2<14, (outs GPRC:$rD), (ins GPRC:$rA, s16imm:$imm),
 938                      "addi $rD, $rA, $imm", IntSimple,
 939                      [(set GPRC:$rD, (add GPRC:$rA, immSExt16:$imm))]>;
 940 def ADDIL  : DForm_2<14, (outs GPRC:$rD), (ins GPRC:$rA, symbolLo:$imm),
 941                      "addi $rD, $rA, $imm", IntSimple,
 942                      [(set GPRC:$rD, (add GPRC:$rA, immSExt16:$imm))]>;
 943 let Defs = [CARRY] in {
 944 def ADDIC  : DForm_2<12, (outs GPRC:$rD), (ins GPRC:$rA, s16imm:$imm),
 945                      "addic $rD, $rA, $imm", IntGeneral,
 946                      [(set GPRC:$rD, (addc GPRC:$rA, immSExt16:$imm))]>,
 947                      PPC970_DGroup_Cracked;
 948 def ADDICo : DForm_2<13, (outs GPRC:$rD), (ins GPRC:$rA, s16imm:$imm),
 949                      "addic. $rD, $rA, $imm", IntGeneral,
 950                      []>;
 951 }
 952 def ADDIS  : DForm_2<15, (outs GPRC:$rD), (ins GPRC:$rA, symbolHi:$imm),
 953                      "addis $rD, $rA, $imm", IntSimple,
 954                      [(set GPRC:$rD, (add GPRC:$rA, imm16ShiftedSExt:$imm))]>;
 955 def LA     : DForm_2<14, (outs GPRC:$rD), (ins GPRC:$rA, symbolLo:$sym),
 956                      "la $rD, $sym($rA)", IntGeneral,
 957                      [(set GPRC:$rD, (add GPRC:$rA,
 958                                           (PPClo tglobaladdr:$sym, 0)))]>;
 959 def MULLI  : DForm_2< 7, (outs GPRC:$rD), (ins GPRC:$rA, s16imm:$imm),
 960                      "mulli $rD, $rA, $imm", IntMulLI,
 961                      [(set GPRC:$rD, (mul GPRC:$rA, immSExt16:$imm))]>;
 962 let Defs = [CARRY] in {
 963 def SUBFIC : DForm_2< 8, (outs GPRC:$rD), (ins GPRC:$rA, s16imm:$imm),
 964                      "subfic $rD, $rA, $imm", IntGeneral,
 965                      [(set GPRC:$rD, (subc immSExt16:$imm, GPRC:$rA))]>;
 966 }
 967
 968 let isReMaterializable = 1 in {
 969   def LI  : DForm_2_r0<14, (outs GPRC:$rD), (ins symbolLo:$imm),
 970                        "li $rD, $imm", IntSimple,
 971                        [(set GPRC:$rD, immSExt16:$imm)]>;
 972   def LIS : DForm_2_r0<15, (outs GPRC:$rD), (ins symbolHi:$imm),
 973                        "lis $rD, $imm", IntSimple,
 974                        [(set GPRC:$rD, imm16ShiftedSExt:$imm)]>;
 975 }
 976 }
 977
 978 let PPC970_Unit = 1 in {  // FXU Operations.
 979 def ANDIo : DForm_4<28, (outs GPRC:$dst), (ins GPRC:$src1, u16imm:$src2),
 980                     "andi. $dst, $src1, $src2", IntGeneral,
 981                     [(set GPRC:$dst, (and GPRC:$src1, immZExt16:$src2))]>,
 982                     isDOT;
 983 def ANDISo : DForm_4<29, (outs GPRC:$dst), (ins GPRC:$src1, u16imm:$src2),
 984                     "andis. $dst, $src1, $src2", IntGeneral,
 985                     [(set GPRC:$dst, (and GPRC:$src1,imm16ShiftedZExt:$src2))]>,
 986                     isDOT;
 987 def ORI   : DForm_4<24, (outs GPRC:$dst), (ins GPRC:$src1, u16imm:$src2),
 988                     "ori $dst, $src1, $src2", IntSimple,
 989                     [(set GPRC:$dst, (or GPRC:$src1, immZExt16:$src2))]>;
 990 def ORIS  : DForm_4<25, (outs GPRC:$dst), (ins GPRC:$src1, u16imm:$src2),
 991                     "oris $dst, $src1, $src2", IntSimple,
 992                     [(set GPRC:$dst, (or GPRC:$src1, imm16ShiftedZExt:$src2))]>;
 993 def XORI  : DForm_4<26, (outs GPRC:$dst), (ins GPRC:$src1, u16imm:$src2),
 994                     "xori $dst, $src1, $src2", IntSimple,
 995                     [(set GPRC:$dst, (xor GPRC:$src1, immZExt16:$src2))]>;
 996 def XORIS : DForm_4<27, (outs GPRC:$dst), (ins GPRC:$src1, u16imm:$src2),
 997                     "xoris $dst, $src1, $src2", IntSimple,
 998                     [(set GPRC:$dst, (xor GPRC:$src1,imm16ShiftedZExt:$src2))]>;
 999 def NOP   : DForm_4_zero<24, (outs), (ins), "nop", IntSimple,
1000                          []>;
1001 def CMPWI : DForm_5_ext<11, (outs CRRC:$crD), (ins GPRC:$rA, s16imm:$imm),
1002                         "cmpwi $crD, $rA, $imm", IntCompare>;
1003 def CMPLWI : DForm_6_ext<10, (outs CRRC:$dst), (ins GPRC:$src1, u16imm:$src2),
1004                          "cmplwi $dst, $src1, $src2", IntCompare>;
1005 }
1006
1007
1008 let PPC970_Unit = 1 in {  // FXU Operations.
1009 def NAND : XForm_6<31, 476, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1010                    "nand $rA, $rS, $rB", IntSimple,
1011                    [(set GPRC:$rA, (not (and GPRC:$rS, GPRC:$rB)))]>;
1012 def AND  : XForm_6<31,  28, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1013                    "and $rA, $rS, $rB", IntSimple,
1014                    [(set GPRC:$rA, (and GPRC:$rS, GPRC:$rB))]>;
1015 def ANDC : XForm_6<31,  60, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1016                    "andc $rA, $rS, $rB", IntSimple,
1017                    [(set GPRC:$rA, (and GPRC:$rS, (not GPRC:$rB)))]>;
1018 def OR   : XForm_6<31, 444, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1019                    "or $rA, $rS, $rB", IntSimple,
1020                    [(set GPRC:$rA, (or GPRC:$rS, GPRC:$rB))]>;
1021 def NOR  : XForm_6<31, 124, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1022                    "nor $rA, $rS, $rB", IntSimple,
1023                    [(set GPRC:$rA, (not (or GPRC:$rS, GPRC:$rB)))]>;
1024 def ORC  : XForm_6<31, 412, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1025                    "orc $rA, $rS, $rB", IntSimple,
1026                    [(set GPRC:$rA, (or GPRC:$rS, (not GPRC:$rB)))]>;
1027 def EQV  : XForm_6<31, 284, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1028                    "eqv $rA, $rS, $rB", IntSimple,
1029                    [(set GPRC:$rA, (not (xor GPRC:$rS, GPRC:$rB)))]>;
1030 def XOR  : XForm_6<31, 316, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1031                    "xor $rA, $rS, $rB", IntSimple,
1032                    [(set GPRC:$rA, (xor GPRC:$rS, GPRC:$rB))]>;
1033 def SLW  : XForm_6<31,  24, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1034                    "slw $rA, $rS, $rB", IntGeneral,
1035                    [(set GPRC:$rA, (PPCshl GPRC:$rS, GPRC:$rB))]>;
1036 def SRW  : XForm_6<31, 536, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1037                    "srw $rA, $rS, $rB", IntGeneral,
1038                    [(set GPRC:$rA, (PPCsrl GPRC:$rS, GPRC:$rB))]>;
1039 let Defs = [CARRY] in {
1040 def SRAW : XForm_6<31, 792, (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB),
1041                    "sraw $rA, $rS, $rB", IntShift,
1042                    [(set GPRC:$rA, (PPCsra GPRC:$rS, GPRC:$rB))]>;
1043 }
1044 }
1045
1046 let PPC970_Unit = 1 in {  // FXU Operations.
1047 let Defs = [CARRY] in {
1048 def SRAWI : XForm_10<31, 824, (outs GPRC:$rA), (ins GPRC:$rS, u5imm:$SH),
1049                      "srawi $rA, $rS, $SH", IntShift,
1050                      [(set GPRC:$rA, (sra GPRC:$rS, (i32 imm:$SH)))]>;
1051 }
1052 def CNTLZW : XForm_11<31,  26, (outs GPRC:$rA), (ins GPRC:$rS),
1053                       "cntlzw $rA, $rS", IntGeneral,
1054                       [(set GPRC:$rA, (ctlz GPRC:$rS))]>;
1055 def EXTSB  : XForm_11<31, 954, (outs GPRC:$rA), (ins GPRC:$rS),
1056                       "extsb $rA, $rS", IntSimple,
1057                       [(set GPRC:$rA, (sext_inreg GPRC:$rS, i8))]>;
1058 def EXTSH  : XForm_11<31, 922, (outs GPRC:$rA), (ins GPRC:$rS),
1059                       "extsh $rA, $rS", IntSimple,
1060                       [(set GPRC:$rA, (sext_inreg GPRC:$rS, i16))]>;
1061
1062 def CMPW   : XForm_16_ext<31, 0, (outs CRRC:$crD), (ins GPRC:$rA, GPRC:$rB),
1063                           "cmpw $crD, $rA, $rB", IntCompare>;
1064 def CMPLW  : XForm_16_ext<31, 32, (outs CRRC:$crD), (ins GPRC:$rA, GPRC:$rB),
1065                           "cmplw $crD, $rA, $rB", IntCompare>;
1066 }
1067 let PPC970_Unit = 3 in {  // FPU Operations.
1068 //def FCMPO  : XForm_17<63, 32, (outs CRRC:$crD), (ins FPRC:$fA, FPRC:$fB),
1069 //                      "fcmpo $crD, $fA, $fB", FPCompare>;
1070 def FCMPUS : XForm_17<63, 0, (outs CRRC:$crD), (ins F4RC:$fA, F4RC:$fB),
1071                       "fcmpu $crD, $fA, $fB", FPCompare>;
1072 def FCMPUD : XForm_17<63, 0, (outs CRRC:$crD), (ins F8RC:$fA, F8RC:$fB),
1073                       "fcmpu $crD, $fA, $fB", FPCompare>;
1074
1075 let Uses = [RM] in {
1076   def FCTIWZ : XForm_26<63, 15, (outs F8RC:$frD), (ins F8RC:$frB),
1077                         "fctiwz $frD, $frB", FPGeneral,
1078                         [(set F8RC:$frD, (PPCfctiwz F8RC:$frB))]>;
1079   def FRSP   : XForm_26<63, 12, (outs F4RC:$frD), (ins F8RC:$frB),
1080                         "frsp $frD, $frB", FPGeneral,
1081                         [(set F4RC:$frD, (fround F8RC:$frB))]>;
1082   def FSQRT  : XForm_26<63, 22, (outs F8RC:$frD), (ins F8RC:$frB),
1083                         "fsqrt $frD, $frB", FPSqrt,
1084                         [(set F8RC:$frD, (fsqrt F8RC:$frB))]>;
1085   def FSQRTS : XForm_26<59, 22, (outs F4RC:$frD), (ins F4RC:$frB),
1086                         "fsqrts $frD, $frB", FPSqrt,
1087                         [(set F4RC:$frD, (fsqrt F4RC:$frB))]>;
1088   }
1089 }
1090
1091 /// Note that FMR is defined as pseudo-ops on the PPC970 because they are
1092 /// often coalesced away and we don't want the dispatch group builder to think
1093 /// that they will fill slots (which could cause the load of a LSU reject to
1094 /// sneak into a d-group with a store).
1095 def FMR   : XForm_26<63, 72, (outs F4RC:$frD), (ins F4RC:$frB),
1096                      "fmr $frD, $frB", FPGeneral,
1097                      []>,  // (set F4RC:$frD, F4RC:$frB)
1098                      PPC970_Unit_Pseudo;
1099
1100 let PPC970_Unit = 3 in {  // FPU Operations.
1101 // These are artificially split into two different forms, for 4/8 byte FP.
1102 def FABSS  : XForm_26<63, 264, (outs F4RC:$frD), (ins F4RC:$frB),
1103                       "fabs $frD, $frB", FPGeneral,
1104                       [(set F4RC:$frD, (fabs F4RC:$frB))]>;
1105 def FABSD  : XForm_26<63, 264, (outs F8RC:$frD), (ins F8RC:$frB),
1106                       "fabs $frD, $frB", FPGeneral,
1107                       [(set F8RC:$frD, (fabs F8RC:$frB))]>;
1108 def FNABSS : XForm_26<63, 136, (outs F4RC:$frD), (ins F4RC:$frB),
1109                       "fnabs $frD, $frB", FPGeneral,
1110                       [(set F4RC:$frD, (fneg (fabs F4RC:$frB)))]>;
1111 def FNABSD : XForm_26<63, 136, (outs F8RC:$frD), (ins F8RC:$frB),
1112                       "fnabs $frD, $frB", FPGeneral,
1113                       [(set F8RC:$frD, (fneg (fabs F8RC:$frB)))]>;
1114 def FNEGS  : XForm_26<63, 40, (outs F4RC:$frD), (ins F4RC:$frB),
1115                       "fneg $frD, $frB", FPGeneral,
1116                       [(set F4RC:$frD, (fneg F4RC:$frB))]>;
1117 def FNEGD  : XForm_26<63, 40, (outs F8RC:$frD), (ins F8RC:$frB),
1118                       "fneg $frD, $frB", FPGeneral,
1119                       [(set F8RC:$frD, (fneg F8RC:$frB))]>;
1120 }
1121
1122
1123 // XL-Form instructions.  condition register logical ops.
1124 //
1125 def MCRF   : XLForm_3<19, 0, (outs CRRC:$BF), (ins CRRC:$BFA),
1126                       "mcrf $BF, $BFA", BrMCR>,
1127              PPC970_DGroup_First, PPC970_Unit_CRU;
1128
1129 def CREQV  : XLForm_1<19, 289, (outs CRBITRC:$CRD),
1130                                (ins CRBITRC:$CRA, CRBITRC:$CRB),
1131                       "creqv $CRD, $CRA, $CRB", BrCR,
1132                       []>;
1133
1134 def CROR  : XLForm_1<19, 449, (outs CRBITRC:$CRD),
1135                                (ins CRBITRC:$CRA, CRBITRC:$CRB),
1136                       "cror $CRD, $CRA, $CRB", BrCR,
1137                       []>;
1138
1139 def CRSET  : XLForm_1_ext<19, 289, (outs CRBITRC:$dst), (ins),
1140               "creqv $dst, $dst, $dst", BrCR,
1141               []>;
1142
1143 def CRUNSET: XLForm_1_ext<19, 193, (outs CRBITRC:$dst), (ins),
1144               "crxor $dst, $dst, $dst", BrCR,
1145               []>;
1146
1147 // XFX-Form instructions.  Instructions that deal with SPRs.
1148 //
1149 let Uses = [CTR] in {
1150 def MFCTR : XFXForm_1_ext<31, 339, 9, (outs GPRC:$rT), (ins),
1151                           "mfctr $rT", SprMFSPR>,
1152             PPC970_DGroup_First, PPC970_Unit_FXU;
1153 }
1154 let Defs = [CTR], Pattern = [(PPCmtctr GPRC:$rS)] in {
1155 def MTCTR : XFXForm_7_ext<31, 467, 9, (outs), (ins GPRC:$rS),
1156                           "mtctr $rS", SprMTSPR>,
1157             PPC970_DGroup_First, PPC970_Unit_FXU;
1158 }
1159
1160 let Defs = [LR] in {
1161 def MTLR  : XFXForm_7_ext<31, 467, 8, (outs), (ins GPRC:$rS),
1162                           "mtlr $rS", SprMTSPR>,
1163             PPC970_DGroup_First, PPC970_Unit_FXU;
1164 }
1165 let Uses = [LR] in {
1166 def MFLR  : XFXForm_1_ext<31, 339, 8, (outs GPRC:$rT), (ins),
1167                           "mflr $rT", SprMFSPR>,
1168             PPC970_DGroup_First, PPC970_Unit_FXU;
1169 }
1170
1171 // Move to/from VRSAVE: despite being a SPR, the VRSAVE register is renamed like
1172 // a GPR on the PPC970.  As such, copies in and out have the same performance
1173 // characteristics as an OR instruction.
1174 def MTVRSAVE : XFXForm_7_ext<31, 467, 256, (outs), (ins GPRC:$rS),
1175                              "mtspr 256, $rS", IntGeneral>,
1176                PPC970_DGroup_Single, PPC970_Unit_FXU;
1177 def MFVRSAVE : XFXForm_1_ext<31, 339, 256, (outs GPRC:$rT), (ins),
1178                              "mfspr $rT, 256", IntGeneral>,
1179                PPC970_DGroup_First, PPC970_Unit_FXU;
1180
1181 def MTCRF : XFXForm_5<31, 144, (outs crbitm:$FXM), (ins GPRC:$rS),
1182                       "mtcrf $FXM, $rS", BrMCRX>,
1183             PPC970_MicroCode, PPC970_Unit_CRU;
1184
1185 // This is a pseudo for MFCR, which implicitly uses all 8 of its subregisters;
1186 // declaring that here gives the local register allocator problems with this:
1187 //  vreg = MCRF  CR0
1188 //  MFCR  <kill of whatever preg got assigned to vreg>
1189 // while not declaring it breaks DeadMachineInstructionElimination.
1190 // As it turns out, in all cases where we currently use this,
1191 // we're only interested in one subregister of it.  Represent this in the
1192 // instruction to keep the register allocator from becoming confused.
1193 //
1194 // FIXME: Make this a real Pseudo instruction when the JIT switches to MC.
1195 def MFCRpseud: XFXForm_3<31, 19, (outs GPRC:$rT), (ins crbitm:$FXM),
1196                        "", SprMFCR>,
1197             PPC970_MicroCode, PPC970_Unit_CRU;
1198
1199 def MFCR : XFXForm_3<31, 19, (outs GPRC:$rT), (ins),
1200                      "mfcr $rT", SprMFCR>,
1201                      PPC970_MicroCode, PPC970_Unit_CRU;
1202
1203 def MFOCRF: XFXForm_5a<31, 19, (outs GPRC:$rT), (ins crbitm:$FXM),
1204                        "mfocrf $rT, $FXM", SprMFCR>,
1205             PPC970_DGroup_First, PPC970_Unit_CRU;
1206
1207 // Instructions to manipulate FPSCR.  Only long double handling uses these.
1208 // FPSCR is not modelled; we use the SDNode Flag to keep things in order.
1209
1210 let Uses = [RM], Defs = [RM] in {
1211   def MTFSB0 : XForm_43<63, 70, (outs), (ins u5imm:$FM),
1212                          "mtfsb0 $FM", IntMTFSB0,
1213                         [(PPCmtfsb0 (i32 imm:$FM))]>,
1214                PPC970_DGroup_Single, PPC970_Unit_FPU;
1215   def MTFSB1 : XForm_43<63, 38, (outs), (ins u5imm:$FM),
1216                          "mtfsb1 $FM", IntMTFSB0,
1217                         [(PPCmtfsb1 (i32 imm:$FM))]>,
1218                PPC970_DGroup_Single, PPC970_Unit_FPU;
1219   // MTFSF does not actually produce an FP result.  We pretend it copies
1220   // input reg B to the output.  If we didn't do this it would look like the
1221   // instruction had no outputs (because we aren't modelling the FPSCR) and
1222   // it would be deleted.
1223   def MTFSF  : XFLForm<63, 711, (outs F8RC:$FRA),
1224                                 (ins i32imm:$FM, F8RC:$rT, F8RC:$FRB),
1225                          "mtfsf $FM, $rT", "$FRB = $FRA", IntMTFSB0,
1226                          [(set F8RC:$FRA, (PPCmtfsf (i32 imm:$FM),
1227                                                      F8RC:$rT, F8RC:$FRB))]>,
1228                PPC970_DGroup_Single, PPC970_Unit_FPU;
1229 }
1230 let Uses = [RM] in {
1231   def MFFS   : XForm_42<63, 583, (outs F8RC:$rT), (ins),
1232                          "mffs $rT", IntMFFS,
1233                          [(set F8RC:$rT, (PPCmffs))]>,
1234                PPC970_DGroup_Single, PPC970_Unit_FPU;
1235   def FADDrtz: AForm_2<63, 21,
1236                       (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRB),
1237                       "fadd $FRT, $FRA, $FRB", FPGeneral,
1238                       [(set F8RC:$FRT, (PPCfaddrtz F8RC:$FRA, F8RC:$FRB))]>,
1239                PPC970_DGroup_Single, PPC970_Unit_FPU;
1240 }
1241
1242
1243 let PPC970_Unit = 1 in {  // FXU Operations.
1244
1245 // XO-Form instructions.  Arithmetic instructions that can set overflow bit
1246 //
1247 def ADD4  : XOForm_1<31, 266, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1248                      "add $rT, $rA, $rB", IntSimple,
1249                      [(set GPRC:$rT, (add GPRC:$rA, GPRC:$rB))]>;
1250 let Defs = [CARRY] in {
1251 def ADDC  : XOForm_1<31, 10, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1252                      "addc $rT, $rA, $rB", IntGeneral,
1253                      [(set GPRC:$rT, (addc GPRC:$rA, GPRC:$rB))]>,
1254                      PPC970_DGroup_Cracked;
1255 }
1256 def DIVW  : XOForm_1<31, 491, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1257                      "divw $rT, $rA, $rB", IntDivW,
1258                      [(set GPRC:$rT, (sdiv GPRC:$rA, GPRC:$rB))]>,
1259                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
1260 def DIVWU : XOForm_1<31, 459, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1261                      "divwu $rT, $rA, $rB", IntDivW,
1262                      [(set GPRC:$rT, (udiv GPRC:$rA, GPRC:$rB))]>,
1263                      PPC970_DGroup_First, PPC970_DGroup_Cracked;
1264 def MULHW : XOForm_1<31, 75, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1265                      "mulhw $rT, $rA, $rB", IntMulHW,
1266                      [(set GPRC:$rT, (mulhs GPRC:$rA, GPRC:$rB))]>;
1267 def MULHWU : XOForm_1<31, 11, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1268                      "mulhwu $rT, $rA, $rB", IntMulHWU,
1269                      [(set GPRC:$rT, (mulhu GPRC:$rA, GPRC:$rB))]>;
1270 def MULLW : XOForm_1<31, 235, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1271                      "mullw $rT, $rA, $rB", IntMulHW,
1272                      [(set GPRC:$rT, (mul GPRC:$rA, GPRC:$rB))]>;
1273 def SUBF  : XOForm_1<31, 40, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1274                      "subf $rT, $rA, $rB", IntGeneral,
1275                      [(set GPRC:$rT, (sub GPRC:$rB, GPRC:$rA))]>;
1276 let Defs = [CARRY] in {
1277 def SUBFC : XOForm_1<31, 8, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1278                      "subfc $rT, $rA, $rB", IntGeneral,
1279                      [(set GPRC:$rT, (subc GPRC:$rB, GPRC:$rA))]>,
1280                      PPC970_DGroup_Cracked;
1281 }
1282 def NEG    : XOForm_3<31, 104, 0, (outs GPRC:$rT), (ins GPRC:$rA),
1283                       "neg $rT, $rA", IntSimple,
1284                       [(set GPRC:$rT, (ineg GPRC:$rA))]>;
1285 let Uses = [CARRY], Defs = [CARRY] in {
1286 def ADDE  : XOForm_1<31, 138, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1287                       "adde $rT, $rA, $rB", IntGeneral,
1288                       [(set GPRC:$rT, (adde GPRC:$rA, GPRC:$rB))]>;
1289 def ADDME  : XOForm_3<31, 234, 0, (outs GPRC:$rT), (ins GPRC:$rA),
1290                       "addme $rT, $rA", IntGeneral,
1291                       [(set GPRC:$rT, (adde GPRC:$rA, -1))]>;
1292 def ADDZE  : XOForm_3<31, 202, 0, (outs GPRC:$rT), (ins GPRC:$rA),
1293                       "addze $rT, $rA", IntGeneral,
1294                       [(set GPRC:$rT, (adde GPRC:$rA, 0))]>;
1295 def SUBFE : XOForm_1<31, 136, 0, (outs GPRC:$rT), (ins GPRC:$rA, GPRC:$rB),
1296                       "subfe $rT, $rA, $rB", IntGeneral,
1297                       [(set GPRC:$rT, (sube GPRC:$rB, GPRC:$rA))]>;
1298 def SUBFME : XOForm_3<31, 232, 0, (outs GPRC:$rT), (ins GPRC:$rA),
1299                       "subfme $rT, $rA", IntGeneral,
1300                       [(set GPRC:$rT, (sube -1, GPRC:$rA))]>;
1301 def SUBFZE : XOForm_3<31, 200, 0, (outs GPRC:$rT), (ins GPRC:$rA),
1302                       "subfze $rT, $rA", IntGeneral,
1303                       [(set GPRC:$rT, (sube 0, GPRC:$rA))]>;
1304 }
1305 }
1306
1307 // A-Form instructions.  Most of the instructions executed in the FPU are of
1308 // this type.
1309 //
1310 let PPC970_Unit = 3 in {  // FPU Operations.
1311 let Uses = [RM] in {
1312   def FMADD : AForm_1<63, 29,
1313                       (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
1314                       "fmadd $FRT, $FRA, $FRC, $FRB", FPFused,
1315                       [(set F8RC:$FRT, (fadd (fmul F8RC:$FRA, F8RC:$FRC),
1316                                              F8RC:$FRB))]>,
1317                       Requires<[FPContractions]>;
1318   def FMADDS : AForm_1<59, 29,
1319                       (outs F4RC:$FRT), (ins F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
1320                       "fmadds $FRT, $FRA, $FRC, $FRB", FPGeneral,
1321                       [(set F4RC:$FRT, (fadd (fmul F4RC:$FRA, F4RC:$FRC),
1322                                              F4RC:$FRB))]>,
1323                       Requires<[FPContractions]>;
1324   def FMSUB : AForm_1<63, 28,
1325                       (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
1326                       "fmsub $FRT, $FRA, $FRC, $FRB", FPFused,
1327                       [(set F8RC:$FRT, (fsub (fmul F8RC:$FRA, F8RC:$FRC),
1328                                              F8RC:$FRB))]>,
1329                       Requires<[FPContractions]>;
1330   def FMSUBS : AForm_1<59, 28,
1331                       (outs F4RC:$FRT), (ins F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
1332                       "fmsubs $FRT, $FRA, $FRC, $FRB", FPGeneral,
1333                       [(set F4RC:$FRT, (fsub (fmul F4RC:$FRA, F4RC:$FRC),
1334                                              F4RC:$FRB))]>,
1335                       Requires<[FPContractions]>;
1336   def FNMADD : AForm_1<63, 31,
1337                       (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
1338                       "fnmadd $FRT, $FRA, $FRC, $FRB", FPFused,
1339                       [(set F8RC:$FRT, (fneg (fadd (fmul F8RC:$FRA, F8RC:$FRC),
1340                                                    F8RC:$FRB)))]>,
1341                       Requires<[FPContractions]>;
1342   def FNMADDS : AForm_1<59, 31,
1343                       (outs F4RC:$FRT), (ins F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
1344                       "fnmadds $FRT, $FRA, $FRC, $FRB", FPGeneral,
1345                       [(set F4RC:$FRT, (fneg (fadd (fmul F4RC:$FRA, F4RC:$FRC),
1346                                                    F4RC:$FRB)))]>,
1347                       Requires<[FPContractions]>;
1348   def FNMSUB : AForm_1<63, 30,
1349                       (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
1350                       "fnmsub $FRT, $FRA, $FRC, $FRB", FPFused,
1351                       [(set F8RC:$FRT, (fneg (fsub (fmul F8RC:$FRA, F8RC:$FRC),
1352                                                    F8RC:$FRB)))]>,
1353                       Requires<[FPContractions]>;
1354   def FNMSUBS : AForm_1<59, 30,
1355                       (outs F4RC:$FRT), (ins F4RC:$FRA, F4RC:$FRC, F4RC:$FRB),
1356                       "fnmsubs $FRT, $FRA, $FRC, $FRB", FPGeneral,
1357                       [(set F4RC:$FRT, (fneg (fsub (fmul F4RC:$FRA, F4RC:$FRC),
1358                                                    F4RC:$FRB)))]>,
1359                       Requires<[FPContractions]>;
1360 }
1361 // FSEL is artificially split into 4 and 8-byte forms for the result.  To avoid
1362 // having 4 of these, force the comparison to always be an 8-byte double (code
1363 // should use an FMRSD if the input comparison value really wants to be a float)
1364 // and 4/8 byte forms for the result and operand type..
1365 def FSELD : AForm_1<63, 23,
1366                     (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRC, F8RC:$FRB),
1367                     "fsel $FRT, $FRA, $FRC, $FRB", FPGeneral,
1368                     [(set F8RC:$FRT, (PPCfsel F8RC:$FRA,F8RC:$FRC,F8RC:$FRB))]>;
1369 def FSELS : AForm_1<63, 23,
1370                      (outs F4RC:$FRT), (ins F8RC:$FRA, F4RC:$FRC, F4RC:$FRB),
1371                      "fsel $FRT, $FRA, $FRC, $FRB", FPGeneral,
1372                     [(set F4RC:$FRT, (PPCfsel F8RC:$FRA,F4RC:$FRC,F4RC:$FRB))]>;
1373 let Uses = [RM] in {
1374   def FADD  : AForm_2<63, 21,
1375                       (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRB),
1376                       "fadd $FRT, $FRA, $FRB", FPGeneral,
1377                       [(set F8RC:$FRT, (fadd F8RC:$FRA, F8RC:$FRB))]>;
1378   def FADDS : AForm_2<59, 21,
1379                       (outs F4RC:$FRT), (ins F4RC:$FRA, F4RC:$FRB),
1380                       "fadds $FRT, $FRA, $FRB", FPGeneral,
1381                       [(set F4RC:$FRT, (fadd F4RC:$FRA, F4RC:$FRB))]>;
1382   def FDIV  : AForm_2<63, 18,
1383                       (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRB),
1384                       "fdiv $FRT, $FRA, $FRB", FPDivD,
1385                       [(set F8RC:$FRT, (fdiv F8RC:$FRA, F8RC:$FRB))]>;
1386   def FDIVS : AForm_2<59, 18,
1387                       (outs F4RC:$FRT), (ins F4RC:$FRA, F4RC:$FRB),
1388                       "fdivs $FRT, $FRA, $FRB", FPDivS,
1389                       [(set F4RC:$FRT, (fdiv F4RC:$FRA, F4RC:$FRB))]>;
1390   def FMUL  : AForm_3<63, 25,
1391                       (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRB),
1392                       "fmul $FRT, $FRA, $FRB", FPFused,
1393                       [(set F8RC:$FRT, (fmul F8RC:$FRA, F8RC:$FRB))]>;
1394   def FMULS : AForm_3<59, 25,
1395                       (outs F4RC:$FRT), (ins F4RC:$FRA, F4RC:$FRB),
1396                       "fmuls $FRT, $FRA, $FRB", FPGeneral,
1397                       [(set F4RC:$FRT, (fmul F4RC:$FRA, F4RC:$FRB))]>;
1398   def FSUB  : AForm_2<63, 20,
1399                       (outs F8RC:$FRT), (ins F8RC:$FRA, F8RC:$FRB),
1400                       "fsub $FRT, $FRA, $FRB", FPGeneral,
1401                       [(set F8RC:$FRT, (fsub F8RC:$FRA, F8RC:$FRB))]>;
1402   def FSUBS : AForm_2<59, 20,
1403                       (outs F4RC:$FRT), (ins F4RC:$FRA, F4RC:$FRB),
1404                       "fsubs $FRT, $FRA, $FRB", FPGeneral,
1405                       [(set F4RC:$FRT, (fsub F4RC:$FRA, F4RC:$FRB))]>;
1406   }
1407 }
1408
1409 let PPC970_Unit = 1 in {  // FXU Operations.
1410 // M-Form instructions.  rotate and mask instructions.
1411 //
1412 let isCommutable = 1 in {
1413 // RLWIMI can be commuted if the rotate amount is zero.
1414 def RLWIMI : MForm_2<20,
1415                      (outs GPRC:$rA), (ins GPRC:$rSi, GPRC:$rS, u5imm:$SH, u5imm:$MB,
1416                       u5imm:$ME), "rlwimi $rA, $rS, $SH, $MB, $ME", IntRotate,
1417                       []>, PPC970_DGroup_Cracked, RegConstraint<"$rSi = $rA">,
1418                       NoEncode<"$rSi">;
1419 }
1420 def RLWINM : MForm_2<21,
1421                      (outs GPRC:$rA), (ins GPRC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
1422                      "rlwinm $rA, $rS, $SH, $MB, $ME", IntGeneral,
1423                      []>;
1424 def RLWINMo : MForm_2<21,
1425                      (outs GPRC:$rA), (ins GPRC:$rS, u5imm:$SH, u5imm:$MB, u5imm:$ME),
1426                      "rlwinm. $rA, $rS, $SH, $MB, $ME", IntGeneral,
1427                      []>, isDOT, PPC970_DGroup_Cracked;
1428 def RLWNM  : MForm_2<23,
1429                      (outs GPRC:$rA), (ins GPRC:$rS, GPRC:$rB, u5imm:$MB, u5imm:$ME),
1430                      "rlwnm $rA, $rS, $rB, $MB, $ME", IntGeneral,
1431                      []>;
1432 }
1433
1434
1435 //===----------------------------------------------------------------------===//
1436 // PowerPC Instruction Patterns
1437 //
1438
1439 // Arbitrary immediate support.  Implement in terms of LIS/ORI.
1440 def : Pat<(i32 imm:$imm),
1441           (ORI (LIS (HI16 imm:$imm)), (LO16 imm:$imm))>;
1442
1443 // Implement the 'not' operation with the NOR instruction.
1444 def NOT : Pat<(not GPRC:$in),
1445               (NOR GPRC:$in, GPRC:$in)>;
1446
1447 // ADD an arbitrary immediate.
1448 def : Pat<(add GPRC:$in, imm:$imm),
1449           (ADDIS (ADDI GPRC:$in, (LO16 imm:$imm)), (HA16 imm:$imm))>;
1450 // OR an arbitrary immediate.
1451 def : Pat<(or GPRC:$in, imm:$imm),
1452           (ORIS (ORI GPRC:$in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
1453 // XOR an arbitrary immediate.
1454 def : Pat<(xor GPRC:$in, imm:$imm),
1455           (XORIS (XORI GPRC:$in, (LO16 imm:$imm)), (HI16 imm:$imm))>;
1456 // SUBFIC
1457 def : Pat<(sub  immSExt16:$imm, GPRC:$in),
1458           (SUBFIC GPRC:$in, imm:$imm)>;
1459
1460 // SHL/SRL
1461 def : Pat<(shl GPRC:$in, (i32 imm:$imm)),
1462           (RLWINM GPRC:$in, imm:$imm, 0, (SHL32 imm:$imm))>;
1463 def : Pat<(srl GPRC:$in, (i32 imm:$imm)),
1464           (RLWINM GPRC:$in, (SRL32 imm:$imm), imm:$imm, 31)>;
1465
1466 // ROTL
1467 def : Pat<(rotl GPRC:$in, GPRC:$sh),
1468           (RLWNM GPRC:$in, GPRC:$sh, 0, 31)>;
1469 def : Pat<(rotl GPRC:$in, (i32 imm:$imm)),
1470           (RLWINM GPRC:$in, imm:$imm, 0, 31)>;
1471
1472 // RLWNM
1473 def : Pat<(and (rotl GPRC:$in, GPRC:$sh), maskimm32:$imm),
1474           (RLWNM GPRC:$in, GPRC:$sh, (MB maskimm32:$imm), (ME maskimm32:$imm))>;
1475
1476 // Calls
1477 def : Pat<(PPCcall_Darwin (i32 tglobaladdr:$dst)),
1478           (BL_Darwin tglobaladdr:$dst)>;
1479 def : Pat<(PPCcall_Darwin (i32 texternalsym:$dst)),
1480           (BL_Darwin texternalsym:$dst)>;
1481 def : Pat<(PPCcall_SVR4 (i32 tglobaladdr:$dst)),
1482           (BL_SVR4 tglobaladdr:$dst)>;
1483 def : Pat<(PPCcall_SVR4 (i32 texternalsym:$dst)),
1484           (BL_SVR4 texternalsym:$dst)>;
1485
1486
1487 def : Pat<(PPCtc_return (i32 tglobaladdr:$dst),  imm:$imm),
1488           (TCRETURNdi tglobaladdr:$dst, imm:$imm)>;
1489
1490 def : Pat<(PPCtc_return (i32 texternalsym:$dst), imm:$imm),
1491           (TCRETURNdi texternalsym:$dst, imm:$imm)>;
1492
1493 def : Pat<(PPCtc_return CTRRC:$dst, imm:$imm),
1494           (TCRETURNri CTRRC:$dst, imm:$imm)>;
1495
1496
1497
1498 // Hi and Lo for Darwin Global Addresses.
1499 def : Pat<(PPChi tglobaladdr:$in, 0), (LIS tglobaladdr:$in)>;
1500 def : Pat<(PPClo tglobaladdr:$in, 0), (LI tglobaladdr:$in)>;
1501 def : Pat<(PPChi tconstpool:$in, 0), (LIS tconstpool:$in)>;
1502 def : Pat<(PPClo tconstpool:$in, 0), (LI tconstpool:$in)>;
1503 def : Pat<(PPChi tjumptable:$in, 0), (LIS tjumptable:$in)>;
1504 def : Pat<(PPClo tjumptable:$in, 0), (LI tjumptable:$in)>;
1505 def : Pat<(PPChi tblockaddress:$in, 0), (LIS tblockaddress:$in)>;
1506 def : Pat<(PPClo tblockaddress:$in, 0), (LI tblockaddress:$in)>;
1507 def : Pat<(PPChi tglobaltlsaddr:$g, GPRC:$in),
1508           (ADDIS GPRC:$in, tglobaltlsaddr:$g)>;
1509 def : Pat<(PPClo tglobaltlsaddr:$g, GPRC:$in),
1510           (ADDIL GPRC:$in, tglobaltlsaddr:$g)>;
1511 def : Pat<(add GPRC:$in, (PPChi tglobaladdr:$g, 0)),
1512           (ADDIS GPRC:$in, tglobaladdr:$g)>;
1513 def : Pat<(add GPRC:$in, (PPChi tconstpool:$g, 0)),
1514           (ADDIS GPRC:$in, tconstpool:$g)>;
1515 def : Pat<(add GPRC:$in, (PPChi tjumptable:$g, 0)),
1516           (ADDIS GPRC:$in, tjumptable:$g)>;
1517 def : Pat<(add GPRC:$in, (PPChi tblockaddress:$g, 0)),
1518           (ADDIS GPRC:$in, tblockaddress:$g)>;
1519
1520 // Fused negative multiply subtract, alternate pattern
1521 def : Pat<(fsub F8RC:$B, (fmul F8RC:$A, F8RC:$C)),
1522           (FNMSUB F8RC:$A, F8RC:$C, F8RC:$B)>,
1523           Requires<[FPContractions]>;
1524 def : Pat<(fsub F4RC:$B, (fmul F4RC:$A, F4RC:$C)),
1525           (FNMSUBS F4RC:$A, F4RC:$C, F4RC:$B)>,
1526           Requires<[FPContractions]>;
1527
1528 // Standard shifts.  These are represented separately from the real shifts above
1529 // so that we can distinguish between shifts that allow 5-bit and 6-bit shift
1530 // amounts.
1531 def : Pat<(sra GPRC:$rS, GPRC:$rB),
1532           (SRAW GPRC:$rS, GPRC:$rB)>;
1533 def : Pat<(srl GPRC:$rS, GPRC:$rB),
1534           (SRW GPRC:$rS, GPRC:$rB)>;
1535 def : Pat<(shl GPRC:$rS, GPRC:$rB),
1536           (SLW GPRC:$rS, GPRC:$rB)>;
1537
1538 def : Pat<(zextloadi1 iaddr:$src),
1539           (LBZ iaddr:$src)>;
1540 def : Pat<(zextloadi1 xaddr:$src),
1541           (LBZX xaddr:$src)>;
1542 def : Pat<(extloadi1 iaddr:$src),
1543           (LBZ iaddr:$src)>;
1544 def : Pat<(extloadi1 xaddr:$src),
1545           (LBZX xaddr:$src)>;
1546 def : Pat<(extloadi8 iaddr:$src),
1547           (LBZ iaddr:$src)>;
1548 def : Pat<(extloadi8 xaddr:$src),
1549           (LBZX xaddr:$src)>;
1550 def : Pat<(extloadi16 iaddr:$src),
1551           (LHZ iaddr:$src)>;
1552 def : Pat<(extloadi16 xaddr:$src),
1553           (LHZX xaddr:$src)>;
1554 def : Pat<(f64 (extloadf32 iaddr:$src)),
1555           (COPY_TO_REGCLASS (LFS iaddr:$src), F8RC)>;
1556 def : Pat<(f64 (extloadf32 xaddr:$src)),
1557           (COPY_TO_REGCLASS (LFSX xaddr:$src), F8RC)>;
1558
1559 def : Pat<(f64 (fextend F4RC:$src)),
1560           (COPY_TO_REGCLASS F4RC:$src, F8RC)>;
1561
1562 // Memory barriers
1563 def : Pat<(membarrier (i32 imm /*ll*/),
1564                       (i32 imm /*ls*/),
1565                       (i32 imm /*sl*/),
1566                       (i32 imm /*ss*/),
1567                       (i32 imm /*device*/)),
1568            (SYNC)>;
1569
1570 def : Pat<(atomic_fence (imm), (imm)), (SYNC)>;
1571
1572 include "PPCInstrAltivec.td"
1573 include "PPCInstr64Bit.td"