lib/Target/R600/EvergreenInstructions.td

   1 //===-- EvergreenInstructions.td - EG Instruction defs  ----*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // TableGen definitions for instructions which are:
  11 // - Available to Evergreen and newer VLIW4/VLIW5 GPUs
  12 // - Available only on Evergreen family GPUs.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 def isEG : Predicate<
  17   "Subtarget.getGeneration() >= AMDGPUSubtarget::EVERGREEN && "
  18   "Subtarget.getGeneration() < AMDGPUSubtarget::SOUTHERN_ISLANDS && "
  19   "!Subtarget.hasCaymanISA()"
  20 >;
  21
  22 def isEGorCayman : Predicate<
  23   "Subtarget.getGeneration() == AMDGPUSubtarget::EVERGREEN ||"
  24   "Subtarget.getGeneration() ==AMDGPUSubtarget::NORTHERN_ISLANDS"
  25 >;
  26
  27 //===----------------------------------------------------------------------===//
  28 // Evergreen / Cayman store instructions
  29 //===----------------------------------------------------------------------===//
  30
  31 let Predicates = [isEGorCayman] in {
  32
  33 class CF_MEM_RAT_CACHELESS <bits<6> rat_inst, bits<4> rat_id, bits<4> mask, dag ins,
  34                            string name, list<dag> pattern>
  35     : EG_CF_RAT <0x57, rat_inst, rat_id, mask, (outs), ins,
  36                  "MEM_RAT_CACHELESS "#name, pattern>;
  37
  38 class CF_MEM_RAT <bits<6> rat_inst, bits<4> rat_id, dag ins, string name,
  39                   list<dag> pattern>
  40     : EG_CF_RAT <0x56, rat_inst, rat_id, 0xf /* mask */, (outs), ins,
  41                  "MEM_RAT "#name, pattern>;
  42
  43 def RAT_MSKOR : CF_MEM_RAT <0x11, 0,
  44   (ins R600_Reg128:$rw_gpr, R600_TReg32_X:$index_gpr),
  45   "MSKOR $rw_gpr.XW, $index_gpr",
  46   [(mskor_global v4i32:$rw_gpr, i32:$index_gpr)]
  47 > {
  48   let eop = 0;
  49 }
  50
  51 } // End let Predicates = [isEGorCayman]
  52
  53 //===----------------------------------------------------------------------===//
  54 // Evergreen Only instructions
  55 //===----------------------------------------------------------------------===//
  56
  57 let Predicates = [isEG] in {
  58
  59 def RECIP_IEEE_eg : RECIP_IEEE_Common<0x86>;
  60 defm DIV_eg : DIV_Common<RECIP_IEEE_eg>;
  61
  62 def MULLO_INT_eg : MULLO_INT_Common<0x8F>;
  63 def MULHI_INT_eg : MULHI_INT_Common<0x90>;
  64 def MULLO_UINT_eg : MULLO_UINT_Common<0x91>;
  65 def MULHI_UINT_eg : MULHI_UINT_Common<0x92>;
  66 def RECIP_UINT_eg : RECIP_UINT_Common<0x94>;
  67 def RECIPSQRT_CLAMPED_eg : RECIPSQRT_CLAMPED_Common<0x87>;
  68 def EXP_IEEE_eg : EXP_IEEE_Common<0x81>;
  69 def LOG_IEEE_eg : LOG_IEEE_Common<0x83>;
  70 def RECIP_CLAMPED_eg : RECIP_CLAMPED_Common<0x84>;
  71 def RECIPSQRT_IEEE_eg : RECIPSQRT_IEEE_Common<0x89>;
  72 def SIN_eg : SIN_Common<0x8D>;
  73 def COS_eg : COS_Common<0x8E>;
  74
  75 def : POW_Common <LOG_IEEE_eg, EXP_IEEE_eg, MUL>;
  76 def : Pat<(fsqrt f32:$src), (MUL $src, (RECIPSQRT_CLAMPED_eg $src))>;
  77
  78 //===----------------------------------------------------------------------===//
  79 // Memory read/write instructions
  80 //===----------------------------------------------------------------------===//
  81
  82 let usesCustomInserter = 1 in {
  83
  84 // 32-bit store
  85 def RAT_WRITE_CACHELESS_32_eg : CF_MEM_RAT_CACHELESS <0x2, 0, 0x1,
  86   (ins R600_TReg32_X:$rw_gpr, R600_TReg32_X:$index_gpr, InstFlag:$eop),
  87   "STORE_RAW $rw_gpr, $index_gpr, $eop",
  88   [(global_store i32:$rw_gpr, i32:$index_gpr)]
  89 >;
  90
  91 // 64-bit store
  92 def RAT_WRITE_CACHELESS_64_eg : CF_MEM_RAT_CACHELESS <0x2, 0, 0x3,
  93   (ins R600_Reg64:$rw_gpr, R600_TReg32_X:$index_gpr, InstFlag:$eop),
  94   "STORE_RAW $rw_gpr.XY, $index_gpr, $eop",
  95   [(global_store v2i32:$rw_gpr, i32:$index_gpr)]
  96 >;
  97
  98 //128-bit store
  99 def RAT_WRITE_CACHELESS_128_eg : CF_MEM_RAT_CACHELESS <0x2, 0, 0xf,
 100   (ins R600_Reg128:$rw_gpr, R600_TReg32_X:$index_gpr, InstFlag:$eop),
 101   "STORE_RAW $rw_gpr.XYZW, $index_gpr, $eop",
 102   [(global_store v4i32:$rw_gpr, i32:$index_gpr)]
 103 >;
 104
 105 } // End usesCustomInserter = 1
 106
 107 class VTX_READ_eg <string name, bits<8> buffer_id, dag outs, list<dag> pattern>
 108     : VTX_WORD0_eg, VTX_READ<name, buffer_id, outs, pattern> {
 109
 110   // Static fields
 111   let VC_INST = 0;
 112   let FETCH_TYPE = 2;
 113   let FETCH_WHOLE_QUAD = 0;
 114   let BUFFER_ID = buffer_id;
 115   let SRC_REL = 0;
 116   // XXX: We can infer this field based on the SRC_GPR.  This would allow us
 117   // to store vertex addresses in any channel, not just X.
 118   let SRC_SEL_X = 0;
 119
 120   let Inst{31-0} = Word0;
 121 }
 122
 123 class VTX_READ_8_eg <bits<8> buffer_id, list<dag> pattern>
 124     : VTX_READ_eg <"VTX_READ_8 $dst_gpr, $src_gpr", buffer_id,
 125                    (outs R600_TReg32_X:$dst_gpr), pattern> {
 126
 127   let MEGA_FETCH_COUNT = 1;
 128   let DST_SEL_X = 0;
 129   let DST_SEL_Y = 7;   // Masked
 130   let DST_SEL_Z = 7;   // Masked
 131   let DST_SEL_W = 7;   // Masked
 132   let DATA_FORMAT = 1; // FMT_8
 133 }
 134
 135 class VTX_READ_16_eg <bits<8> buffer_id, list<dag> pattern>
 136     : VTX_READ_eg <"VTX_READ_16 $dst_gpr, $src_gpr", buffer_id,
 137                    (outs R600_TReg32_X:$dst_gpr), pattern> {
 138   let MEGA_FETCH_COUNT = 2;
 139   let DST_SEL_X = 0;
 140   let DST_SEL_Y = 7;   // Masked
 141   let DST_SEL_Z = 7;   // Masked
 142   let DST_SEL_W = 7;   // Masked
 143   let DATA_FORMAT = 5; // FMT_16
 144
 145 }
 146
 147 class VTX_READ_32_eg <bits<8> buffer_id, list<dag> pattern>
 148     : VTX_READ_eg <"VTX_READ_32 $dst_gpr, $src_gpr", buffer_id,
 149                    (outs R600_TReg32_X:$dst_gpr), pattern> {
 150
 151   let MEGA_FETCH_COUNT = 4;
 152   let DST_SEL_X        = 0;
 153   let DST_SEL_Y        = 7;   // Masked
 154   let DST_SEL_Z        = 7;   // Masked
 155   let DST_SEL_W        = 7;   // Masked
 156   let DATA_FORMAT      = 0xD; // COLOR_32
 157
 158   // This is not really necessary, but there were some GPU hangs that appeared
 159   // to be caused by ALU instructions in the next instruction group that wrote
 160   // to the $src_gpr registers of the VTX_READ.
 161   // e.g.
 162   // %T3_X<def> = VTX_READ_PARAM_32_eg %T2_X<kill>, 24
 163   // %T2_X<def> = MOV %ZERO
 164   //Adding this constraint prevents this from happening.
 165   let Constraints = "$src_gpr.ptr = $dst_gpr";
 166 }
 167
 168 class VTX_READ_64_eg <bits<8> buffer_id, list<dag> pattern>
 169     : VTX_READ_eg <"VTX_READ_64 $dst_gpr.XY, $src_gpr", buffer_id,
 170                    (outs R600_Reg64:$dst_gpr), pattern> {
 171
 172   let MEGA_FETCH_COUNT = 8;
 173   let DST_SEL_X        = 0;
 174   let DST_SEL_Y        = 1;
 175   let DST_SEL_Z        = 7;
 176   let DST_SEL_W        = 7;
 177   let DATA_FORMAT      = 0x1D; // COLOR_32_32
 178 }
 179
 180 class VTX_READ_128_eg <bits<8> buffer_id, list<dag> pattern>
 181     : VTX_READ_eg <"VTX_READ_128 $dst_gpr.XYZW, $src_gpr", buffer_id,
 182                    (outs R600_Reg128:$dst_gpr), pattern> {
 183
 184   let MEGA_FETCH_COUNT = 16;
 185   let DST_SEL_X        =  0;
 186   let DST_SEL_Y        =  1;
 187   let DST_SEL_Z        =  2;
 188   let DST_SEL_W        =  3;
 189   let DATA_FORMAT      =  0x22; // COLOR_32_32_32_32
 190
 191   // XXX: Need to force VTX_READ_128 instructions to write to the same register
 192   // that holds its buffer address to avoid potential hangs.  We can't use
 193   // the same constraint as VTX_READ_32_eg, because the $src_gpr.ptr and $dst
 194   // registers are different sizes.
 195 }
 196
 197 //===----------------------------------------------------------------------===//
 198 // VTX Read from parameter memory space
 199 //===----------------------------------------------------------------------===//
 200
 201 def VTX_READ_PARAM_8_eg : VTX_READ_8_eg <0,
 202   [(set i32:$dst_gpr, (load_param_exti8 ADDRVTX_READ:$src_gpr))]
 203 >;
 204
 205 def VTX_READ_PARAM_16_eg : VTX_READ_16_eg <0,
 206   [(set i32:$dst_gpr, (load_param_exti16 ADDRVTX_READ:$src_gpr))]
 207 >;
 208
 209 def VTX_READ_PARAM_32_eg : VTX_READ_32_eg <0,
 210   [(set i32:$dst_gpr, (load_param ADDRVTX_READ:$src_gpr))]
 211 >;
 212
 213 def VTX_READ_PARAM_64_eg : VTX_READ_64_eg <0,
 214   [(set v2i32:$dst_gpr, (load_param ADDRVTX_READ:$src_gpr))]
 215 >;
 216
 217 def VTX_READ_PARAM_128_eg : VTX_READ_128_eg <0,
 218   [(set v4i32:$dst_gpr, (load_param ADDRVTX_READ:$src_gpr))]
 219 >;
 220
 221 //===----------------------------------------------------------------------===//
 222 // VTX Read from global memory space
 223 //===----------------------------------------------------------------------===//
 224
 225 // 8-bit reads
 226 def VTX_READ_GLOBAL_8_eg : VTX_READ_8_eg <1,
 227   [(set i32:$dst_gpr, (az_extloadi8_global ADDRVTX_READ:$src_gpr))]
 228 >;
 229
 230 def VTX_READ_GLOBAL_16_eg : VTX_READ_16_eg <1,
 231   [(set i32:$dst_gpr, (az_extloadi16_global ADDRVTX_READ:$src_gpr))]
 232 >;
 233
 234 // 32-bit reads
 235 def VTX_READ_GLOBAL_32_eg : VTX_READ_32_eg <1,
 236   [(set i32:$dst_gpr, (global_load ADDRVTX_READ:$src_gpr))]
 237 >;
 238
 239 // 64-bit reads
 240 def VTX_READ_GLOBAL_64_eg : VTX_READ_64_eg <1,
 241   [(set v2i32:$dst_gpr, (global_load ADDRVTX_READ:$src_gpr))]
 242 >;
 243
 244 // 128-bit reads
 245 def VTX_READ_GLOBAL_128_eg : VTX_READ_128_eg <1,
 246   [(set v4i32:$dst_gpr, (global_load ADDRVTX_READ:$src_gpr))]
 247 >;
 248
 249 } // End Predicates = [isEG]
 250
 251 //===----------------------------------------------------------------------===//
 252 // Evergreen / Cayman Instructions
 253 //===----------------------------------------------------------------------===//
 254
 255 let Predicates = [isEGorCayman] in {
 256
 257 // BFE_UINT - bit_extract, an optimization for mask and shift
 258 // Src0 = Input
 259 // Src1 = Offset
 260 // Src2 = Width
 261 //
 262 // bit_extract = (Input << (32 - Offset - Width)) >> (32 - Width)
 263 //
 264 // Example Usage:
 265 // (Offset, Width)
 266 //
 267 // (0, 8)  = (Input << 24) >> 24 = (Input &  0xff)       >> 0
 268 // (8, 8)  = (Input << 16) >> 24 = (Input &  0xffff)     >> 8
 269 // (16, 8) = (Input <<  8) >> 24 = (Input &  0xffffff)   >> 16
 270 // (24, 8) = (Input <<  0) >> 24 = (Input &  0xffffffff) >> 24
 271 def BFE_UINT_eg : R600_3OP <0x4, "BFE_UINT",
 272   [(set i32:$dst, (AMDGPUbfe_u32 i32:$src0, i32:$src1, i32:$src2))],
 273   VecALU
 274 >;
 275
 276 def BFE_INT_eg : R600_3OP <0x4, "BFE_INT",
 277   [(set i32:$dst, (AMDGPUbfe_i32 i32:$src0, i32:$src1, i32:$src2))],
 278   VecALU
 279 >;
 280
 281 // XXX: This pattern is broken, disabling for now.  See comment in
 282 // AMDGPUInstructions.td for more info.
 283 //  def : BFEPattern <BFE_UINT_eg>;
 284
 285 def BFI_INT_eg : R600_3OP <0x06, "BFI_INT", [], VecALU>;
 286 defm : BFIPatterns <BFI_INT_eg>;
 287
 288 def MULADD_UINT24_eg : R600_3OP <0x10, "MULADD_UINT24",
 289   [(set i32:$dst, (add (mul U24:$src0, U24:$src1), i32:$src2))], VecALU
 290 >;
 291 def BIT_ALIGN_INT_eg : R600_3OP <0xC, "BIT_ALIGN_INT", [], VecALU>;
 292 def : ROTRPattern <BIT_ALIGN_INT_eg>;
 293 def MULADD_eg : MULADD_Common<0x14>;
 294 def MULADD_IEEE_eg : MULADD_IEEE_Common<0x18>;
 295 def ASHR_eg : ASHR_Common<0x15>;
 296 def LSHR_eg : LSHR_Common<0x16>;
 297 def LSHL_eg : LSHL_Common<0x17>;
 298 def CNDE_eg : CNDE_Common<0x19>;
 299 def CNDGT_eg : CNDGT_Common<0x1A>;
 300 def CNDGE_eg : CNDGE_Common<0x1B>;
 301 def MUL_LIT_eg : MUL_LIT_Common<0x1F>;
 302 def LOG_CLAMPED_eg : LOG_CLAMPED_Common<0x82>;
 303 def MUL_UINT24_eg : R600_2OP <0xB5, "MUL_UINT24",
 304   [(set i32:$dst, (mul U24:$src0, U24:$src1))], VecALU
 305 >;
 306 def DOT4_eg : DOT4_Common<0xBE>;
 307 defm CUBE_eg : CUBE_Common<0xC0>;
 308
 309 let hasSideEffects = 1 in {
 310   def MOVA_INT_eg : R600_1OP <0xCC, "MOVA_INT", [], VecALU>;
 311 }
 312
 313 def TGSI_LIT_Z_eg : TGSI_LIT_Z_Common<MUL_LIT_eg, LOG_CLAMPED_eg, EXP_IEEE_eg>;
 314
 315 def FLT_TO_INT_eg : FLT_TO_INT_Common<0x50> {
 316   let Pattern = [];
 317   let Itinerary = AnyALU;
 318 }
 319
 320 def INT_TO_FLT_eg : INT_TO_FLT_Common<0x9B>;
 321
 322 def FLT_TO_UINT_eg : FLT_TO_UINT_Common<0x9A> {
 323   let Pattern = [];
 324 }
 325
 326 def UINT_TO_FLT_eg : UINT_TO_FLT_Common<0x9C>;
 327
 328 def GROUP_BARRIER : InstR600 <
 329     (outs), (ins), "  GROUP_BARRIER", [(int_AMDGPU_barrier_local)], AnyALU>,
 330     R600ALU_Word0,
 331     R600ALU_Word1_OP2 <0x54> {
 332
 333   let dst = 0;
 334   let dst_rel = 0;
 335   let src0 = 0;
 336   let src0_rel = 0;
 337   let src0_neg = 0;
 338   let src0_abs = 0;
 339   let src1 = 0;
 340   let src1_rel = 0;
 341   let src1_neg = 0;
 342   let src1_abs = 0;
 343   let write = 0;
 344   let omod = 0;
 345   let clamp = 0;
 346   let last = 1;
 347   let bank_swizzle = 0;
 348   let pred_sel = 0;
 349   let update_exec_mask = 0;
 350   let update_pred = 0;
 351
 352   let Inst{31-0}  = Word0;
 353   let Inst{63-32} = Word1;
 354
 355   let ALUInst = 1;
 356 }
 357
 358 //===----------------------------------------------------------------------===//
 359 // LDS Instructions
 360 //===----------------------------------------------------------------------===//
 361 class R600_LDS  <bits<6> op, dag outs, dag ins, string asm,
 362                  list<dag> pattern = []> :
 363
 364     InstR600 <outs, ins, asm, pattern, XALU>,
 365     R600_ALU_LDS_Word0,
 366     R600LDS_Word1 {
 367
 368   bits<6>  offset = 0;
 369   let lds_op = op;
 370
 371   let Word1{27} = offset{0};
 372   let Word1{12} = offset{1};
 373   let Word1{28} = offset{2};
 374   let Word1{31} = offset{3};
 375   let Word0{12} = offset{4};
 376   let Word0{25} = offset{5};
 377
 378
 379   let Inst{31-0}  = Word0;
 380   let Inst{63-32} = Word1;
 381
 382   let ALUInst = 1;
 383   let HasNativeOperands = 1;
 384   let UseNamedOperandTable = 1;
 385 }
 386
 387 class R600_LDS_1A <bits<6> lds_op, string name, list<dag> pattern> : R600_LDS <
 388   lds_op,
 389   (outs R600_Reg32:$dst),
 390   (ins R600_Reg32:$src0, REL:$src0_rel, SEL:$src0_sel,
 391        LAST:$last, R600_Pred:$pred_sel,
 392        BANK_SWIZZLE:$bank_swizzle),
 393   "  "#name#" $last OQAP, $src0$src0_rel $pred_sel",
 394   pattern
 395   > {
 396
 397   let src1 = 0;
 398   let src1_rel = 0;
 399   let src2 = 0;
 400   let src2_rel = 0;
 401
 402   let usesCustomInserter = 1;
 403   let LDS_1A = 1;
 404   let DisableEncoding = "$dst";
 405 }
 406
 407 class R600_LDS_1A1D <bits<6> lds_op, dag outs, string name, list<dag> pattern,
 408                      string dst =""> :
 409     R600_LDS <
 410   lds_op, outs,
 411   (ins R600_Reg32:$src0, REL:$src0_rel, SEL:$src0_sel,
 412        R600_Reg32:$src1, REL:$src1_rel, SEL:$src1_sel,
 413        LAST:$last, R600_Pred:$pred_sel,
 414        BANK_SWIZZLE:$bank_swizzle),
 415   "  "#name#" $last "#dst#"$src0$src0_rel, $src1$src1_rel, $pred_sel",
 416   pattern
 417   > {
 418
 419   field string BaseOp;
 420
 421   let src2 = 0;
 422   let src2_rel = 0;
 423   let LDS_1A1D = 1;
 424 }
 425
 426 class R600_LDS_1A1D_NORET <bits<6> lds_op, string name, list<dag> pattern> :
 427     R600_LDS_1A1D <lds_op, (outs), name, pattern> {
 428   let BaseOp = name;
 429 }
 430
 431 class R600_LDS_1A1D_RET <bits<6> lds_op, string name, list<dag> pattern> :
 432     R600_LDS_1A1D <lds_op,  (outs R600_Reg32:$dst), name##"_RET", pattern, "OQAP, "> {
 433
 434   let BaseOp = name;
 435   let usesCustomInserter = 1;
 436   let DisableEncoding = "$dst";
 437 }
 438
 439 class R600_LDS_1A2D <bits<6> lds_op, string name, list<dag> pattern> :
 440     R600_LDS <
 441   lds_op,
 442   (outs),
 443   (ins R600_Reg32:$src0, REL:$src0_rel, SEL:$src0_sel,
 444        R600_Reg32:$src1, REL:$src1_rel, SEL:$src1_sel,
 445        R600_Reg32:$src2, REL:$src2_rel, SEL:$src2_sel,
 446        LAST:$last, R600_Pred:$pred_sel, BANK_SWIZZLE:$bank_swizzle),
 447   "  "#name# "$last $src0$src0_rel, $src1$src1_rel, $src2$src2_rel, $pred_sel",
 448   pattern> {
 449   let LDS_1A2D = 1;
 450 }
 451
 452 def LDS_ADD : R600_LDS_1A1D_NORET <0x0, "LDS_ADD", [] >;
 453 def LDS_SUB : R600_LDS_1A1D_NORET <0x1, "LDS_SUB", [] >;
 454 def LDS_WRITE : R600_LDS_1A1D_NORET <0xD, "LDS_WRITE",
 455   [(local_store (i32 R600_Reg32:$src1), R600_Reg32:$src0)]
 456 >;
 457 def LDS_BYTE_WRITE : R600_LDS_1A1D_NORET<0x12, "LDS_BYTE_WRITE",
 458   [(truncstorei8_local i32:$src1, i32:$src0)]
 459 >;
 460 def LDS_SHORT_WRITE : R600_LDS_1A1D_NORET<0x13, "LDS_SHORT_WRITE",
 461   [(truncstorei16_local i32:$src1, i32:$src0)]
 462 >;
 463 def LDS_ADD_RET : R600_LDS_1A1D_RET <0x20, "LDS_ADD",
 464   [(set i32:$dst, (atomic_load_add_local i32:$src0, i32:$src1))]
 465 >;
 466 def LDS_SUB_RET : R600_LDS_1A1D_RET <0x21, "LDS_SUB",
 467   [(set i32:$dst, (atomic_load_sub_local i32:$src0, i32:$src1))]
 468 >;
 469 def LDS_READ_RET : R600_LDS_1A <0x32, "LDS_READ_RET",
 470   [(set (i32 R600_Reg32:$dst), (local_load R600_Reg32:$src0))]
 471 >;
 472 def LDS_BYTE_READ_RET : R600_LDS_1A <0x36, "LDS_BYTE_READ_RET",
 473   [(set i32:$dst, (sextloadi8_local i32:$src0))]
 474 >;
 475 def LDS_UBYTE_READ_RET : R600_LDS_1A <0x37, "LDS_UBYTE_READ_RET",
 476   [(set i32:$dst, (az_extloadi8_local i32:$src0))]
 477 >;
 478 def LDS_SHORT_READ_RET : R600_LDS_1A <0x38, "LDS_SHORT_READ_RET",
 479   [(set i32:$dst, (sextloadi16_local i32:$src0))]
 480 >;
 481 def LDS_USHORT_READ_RET : R600_LDS_1A <0x39, "LDS_USHORT_READ_RET",
 482   [(set i32:$dst, (az_extloadi16_local i32:$src0))]
 483 >;
 484
 485 // TRUNC is used for the FLT_TO_INT instructions to work around a
 486 // perceived problem where the rounding modes are applied differently
 487 // depending on the instruction and the slot they are in.
 488 // See:
 489 // https://bugs.freedesktop.org/show_bug.cgi?id=50232
 490 // Mesa commit: a1a0974401c467cb86ef818f22df67c21774a38c
 491 //
 492 // XXX: Lowering SELECT_CC will sometimes generate fp_to_[su]int nodes,
 493 // which do not need to be truncated since the fp values are 0.0f or 1.0f.
 494 // We should look into handling these cases separately.
 495 def : Pat<(fp_to_sint f32:$src0), (FLT_TO_INT_eg (TRUNC $src0))>;
 496
 497 def : Pat<(fp_to_uint f32:$src0), (FLT_TO_UINT_eg (TRUNC $src0))>;
 498
 499 // SHA-256 Patterns
 500 def : SHA256MaPattern <BFI_INT_eg, XOR_INT>;
 501
 502 def : FROUNDPat <CNDGE_eg>;
 503
 504 def EG_ExportSwz : ExportSwzInst {
 505   let Word1{19-16} = 0; // BURST_COUNT
 506   let Word1{20} = 0; // VALID_PIXEL_MODE
 507   let Word1{21} = eop;
 508   let Word1{29-22} = inst;
 509   let Word1{30} = 0; // MARK
 510   let Word1{31} = 1; // BARRIER
 511 }
 512 defm : ExportPattern<EG_ExportSwz, 83>;
 513
 514 def EG_ExportBuf : ExportBufInst {
 515   let Word1{19-16} = 0; // BURST_COUNT
 516   let Word1{20} = 0; // VALID_PIXEL_MODE
 517   let Word1{21} = eop;
 518   let Word1{29-22} = inst;
 519   let Word1{30} = 0; // MARK
 520   let Word1{31} = 1; // BARRIER
 521 }
 522 defm : SteamOutputExportPattern<EG_ExportBuf, 0x40, 0x41, 0x42, 0x43>;
 523
 524 def CF_TC_EG : CF_CLAUSE_EG<1, (ins i32imm:$ADDR, i32imm:$COUNT),
 525   "TEX $COUNT @$ADDR"> {
 526   let POP_COUNT = 0;
 527 }
 528 def CF_VC_EG : CF_CLAUSE_EG<2, (ins i32imm:$ADDR, i32imm:$COUNT),
 529   "VTX $COUNT @$ADDR"> {
 530   let POP_COUNT = 0;
 531 }
 532 def WHILE_LOOP_EG : CF_CLAUSE_EG<6, (ins i32imm:$ADDR),
 533   "LOOP_START_DX10 @$ADDR"> {
 534   let POP_COUNT = 0;
 535   let COUNT = 0;
 536 }
 537 def END_LOOP_EG : CF_CLAUSE_EG<5, (ins i32imm:$ADDR), "END_LOOP @$ADDR"> {
 538   let POP_COUNT = 0;
 539   let COUNT = 0;
 540 }
 541 def LOOP_BREAK_EG : CF_CLAUSE_EG<9, (ins i32imm:$ADDR),
 542   "LOOP_BREAK @$ADDR"> {
 543   let POP_COUNT = 0;
 544   let COUNT = 0;
 545 }
 546 def CF_CONTINUE_EG : CF_CLAUSE_EG<8, (ins i32imm:$ADDR),
 547   "CONTINUE @$ADDR"> {
 548   let POP_COUNT = 0;
 549   let COUNT = 0;
 550 }
 551 def CF_JUMP_EG : CF_CLAUSE_EG<10, (ins i32imm:$ADDR, i32imm:$POP_COUNT),
 552   "JUMP @$ADDR POP:$POP_COUNT"> {
 553   let COUNT = 0;
 554 }
 555 def CF_PUSH_EG : CF_CLAUSE_EG<11, (ins i32imm:$ADDR, i32imm:$POP_COUNT),
 556                               "PUSH @$ADDR POP:$POP_COUNT"> {
 557   let COUNT = 0;
 558 }
 559 def CF_ELSE_EG : CF_CLAUSE_EG<13, (ins i32imm:$ADDR, i32imm:$POP_COUNT),
 560   "ELSE @$ADDR POP:$POP_COUNT"> {
 561   let COUNT = 0;
 562 }
 563 def CF_CALL_FS_EG : CF_CLAUSE_EG<19, (ins), "CALL_FS"> {
 564   let ADDR = 0;
 565   let COUNT = 0;
 566   let POP_COUNT = 0;
 567 }
 568 def POP_EG : CF_CLAUSE_EG<14, (ins i32imm:$ADDR, i32imm:$POP_COUNT),
 569   "POP @$ADDR POP:$POP_COUNT"> {
 570   let COUNT = 0;
 571 }
 572 def CF_END_EG :  CF_CLAUSE_EG<0, (ins), "CF_END"> {
 573   let COUNT = 0;
 574   let POP_COUNT = 0;
 575   let ADDR = 0;
 576   let END_OF_PROGRAM = 1;
 577 }
 578
 579 } // End Predicates = [isEGorCayman]