lib/Target/SystemZ/SystemZOperators.td

   1 //===-- SystemZOperators.td - SystemZ-specific operators ------*- tblgen-*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // Type profiles
  12 //===----------------------------------------------------------------------===//
  13 def SDT_CallSeqStart        : SDCallSeqStart<[SDTCisVT<0, i64>]>;
  14 def SDT_CallSeqEnd          : SDCallSeqEnd<[SDTCisVT<0, i64>,
  15                                             SDTCisVT<1, i64>]>;
  16 def SDT_ZCall               : SDTypeProfile<0, -1, [SDTCisPtrTy<0>]>;
  17 def SDT_ZCmp                : SDTypeProfile<0, 2, [SDTCisSameAs<0, 1>]>;
  18 def SDT_ZBRCCMask           : SDTypeProfile<0, 3,
  19                                             [SDTCisVT<0, i8>,
  20                                              SDTCisVT<1, i8>,
  21                                              SDTCisVT<2, OtherVT>]>;
  22 def SDT_ZSelectCCMask       : SDTypeProfile<1, 4,
  23                                             [SDTCisSameAs<0, 1>,
  24                                              SDTCisSameAs<1, 2>,
  25                                              SDTCisVT<3, i8>,
  26                                              SDTCisVT<4, i8>]>;
  27 def SDT_ZWrapPtr            : SDTypeProfile<1, 1,
  28                                             [SDTCisSameAs<0, 1>,
  29                                              SDTCisPtrTy<0>]>;
  30 def SDT_ZAdjDynAlloc        : SDTypeProfile<1, 0, [SDTCisVT<0, i64>]>;
  31 def SDT_ZExtractAccess      : SDTypeProfile<1, 1,
  32                                             [SDTCisVT<0, i32>,
  33                                              SDTCisVT<1, i8>]>;
  34 def SDT_ZGR128Binary32      : SDTypeProfile<1, 2,
  35                                             [SDTCisVT<0, untyped>,
  36                                              SDTCisVT<1, untyped>,
  37                                              SDTCisVT<2, i32>]>;
  38 def SDT_ZGR128Binary64      : SDTypeProfile<1, 2,
  39                                             [SDTCisVT<0, untyped>,
  40                                              SDTCisVT<1, untyped>,
  41                                              SDTCisVT<2, i64>]>;
  42 def SDT_ZAtomicLoadBinaryW  : SDTypeProfile<1, 5,
  43                                             [SDTCisVT<0, i32>,
  44                                              SDTCisPtrTy<1>,
  45                                              SDTCisVT<2, i32>,
  46                                              SDTCisVT<3, i32>,
  47                                              SDTCisVT<4, i32>,
  48                                              SDTCisVT<5, i32>]>;
  49 def SDT_ZAtomicCmpSwapW     : SDTypeProfile<1, 6,
  50                                             [SDTCisVT<0, i32>,
  51                                              SDTCisPtrTy<1>,
  52                                              SDTCisVT<2, i32>,
  53                                              SDTCisVT<3, i32>,
  54                                              SDTCisVT<4, i32>,
  55                                              SDTCisVT<5, i32>,
  56                                              SDTCisVT<6, i32>]>;
  57 def SDT_ZMemMemLength       : SDTypeProfile<0, 3,
  58                                             [SDTCisPtrTy<0>,
  59                                              SDTCisPtrTy<1>,
  60                                              SDTCisVT<2, i32>]>;
  61 def SDT_ZString             : SDTypeProfile<1, 3,
  62                                             [SDTCisPtrTy<0>,
  63                                              SDTCisPtrTy<1>,
  64                                              SDTCisPtrTy<2>,
  65                                              SDTCisVT<3, i32>]>;
  66 def SDT_ZI32Intrinsic       : SDTypeProfile<1, 0, [SDTCisVT<0, i32>]>;
  67
  68 //===----------------------------------------------------------------------===//
  69 // Node definitions
  70 //===----------------------------------------------------------------------===//
  71
  72 // These are target-independent nodes, but have target-specific formats.
  73 def callseq_start       : SDNode<"ISD::CALLSEQ_START", SDT_CallSeqStart,
  74                                  [SDNPHasChain, SDNPSideEffect, SDNPOutGlue]>;
  75 def callseq_end         : SDNode<"ISD::CALLSEQ_END",   SDT_CallSeqEnd,
  76                                  [SDNPHasChain, SDNPSideEffect, SDNPOptInGlue,
  77                                   SDNPOutGlue]>;
  78
  79 // Nodes for SystemZISD::*.  See SystemZISelLowering.h for more details.
  80 def z_retflag           : SDNode<"SystemZISD::RET_FLAG", SDTNone,
  81                                  [SDNPHasChain, SDNPOptInGlue, SDNPVariadic]>;
  82 def z_call              : SDNode<"SystemZISD::CALL", SDT_ZCall,
  83                                  [SDNPHasChain, SDNPOutGlue, SDNPOptInGlue,
  84                                   SDNPVariadic]>;
  85 def z_pcrel_wrapper     : SDNode<"SystemZISD::PCREL_WRAPPER", SDT_ZWrapPtr, []>;
  86 def z_cmp               : SDNode<"SystemZISD::CMP", SDT_ZCmp, [SDNPOutGlue]>;
  87 def z_ucmp              : SDNode<"SystemZISD::UCMP", SDT_ZCmp, [SDNPOutGlue]>;
  88 def z_br_ccmask         : SDNode<"SystemZISD::BR_CCMASK", SDT_ZBRCCMask,
  89                                  [SDNPHasChain, SDNPInGlue]>;
  90 def z_select_ccmask     : SDNode<"SystemZISD::SELECT_CCMASK", SDT_ZSelectCCMask,
  91                                  [SDNPInGlue]>;
  92 def z_adjdynalloc       : SDNode<"SystemZISD::ADJDYNALLOC", SDT_ZAdjDynAlloc>;
  93 def z_extract_access    : SDNode<"SystemZISD::EXTRACT_ACCESS",
  94                                  SDT_ZExtractAccess>;
  95 def z_umul_lohi64       : SDNode<"SystemZISD::UMUL_LOHI64", SDT_ZGR128Binary64>;
  96 def z_sdivrem32         : SDNode<"SystemZISD::SDIVREM32", SDT_ZGR128Binary32>;
  97 def z_sdivrem64         : SDNode<"SystemZISD::SDIVREM64", SDT_ZGR128Binary64>;
  98 def z_udivrem32         : SDNode<"SystemZISD::UDIVREM32", SDT_ZGR128Binary32>;
  99 def z_udivrem64         : SDNode<"SystemZISD::UDIVREM64", SDT_ZGR128Binary64>;
 100
 101 class AtomicWOp<string name, SDTypeProfile profile = SDT_ZAtomicLoadBinaryW>
 102   : SDNode<"SystemZISD::"##name, profile,
 103            [SDNPHasChain, SDNPMayStore, SDNPMayLoad, SDNPMemOperand]>;
 104
 105 def z_atomic_swapw      : AtomicWOp<"ATOMIC_SWAPW">;
 106 def z_atomic_loadw_add  : AtomicWOp<"ATOMIC_LOADW_ADD">;
 107 def z_atomic_loadw_sub  : AtomicWOp<"ATOMIC_LOADW_SUB">;
 108 def z_atomic_loadw_and  : AtomicWOp<"ATOMIC_LOADW_AND">;
 109 def z_atomic_loadw_or   : AtomicWOp<"ATOMIC_LOADW_OR">;
 110 def z_atomic_loadw_xor  : AtomicWOp<"ATOMIC_LOADW_XOR">;
 111 def z_atomic_loadw_nand : AtomicWOp<"ATOMIC_LOADW_NAND">;
 112 def z_atomic_loadw_min  : AtomicWOp<"ATOMIC_LOADW_MIN">;
 113 def z_atomic_loadw_max  : AtomicWOp<"ATOMIC_LOADW_MAX">;
 114 def z_atomic_loadw_umin : AtomicWOp<"ATOMIC_LOADW_UMIN">;
 115 def z_atomic_loadw_umax : AtomicWOp<"ATOMIC_LOADW_UMAX">;
 116 def z_atomic_cmp_swapw  : AtomicWOp<"ATOMIC_CMP_SWAPW", SDT_ZAtomicCmpSwapW>;
 117
 118 def z_mvc               : SDNode<"SystemZISD::MVC", SDT_ZMemMemLength,
 119                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 120 def z_clc               : SDNode<"SystemZISD::CLC", SDT_ZMemMemLength,
 121                                  [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
 122 def z_strcmp            : SDNode<"SystemZISD::STRCMP", SDT_ZString,
 123                                  [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
 124 def z_stpcpy            : SDNode<"SystemZISD::STPCPY", SDT_ZString,
 125                                  [SDNPHasChain, SDNPMayStore, SDNPMayLoad]>;
 126 def z_search_string     : SDNode<"SystemZISD::SEARCH_STRING", SDT_ZString,
 127                                  [SDNPHasChain, SDNPOutGlue, SDNPMayLoad]>;
 128 def z_ipm               : SDNode<"SystemZISD::IPM", SDT_ZI32Intrinsic,
 129                                  [SDNPInGlue]>;
 130
 131 //===----------------------------------------------------------------------===//
 132 // Pattern fragments
 133 //===----------------------------------------------------------------------===//
 134
 135 // Register sign-extend operations.  Sub-32-bit values are represented as i32s.
 136 def sext8  : PatFrag<(ops node:$src), (sext_inreg node:$src, i8)>;
 137 def sext16 : PatFrag<(ops node:$src), (sext_inreg node:$src, i16)>;
 138 def sext32 : PatFrag<(ops node:$src), (sext (i32 node:$src))>;
 139
 140 // Register zero-extend operations.  Sub-32-bit values are represented as i32s.
 141 def zext8  : PatFrag<(ops node:$src), (and node:$src, 0xff)>;
 142 def zext16 : PatFrag<(ops node:$src), (and node:$src, 0xffff)>;
 143 def zext32 : PatFrag<(ops node:$src), (zext (i32 node:$src))>;
 144
 145 // Typed floating-point loads.
 146 def loadf32 : PatFrag<(ops node:$src), (f32 (load node:$src))>;
 147 def loadf64 : PatFrag<(ops node:$src), (f64 (load node:$src))>;
 148
 149 // Extending loads in which the extension type doesn't matter.
 150 def anyextload : PatFrag<(ops node:$ptr), (unindexedload node:$ptr), [{
 151   return cast<LoadSDNode>(N)->getExtensionType() != ISD::NON_EXTLOAD;
 152 }]>;
 153 def anyextloadi8 : PatFrag<(ops node:$ptr), (anyextload node:$ptr), [{
 154   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i8;
 155 }]>;
 156 def anyextloadi16 : PatFrag<(ops node:$ptr), (anyextload node:$ptr), [{
 157   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i16;
 158 }]>;
 159 def anyextloadi32 : PatFrag<(ops node:$ptr), (anyextload node:$ptr), [{
 160   return cast<LoadSDNode>(N)->getMemoryVT() == MVT::i32;
 161 }]>;
 162
 163 // Aligned loads.
 164 class AlignedLoad<SDPatternOperator load>
 165   : PatFrag<(ops node:$addr), (load node:$addr), [{
 166   LoadSDNode *Load = cast<LoadSDNode>(N);
 167   return Load->getAlignment() >= Load->getMemoryVT().getStoreSize();
 168 }]>;
 169 def aligned_load        : AlignedLoad<load>;
 170 def aligned_sextloadi16 : AlignedLoad<sextloadi16>;
 171 def aligned_sextloadi32 : AlignedLoad<sextloadi32>;
 172 def aligned_zextloadi16 : AlignedLoad<zextloadi16>;
 173 def aligned_zextloadi32 : AlignedLoad<zextloadi32>;
 174
 175 // Aligned stores.
 176 class AlignedStore<SDPatternOperator store>
 177   : PatFrag<(ops node:$src, node:$addr), (store node:$src, node:$addr), [{
 178   StoreSDNode *Store = cast<StoreSDNode>(N);
 179   return Store->getAlignment() >= Store->getMemoryVT().getStoreSize();
 180 }]>;
 181 def aligned_store         : AlignedStore<store>;
 182 def aligned_truncstorei16 : AlignedStore<truncstorei16>;
 183 def aligned_truncstorei32 : AlignedStore<truncstorei32>;
 184
 185 // Non-volatile loads.  Used for instructions that might access the storage
 186 // location multiple times.
 187 class NonvolatileLoad<SDPatternOperator load>
 188   : PatFrag<(ops node:$addr), (load node:$addr), [{
 189   LoadSDNode *Load = cast<LoadSDNode>(N);
 190   return !Load->isVolatile();
 191 }]>;
 192 def nonvolatile_load          : NonvolatileLoad<load>;
 193 def nonvolatile_anyextloadi8  : NonvolatileLoad<anyextloadi8>;
 194 def nonvolatile_anyextloadi16 : NonvolatileLoad<anyextloadi16>;
 195 def nonvolatile_anyextloadi32 : NonvolatileLoad<anyextloadi32>;
 196
 197 // Non-volatile stores.
 198 class NonvolatileStore<SDPatternOperator store>
 199   : PatFrag<(ops node:$src, node:$addr), (store node:$src, node:$addr), [{
 200   StoreSDNode *Store = cast<StoreSDNode>(N);
 201   return !Store->isVolatile();
 202 }]>;
 203 def nonvolatile_store         : NonvolatileStore<store>;
 204 def nonvolatile_truncstorei8  : NonvolatileStore<truncstorei8>;
 205 def nonvolatile_truncstorei16 : NonvolatileStore<truncstorei16>;
 206 def nonvolatile_truncstorei32 : NonvolatileStore<truncstorei32>;
 207
 208 // Insertions.
 209 def inserti8 : PatFrag<(ops node:$src1, node:$src2),
 210                        (or (and node:$src1, -256), node:$src2)>;
 211 def insertll : PatFrag<(ops node:$src1, node:$src2),
 212                        (or (and node:$src1, 0xffffffffffff0000), node:$src2)>;
 213 def insertlh : PatFrag<(ops node:$src1, node:$src2),
 214                        (or (and node:$src1, 0xffffffff0000ffff), node:$src2)>;
 215 def inserthl : PatFrag<(ops node:$src1, node:$src2),
 216                        (or (and node:$src1, 0xffff0000ffffffff), node:$src2)>;
 217 def inserthh : PatFrag<(ops node:$src1, node:$src2),
 218                        (or (and node:$src1, 0x0000ffffffffffff), node:$src2)>;
 219 def insertlf : PatFrag<(ops node:$src1, node:$src2),
 220                        (or (and node:$src1, 0xffffffff00000000), node:$src2)>;
 221 def inserthf : PatFrag<(ops node:$src1, node:$src2),
 222                        (or (and node:$src1, 0x00000000ffffffff), node:$src2)>;
 223
 224 // ORs that can be treated as insertions.
 225 def or_as_inserti8 : PatFrag<(ops node:$src1, node:$src2),
 226                              (or node:$src1, node:$src2), [{
 227   unsigned BitWidth = N->getValueType(0).getScalarType().getSizeInBits();
 228   return CurDAG->MaskedValueIsZero(N->getOperand(0),
 229                                    APInt::getLowBitsSet(BitWidth, 8));
 230 }]>;
 231
 232 // ORs that can be treated as reversed insertions.
 233 def or_as_revinserti8 : PatFrag<(ops node:$src1, node:$src2),
 234                                 (or node:$src1, node:$src2), [{
 235   unsigned BitWidth = N->getValueType(0).getScalarType().getSizeInBits();
 236   return CurDAG->MaskedValueIsZero(N->getOperand(1),
 237                                    APInt::getLowBitsSet(BitWidth, 8));
 238 }]>;
 239
 240 // Fused multiply-add and multiply-subtract, but with the order of the
 241 // operands matching SystemZ's MA and MS instructions.
 242 def z_fma : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 243                     (fma node:$src2, node:$src3, node:$src1)>;
 244 def z_fms : PatFrag<(ops node:$src1, node:$src2, node:$src3),
 245                     (fma node:$src2, node:$src3, (fneg node:$src1))>;
 246
 247 // Floating-point negative absolute.
 248 def fnabs : PatFrag<(ops node:$ptr), (fneg (fabs node:$ptr))>;
 249
 250 // Create a unary operator that loads from memory and then performs
 251 // the given operation on it.
 252 class loadu<SDPatternOperator operator, SDPatternOperator load = load>
 253   : PatFrag<(ops node:$addr), (operator (load node:$addr))>;
 254
 255 // Create a store operator that performs the given unary operation
 256 // on the value before storing it.
 257 class storeu<SDPatternOperator operator, SDPatternOperator store = store>
 258   : PatFrag<(ops node:$value, node:$addr),
 259             (store (operator node:$value), node:$addr)>;