lib/Target/R600/SIInstrFormats.td

   1 //===-- SIInstrFormats.td - SI Instruction Encodings ----------------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // SI Instruction format definitions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 class InstSI <dag outs, dag ins, string asm, list<dag> pattern> :
  15     AMDGPUInst<outs, ins, asm, pattern>, PredicateControl {
  16
  17   field bits<1> VM_CNT = 0;
  18   field bits<1> EXP_CNT = 0;
  19   field bits<1> LGKM_CNT = 0;
  20
  21   field bits<1> SALU = 0;
  22   field bits<1> VALU = 0;
  23
  24   field bits<1> SOP1 = 0;
  25   field bits<1> SOP2 = 0;
  26   field bits<1> SOPC = 0;
  27   field bits<1> SOPK = 0;
  28   field bits<1> SOPP = 0;
  29
  30   field bits<1> VOP1 = 0;
  31   field bits<1> VOP2 = 0;
  32   field bits<1> VOP3 = 0;
  33   field bits<1> VOPC = 0;
  34
  35   field bits<1> MUBUF = 0;
  36   field bits<1> MTBUF = 0;
  37   field bits<1> SMRD = 0;
  38   field bits<1> DS = 0;
  39   field bits<1> MIMG = 0;
  40   field bits<1> FLAT = 0;
  41   field bits<1> WQM = 0;
  42
  43   // These need to be kept in sync with the enum in SIInstrFlags.
  44   let TSFlags{0} = VM_CNT;
  45   let TSFlags{1} = EXP_CNT;
  46   let TSFlags{2} = LGKM_CNT;
  47
  48   let TSFlags{3} = SALU;
  49   let TSFlags{4} = VALU;
  50
  51   let TSFlags{5} = SOP1;
  52   let TSFlags{6} = SOP2;
  53   let TSFlags{7} = SOPC;
  54   let TSFlags{8} = SOPK;
  55   let TSFlags{9} = SOPP;
  56
  57   let TSFlags{10} = VOP1;
  58   let TSFlags{11} = VOP2;
  59   let TSFlags{12} = VOP3;
  60   let TSFlags{13} = VOPC;
  61
  62   let TSFlags{14} = MUBUF;
  63   let TSFlags{15} = MTBUF;
  64   let TSFlags{16} = SMRD;
  65   let TSFlags{17} = DS;
  66   let TSFlags{18} = MIMG;
  67   let TSFlags{19} = FLAT;
  68   let TSFlags{20} = WQM;
  69
  70   // Most instructions require adjustments after selection to satisfy
  71   // operand requirements.
  72   let hasPostISelHook = 1;
  73   let SchedRW = [Write32Bit];
  74 }
  75
  76 class Enc32 {
  77   field bits<32> Inst;
  78   int Size = 4;
  79 }
  80
  81 class Enc64 {
  82   field bits<64> Inst;
  83   int Size = 8;
  84 }
  85
  86 let Uses = [EXEC] in {
  87
  88 class VOPAnyCommon <dag outs, dag ins, string asm, list<dag> pattern> :
  89     InstSI <outs, ins, asm, pattern> {
  90
  91   let mayLoad = 0;
  92   let mayStore = 0;
  93   let hasSideEffects = 0;
  94   let UseNamedOperandTable = 1;
  95   let VALU = 1;
  96 }
  97
  98 class VOPCCommon <dag ins, string asm, list<dag> pattern> :
  99     VOPAnyCommon <(outs VCCReg:$dst), ins, asm, pattern> {
 100
 101   let DisableEncoding = "$dst";
 102   let VOPC = 1;
 103   let Size = 4;
 104 }
 105
 106 class VOP1Common <dag outs, dag ins, string asm, list<dag> pattern> :
 107     VOPAnyCommon <outs, ins, asm, pattern> {
 108
 109   let VOP1 = 1;
 110   let Size = 4;
 111 }
 112
 113 class VOP2Common <dag outs, dag ins, string asm, list<dag> pattern> :
 114     VOPAnyCommon <outs, ins, asm, pattern> {
 115
 116   let VOP2 = 1;
 117   let Size = 4;
 118 }
 119
 120 class VOP3Common <dag outs, dag ins, string asm, list<dag> pattern> :
 121     VOPAnyCommon <outs, ins, asm, pattern> {
 122
 123   // Using complex patterns gives VOP3 patterns a very high complexity rating,
 124   // but standalone patterns are almost always prefered, so we need to adjust the
 125   // priority lower.  The goal is to use a high number to reduce complexity to
 126   // zero (or less than zero).
 127   let AddedComplexity = -1000;
 128
 129   let VOP3 = 1;
 130   int Size = 8;
 131 }
 132
 133 } // End Uses = [EXEC]
 134
 135 //===----------------------------------------------------------------------===//
 136 // Scalar operations
 137 //===----------------------------------------------------------------------===//
 138
 139 class SOP1e <bits<8> op> : Enc32 {
 140   bits<7> sdst;
 141   bits<8> ssrc0;
 142
 143   let Inst{7-0} = ssrc0;
 144   let Inst{15-8} = op;
 145   let Inst{22-16} = sdst;
 146   let Inst{31-23} = 0x17d; //encoding;
 147 }
 148
 149 class SOP2e <bits<7> op> : Enc32 {
 150   bits<7> sdst;
 151   bits<8> ssrc0;
 152   bits<8> ssrc1;
 153
 154   let Inst{7-0} = ssrc0;
 155   let Inst{15-8} = ssrc1;
 156   let Inst{22-16} = sdst;
 157   let Inst{29-23} = op;
 158   let Inst{31-30} = 0x2; // encoding
 159 }
 160
 161 class SOPCe <bits<7> op> : Enc32 {
 162   bits<8> ssrc0;
 163   bits<8> ssrc1;
 164
 165   let Inst{7-0} = ssrc0;
 166   let Inst{15-8} = ssrc1;
 167   let Inst{22-16} = op;
 168   let Inst{31-23} = 0x17e;
 169 }
 170
 171 class SOPKe <bits<5> op> : Enc32 {
 172   bits <7> sdst;
 173   bits <16> simm16;
 174
 175   let Inst{15-0} = simm16;
 176   let Inst{22-16} = sdst;
 177   let Inst{27-23} = op;
 178   let Inst{31-28} = 0xb; //encoding
 179 }
 180
 181 class SOPPe <bits<7> op> : Enc32 {
 182   bits <16> simm16;
 183
 184   let Inst{15-0} = simm16;
 185   let Inst{22-16} = op;
 186   let Inst{31-23} = 0x17f; // encoding
 187 }
 188
 189 class SMRDe <bits<5> op, bits<1> imm> : Enc32 {
 190   bits<7> sdst;
 191   bits<7> sbase;
 192   bits<8> offset;
 193
 194   let Inst{7-0} = offset;
 195   let Inst{8} = imm;
 196   let Inst{14-9} = sbase{6-1};
 197   let Inst{21-15} = sdst;
 198   let Inst{26-22} = op;
 199   let Inst{31-27} = 0x18; //encoding
 200 }
 201
 202 let SchedRW = [WriteSALU] in {
 203 class SOP1 <dag outs, dag ins, string asm, list<dag> pattern> :
 204     InstSI<outs, ins, asm, pattern> {
 205   let mayLoad = 0;
 206   let mayStore = 0;
 207   let hasSideEffects = 0;
 208   let SALU = 1;
 209   let SOP1 = 1;
 210 }
 211
 212 class SOP2 <dag outs, dag ins, string asm, list<dag> pattern> :
 213     InstSI <outs, ins, asm, pattern> {
 214
 215   let mayLoad = 0;
 216   let mayStore = 0;
 217   let hasSideEffects = 0;
 218   let SALU = 1;
 219   let SOP2 = 1;
 220
 221   let UseNamedOperandTable = 1;
 222 }
 223
 224 class SOPC <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern> :
 225   InstSI<outs, ins, asm, pattern>, SOPCe <op> {
 226
 227   let DisableEncoding = "$dst";
 228   let mayLoad = 0;
 229   let mayStore = 0;
 230   let hasSideEffects = 0;
 231   let SALU = 1;
 232   let SOPC = 1;
 233
 234   let UseNamedOperandTable = 1;
 235 }
 236
 237 class SOPK <dag outs, dag ins, string asm, list<dag> pattern> :
 238    InstSI <outs, ins , asm, pattern> {
 239
 240   let mayLoad = 0;
 241   let mayStore = 0;
 242   let hasSideEffects = 0;
 243   let SALU = 1;
 244   let SOPK = 1;
 245
 246   let UseNamedOperandTable = 1;
 247 }
 248
 249 class SOPP <bits<7> op, dag ins, string asm, list<dag> pattern = []> :
 250                 InstSI <(outs), ins, asm, pattern >, SOPPe <op> {
 251
 252   let mayLoad = 0;
 253   let mayStore = 0;
 254   let hasSideEffects = 0;
 255   let isCodeGenOnly = 0;
 256   let SALU = 1;
 257   let SOPP = 1;
 258
 259   let UseNamedOperandTable = 1;
 260 }
 261
 262 } // let SchedRW = [WriteSALU]
 263
 264 class SMRD <dag outs, dag ins, string asm, list<dag> pattern> :
 265     InstSI<outs, ins, asm, pattern> {
 266
 267   let LGKM_CNT = 1;
 268   let SMRD = 1;
 269   let mayStore = 0;
 270   let mayLoad = 1;
 271   let hasSideEffects = 0;
 272   let UseNamedOperandTable = 1;
 273   let SchedRW = [WriteSMEM];
 274 }
 275
 276 //===----------------------------------------------------------------------===//
 277 // Vector ALU operations
 278 //===----------------------------------------------------------------------===//
 279
 280 class VOP1e <bits<8> op> : Enc32 {
 281   bits<8> vdst;
 282   bits<9> src0;
 283
 284   let Inst{8-0} = src0;
 285   let Inst{16-9} = op;
 286   let Inst{24-17} = vdst;
 287   let Inst{31-25} = 0x3f; //encoding
 288 }
 289
 290 class VOP2e <bits<6> op> : Enc32 {
 291   bits<8> vdst;
 292   bits<9> src0;
 293   bits<8> vsrc1;
 294
 295   let Inst{8-0} = src0;
 296   let Inst{16-9} = vsrc1;
 297   let Inst{24-17} = vdst;
 298   let Inst{30-25} = op;
 299   let Inst{31} = 0x0; //encoding
 300 }
 301
 302 class VOP3e <bits<9> op> : Enc64 {
 303   bits<8> vdst;
 304   bits<2> src0_modifiers;
 305   bits<9> src0;
 306   bits<2> src1_modifiers;
 307   bits<9> src1;
 308   bits<2> src2_modifiers;
 309   bits<9> src2;
 310   bits<1> clamp;
 311   bits<2> omod;
 312
 313   let Inst{7-0} = vdst;
 314   let Inst{8} = src0_modifiers{1};
 315   let Inst{9} = src1_modifiers{1};
 316   let Inst{10} = src2_modifiers{1};
 317   let Inst{11} = clamp;
 318   let Inst{25-17} = op;
 319   let Inst{31-26} = 0x34; //encoding
 320   let Inst{40-32} = src0;
 321   let Inst{49-41} = src1;
 322   let Inst{58-50} = src2;
 323   let Inst{60-59} = omod;
 324   let Inst{61} = src0_modifiers{0};
 325   let Inst{62} = src1_modifiers{0};
 326   let Inst{63} = src2_modifiers{0};
 327 }
 328
 329 class VOP3be <bits<9> op> : Enc64 {
 330   bits<8> vdst;
 331   bits<2> src0_modifiers;
 332   bits<9> src0;
 333   bits<2> src1_modifiers;
 334   bits<9> src1;
 335   bits<2> src2_modifiers;
 336   bits<9> src2;
 337   bits<7> sdst;
 338   bits<2> omod;
 339
 340   let Inst{7-0} = vdst;
 341   let Inst{14-8} = sdst;
 342   let Inst{25-17} = op;
 343   let Inst{31-26} = 0x34; //encoding
 344   let Inst{40-32} = src0;
 345   let Inst{49-41} = src1;
 346   let Inst{58-50} = src2;
 347   let Inst{60-59} = omod;
 348   let Inst{61} = src0_modifiers{0};
 349   let Inst{62} = src1_modifiers{0};
 350   let Inst{63} = src2_modifiers{0};
 351 }
 352
 353 class VOPCe <bits<8> op> : Enc32 {
 354   bits<9> src0;
 355   bits<8> vsrc1;
 356
 357   let Inst{8-0} = src0;
 358   let Inst{16-9} = vsrc1;
 359   let Inst{24-17} = op;
 360   let Inst{31-25} = 0x3e;
 361 }
 362
 363 class VINTRPe <bits<2> op> : Enc32 {
 364   bits<8> vdst;
 365   bits<8> vsrc;
 366   bits<2> attrchan;
 367   bits<6> attr;
 368
 369   let Inst{7-0} = vsrc;
 370   let Inst{9-8} = attrchan;
 371   let Inst{15-10} = attr;
 372   let Inst{17-16} = op;
 373   let Inst{25-18} = vdst;
 374   let Inst{31-26} = 0x32; // encoding
 375 }
 376
 377 class DSe <bits<8> op> : Enc64 {
 378   bits<8> vdst;
 379   bits<1> gds;
 380   bits<8> addr;
 381   bits<8> data0;
 382   bits<8> data1;
 383   bits<8> offset0;
 384   bits<8> offset1;
 385
 386   let Inst{7-0} = offset0;
 387   let Inst{15-8} = offset1;
 388   let Inst{17} = gds;
 389   let Inst{25-18} = op;
 390   let Inst{31-26} = 0x36; //encoding
 391   let Inst{39-32} = addr;
 392   let Inst{47-40} = data0;
 393   let Inst{55-48} = data1;
 394   let Inst{63-56} = vdst;
 395 }
 396
 397 class MUBUFe <bits<7> op> : Enc64 {
 398   bits<12> offset;
 399   bits<1> offen;
 400   bits<1> idxen;
 401   bits<1> glc;
 402   bits<1> addr64;
 403   bits<1> lds;
 404   bits<8> vaddr;
 405   bits<8> vdata;
 406   bits<7> srsrc;
 407   bits<1> slc;
 408   bits<1> tfe;
 409   bits<8> soffset;
 410
 411   let Inst{11-0} = offset;
 412   let Inst{12} = offen;
 413   let Inst{13} = idxen;
 414   let Inst{14} = glc;
 415   let Inst{15} = addr64;
 416   let Inst{16} = lds;
 417   let Inst{24-18} = op;
 418   let Inst{31-26} = 0x38; //encoding
 419   let Inst{39-32} = vaddr;
 420   let Inst{47-40} = vdata;
 421   let Inst{52-48} = srsrc{6-2};
 422   let Inst{54} = slc;
 423   let Inst{55} = tfe;
 424   let Inst{63-56} = soffset;
 425 }
 426
 427 class MTBUFe <bits<3> op> : Enc64 {
 428   bits<8> vdata;
 429   bits<12> offset;
 430   bits<1> offen;
 431   bits<1> idxen;
 432   bits<1> glc;
 433   bits<1> addr64;
 434   bits<4> dfmt;
 435   bits<3> nfmt;
 436   bits<8> vaddr;
 437   bits<7> srsrc;
 438   bits<1> slc;
 439   bits<1> tfe;
 440   bits<8> soffset;
 441
 442   let Inst{11-0} = offset;
 443   let Inst{12} = offen;
 444   let Inst{13} = idxen;
 445   let Inst{14} = glc;
 446   let Inst{15} = addr64;
 447   let Inst{18-16} = op;
 448   let Inst{22-19} = dfmt;
 449   let Inst{25-23} = nfmt;
 450   let Inst{31-26} = 0x3a; //encoding
 451   let Inst{39-32} = vaddr;
 452   let Inst{47-40} = vdata;
 453   let Inst{52-48} = srsrc{6-2};
 454   let Inst{54} = slc;
 455   let Inst{55} = tfe;
 456   let Inst{63-56} = soffset;
 457 }
 458
 459 class MIMGe <bits<7> op> : Enc64 {
 460   bits<8> vdata;
 461   bits<4> dmask;
 462   bits<1> unorm;
 463   bits<1> glc;
 464   bits<1> da;
 465   bits<1> r128;
 466   bits<1> tfe;
 467   bits<1> lwe;
 468   bits<1> slc;
 469   bits<8> vaddr;
 470   bits<7> srsrc;
 471   bits<7> ssamp;
 472
 473   let Inst{11-8} = dmask;
 474   let Inst{12} = unorm;
 475   let Inst{13} = glc;
 476   let Inst{14} = da;
 477   let Inst{15} = r128;
 478   let Inst{16} = tfe;
 479   let Inst{17} = lwe;
 480   let Inst{24-18} = op;
 481   let Inst{25} = slc;
 482   let Inst{31-26} = 0x3c;
 483   let Inst{39-32} = vaddr;
 484   let Inst{47-40} = vdata;
 485   let Inst{52-48} = srsrc{6-2};
 486   let Inst{57-53} = ssamp{6-2};
 487 }
 488
 489 class FLATe<bits<7> op> : Enc64 {
 490   bits<8> addr;
 491   bits<8> data;
 492   bits<8> vdst;
 493   bits<1> slc;
 494   bits<1> glc;
 495   bits<1> tfe;
 496
 497   // 15-0 is reserved.
 498   let Inst{16} = glc;
 499   let Inst{17} = slc;
 500   let Inst{24-18} = op;
 501   let Inst{31-26} = 0x37; // Encoding.
 502   let Inst{39-32} = addr;
 503   let Inst{47-40} = data;
 504   // 54-48 is reserved.
 505   let Inst{55} = tfe;
 506   let Inst{63-56} = vdst;
 507 }
 508
 509 class EXPe : Enc64 {
 510   bits<4> en;
 511   bits<6> tgt;
 512   bits<1> compr;
 513   bits<1> done;
 514   bits<1> vm;
 515   bits<8> vsrc0;
 516   bits<8> vsrc1;
 517   bits<8> vsrc2;
 518   bits<8> vsrc3;
 519
 520   let Inst{3-0} = en;
 521   let Inst{9-4} = tgt;
 522   let Inst{10} = compr;
 523   let Inst{11} = done;
 524   let Inst{12} = vm;
 525   let Inst{31-26} = 0x3e;
 526   let Inst{39-32} = vsrc0;
 527   let Inst{47-40} = vsrc1;
 528   let Inst{55-48} = vsrc2;
 529   let Inst{63-56} = vsrc3;
 530 }
 531
 532 let Uses = [EXEC] in {
 533
 534 class VOP1 <bits<8> op, dag outs, dag ins, string asm, list<dag> pattern> :
 535     VOP1Common <outs, ins, asm, pattern>,
 536     VOP1e<op>;
 537
 538 class VOP2 <bits<6> op, dag outs, dag ins, string asm, list<dag> pattern> :
 539     VOP2Common <outs, ins, asm, pattern>, VOP2e<op>;
 540
 541 class VOPC <bits<8> op, dag ins, string asm, list<dag> pattern> :
 542     VOPCCommon <ins, asm, pattern>, VOPCe <op>;
 543
 544 class VINTRPCommon <dag outs, dag ins, string asm, list<dag> pattern> :
 545     InstSI <outs, ins, asm, pattern> {
 546   let mayLoad = 1;
 547   let mayStore = 0;
 548   let hasSideEffects = 0;
 549 }
 550
 551 } // End Uses = [EXEC]
 552
 553 //===----------------------------------------------------------------------===//
 554 // Vector I/O operations
 555 //===----------------------------------------------------------------------===//
 556
 557 let Uses = [EXEC] in {
 558
 559 class DS <dag outs, dag ins, string asm, list<dag> pattern> :
 560     InstSI <outs, ins, asm, pattern> {
 561
 562   let LGKM_CNT = 1;
 563   let DS = 1;
 564   let UseNamedOperandTable = 1;
 565   let DisableEncoding = "$m0";
 566   let SchedRW = [WriteLDS];
 567 }
 568
 569 class MUBUF <dag outs, dag ins, string asm, list<dag> pattern> :
 570     InstSI<outs, ins, asm, pattern> {
 571
 572   let VM_CNT = 1;
 573   let EXP_CNT = 1;
 574   let MUBUF = 1;
 575
 576   let hasSideEffects = 0;
 577   let UseNamedOperandTable = 1;
 578   let SchedRW = [WriteVMEM];
 579 }
 580
 581 class MTBUF <dag outs, dag ins, string asm, list<dag> pattern> :
 582     InstSI<outs, ins, asm, pattern> {
 583
 584   let VM_CNT = 1;
 585   let EXP_CNT = 1;
 586   let MTBUF = 1;
 587
 588   let hasSideEffects = 0;
 589   let UseNamedOperandTable = 1;
 590   let SchedRW = [WriteVMEM];
 591 }
 592
 593 class FLAT <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern> :
 594     InstSI<outs, ins, asm, pattern>, FLATe <op> {
 595   let FLAT = 1;
 596   // Internally, FLAT instruction are executed as both an LDS and a
 597   // Buffer instruction; so, they increment both VM_CNT and LGKM_CNT
 598   // and are not considered done until both have been decremented.
 599   let VM_CNT = 1;
 600   let LGKM_CNT = 1;
 601
 602   let Uses = [EXEC, FLAT_SCR]; // M0
 603
 604   let UseNamedOperandTable = 1;
 605   let hasSideEffects = 0;
 606 }
 607
 608 class MIMG <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern> :
 609     InstSI <outs, ins, asm, pattern>, MIMGe <op> {
 610
 611   let VM_CNT = 1;
 612   let EXP_CNT = 1;
 613   let MIMG = 1;
 614
 615   let hasSideEffects = 0; // XXX ????
 616 }
 617
 618
 619 } // End Uses = [EXEC]