lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 //===----------------------------------------------------------------------===//
  55 // Selection DAG Type Profile definitions.
  56 //
  57 // These use the constraints defined above to describe the type requirements of
  58 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  59 // add their own if needed.
  60 //
  61
  62 // SDTypeProfile - This profile describes the type requirements of a Selection
  63 // DAG node.
  64 class SDTypeProfile<int numresults, int numoperands,
  65                     list<SDTypeConstraint> constraints> {
  66   int NumResults = numresults;
  67   int NumOperands = numoperands;
  68   list<SDTypeConstraint> Constraints = constraints;
  69 }
  70
  71 // Builtin profiles.
  72 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  73 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  74 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  75 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  76 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  77   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  78 ]>;
  79 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  80   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  81 ]>;
  82 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  83   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  84 ]>;
  85 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
  86   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
  87 ]>;
  88 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  89   SDTCisSameAs<0, 1>, SDTCisInt<0>
  90 ]>;
  91 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
  92   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
  93 ]>;
  94 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
  95   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
  96 ]>;
  97 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
  98   SDTCisSameAs<0, 1>, SDTCisFP<0>
  99 ]>;
 100 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 101   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 102 ]>;
 103 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 104   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 105 ]>;
 106 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 107   SDTCisFP<0>, SDTCisInt<1>
 108 ]>;
 109 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 110   SDTCisInt<0>, SDTCisFP<1>
 111 ]>;
 112 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 113   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 114   SDTCisVTSmallerThanOp<2, 1>
 115 ]>;
 116
 117 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 118   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 119 ]>;
 120
 121 def SDTSelect : SDTypeProfile<1, 3, [ // select
 122   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 123 ]>;
 124
 125 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 126   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 127   SDTCisVT<5, OtherVT>
 128 ]>;
 129
 130 def SDTBr : SDTypeProfile<0, 1, [ // br
 131   SDTCisVT<0, OtherVT>
 132 ]>;
 133
 134 def SDTBrCond : SDTypeProfile<0, 2, [ // brcond
 135   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 136 ]>;
 137
 138 def SDTRet : SDTypeProfile<0, 0, [ // ret
 139 ]>;
 140
 141 def SDTWritePort : SDTypeProfile<0, 2, [ // writeport
 142   SDTCisInt<0>, SDTCisInt<1>
 143 ]>;
 144
 145 def SDTLoad : SDTypeProfile<1, 1, [ // load
 146   SDTCisPtrTy<1>
 147 ]>;
 148
 149 def SDTStore : SDTypeProfile<0, 2, [ // store
 150   SDTCisPtrTy<1>
 151 ]>;
 152
 153 //===----------------------------------------------------------------------===//
 154 // Selection DAG Node Properties.
 155 //
 156 // Note: These are hard coded into tblgen.
 157 //
 158 class SDNodeProperty;
 159 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 160 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 161 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 162
 163 //===----------------------------------------------------------------------===//
 164 // Selection DAG Node definitions.
 165 //
 166 class SDNode<string opcode, SDTypeProfile typeprof,
 167              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 168   string Opcode  = opcode;
 169   string SDClass = sdclass;
 170   list<SDNodeProperty> Properties = props;
 171   SDTypeProfile TypeProfile = typeprof;
 172 }
 173
 174 def set;
 175 def node;
 176
 177 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 178 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 179 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 180 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 181 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 182 def globaladdr : SDNode<"ISD::GlobalAddress", SDTPtrLeaf, [],
 183                         "GlobalAddressSDNode">;
 184 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress", SDTPtrLeaf, [],
 185                         "GlobalAddressSDNode">;
 186 def tconstpool  : SDNode<"ISD::TargetConstantPool", SDTPtrLeaf, [],
 187                         "ConstantPoolSDNode">;
 188 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 189                         [SDNPCommutative, SDNPAssociative]>;
 190 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 191 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 192                         [SDNPCommutative, SDNPAssociative]>;
 193 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 194 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 195 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 196 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 197 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 198 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 199 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 200 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 201 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 202 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 203                         [SDNPCommutative, SDNPAssociative]>;
 204 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 205                         [SDNPCommutative, SDNPAssociative]>;
 206 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 207                         [SDNPCommutative, SDNPAssociative]>;
 208
 209 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 210 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 211 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 212 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 213 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 214 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 215 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 216 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 217
 218 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 219 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 220 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 221 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 222 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 223 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 224 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 225 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 226
 227 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 228 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 229
 230 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 231 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 232 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 233 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 234
 235 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 236 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 237 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 238
 239 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 240 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrCond, [SDNPHasChain]>;
 241 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 242
 243 def writeport  : SDNode<"ISD::WRITEPORT"  , SDTWritePort, [SDNPHasChain]>;
 244
 245 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 246 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 247
 248 //===----------------------------------------------------------------------===//
 249 // Selection DAG Condition Codes
 250
 251 class CondCode; // ISD::CondCode enums
 252 def SETOEQ : CondCode; def SETOGT : CondCode;
 253 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 254 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 255 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 256 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 257
 258 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 259 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 260
 261
 262 //===----------------------------------------------------------------------===//
 263 // Selection DAG Node Transformation Functions.
 264 //
 265 // This mechanism allows targets to manipulate nodes in the output DAG once a
 266 // match has been formed.  This is typically used to manipulate immediate
 267 // values.
 268 //
 269 class SDNodeXForm<SDNode opc, code xformFunction> {
 270   SDNode Opcode = opc;
 271   code XFormFunction = xformFunction;
 272 }
 273
 274 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 275
 276
 277 //===----------------------------------------------------------------------===//
 278 // Selection DAG Pattern Fragments.
 279 //
 280 // Pattern fragments are reusable chunks of dags that match specific things.
 281 // They can take arguments and have C++ predicates that control whether they
 282 // match.  They are intended to make the patterns for common instructions more
 283 // compact and readable.
 284 //
 285
 286 /// PatFrag - Represents a pattern fragment.  This can match something on the
 287 /// DAG, frame a single node to multiply nested other fragments.
 288 ///
 289 class PatFrag<dag ops, dag frag, code pred = [{}],
 290               SDNodeXForm xform = NOOP_SDNodeXForm> {
 291   dag Operands = ops;
 292   dag Fragment = frag;
 293   code Predicate = pred;
 294   SDNodeXForm OperandTransform = xform;
 295 }
 296
 297 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 298 // to define immediates and other common things concisely.
 299 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 300  : PatFrag<(ops), frag, pred, xform>;
 301
 302 // Leaf fragments.
 303
 304 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 305
 306 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 307 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 308
 309 // Other helper fragments.
 310
 311 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 312 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 313
 314
 315 // setcc convenience fragments.
 316 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 317                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 318 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 319                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 320 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 321                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 322 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 323                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 324 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 325                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 326 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 327                      (setcc node:$lhs, node:$rhs, SETONE)>;
 328 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 329                      (setcc node:$lhs, node:$rhs, SETO)>;
 330 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 331                      (setcc node:$lhs, node:$rhs, SETUO)>;
 332 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 333                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 334 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 335                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 336 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 337                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 338 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 339                      (setcc node:$lhs, node:$rhs, SETULT)>;
 340 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 341                      (setcc node:$lhs, node:$rhs, SETULE)>;
 342 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 343                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 344 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 345                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 346 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 347                      (setcc node:$lhs, node:$rhs, SETGT)>;
 348 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 349                      (setcc node:$lhs, node:$rhs, SETGE)>;
 350 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 351                      (setcc node:$lhs, node:$rhs, SETLT)>;
 352 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 353                      (setcc node:$lhs, node:$rhs, SETLE)>;
 354 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 355                      (setcc node:$lhs, node:$rhs, SETNE)>;
 356
 357 //===----------------------------------------------------------------------===//
 358 // Selection DAG Pattern Support.
 359 //
 360 // Patterns are what are actually matched against the target-flavored
 361 // instruction selection DAG.  Instructions defined by the target implicitly
 362 // define patterns in most cases, but patterns can also be explicitly added when
 363 // an operation is defined by a sequence of instructions (e.g. loading a large
 364 // immediate value on RISC targets that do not support immediates as large as
 365 // their GPRs).
 366 //
 367
 368 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 369   dag       PatternToMatch = patternToMatch;
 370   list<dag> ResultInstrs   = resultInstrs;
 371 }
 372
 373 // Pat - A simple (but common) form of a pattern, which produces a simple result
 374 // not needing a full list.
 375 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 376
 377 //===----------------------------------------------------------------------===//
 378 // Complex pattern definitions.
 379 //
 380 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 381 // in C++. NumOperands is the number of operands returned by the select function;
 382 // SelectFunc is the name of the function used to pattern match the max. pattern;
 383 // RootNodes are the list of possible root nodes of the sub-dags to match.
 384 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 385 //
 386 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 387   ValueType Ty = ty;
 388   int NumOperands = numops;
 389   string SelectFunc = fn;
 390   list<SDNode> RootNodes = roots;
 391 }