lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 //===----------------------------------------------------------------------===//
  55 // Selection DAG Type Profile definitions.
  56 //
  57 // These use the constraints defined above to describe the type requirements of
  58 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  59 // add their own if needed.
  60 //
  61
  62 // SDTypeProfile - This profile describes the type requirements of a Selection
  63 // DAG node.
  64 class SDTypeProfile<int numresults, int numoperands,
  65                     list<SDTypeConstraint> constraints> {
  66   int NumResults = numresults;
  67   int NumOperands = numoperands;
  68   list<SDTypeConstraint> Constraints = constraints;
  69 }
  70
  71 // Builtin profiles.
  72 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  73 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  74 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  75 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  76 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  77   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  78 ]>;
  79 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  80   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  81 ]>;
  82 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  83   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  84 ]>;
  85 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
  86   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
  87 ]>;
  88 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  89   SDTCisSameAs<0, 1>, SDTCisInt<0>
  90 ]>;
  91 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
  92   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
  93 ]>;
  94 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
  95   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
  96 ]>;
  97 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
  98   SDTCisSameAs<0, 1>, SDTCisFP<0>
  99 ]>;
 100 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 101   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 102 ]>;
 103 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 104   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 105 ]>;
 106 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 107   SDTCisFP<0>, SDTCisInt<1>
 108 ]>;
 109 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 110   SDTCisInt<0>, SDTCisFP<1>
 111 ]>;
 112 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 113   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 114   SDTCisVTSmallerThanOp<2, 1>
 115 ]>;
 116
 117 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 118   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 119 ]>;
 120
 121 def SDTSelect : SDTypeProfile<1, 3, [ // select
 122   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 123 ]>;
 124
 125 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 126   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 127   SDTCisVT<5, OtherVT>
 128 ]>;
 129
 130 def SDTBr : SDTypeProfile<0, 1, [ // br
 131   SDTCisVT<0, OtherVT>
 132 ]>;
 133
 134 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 135   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 136 ]>;
 137
 138 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 139
 140 def SDTReadPort : SDTypeProfile<1, 1, [ // readport
 141   SDTCisInt<0>, SDTCisInt<1>
 142 ]>;
 143
 144 def SDTWritePort : SDTypeProfile<0, 2, [ // writeport
 145   SDTCisInt<0>, SDTCisInt<1>
 146 ]>;
 147
 148 def SDTLoad : SDTypeProfile<1, 1, [ // load
 149   SDTCisPtrTy<1>
 150 ]>;
 151
 152 def SDTStore : SDTypeProfile<0, 2, [ // store
 153   SDTCisPtrTy<1>
 154 ]>;
 155
 156 def SDTExtLoad : SDTypeProfile<1, 3, [  // extload
 157   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 158 ]>;
 159 def SDTIntExtLoad : SDTypeProfile<1, 3, [  // sextload, zextload
 160   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 161 ]>;
 162 def SDTTruncStore : SDTypeProfile<0, 4, [  // truncstore
 163   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 164 ]>;
 165
 166
 167 //===----------------------------------------------------------------------===//
 168 // Selection DAG Node Properties.
 169 //
 170 // Note: These are hard coded into tblgen.
 171 //
 172 class SDNodeProperty;
 173 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 174 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 175 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 176
 177 //===----------------------------------------------------------------------===//
 178 // Selection DAG Node definitions.
 179 //
 180 class SDNode<string opcode, SDTypeProfile typeprof,
 181              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 182   string Opcode  = opcode;
 183   string SDClass = sdclass;
 184   list<SDNodeProperty> Properties = props;
 185   SDTypeProfile TypeProfile = typeprof;
 186 }
 187
 188 def set;
 189 def node;
 190 def srcvalue;
 191
 192 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 193 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 194 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 195 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 196 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 197 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 198                         "GlobalAddressSDNode">;
 199 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 200                          "GlobalAddressSDNode">;
 201 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 202                          "ConstantPoolSDNode">;
 203 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 204                          "ConstantPoolSDNode">;
 205 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 206                          "FrameIndexSDNode">;
 207 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 208                          "FrameIndexSDNode">;
 209 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 210                          "ExternalSymbolSDNode">;
 211 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 212                          "ExternalSymbolSDNode">;
 213
 214 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 215                         [SDNPCommutative, SDNPAssociative]>;
 216 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 217 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 218                         [SDNPCommutative, SDNPAssociative]>;
 219 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 220 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 221 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 222 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 223 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 224 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 225 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 226 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 227 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 228 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 229                         [SDNPCommutative, SDNPAssociative]>;
 230 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 231                         [SDNPCommutative, SDNPAssociative]>;
 232 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 233                         [SDNPCommutative, SDNPAssociative]>;
 234
 235 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 236 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 237 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 238 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 239 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 240 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 241 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 242 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 243
 244 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 245 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 246 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 247 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 248 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 249 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 250 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 251 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 252 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 253 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 254
 255 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 256 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 257
 258 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 259 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 260 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 261 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 262
 263 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 264 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 265 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 266
 267 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 268 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 269 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 270
 271 def readport   : SDNode<"ISD::READPORT"   , SDTReadPort,  [SDNPHasChain]>;
 272 def writeport  : SDNode<"ISD::WRITEPORT"  , SDTWritePort, [SDNPHasChain]>;
 273
 274 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 275 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 276
 277 // Do not use sextld and zextld directly. Use sextload and zextload (see
 278 // below) which pass in a dummy srcvalue node which tblgen will skip over.
 279 def sextld     : SDNode<"ISD::SEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 280 def zextld     : SDNode<"ISD::ZEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 281 def extld      : SDNode<"ISD::EXTLOAD"    , SDTExtLoad,    [SDNPHasChain]>;
 282 def truncst    : SDNode<"ISD::TRUNCSTORE" , SDTTruncStore, [SDNPHasChain]>;
 283
 284 //===----------------------------------------------------------------------===//
 285 // Selection DAG Condition Codes
 286
 287 class CondCode; // ISD::CondCode enums
 288 def SETOEQ : CondCode; def SETOGT : CondCode;
 289 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 290 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 291 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 292 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 293
 294 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 295 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 296
 297
 298 //===----------------------------------------------------------------------===//
 299 // Selection DAG Node Transformation Functions.
 300 //
 301 // This mechanism allows targets to manipulate nodes in the output DAG once a
 302 // match has been formed.  This is typically used to manipulate immediate
 303 // values.
 304 //
 305 class SDNodeXForm<SDNode opc, code xformFunction> {
 306   SDNode Opcode = opc;
 307   code XFormFunction = xformFunction;
 308 }
 309
 310 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 311
 312
 313 //===----------------------------------------------------------------------===//
 314 // Selection DAG Pattern Fragments.
 315 //
 316 // Pattern fragments are reusable chunks of dags that match specific things.
 317 // They can take arguments and have C++ predicates that control whether they
 318 // match.  They are intended to make the patterns for common instructions more
 319 // compact and readable.
 320 //
 321
 322 /// PatFrag - Represents a pattern fragment.  This can match something on the
 323 /// DAG, frame a single node to multiply nested other fragments.
 324 ///
 325 class PatFrag<dag ops, dag frag, code pred = [{}],
 326               SDNodeXForm xform = NOOP_SDNodeXForm> {
 327   dag Operands = ops;
 328   dag Fragment = frag;
 329   code Predicate = pred;
 330   SDNodeXForm OperandTransform = xform;
 331 }
 332
 333 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 334 // to define immediates and other common things concisely.
 335 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 336  : PatFrag<(ops), frag, pred, xform>;
 337
 338 // Leaf fragments.
 339
 340 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 341
 342 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 343 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 344
 345 // Other helper fragments.
 346
 347 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 348 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 349
 350 // extending load & truncstore fragments.
 351 def sextload      : PatFrag<(ops node:$ptr, node:$vt),
 352                             (sextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 353 def zextload      : PatFrag<(ops node:$ptr, node:$vt),
 354                             (zextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 355 def extload       : PatFrag<(ops node:$ptr, node:$vt),
 356                             (extld node:$ptr, srcvalue:$dummy, node:$vt)>;
 357 def truncstore    : PatFrag<(ops node:$val, node:$ptr, node:$vt),
 358                             (truncst node:$val, node:$ptr, srcvalue:$dummy,
 359                             node:$vt)>;
 360
 361 // setcc convenience fragments.
 362 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 363                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 364 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 365                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 366 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 367                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 368 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 369                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 370 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 371                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 372 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 373                      (setcc node:$lhs, node:$rhs, SETONE)>;
 374 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 375                      (setcc node:$lhs, node:$rhs, SETO)>;
 376 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 377                      (setcc node:$lhs, node:$rhs, SETUO)>;
 378 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 379                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 380 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 381                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 382 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 383                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 384 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 385                      (setcc node:$lhs, node:$rhs, SETULT)>;
 386 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 387                      (setcc node:$lhs, node:$rhs, SETULE)>;
 388 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 389                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 390 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 391                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 392 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 393                      (setcc node:$lhs, node:$rhs, SETGT)>;
 394 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 395                      (setcc node:$lhs, node:$rhs, SETGE)>;
 396 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 397                      (setcc node:$lhs, node:$rhs, SETLT)>;
 398 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 399                      (setcc node:$lhs, node:$rhs, SETLE)>;
 400 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 401                      (setcc node:$lhs, node:$rhs, SETNE)>;
 402
 403 //===----------------------------------------------------------------------===//
 404 // Selection DAG Pattern Support.
 405 //
 406 // Patterns are what are actually matched against the target-flavored
 407 // instruction selection DAG.  Instructions defined by the target implicitly
 408 // define patterns in most cases, but patterns can also be explicitly added when
 409 // an operation is defined by a sequence of instructions (e.g. loading a large
 410 // immediate value on RISC targets that do not support immediates as large as
 411 // their GPRs).
 412 //
 413
 414 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 415   dag             PatternToMatch = patternToMatch;
 416   list<dag>       ResultInstrs   = resultInstrs;
 417   list<Predicate> Predicates     = [];  // See class Instruction in Target.td.
 418 }
 419
 420 // Pat - A simple (but common) form of a pattern, which produces a simple result
 421 // not needing a full list.
 422 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 423
 424 //===----------------------------------------------------------------------===//
 425 // Complex pattern definitions.
 426 //
 427 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 428 // in C++. NumOperands is the number of operands returned by the select function;
 429 // SelectFunc is the name of the function used to pattern match the max. pattern;
 430 // RootNodes are the list of possible root nodes of the sub-dags to match.
 431 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 432 //
 433 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 434   ValueType Ty = ty;
 435   int NumOperands = numops;
 436   string SelectFunc = fn;
 437   list<SDNode> RootNodes = roots;
 438 }
 439
 440 //===----------------------------------------------------------------------===//
 441 // Dwarf support.
 442 //
 443 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 444                                     [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 445 def dwarf_loc  : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 446
 447
 448