lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 //===----------------------------------------------------------------------===//
  55 // Selection DAG Type Profile definitions.
  56 //
  57 // These use the constraints defined above to describe the type requirements of
  58 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  59 // add their own if needed.
  60 //
  61
  62 // SDTypeProfile - This profile describes the type requirements of a Selection
  63 // DAG node.
  64 class SDTypeProfile<int numresults, int numoperands,
  65                     list<SDTypeConstraint> constraints> {
  66   int NumResults = numresults;
  67   int NumOperands = numoperands;
  68   list<SDTypeConstraint> Constraints = constraints;
  69 }
  70
  71 // Builtin profiles.
  72 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  73 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;       // for 'fpimm'.
  74 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  75 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  76 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  77 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  78   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  79 ]>;
  80 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  81   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  82 ]>;
  83 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  84   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  85 ]>;
  86 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
  87   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
  88 ]>;
  89 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  90   SDTCisSameAs<0, 1>, SDTCisInt<0>
  91 ]>;
  92 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
  93   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
  94 ]>;
  95 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
  96   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
  97 ]>;
  98 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
  99   SDTCisSameAs<0, 1>, SDTCisFP<0>
 100 ]>;
 101 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 102   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 103 ]>;
 104 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 105   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 106 ]>;
 107 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 108   SDTCisFP<0>, SDTCisInt<1>
 109 ]>;
 110 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 111   SDTCisInt<0>, SDTCisFP<1>
 112 ]>;
 113 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 114   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 115   SDTCisVTSmallerThanOp<2, 1>
 116 ]>;
 117
 118 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 119   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 120 ]>;
 121
 122 def SDTSelect : SDTypeProfile<1, 3, [ // select
 123   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 124 ]>;
 125
 126 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 127   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 128   SDTCisVT<5, OtherVT>
 129 ]>;
 130
 131 def SDTBr : SDTypeProfile<0, 1, [ // br
 132   SDTCisVT<0, OtherVT>
 133 ]>;
 134
 135 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 136   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 137 ]>;
 138
 139 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 140
 141 def SDTReadPort : SDTypeProfile<1, 1, [ // readport
 142   SDTCisInt<0>, SDTCisInt<1>
 143 ]>;
 144
 145 def SDTWritePort : SDTypeProfile<0, 2, [ // writeport
 146   SDTCisInt<0>, SDTCisInt<1>
 147 ]>;
 148
 149 def SDTLoad : SDTypeProfile<1, 1, [ // load
 150   SDTCisPtrTy<1>
 151 ]>;
 152
 153 def SDTStore : SDTypeProfile<0, 2, [ // store
 154   SDTCisPtrTy<1>
 155 ]>;
 156
 157 def SDTExtLoad : SDTypeProfile<1, 3, [  // extload
 158   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 159 ]>;
 160 def SDTIntExtLoad : SDTypeProfile<1, 3, [  // sextload, zextload
 161   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 162 ]>;
 163 def SDTTruncStore : SDTypeProfile<0, 4, [  // truncstore
 164   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 165 ]>;
 166
 167
 168 //===----------------------------------------------------------------------===//
 169 // Selection DAG Node Properties.
 170 //
 171 // Note: These are hard coded into tblgen.
 172 //
 173 class SDNodeProperty;
 174 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 175 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 176 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 177
 178 //===----------------------------------------------------------------------===//
 179 // Selection DAG Node definitions.
 180 //
 181 class SDNode<string opcode, SDTypeProfile typeprof,
 182              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 183   string Opcode  = opcode;
 184   string SDClass = sdclass;
 185   list<SDNodeProperty> Properties = props;
 186   SDTypeProfile TypeProfile = typeprof;
 187 }
 188
 189 def set;
 190 def node;
 191 def srcvalue;
 192
 193 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 194 def fpimm      : SDNode<"ISD::ConstantFP", SDTFPLeaf  , [], "ConstantFPSDNode">;
 195 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 196 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 197 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 198 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 199 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 200                         "GlobalAddressSDNode">;
 201 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 202                          "GlobalAddressSDNode">;
 203 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 204                          "ConstantPoolSDNode">;
 205 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 206                          "ConstantPoolSDNode">;
 207 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 208                          "FrameIndexSDNode">;
 209 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 210                          "FrameIndexSDNode">;
 211 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 212                          "ExternalSymbolSDNode">;
 213 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 214                          "ExternalSymbolSDNode">;
 215
 216 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 217                         [SDNPCommutative, SDNPAssociative]>;
 218 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 219 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 220                         [SDNPCommutative, SDNPAssociative]>;
 221 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 222 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 223 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 224 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 225 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 226 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 227 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 228 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 229 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 230 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 231                         [SDNPCommutative, SDNPAssociative]>;
 232 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 233                         [SDNPCommutative, SDNPAssociative]>;
 234 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 235                         [SDNPCommutative, SDNPAssociative]>;
 236
 237 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 238 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 239 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 240 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 241 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 242 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 243 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 244 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 245
 246 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 247 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 248 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 249 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 250 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 251 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 252 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 253 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 254 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 255 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 256
 257 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 258 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 259
 260 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 261 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 262 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 263 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 264
 265 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 266 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 267 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 268
 269 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 270 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 271 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 272
 273 def readport   : SDNode<"ISD::READPORT"   , SDTReadPort,  [SDNPHasChain]>;
 274 def writeport  : SDNode<"ISD::WRITEPORT"  , SDTWritePort, [SDNPHasChain]>;
 275
 276 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 277 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 278
 279 // Do not use sextld and zextld directly. Use sextload and zextload (see
 280 // below) which pass in a dummy srcvalue node which tblgen will skip over.
 281 def sextld     : SDNode<"ISD::SEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 282 def zextld     : SDNode<"ISD::ZEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 283 def extld      : SDNode<"ISD::EXTLOAD"    , SDTExtLoad,    [SDNPHasChain]>;
 284 def truncst    : SDNode<"ISD::TRUNCSTORE" , SDTTruncStore, [SDNPHasChain]>;
 285
 286 //===----------------------------------------------------------------------===//
 287 // Selection DAG Condition Codes
 288
 289 class CondCode; // ISD::CondCode enums
 290 def SETOEQ : CondCode; def SETOGT : CondCode;
 291 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 292 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 293 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 294 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 295
 296 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 297 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 298
 299
 300 //===----------------------------------------------------------------------===//
 301 // Selection DAG Node Transformation Functions.
 302 //
 303 // This mechanism allows targets to manipulate nodes in the output DAG once a
 304 // match has been formed.  This is typically used to manipulate immediate
 305 // values.
 306 //
 307 class SDNodeXForm<SDNode opc, code xformFunction> {
 308   SDNode Opcode = opc;
 309   code XFormFunction = xformFunction;
 310 }
 311
 312 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 313
 314
 315 //===----------------------------------------------------------------------===//
 316 // Selection DAG Pattern Fragments.
 317 //
 318 // Pattern fragments are reusable chunks of dags that match specific things.
 319 // They can take arguments and have C++ predicates that control whether they
 320 // match.  They are intended to make the patterns for common instructions more
 321 // compact and readable.
 322 //
 323
 324 /// PatFrag - Represents a pattern fragment.  This can match something on the
 325 /// DAG, frame a single node to multiply nested other fragments.
 326 ///
 327 class PatFrag<dag ops, dag frag, code pred = [{}],
 328               SDNodeXForm xform = NOOP_SDNodeXForm> {
 329   dag Operands = ops;
 330   dag Fragment = frag;
 331   code Predicate = pred;
 332   SDNodeXForm OperandTransform = xform;
 333 }
 334
 335 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 336 // to define immediates and other common things concisely.
 337 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 338  : PatFrag<(ops), frag, pred, xform>;
 339
 340 // Leaf fragments.
 341
 342 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 343
 344 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 345 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 346
 347 // Other helper fragments.
 348
 349 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 350 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 351
 352 // extending load & truncstore fragments.
 353 def sextload      : PatFrag<(ops node:$ptr, node:$vt),
 354                             (sextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 355 def zextload      : PatFrag<(ops node:$ptr, node:$vt),
 356                             (zextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 357 def extload       : PatFrag<(ops node:$ptr, node:$vt),
 358                             (extld node:$ptr, srcvalue:$dummy, node:$vt)>;
 359 def truncstore    : PatFrag<(ops node:$val, node:$ptr, node:$vt),
 360                             (truncst node:$val, node:$ptr, srcvalue:$dummy,
 361                             node:$vt)>;
 362
 363 // setcc convenience fragments.
 364 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 365                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 366 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 367                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 368 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 369                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 370 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 371                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 372 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 373                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 374 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 375                      (setcc node:$lhs, node:$rhs, SETONE)>;
 376 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 377                      (setcc node:$lhs, node:$rhs, SETO)>;
 378 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 379                      (setcc node:$lhs, node:$rhs, SETUO)>;
 380 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 381                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 382 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 383                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 384 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 385                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 386 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 387                      (setcc node:$lhs, node:$rhs, SETULT)>;
 388 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 389                      (setcc node:$lhs, node:$rhs, SETULE)>;
 390 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 391                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 392 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 393                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 394 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 395                      (setcc node:$lhs, node:$rhs, SETGT)>;
 396 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 397                      (setcc node:$lhs, node:$rhs, SETGE)>;
 398 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 399                      (setcc node:$lhs, node:$rhs, SETLT)>;
 400 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 401                      (setcc node:$lhs, node:$rhs, SETLE)>;
 402 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 403                      (setcc node:$lhs, node:$rhs, SETNE)>;
 404
 405 //===----------------------------------------------------------------------===//
 406 // Selection DAG Pattern Support.
 407 //
 408 // Patterns are what are actually matched against the target-flavored
 409 // instruction selection DAG.  Instructions defined by the target implicitly
 410 // define patterns in most cases, but patterns can also be explicitly added when
 411 // an operation is defined by a sequence of instructions (e.g. loading a large
 412 // immediate value on RISC targets that do not support immediates as large as
 413 // their GPRs).
 414 //
 415
 416 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 417   dag             PatternToMatch = patternToMatch;
 418   list<dag>       ResultInstrs   = resultInstrs;
 419   list<Predicate> Predicates     = [];  // See class Instruction in Target.td.
 420 }
 421
 422 // Pat - A simple (but common) form of a pattern, which produces a simple result
 423 // not needing a full list.
 424 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 425
 426 //===----------------------------------------------------------------------===//
 427 // Complex pattern definitions.
 428 //
 429 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 430 // in C++. NumOperands is the number of operands returned by the select function;
 431 // SelectFunc is the name of the function used to pattern match the max. pattern;
 432 // RootNodes are the list of possible root nodes of the sub-dags to match.
 433 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 434 //
 435 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 436   ValueType Ty = ty;
 437   int NumOperands = numops;
 438   string SelectFunc = fn;
 439   list<SDNode> RootNodes = roots;
 440 }
 441
 442 //===----------------------------------------------------------------------===//
 443 // Dwarf support.
 444 //
 445 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 446                       [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 447 def dwarf_loc : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 448
 449 def SDT_dwarf_label : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 450 def dwarf_label : SDNode<"ISD::DEBUG_LABEL", SDT_dwarf_label,[SDNPHasChain]>;
 451
 452
 453