lib/Target/R600/SIInstrFormats.td

   1 //===-- SIInstrFormats.td - SI Instruction Encodings ----------------------===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // SI Instruction format definitions.
  11 //
  12 //===----------------------------------------------------------------------===//
  13
  14 class InstSI <dag outs, dag ins, string asm, list<dag> pattern> :
  15     AMDGPUInst<outs, ins, asm, pattern>, PredicateControl {
  16
  17   field bits<1> VM_CNT = 0;
  18   field bits<1> EXP_CNT = 0;
  19   field bits<1> LGKM_CNT = 0;
  20
  21   field bits<1> SALU = 0;
  22   field bits<1> VALU = 0;
  23
  24   field bits<1> SOP1 = 0;
  25   field bits<1> SOP2 = 0;
  26   field bits<1> SOPC = 0;
  27   field bits<1> SOPK = 0;
  28   field bits<1> SOPP = 0;
  29
  30   field bits<1> VOP1 = 0;
  31   field bits<1> VOP2 = 0;
  32   field bits<1> VOP3 = 0;
  33   field bits<1> VOPC = 0;
  34
  35   field bits<1> MUBUF = 0;
  36   field bits<1> MTBUF = 0;
  37   field bits<1> SMRD = 0;
  38   field bits<1> DS = 0;
  39   field bits<1> MIMG = 0;
  40   field bits<1> FLAT = 0;
  41   field bits<1> WQM = 0;
  42
  43   // These need to be kept in sync with the enum in SIInstrFlags.
  44   let TSFlags{0} = VM_CNT;
  45   let TSFlags{1} = EXP_CNT;
  46   let TSFlags{2} = LGKM_CNT;
  47
  48   let TSFlags{3} = SALU;
  49   let TSFlags{4} = VALU;
  50
  51   let TSFlags{5} = SOP1;
  52   let TSFlags{6} = SOP2;
  53   let TSFlags{7} = SOPC;
  54   let TSFlags{8} = SOPK;
  55   let TSFlags{9} = SOPP;
  56
  57   let TSFlags{10} = VOP1;
  58   let TSFlags{11} = VOP2;
  59   let TSFlags{12} = VOP3;
  60   let TSFlags{13} = VOPC;
  61
  62   let TSFlags{14} = MUBUF;
  63   let TSFlags{15} = MTBUF;
  64   let TSFlags{16} = SMRD;
  65   let TSFlags{17} = DS;
  66   let TSFlags{18} = MIMG;
  67   let TSFlags{19} = FLAT;
  68   let TSFlags{20} = WQM;
  69
  70   // Most instructions require adjustments after selection to satisfy
  71   // operand requirements.
  72   let hasPostISelHook = 1;
  73   let SchedRW = [Write32Bit];
  74 }
  75
  76 class Enc32 {
  77   field bits<32> Inst;
  78   int Size = 4;
  79 }
  80
  81 class Enc64 {
  82   field bits<64> Inst;
  83   int Size = 8;
  84 }
  85
  86 let Uses = [EXEC] in {
  87
  88 class VOPAnyCommon <dag outs, dag ins, string asm, list<dag> pattern> :
  89     InstSI <outs, ins, asm, pattern> {
  90
  91   let mayLoad = 0;
  92   let mayStore = 0;
  93   let hasSideEffects = 0;
  94   let UseNamedOperandTable = 1;
  95   let VALU = 1;
  96 }
  97
  98 class VOPCCommon <dag ins, string asm, list<dag> pattern> :
  99     VOPAnyCommon <(outs VCCReg:$dst), ins, asm, pattern> {
 100
 101   let DisableEncoding = "$dst";
 102   let VOPC = 1;
 103   let Size = 4;
 104 }
 105
 106 class VOP1Common <dag outs, dag ins, string asm, list<dag> pattern> :
 107     VOPAnyCommon <outs, ins, asm, pattern> {
 108
 109   let VOP1 = 1;
 110   let Size = 4;
 111 }
 112
 113 class VOP2Common <dag outs, dag ins, string asm, list<dag> pattern> :
 114     VOPAnyCommon <outs, ins, asm, pattern> {
 115
 116   let VOP2 = 1;
 117   let Size = 4;
 118 }
 119
 120 class VOP3Common <dag outs, dag ins, string asm, list<dag> pattern> :
 121     VOPAnyCommon <outs, ins, asm, pattern> {
 122
 123   // Using complex patterns gives VOP3 patterns a very high complexity rating,
 124   // but standalone patterns are almost always prefered, so we need to adjust the
 125   // priority lower.  The goal is to use a high number to reduce complexity to
 126   // zero (or less than zero).
 127   let AddedComplexity = -1000;
 128
 129   let VOP3 = 1;
 130   int Size = 8;
 131 }
 132
 133 } // End Uses = [EXEC]
 134
 135 //===----------------------------------------------------------------------===//
 136 // Scalar operations
 137 //===----------------------------------------------------------------------===//
 138
 139 class SOP1e <bits<8> op> : Enc32 {
 140   bits<7> sdst;
 141   bits<8> ssrc0;
 142
 143   let Inst{7-0} = ssrc0;
 144   let Inst{15-8} = op;
 145   let Inst{22-16} = sdst;
 146   let Inst{31-23} = 0x17d; //encoding;
 147 }
 148
 149 class SOP2e <bits<7> op> : Enc32 {
 150   bits<7> sdst;
 151   bits<8> ssrc0;
 152   bits<8> ssrc1;
 153
 154   let Inst{7-0} = ssrc0;
 155   let Inst{15-8} = ssrc1;
 156   let Inst{22-16} = sdst;
 157   let Inst{29-23} = op;
 158   let Inst{31-30} = 0x2; // encoding
 159 }
 160
 161 class SOPCe <bits<7> op> : Enc32 {
 162   bits<8> ssrc0;
 163   bits<8> ssrc1;
 164
 165   let Inst{7-0} = ssrc0;
 166   let Inst{15-8} = ssrc1;
 167   let Inst{22-16} = op;
 168   let Inst{31-23} = 0x17e;
 169 }
 170
 171 class SOPKe <bits<5> op> : Enc32 {
 172   bits <7> sdst;
 173   bits <16> simm16;
 174
 175   let Inst{15-0} = simm16;
 176   let Inst{22-16} = sdst;
 177   let Inst{27-23} = op;
 178   let Inst{31-28} = 0xb; //encoding
 179 }
 180
 181 class SOPPe <bits<7> op> : Enc32 {
 182   bits <16> simm16;
 183
 184   let Inst{15-0} = simm16;
 185   let Inst{22-16} = op;
 186   let Inst{31-23} = 0x17f; // encoding
 187 }
 188
 189 class SMRDe <bits<5> op, bits<1> imm> : Enc32 {
 190   bits<7> sdst;
 191   bits<7> sbase;
 192   bits<8> offset;
 193
 194   let Inst{7-0} = offset;
 195   let Inst{8} = imm;
 196   let Inst{14-9} = sbase{6-1};
 197   let Inst{21-15} = sdst;
 198   let Inst{26-22} = op;
 199   let Inst{31-27} = 0x18; //encoding
 200 }
 201
 202 let SchedRW = [WriteSALU] in {
 203 class SOP1 <dag outs, dag ins, string asm, list<dag> pattern> :
 204     InstSI<outs, ins, asm, pattern> {
 205   let mayLoad = 0;
 206   let mayStore = 0;
 207   let hasSideEffects = 0;
 208   let SALU = 1;
 209   let SOP1 = 1;
 210 }
 211
 212 class SOP2 <dag outs, dag ins, string asm, list<dag> pattern> :
 213     InstSI <outs, ins, asm, pattern> {
 214
 215   let mayLoad = 0;
 216   let mayStore = 0;
 217   let hasSideEffects = 0;
 218   let SALU = 1;
 219   let SOP2 = 1;
 220
 221   let UseNamedOperandTable = 1;
 222 }
 223
 224 class SOPC <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern> :
 225   InstSI<outs, ins, asm, pattern>, SOPCe <op> {
 226
 227   let DisableEncoding = "$dst";
 228   let mayLoad = 0;
 229   let mayStore = 0;
 230   let hasSideEffects = 0;
 231   let SALU = 1;
 232   let SOPC = 1;
 233
 234   let UseNamedOperandTable = 1;
 235 }
 236
 237 class SOPK <dag outs, dag ins, string asm, list<dag> pattern> :
 238    InstSI <outs, ins , asm, pattern> {
 239
 240   let mayLoad = 0;
 241   let mayStore = 0;
 242   let hasSideEffects = 0;
 243   let SALU = 1;
 244   let SOPK = 1;
 245
 246   let UseNamedOperandTable = 1;
 247 }
 248
 249 class SOPP <bits<7> op, dag ins, string asm, list<dag> pattern = []> :
 250                 InstSI <(outs), ins, asm, pattern >, SOPPe <op> {
 251
 252   let mayLoad = 0;
 253   let mayStore = 0;
 254   let hasSideEffects = 0;
 255   let SALU = 1;
 256   let SOPP = 1;
 257
 258   let UseNamedOperandTable = 1;
 259 }
 260
 261 } // let SchedRW = [WriteSALU]
 262
 263 class SMRD <dag outs, dag ins, string asm, list<dag> pattern> :
 264     InstSI<outs, ins, asm, pattern> {
 265
 266   let LGKM_CNT = 1;
 267   let SMRD = 1;
 268   let mayStore = 0;
 269   let mayLoad = 1;
 270   let hasSideEffects = 0;
 271   let UseNamedOperandTable = 1;
 272   let SchedRW = [WriteSMEM];
 273 }
 274
 275 //===----------------------------------------------------------------------===//
 276 // Vector ALU operations
 277 //===----------------------------------------------------------------------===//
 278
 279 class VOP1e <bits<8> op> : Enc32 {
 280   bits<8> vdst;
 281   bits<9> src0;
 282
 283   let Inst{8-0} = src0;
 284   let Inst{16-9} = op;
 285   let Inst{24-17} = vdst;
 286   let Inst{31-25} = 0x3f; //encoding
 287 }
 288
 289 class VOP2e <bits<6> op> : Enc32 {
 290   bits<8> vdst;
 291   bits<9> src0;
 292   bits<8> vsrc1;
 293
 294   let Inst{8-0} = src0;
 295   let Inst{16-9} = vsrc1;
 296   let Inst{24-17} = vdst;
 297   let Inst{30-25} = op;
 298   let Inst{31} = 0x0; //encoding
 299 }
 300
 301 class VOP3e <bits<9> op> : Enc64 {
 302   bits<8> vdst;
 303   bits<2> src0_modifiers;
 304   bits<9> src0;
 305   bits<2> src1_modifiers;
 306   bits<9> src1;
 307   bits<2> src2_modifiers;
 308   bits<9> src2;
 309   bits<1> clamp;
 310   bits<2> omod;
 311
 312   let Inst{7-0} = vdst;
 313   let Inst{8} = src0_modifiers{1};
 314   let Inst{9} = src1_modifiers{1};
 315   let Inst{10} = src2_modifiers{1};
 316   let Inst{11} = clamp;
 317   let Inst{25-17} = op;
 318   let Inst{31-26} = 0x34; //encoding
 319   let Inst{40-32} = src0;
 320   let Inst{49-41} = src1;
 321   let Inst{58-50} = src2;
 322   let Inst{60-59} = omod;
 323   let Inst{61} = src0_modifiers{0};
 324   let Inst{62} = src1_modifiers{0};
 325   let Inst{63} = src2_modifiers{0};
 326 }
 327
 328 class VOP3be <bits<9> op> : Enc64 {
 329   bits<8> vdst;
 330   bits<2> src0_modifiers;
 331   bits<9> src0;
 332   bits<2> src1_modifiers;
 333   bits<9> src1;
 334   bits<2> src2_modifiers;
 335   bits<9> src2;
 336   bits<7> sdst;
 337   bits<2> omod;
 338
 339   let Inst{7-0} = vdst;
 340   let Inst{14-8} = sdst;
 341   let Inst{25-17} = op;
 342   let Inst{31-26} = 0x34; //encoding
 343   let Inst{40-32} = src0;
 344   let Inst{49-41} = src1;
 345   let Inst{58-50} = src2;
 346   let Inst{60-59} = omod;
 347   let Inst{61} = src0_modifiers{0};
 348   let Inst{62} = src1_modifiers{0};
 349   let Inst{63} = src2_modifiers{0};
 350 }
 351
 352 class VOPCe <bits<8> op> : Enc32 {
 353   bits<9> src0;
 354   bits<8> vsrc1;
 355
 356   let Inst{8-0} = src0;
 357   let Inst{16-9} = vsrc1;
 358   let Inst{24-17} = op;
 359   let Inst{31-25} = 0x3e;
 360 }
 361
 362 class VINTRPe <bits<2> op> : Enc32 {
 363   bits<8> vdst;
 364   bits<8> vsrc;
 365   bits<2> attrchan;
 366   bits<6> attr;
 367
 368   let Inst{7-0} = vsrc;
 369   let Inst{9-8} = attrchan;
 370   let Inst{15-10} = attr;
 371   let Inst{17-16} = op;
 372   let Inst{25-18} = vdst;
 373   let Inst{31-26} = 0x32; // encoding
 374 }
 375
 376 class DSe <bits<8> op> : Enc64 {
 377   bits<8> vdst;
 378   bits<1> gds;
 379   bits<8> addr;
 380   bits<8> data0;
 381   bits<8> data1;
 382   bits<8> offset0;
 383   bits<8> offset1;
 384
 385   let Inst{7-0} = offset0;
 386   let Inst{15-8} = offset1;
 387   let Inst{17} = gds;
 388   let Inst{25-18} = op;
 389   let Inst{31-26} = 0x36; //encoding
 390   let Inst{39-32} = addr;
 391   let Inst{47-40} = data0;
 392   let Inst{55-48} = data1;
 393   let Inst{63-56} = vdst;
 394 }
 395
 396 class MUBUFe <bits<7> op> : Enc64 {
 397   bits<12> offset;
 398   bits<1> offen;
 399   bits<1> idxen;
 400   bits<1> glc;
 401   bits<1> addr64;
 402   bits<1> lds;
 403   bits<8> vaddr;
 404   bits<8> vdata;
 405   bits<7> srsrc;
 406   bits<1> slc;
 407   bits<1> tfe;
 408   bits<8> soffset;
 409
 410   let Inst{11-0} = offset;
 411   let Inst{12} = offen;
 412   let Inst{13} = idxen;
 413   let Inst{14} = glc;
 414   let Inst{15} = addr64;
 415   let Inst{16} = lds;
 416   let Inst{24-18} = op;
 417   let Inst{31-26} = 0x38; //encoding
 418   let Inst{39-32} = vaddr;
 419   let Inst{47-40} = vdata;
 420   let Inst{52-48} = srsrc{6-2};
 421   let Inst{54} = slc;
 422   let Inst{55} = tfe;
 423   let Inst{63-56} = soffset;
 424 }
 425
 426 class MTBUFe <bits<3> op> : Enc64 {
 427   bits<8> vdata;
 428   bits<12> offset;
 429   bits<1> offen;
 430   bits<1> idxen;
 431   bits<1> glc;
 432   bits<1> addr64;
 433   bits<4> dfmt;
 434   bits<3> nfmt;
 435   bits<8> vaddr;
 436   bits<7> srsrc;
 437   bits<1> slc;
 438   bits<1> tfe;
 439   bits<8> soffset;
 440
 441   let Inst{11-0} = offset;
 442   let Inst{12} = offen;
 443   let Inst{13} = idxen;
 444   let Inst{14} = glc;
 445   let Inst{15} = addr64;
 446   let Inst{18-16} = op;
 447   let Inst{22-19} = dfmt;
 448   let Inst{25-23} = nfmt;
 449   let Inst{31-26} = 0x3a; //encoding
 450   let Inst{39-32} = vaddr;
 451   let Inst{47-40} = vdata;
 452   let Inst{52-48} = srsrc{6-2};
 453   let Inst{54} = slc;
 454   let Inst{55} = tfe;
 455   let Inst{63-56} = soffset;
 456 }
 457
 458 class MIMGe <bits<7> op> : Enc64 {
 459   bits<8> vdata;
 460   bits<4> dmask;
 461   bits<1> unorm;
 462   bits<1> glc;
 463   bits<1> da;
 464   bits<1> r128;
 465   bits<1> tfe;
 466   bits<1> lwe;
 467   bits<1> slc;
 468   bits<8> vaddr;
 469   bits<7> srsrc;
 470   bits<7> ssamp;
 471
 472   let Inst{11-8} = dmask;
 473   let Inst{12} = unorm;
 474   let Inst{13} = glc;
 475   let Inst{14} = da;
 476   let Inst{15} = r128;
 477   let Inst{16} = tfe;
 478   let Inst{17} = lwe;
 479   let Inst{24-18} = op;
 480   let Inst{25} = slc;
 481   let Inst{31-26} = 0x3c;
 482   let Inst{39-32} = vaddr;
 483   let Inst{47-40} = vdata;
 484   let Inst{52-48} = srsrc{6-2};
 485   let Inst{57-53} = ssamp{6-2};
 486 }
 487
 488 class FLATe<bits<7> op> : Enc64 {
 489   bits<8> addr;
 490   bits<8> data;
 491   bits<8> vdst;
 492   bits<1> slc;
 493   bits<1> glc;
 494   bits<1> tfe;
 495
 496   // 15-0 is reserved.
 497   let Inst{16} = glc;
 498   let Inst{17} = slc;
 499   let Inst{24-18} = op;
 500   let Inst{31-26} = 0x37; // Encoding.
 501   let Inst{39-32} = addr;
 502   let Inst{47-40} = data;
 503   // 54-48 is reserved.
 504   let Inst{55} = tfe;
 505   let Inst{63-56} = vdst;
 506 }
 507
 508 class EXPe : Enc64 {
 509   bits<4> en;
 510   bits<6> tgt;
 511   bits<1> compr;
 512   bits<1> done;
 513   bits<1> vm;
 514   bits<8> vsrc0;
 515   bits<8> vsrc1;
 516   bits<8> vsrc2;
 517   bits<8> vsrc3;
 518
 519   let Inst{3-0} = en;
 520   let Inst{9-4} = tgt;
 521   let Inst{10} = compr;
 522   let Inst{11} = done;
 523   let Inst{12} = vm;
 524   let Inst{31-26} = 0x3e;
 525   let Inst{39-32} = vsrc0;
 526   let Inst{47-40} = vsrc1;
 527   let Inst{55-48} = vsrc2;
 528   let Inst{63-56} = vsrc3;
 529 }
 530
 531 let Uses = [EXEC] in {
 532
 533 class VOP1 <bits<8> op, dag outs, dag ins, string asm, list<dag> pattern> :
 534     VOP1Common <outs, ins, asm, pattern>,
 535     VOP1e<op>;
 536
 537 class VOP2 <bits<6> op, dag outs, dag ins, string asm, list<dag> pattern> :
 538     VOP2Common <outs, ins, asm, pattern>, VOP2e<op>;
 539
 540 class VOPC <bits<8> op, dag ins, string asm, list<dag> pattern> :
 541     VOPCCommon <ins, asm, pattern>, VOPCe <op>;
 542
 543 class VINTRPCommon <dag outs, dag ins, string asm, list<dag> pattern> :
 544     InstSI <outs, ins, asm, pattern> {
 545   let mayLoad = 1;
 546   let mayStore = 0;
 547   let hasSideEffects = 0;
 548 }
 549
 550 } // End Uses = [EXEC]
 551
 552 //===----------------------------------------------------------------------===//
 553 // Vector I/O operations
 554 //===----------------------------------------------------------------------===//
 555
 556 let Uses = [EXEC] in {
 557
 558 class DS <dag outs, dag ins, string asm, list<dag> pattern> :
 559     InstSI <outs, ins, asm, pattern> {
 560
 561   let LGKM_CNT = 1;
 562   let DS = 1;
 563   let UseNamedOperandTable = 1;
 564   let DisableEncoding = "$m0";
 565   let SchedRW = [WriteLDS];
 566 }
 567
 568 class MUBUF <dag outs, dag ins, string asm, list<dag> pattern> :
 569     InstSI<outs, ins, asm, pattern> {
 570
 571   let VM_CNT = 1;
 572   let EXP_CNT = 1;
 573   let MUBUF = 1;
 574
 575   let hasSideEffects = 0;
 576   let UseNamedOperandTable = 1;
 577   let SchedRW = [WriteVMEM];
 578 }
 579
 580 class MTBUF <dag outs, dag ins, string asm, list<dag> pattern> :
 581     InstSI<outs, ins, asm, pattern> {
 582
 583   let VM_CNT = 1;
 584   let EXP_CNT = 1;
 585   let MTBUF = 1;
 586
 587   let hasSideEffects = 0;
 588   let UseNamedOperandTable = 1;
 589   let SchedRW = [WriteVMEM];
 590 }
 591
 592 class FLAT <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern> :
 593     InstSI<outs, ins, asm, pattern>, FLATe <op> {
 594   let FLAT = 1;
 595   // Internally, FLAT instruction are executed as both an LDS and a
 596   // Buffer instruction; so, they increment both VM_CNT and LGKM_CNT
 597   // and are not considered done until both have been decremented.
 598   let VM_CNT = 1;
 599   let LGKM_CNT = 1;
 600
 601   let Uses = [EXEC, FLAT_SCR]; // M0
 602
 603   let UseNamedOperandTable = 1;
 604   let hasSideEffects = 0;
 605 }
 606
 607 class MIMG <bits<7> op, dag outs, dag ins, string asm, list<dag> pattern> :
 608     InstSI <outs, ins, asm, pattern>, MIMGe <op> {
 609
 610   let VM_CNT = 1;
 611   let EXP_CNT = 1;
 612   let MIMG = 1;
 613
 614   let hasSideEffects = 0; // XXX ????
 615 }
 616
 617
 618 } // End Uses = [EXEC]