lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 //===----------------------------------------------------------------------===//
  55 // Selection DAG Type Profile definitions.
  56 //
  57 // These use the constraints defined above to describe the type requirements of
  58 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  59 // add their own if needed.
  60 //
  61
  62 // SDTypeProfile - This profile describes the type requirements of a Selection
  63 // DAG node.
  64 class SDTypeProfile<int numresults, int numoperands,
  65                     list<SDTypeConstraint> constraints> {
  66   int NumResults = numresults;
  67   int NumOperands = numoperands;
  68   list<SDTypeConstraint> Constraints = constraints;
  69 }
  70
  71 // Builtin profiles.
  72 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  73 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;       // for 'fpimm'.
  74 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  75 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  76 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  77 def SDTUnaryOp  : SDTypeProfile<1, 1, []>; // bitconvert
  78
  79 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  80   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  81 ]>;
  82 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  83   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  84 ]>;
  85 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  86   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  87 ]>;
  88 def SDTFPSignOp : SDTypeProfile<1, 2, [      // fcopysign.
  89   SDTCisSameAs<0, 1>, SDTCisFP<0>, SDTCisFP<2>
  90 ]>;
  91 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
  92   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
  93 ]>;
  94 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  95   SDTCisSameAs<0, 1>, SDTCisInt<0>
  96 ]>;
  97 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
  98   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
  99 ]>;
 100 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
 101   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
 102 ]>;
 103 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
 104   SDTCisSameAs<0, 1>, SDTCisFP<0>
 105 ]>;
 106 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 107   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 108 ]>;
 109 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 110   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 111 ]>;
 112 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 113   SDTCisFP<0>, SDTCisInt<1>
 114 ]>;
 115 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 116   SDTCisInt<0>, SDTCisFP<1>
 117 ]>;
 118 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 119   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 120   SDTCisVTSmallerThanOp<2, 1>
 121 ]>;
 122
 123 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 124   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 125 ]>;
 126
 127 def SDTSelect : SDTypeProfile<1, 3, [ // select
 128   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 129 ]>;
 130
 131 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 132   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 133   SDTCisVT<5, OtherVT>
 134 ]>;
 135
 136 def SDTBr : SDTypeProfile<0, 1, [ // br
 137   SDTCisVT<0, OtherVT>
 138 ]>;
 139
 140 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 141   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 142 ]>;
 143
 144 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 145
 146 def SDTLoad : SDTypeProfile<1, 1, [ // load
 147   SDTCisPtrTy<1>
 148 ]>;
 149
 150 def SDTStore : SDTypeProfile<0, 2, [ // store
 151   SDTCisPtrTy<1>
 152 ]>;
 153
 154 def SDTExtLoad : SDTypeProfile<1, 3, [  // extload
 155   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 156 ]>;
 157 def SDTIntExtLoad : SDTypeProfile<1, 3, [  // sextload, zextload
 158   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 159 ]>;
 160 def SDTTruncStore : SDTypeProfile<0, 4, [  // truncstore
 161   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 162 ]>;
 163
 164 //===----------------------------------------------------------------------===//
 165 // Selection DAG Node Properties.
 166 //
 167 // Note: These are hard coded into tblgen.
 168 //
 169 class SDNodeProperty;
 170 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 171 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 172 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 173 def SDNPOutFlag     : SDNodeProperty;   // Write a flag result
 174 def SDNPInFlag      : SDNodeProperty;   // Read a flag operand
 175 def SDNPOptInFlag   : SDNodeProperty;   // Optionally read a flag operand
 176
 177 //===----------------------------------------------------------------------===//
 178 // Selection DAG Node definitions.
 179 //
 180 class SDNode<string opcode, SDTypeProfile typeprof,
 181              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 182   string Opcode  = opcode;
 183   string SDClass = sdclass;
 184   list<SDNodeProperty> Properties = props;
 185   SDTypeProfile TypeProfile = typeprof;
 186 }
 187
 188 def set;
 189 def node;
 190 def srcvalue;
 191
 192 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 193 def fpimm      : SDNode<"ISD::TargetConstantFP",
 194                          SDTFPLeaf, [], "ConstantFPSDNode">;
 195 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 196 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 197 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 198 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 199 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 200                         "GlobalAddressSDNode">;
 201 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 202                          "GlobalAddressSDNode">;
 203 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 204                          "ConstantPoolSDNode">;
 205 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 206                          "ConstantPoolSDNode">;
 207 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 208                          "FrameIndexSDNode">;
 209 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 210                          "FrameIndexSDNode">;
 211 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 212                          "ExternalSymbolSDNode">;
 213 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 214                          "ExternalSymbolSDNode">;
 215
 216 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 217                         [SDNPCommutative, SDNPAssociative]>;
 218 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 219 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 220                         [SDNPCommutative, SDNPAssociative]>;
 221 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 222 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 223 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 224 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 225 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 226 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 227 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 228 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 229 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 230 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 231 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 232 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 233                         [SDNPCommutative, SDNPAssociative]>;
 234 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 235                         [SDNPCommutative, SDNPAssociative]>;
 236 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 237                         [SDNPCommutative, SDNPAssociative]>;
 238 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 239                         [SDNPCommutative, SDNPOutFlag]>;
 240 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 241                         [SDNPCommutative, SDNPOutFlag, SDNPInFlag]>;
 242 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 243                         [SDNPOutFlag]>;
 244 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 245                         [SDNPOutFlag, SDNPInFlag]>;
 246
 247 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 248 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 249 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 250 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 251 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 252 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 253 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 254 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 255 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 256 def bitconvert : SDNode<"ISD::BIT_CONVERT", SDTUnaryOp>;
 257
 258 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 259 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 260 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 261 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 262 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 263 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 264 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 265 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 266 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 267 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 268
 269 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 270 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 271 def fcopysign  : SDNode<"ISD::FCOPYSIGN"  , SDTFPSignOp>;
 272
 273 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 274 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 275 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 276 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 277
 278 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 279 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 280 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 281
 282 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 283 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 284 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 285
 286 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 287 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 288
 289 // Do not use sextld and zextld directly. Use sextload and zextload (see
 290 // below) which pass in a dummy srcvalue node which tblgen will skip over.
 291 def sextld     : SDNode<"ISD::SEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 292 def zextld     : SDNode<"ISD::ZEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 293 def extld      : SDNode<"ISD::EXTLOAD"    , SDTExtLoad,    [SDNPHasChain]>;
 294 def truncst    : SDNode<"ISD::TRUNCSTORE" , SDTTruncStore, [SDNPHasChain]>;
 295
 296 //===----------------------------------------------------------------------===//
 297 // Selection DAG Condition Codes
 298
 299 class CondCode; // ISD::CondCode enums
 300 def SETOEQ : CondCode; def SETOGT : CondCode;
 301 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 302 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 303 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 304 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 305
 306 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 307 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 308
 309
 310 //===----------------------------------------------------------------------===//
 311 // Selection DAG Node Transformation Functions.
 312 //
 313 // This mechanism allows targets to manipulate nodes in the output DAG once a
 314 // match has been formed.  This is typically used to manipulate immediate
 315 // values.
 316 //
 317 class SDNodeXForm<SDNode opc, code xformFunction> {
 318   SDNode Opcode = opc;
 319   code XFormFunction = xformFunction;
 320 }
 321
 322 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 323
 324
 325 //===----------------------------------------------------------------------===//
 326 // Selection DAG Pattern Fragments.
 327 //
 328 // Pattern fragments are reusable chunks of dags that match specific things.
 329 // They can take arguments and have C++ predicates that control whether they
 330 // match.  They are intended to make the patterns for common instructions more
 331 // compact and readable.
 332 //
 333
 334 /// PatFrag - Represents a pattern fragment.  This can match something on the
 335 /// DAG, frame a single node to multiply nested other fragments.
 336 ///
 337 class PatFrag<dag ops, dag frag, code pred = [{}],
 338               SDNodeXForm xform = NOOP_SDNodeXForm> {
 339   dag Operands = ops;
 340   dag Fragment = frag;
 341   code Predicate = pred;
 342   SDNodeXForm OperandTransform = xform;
 343 }
 344
 345 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 346 // to define immediates and other common things concisely.
 347 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 348  : PatFrag<(ops), frag, pred, xform>;
 349
 350 // Leaf fragments.
 351
 352 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 353 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 354 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 355
 356 // Other helper fragments.
 357
 358 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 359 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 360
 361 // extending load & truncstore fragments.
 362 def sextload      : PatFrag<(ops node:$ptr, node:$vt),
 363                             (sextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 364 def zextload      : PatFrag<(ops node:$ptr, node:$vt),
 365                             (zextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 366 def extload       : PatFrag<(ops node:$ptr, node:$vt),
 367                             (extld node:$ptr, srcvalue:$dummy, node:$vt)>;
 368 def truncstore    : PatFrag<(ops node:$val, node:$ptr, node:$vt),
 369                             (truncst node:$val, node:$ptr, srcvalue:$dummy,
 370                             node:$vt)>;
 371
 372 // setcc convenience fragments.
 373 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 374                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 375 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 376                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 377 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 378                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 379 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 380                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 381 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 382                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 383 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 384                      (setcc node:$lhs, node:$rhs, SETONE)>;
 385 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 386                      (setcc node:$lhs, node:$rhs, SETO)>;
 387 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 388                      (setcc node:$lhs, node:$rhs, SETUO)>;
 389 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 390                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 391 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 392                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 393 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 394                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 395 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 396                      (setcc node:$lhs, node:$rhs, SETULT)>;
 397 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 398                      (setcc node:$lhs, node:$rhs, SETULE)>;
 399 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 400                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 401 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 402                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 403 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 404                      (setcc node:$lhs, node:$rhs, SETGT)>;
 405 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 406                      (setcc node:$lhs, node:$rhs, SETGE)>;
 407 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 408                      (setcc node:$lhs, node:$rhs, SETLT)>;
 409 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 410                      (setcc node:$lhs, node:$rhs, SETLE)>;
 411 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 412                      (setcc node:$lhs, node:$rhs, SETNE)>;
 413
 414 //===----------------------------------------------------------------------===//
 415 // Selection DAG Pattern Support.
 416 //
 417 // Patterns are what are actually matched against the target-flavored
 418 // instruction selection DAG.  Instructions defined by the target implicitly
 419 // define patterns in most cases, but patterns can also be explicitly added when
 420 // an operation is defined by a sequence of instructions (e.g. loading a large
 421 // immediate value on RISC targets that do not support immediates as large as
 422 // their GPRs).
 423 //
 424
 425 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 426   dag             PatternToMatch = patternToMatch;
 427   list<dag>       ResultInstrs   = resultInstrs;
 428   list<Predicate> Predicates     = [];  // See class Instruction in Target.td.
 429 }
 430
 431 // Pat - A simple (but common) form of a pattern, which produces a simple result
 432 // not needing a full list.
 433 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 434
 435 //===----------------------------------------------------------------------===//
 436 // Complex pattern definitions.
 437 //
 438 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 439 // in C++. NumOperands is the number of operands returned by the select function;
 440 // SelectFunc is the name of the function used to pattern match the max. pattern;
 441 // RootNodes are the list of possible root nodes of the sub-dags to match.
 442 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 443 //
 444 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 445   ValueType Ty = ty;
 446   int NumOperands = numops;
 447   string SelectFunc = fn;
 448   list<SDNode> RootNodes = roots;
 449 }
 450
 451 //===----------------------------------------------------------------------===//
 452 // Dwarf support.
 453 //
 454 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 455                       [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 456 def dwarf_loc : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 457
 458 def SDT_dwarf_label : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 459 def dwarf_label : SDNode<"ISD::DEBUG_LABEL", SDT_dwarf_label,[SDNPHasChain]>;
 460
 461
 462