lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 //===----------------------------------------------------------------------===//
  55 // Selection DAG Type Profile definitions.
  56 //
  57 // These use the constraints defined above to describe the type requirements of
  58 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  59 // add their own if needed.
  60 //
  61
  62 // SDTypeProfile - This profile describes the type requirements of a Selection
  63 // DAG node.
  64 class SDTypeProfile<int numresults, int numoperands,
  65                     list<SDTypeConstraint> constraints> {
  66   int NumResults = numresults;
  67   int NumOperands = numoperands;
  68   list<SDTypeConstraint> Constraints = constraints;
  69 }
  70
  71 // Builtin profiles.
  72 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  73 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;       // for 'fpimm'.
  74 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  75 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  76 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  77 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  78   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  79 ]>;
  80 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  81   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  82 ]>;
  83 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  84   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  85 ]>;
  86 def SDTFPSignOp : SDTypeProfile<1, 2, [      // fcopysign.
  87   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisFP<2>
  88 ]>;
  89 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
  90   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
  91 ]>;
  92 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  93   SDTCisSameAs<0, 1>, SDTCisInt<0>
  94 ]>;
  95 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
  96   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
  97 ]>;
  98 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
  99   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
 100 ]>;
 101 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
 102   SDTCisSameAs<0, 1>, SDTCisFP<0>
 103 ]>;
 104 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 105   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 106 ]>;
 107 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 108   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 109 ]>;
 110 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 111   SDTCisFP<0>, SDTCisInt<1>
 112 ]>;
 113 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 114   SDTCisInt<0>, SDTCisFP<1>
 115 ]>;
 116 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 117   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 118   SDTCisVTSmallerThanOp<2, 1>
 119 ]>;
 120
 121 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 122   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 123 ]>;
 124
 125 def SDTSelect : SDTypeProfile<1, 3, [ // select
 126   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 127 ]>;
 128
 129 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 130   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 131   SDTCisVT<5, OtherVT>
 132 ]>;
 133
 134 def SDTBr : SDTypeProfile<0, 1, [ // br
 135   SDTCisVT<0, OtherVT>
 136 ]>;
 137
 138 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 139   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 140 ]>;
 141
 142 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 143
 144 def SDTLoad : SDTypeProfile<1, 1, [ // load
 145   SDTCisPtrTy<1>
 146 ]>;
 147
 148 def SDTStore : SDTypeProfile<0, 2, [ // store
 149   SDTCisPtrTy<1>
 150 ]>;
 151
 152 def SDTExtLoad : SDTypeProfile<1, 3, [  // extload
 153   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 154 ]>;
 155 def SDTIntExtLoad : SDTypeProfile<1, 3, [  // sextload, zextload
 156   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 157 ]>;
 158 def SDTTruncStore : SDTypeProfile<0, 4, [  // truncstore
 159   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 160 ]>;
 161
 162 //===----------------------------------------------------------------------===//
 163 // Selection DAG Node Properties.
 164 //
 165 // Note: These are hard coded into tblgen.
 166 //
 167 class SDNodeProperty;
 168 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 169 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 170 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 171 def SDNPOutFlag     : SDNodeProperty;   // Write a flag result
 172 def SDNPInFlag      : SDNodeProperty;   // Read a flag operand
 173 def SDNPOptInFlag   : SDNodeProperty;   // Optionally read a flag operand
 174
 175 //===----------------------------------------------------------------------===//
 176 // Selection DAG Node definitions.
 177 //
 178 class SDNode<string opcode, SDTypeProfile typeprof,
 179              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 180   string Opcode  = opcode;
 181   string SDClass = sdclass;
 182   list<SDNodeProperty> Properties = props;
 183   SDTypeProfile TypeProfile = typeprof;
 184 }
 185
 186 def set;
 187 def node;
 188 def srcvalue;
 189
 190 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 191 def fpimm      : SDNode<"ISD::TargetConstantFP",
 192                          SDTFPLeaf, [], "ConstantFPSDNode">;
 193 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 194 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 195 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 196 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 197 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 198                         "GlobalAddressSDNode">;
 199 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 200                          "GlobalAddressSDNode">;
 201 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 202                          "ConstantPoolSDNode">;
 203 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 204                          "ConstantPoolSDNode">;
 205 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 206                          "FrameIndexSDNode">;
 207 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 208                          "FrameIndexSDNode">;
 209 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 210                          "ExternalSymbolSDNode">;
 211 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 212                          "ExternalSymbolSDNode">;
 213
 214 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 215                         [SDNPCommutative, SDNPAssociative]>;
 216 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 217 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 218                         [SDNPCommutative, SDNPAssociative]>;
 219 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 220 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 221 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 222 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 223 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 224 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 225 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 226 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 227 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 228 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 229 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 230 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 231                         [SDNPCommutative, SDNPAssociative]>;
 232 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 233                         [SDNPCommutative, SDNPAssociative]>;
 234 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 235                         [SDNPCommutative, SDNPAssociative]>;
 236 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 237                         [SDNPCommutative, SDNPOutFlag]>;
 238 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 239                         [SDNPCommutative, SDNPOutFlag, SDNPInFlag]>;
 240 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 241                         [SDNPOutFlag]>;
 242 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 243                         [SDNPOutFlag, SDNPInFlag]>;
 244
 245 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 246 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 247 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 248 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 249 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 250 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 251 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 252 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 253 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 254
 255 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 256 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 257 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 258 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 259 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 260 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 261 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 262 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 263 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 264 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 265
 266 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 267 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 268 def fcopysign  : SDNode<"ISD::FCOPYSIGN"  , SDTFPSignOp>;
 269
 270 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 271 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 272 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 273 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 274
 275 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 276 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 277 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 278
 279 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 280 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 281 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 282
 283 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 284 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 285
 286 // Do not use sextld and zextld directly. Use sextload and zextload (see
 287 // below) which pass in a dummy srcvalue node which tblgen will skip over.
 288 def sextld     : SDNode<"ISD::SEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 289 def zextld     : SDNode<"ISD::ZEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 290 def extld      : SDNode<"ISD::EXTLOAD"    , SDTExtLoad,    [SDNPHasChain]>;
 291 def truncst    : SDNode<"ISD::TRUNCSTORE" , SDTTruncStore, [SDNPHasChain]>;
 292
 293 //===----------------------------------------------------------------------===//
 294 // Selection DAG Condition Codes
 295
 296 class CondCode; // ISD::CondCode enums
 297 def SETOEQ : CondCode; def SETOGT : CondCode;
 298 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 299 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 300 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 301 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 302
 303 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 304 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 305
 306
 307 //===----------------------------------------------------------------------===//
 308 // Selection DAG Node Transformation Functions.
 309 //
 310 // This mechanism allows targets to manipulate nodes in the output DAG once a
 311 // match has been formed.  This is typically used to manipulate immediate
 312 // values.
 313 //
 314 class SDNodeXForm<SDNode opc, code xformFunction> {
 315   SDNode Opcode = opc;
 316   code XFormFunction = xformFunction;
 317 }
 318
 319 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 320
 321
 322 //===----------------------------------------------------------------------===//
 323 // Selection DAG Pattern Fragments.
 324 //
 325 // Pattern fragments are reusable chunks of dags that match specific things.
 326 // They can take arguments and have C++ predicates that control whether they
 327 // match.  They are intended to make the patterns for common instructions more
 328 // compact and readable.
 329 //
 330
 331 /// PatFrag - Represents a pattern fragment.  This can match something on the
 332 /// DAG, frame a single node to multiply nested other fragments.
 333 ///
 334 class PatFrag<dag ops, dag frag, code pred = [{}],
 335               SDNodeXForm xform = NOOP_SDNodeXForm> {
 336   dag Operands = ops;
 337   dag Fragment = frag;
 338   code Predicate = pred;
 339   SDNodeXForm OperandTransform = xform;
 340 }
 341
 342 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 343 // to define immediates and other common things concisely.
 344 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 345  : PatFrag<(ops), frag, pred, xform>;
 346
 347 // Leaf fragments.
 348
 349 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 350 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 351 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 352
 353 // Other helper fragments.
 354
 355 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 356 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 357
 358 // extending load & truncstore fragments.
 359 def sextload      : PatFrag<(ops node:$ptr, node:$vt),
 360                             (sextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 361 def zextload      : PatFrag<(ops node:$ptr, node:$vt),
 362                             (zextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 363 def extload       : PatFrag<(ops node:$ptr, node:$vt),
 364                             (extld node:$ptr, srcvalue:$dummy, node:$vt)>;
 365 def truncstore    : PatFrag<(ops node:$val, node:$ptr, node:$vt),
 366                             (truncst node:$val, node:$ptr, srcvalue:$dummy,
 367                             node:$vt)>;
 368
 369 // setcc convenience fragments.
 370 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 371                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 372 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 373                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 374 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 375                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 376 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 377                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 378 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 379                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 380 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 381                      (setcc node:$lhs, node:$rhs, SETONE)>;
 382 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 383                      (setcc node:$lhs, node:$rhs, SETO)>;
 384 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 385                      (setcc node:$lhs, node:$rhs, SETUO)>;
 386 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 387                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 388 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 389                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 390 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 391                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 392 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 393                      (setcc node:$lhs, node:$rhs, SETULT)>;
 394 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 395                      (setcc node:$lhs, node:$rhs, SETULE)>;
 396 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 397                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 398 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 399                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 400 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 401                      (setcc node:$lhs, node:$rhs, SETGT)>;
 402 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 403                      (setcc node:$lhs, node:$rhs, SETGE)>;
 404 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 405                      (setcc node:$lhs, node:$rhs, SETLT)>;
 406 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 407                      (setcc node:$lhs, node:$rhs, SETLE)>;
 408 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 409                      (setcc node:$lhs, node:$rhs, SETNE)>;
 410
 411 //===----------------------------------------------------------------------===//
 412 // Selection DAG Pattern Support.
 413 //
 414 // Patterns are what are actually matched against the target-flavored
 415 // instruction selection DAG.  Instructions defined by the target implicitly
 416 // define patterns in most cases, but patterns can also be explicitly added when
 417 // an operation is defined by a sequence of instructions (e.g. loading a large
 418 // immediate value on RISC targets that do not support immediates as large as
 419 // their GPRs).
 420 //
 421
 422 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 423   dag             PatternToMatch = patternToMatch;
 424   list<dag>       ResultInstrs   = resultInstrs;
 425   list<Predicate> Predicates     = [];  // See class Instruction in Target.td.
 426 }
 427
 428 // Pat - A simple (but common) form of a pattern, which produces a simple result
 429 // not needing a full list.
 430 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 431
 432 //===----------------------------------------------------------------------===//
 433 // Complex pattern definitions.
 434 //
 435 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 436 // in C++. NumOperands is the number of operands returned by the select function;
 437 // SelectFunc is the name of the function used to pattern match the max. pattern;
 438 // RootNodes are the list of possible root nodes of the sub-dags to match.
 439 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 440 //
 441 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 442   ValueType Ty = ty;
 443   int NumOperands = numops;
 444   string SelectFunc = fn;
 445   list<SDNode> RootNodes = roots;
 446 }
 447
 448 //===----------------------------------------------------------------------===//
 449 // Dwarf support.
 450 //
 451 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 452                       [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 453 def dwarf_loc : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 454
 455 def SDT_dwarf_label : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 456 def dwarf_label : SDNode<"ISD::DEBUG_LABEL", SDT_dwarf_label,[SDNPHasChain]>;
 457
 458
 459