lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 //===----------------------------------------------------------------------===//
  55 // Selection DAG Type Profile definitions.
  56 //
  57 // These use the constraints defined above to describe the type requirements of
  58 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  59 // add their own if needed.
  60 //
  61
  62 // SDTypeProfile - This profile describes the type requirements of a Selection
  63 // DAG node.
  64 class SDTypeProfile<int numresults, int numoperands,
  65                     list<SDTypeConstraint> constraints> {
  66   int NumResults = numresults;
  67   int NumOperands = numoperands;
  68   list<SDTypeConstraint> Constraints = constraints;
  69 }
  70
  71 // Builtin profiles.
  72 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  73 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  74 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  75 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  76 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  77   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  78 ]>;
  79 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  80   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  81 ]>;
  82 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  83   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  84 ]>;
  85 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  86   SDTCisSameAs<0, 1>, SDTCisInt<0>
  87 ]>;
  88 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
  89   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
  90 ]>;
  91 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
  92   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
  93 ]>;
  94 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
  95   SDTCisSameAs<0, 1>, SDTCisFP<0>
  96 ]>;
  97 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
  98   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
  99 ]>;
 100 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 101   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 102 ]>;
 103 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 104   SDTCisFP<0>, SDTCisInt<1>
 105 ]>;
 106 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 107   SDTCisInt<0>, SDTCisFP<1>
 108 ]>;
 109 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 110   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 111   SDTCisVTSmallerThanOp<2, 1>
 112 ]>;
 113
 114 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 115   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 116 ]>;
 117
 118 def SDTSelect : SDTypeProfile<1, 3, [ // select
 119   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 120 ]>;
 121
 122 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 123   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 124   SDTCisVT<5, OtherVT>
 125 ]>;
 126
 127 def SDTBr : SDTypeProfile<0, 1, [ // br
 128   SDTCisVT<0, OtherVT>
 129 ]>;
 130
 131 def SDTBrCond : SDTypeProfile<0, 2, [ // brcond
 132   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 133 ]>;
 134
 135 def SDTRet : SDTypeProfile<0, 0, [ // ret
 136 ]>;
 137
 138 def SDTWritePort : SDTypeProfile<0, 2, [ // writeport
 139   SDTCisInt<0>, SDTCisInt<1>
 140 ]>;
 141
 142 def SDTLoad : SDTypeProfile<1, 1, [ // load
 143   SDTCisPtrTy<1>
 144 ]>;
 145
 146 def SDTStore : SDTypeProfile<0, 2, [ // store
 147   SDTCisPtrTy<1>
 148 ]>;
 149
 150 //===----------------------------------------------------------------------===//
 151 // Selection DAG Node Properties.
 152 //
 153 // Note: These are hard coded into tblgen.
 154 //
 155 class SDNodeProperty;
 156 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 157 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 158 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 159
 160 //===----------------------------------------------------------------------===//
 161 // Selection DAG Node definitions.
 162 //
 163 class SDNode<string opcode, SDTypeProfile typeprof,
 164              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 165   string Opcode  = opcode;
 166   string SDClass = sdclass;
 167   list<SDNodeProperty> Properties = props;
 168   SDTypeProfile TypeProfile = typeprof;
 169 }
 170
 171 def set;
 172 def node;
 173
 174 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 175 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 176 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 177 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 178 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 179 def globaladdr : SDNode<"ISD::GlobalAddress", SDTPtrLeaf, [],
 180                         "GlobalAddressSDNode">;
 181 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress", SDTPtrLeaf, [],
 182                         "GlobalAddressSDNode">;
 183 def tconstpool  : SDNode<"ISD::TargetConstantPool", SDTPtrLeaf, [],
 184                         "ConstantPoolSDNode">;
 185 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 186                         [SDNPCommutative, SDNPAssociative]>;
 187 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 188 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 189                         [SDNPCommutative, SDNPAssociative]>;
 190 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 191 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 192 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 193 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 194 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 195 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 196 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 197 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 198 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 199 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 200                         [SDNPCommutative, SDNPAssociative]>;
 201 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 202                         [SDNPCommutative, SDNPAssociative]>;
 203 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 204                         [SDNPCommutative, SDNPAssociative]>;
 205
 206 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 207 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 208 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 209 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 210 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 211 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 212 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 213 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 214
 215 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 216 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 217 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 218 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 219 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 220 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 221 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 222 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 223
 224 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 225 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 226
 227 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 228 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 229 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 230 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 231
 232 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 233 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 234 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 235
 236 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 237 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrCond, [SDNPHasChain]>;
 238 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 239
 240 def writeport  : SDNode<"ISD::WRITEPORT"  , SDTWritePort, [SDNPHasChain]>;
 241
 242 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 243 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 244
 245 //===----------------------------------------------------------------------===//
 246 // Selection DAG Condition Codes
 247
 248 class CondCode; // ISD::CondCode enums
 249 def SETOEQ : CondCode; def SETOGT : CondCode;
 250 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 251 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 252 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 253 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 254
 255 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 256 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 257
 258
 259 //===----------------------------------------------------------------------===//
 260 // Selection DAG Node Transformation Functions.
 261 //
 262 // This mechanism allows targets to manipulate nodes in the output DAG once a
 263 // match has been formed.  This is typically used to manipulate immediate
 264 // values.
 265 //
 266 class SDNodeXForm<SDNode opc, code xformFunction> {
 267   SDNode Opcode = opc;
 268   code XFormFunction = xformFunction;
 269 }
 270
 271 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 272
 273
 274 //===----------------------------------------------------------------------===//
 275 // Selection DAG Pattern Fragments.
 276 //
 277 // Pattern fragments are reusable chunks of dags that match specific things.
 278 // They can take arguments and have C++ predicates that control whether they
 279 // match.  They are intended to make the patterns for common instructions more
 280 // compact and readable.
 281 //
 282
 283 /// PatFrag - Represents a pattern fragment.  This can match something on the
 284 /// DAG, frame a single node to multiply nested other fragments.
 285 ///
 286 class PatFrag<dag ops, dag frag, code pred = [{}],
 287               SDNodeXForm xform = NOOP_SDNodeXForm> {
 288   dag Operands = ops;
 289   dag Fragment = frag;
 290   code Predicate = pred;
 291   SDNodeXForm OperandTransform = xform;
 292 }
 293
 294 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 295 // to define immediates and other common things concisely.
 296 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 297  : PatFrag<(ops), frag, pred, xform>;
 298
 299 // Leaf fragments.
 300
 301 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 302
 303 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 304 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 305
 306 // Other helper fragments.
 307
 308 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 309 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 310
 311
 312 // setcc convenience fragments.
 313 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 314                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 315 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 316                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 317 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 318                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 319 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 320                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 321 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 322                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 323 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 324                      (setcc node:$lhs, node:$rhs, SETONE)>;
 325 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 326                      (setcc node:$lhs, node:$rhs, SETO)>;
 327 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 328                      (setcc node:$lhs, node:$rhs, SETUO)>;
 329 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 330                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 331 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 332                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 333 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 334                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 335 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 336                      (setcc node:$lhs, node:$rhs, SETULT)>;
 337 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 338                      (setcc node:$lhs, node:$rhs, SETULE)>;
 339 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 340                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 341 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 342                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 343 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 344                      (setcc node:$lhs, node:$rhs, SETGT)>;
 345 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 346                      (setcc node:$lhs, node:$rhs, SETGE)>;
 347 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 348                      (setcc node:$lhs, node:$rhs, SETLT)>;
 349 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 350                      (setcc node:$lhs, node:$rhs, SETLE)>;
 351 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 352                      (setcc node:$lhs, node:$rhs, SETNE)>;
 353
 354 //===----------------------------------------------------------------------===//
 355 // Selection DAG Pattern Support.
 356 //
 357 // Patterns are what are actually matched against the target-flavored
 358 // instruction selection DAG.  Instructions defined by the target implicitly
 359 // define patterns in most cases, but patterns can also be explicitly added when
 360 // an operation is defined by a sequence of instructions (e.g. loading a large
 361 // immediate value on RISC targets that do not support immediates as large as
 362 // their GPRs).
 363 //
 364
 365 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 366   dag       PatternToMatch = patternToMatch;
 367   list<dag> ResultInstrs   = resultInstrs;
 368 }
 369
 370 // Pat - A simple (but common) form of a pattern, which produces a simple result
 371 // not needing a full list.
 372 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 373
 374 //===----------------------------------------------------------------------===//
 375 // Complex pattern definitions.
 376 //
 377 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 378 // in C++. NumOperands is the number of operands returned by the select function;
 379 // SelectFunc is the name of the function used to pattern match the max. pattern;
 380 // RootNodes are the list of possible root nodes of the sub-dags to match.
 381 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 382 //
 383 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 384   ValueType Ty = ty;
 385   int NumOperands = numops;
 386   string SelectFunc = fn;
 387   list<SDNode> RootNodes = roots;
 388 }