lib/Target/TargetSelectionDAG.td

   1 //===- TargetSelectionDAG.td - Common code for DAG isels ---*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the LLVM research group and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file defines the target-independent interfaces used by SelectionDAG
  11 // instruction selection generators.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 //===----------------------------------------------------------------------===//
  16 // Selection DAG Type Constraint definitions.
  17 //
  18 // Note that the semantics of these constraints are hard coded into tblgen.  To
  19 // modify or add constraints, you have to hack tblgen.
  20 //
  21
  22 class SDTypeConstraint<int opnum> {
  23   int OperandNum = opnum;
  24 }
  25
  26 // SDTCisVT - The specified operand has exactly this VT.
  27 class SDTCisVT<int OpNum, ValueType vt> : SDTypeConstraint<OpNum> {
  28   ValueType VT = vt;
  29 }
  30
  31 class SDTCisPtrTy<int OpNum> : SDTypeConstraint<OpNum>;
  32
  33 // SDTCisInt - The specified operand is has integer type.
  34 class SDTCisInt<int OpNum> : SDTypeConstraint<OpNum>;
  35
  36 // SDTCisFP - The specified operand is has floating point type.
  37 class SDTCisFP<int OpNum> : SDTypeConstraint<OpNum>;
  38
  39 // SDTCisSameAs - The two specified operands have identical types.
  40 class SDTCisSameAs<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  41   int OtherOperandNum = OtherOp;
  42 }
  43
  44 // SDTCisVTSmallerThanOp - The specified operand is a VT SDNode, and its type is
  45 // smaller than the 'Other' operand.
  46 class SDTCisVTSmallerThanOp<int OpNum, int OtherOp> : SDTypeConstraint<OpNum> {
  47   int OtherOperandNum = OtherOp;
  48 }
  49
  50 class SDTCisOpSmallerThanOp<int SmallOp, int BigOp> : SDTypeConstraint<SmallOp>{
  51   int BigOperandNum = BigOp;
  52 }
  53
  54 //===----------------------------------------------------------------------===//
  55 // Selection DAG Type Profile definitions.
  56 //
  57 // These use the constraints defined above to describe the type requirements of
  58 // the various nodes.  These are not hard coded into tblgen, allowing targets to
  59 // add their own if needed.
  60 //
  61
  62 // SDTypeProfile - This profile describes the type requirements of a Selection
  63 // DAG node.
  64 class SDTypeProfile<int numresults, int numoperands,
  65                     list<SDTypeConstraint> constraints> {
  66   int NumResults = numresults;
  67   int NumOperands = numoperands;
  68   list<SDTypeConstraint> Constraints = constraints;
  69 }
  70
  71 // Builtin profiles.
  72 def SDTIntLeaf: SDTypeProfile<1, 0, [SDTCisInt<0>]>;      // for 'imm'.
  73 def SDTFPLeaf : SDTypeProfile<1, 0, [SDTCisFP<0>]>;       // for 'fpimm'.
  74 def SDTPtrLeaf: SDTypeProfile<1, 0, [SDTCisPtrTy<0>]>;      // for '&g'.
  75 def SDTOther  : SDTypeProfile<1, 0, [SDTCisVT<0, OtherVT>]>; // for 'vt'.
  76 def SDTUNDEF  : SDTypeProfile<1, 0, []>; // for 'undef'.
  77 def SDTIntBinOp : SDTypeProfile<1, 2, [   // add, and, or, xor, udiv, etc.
  78   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisInt<0>
  79 ]>;
  80 def SDTIntShiftOp : SDTypeProfile<1, 2, [   // shl, sra, srl
  81   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisInt<2>
  82 ]>;
  83 def SDTFPBinOp : SDTypeProfile<1, 2, [      // fadd, fmul, etc.
  84   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisFP<0>
  85 ]>;
  86 def SDTFPTernaryOp : SDTypeProfile<1, 3, [      // fmadd, fnmsub, etc.
  87   SDTCisSameAs<0, 1>, SDTCisSameAs<0, 2>, SDTCisSameAs<0, 3>, SDTCisFP<0>
  88 ]>;
  89 def SDTIntUnaryOp : SDTypeProfile<1, 1, [   // ctlz
  90   SDTCisSameAs<0, 1>, SDTCisInt<0>
  91 ]>;
  92 def SDTIntExtendOp : SDTypeProfile<1, 1, [  // sext, zext, anyext
  93   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<1, 0>
  94 ]>;
  95 def SDTIntTruncOp  : SDTypeProfile<1, 1, [  // trunc
  96   SDTCisInt<0>, SDTCisInt<1>, SDTCisOpSmallerThanOp<0, 1>
  97 ]>;
  98 def SDTFPUnaryOp  : SDTypeProfile<1, 1, [   // fneg, fsqrt, etc
  99   SDTCisSameAs<0, 1>, SDTCisFP<0>
 100 ]>;
 101 def SDTFPRoundOp  : SDTypeProfile<1, 1, [   // fround
 102   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<0, 1>
 103 ]>;
 104 def SDTFPExtendOp  : SDTypeProfile<1, 1, [   // fextend
 105   SDTCisFP<0>, SDTCisFP<1>, SDTCisOpSmallerThanOp<1, 0>
 106 ]>;
 107 def SDTIntToFPOp : SDTypeProfile<1, 1, [   // [su]int_to_fp
 108   SDTCisFP<0>, SDTCisInt<1>
 109 ]>;
 110 def SDTFPToIntOp : SDTypeProfile<1, 1, [   // fp_to_[su]int
 111   SDTCisInt<0>, SDTCisFP<1>
 112 ]>;
 113 def SDTExtInreg : SDTypeProfile<1, 2, [   // sext_inreg
 114   SDTCisSameAs<0, 1>, SDTCisInt<0>, SDTCisVT<2, OtherVT>,
 115   SDTCisVTSmallerThanOp<2, 1>
 116 ]>;
 117
 118 def SDTSetCC : SDTypeProfile<1, 3, [ // setcc
 119   SDTCisInt<0>, SDTCisSameAs<1, 2>, SDTCisVT<3, OtherVT>
 120 ]>;
 121
 122 def SDTSelect : SDTypeProfile<1, 3, [ // select
 123   SDTCisInt<1>, SDTCisSameAs<0, 2>, SDTCisSameAs<2, 3>
 124 ]>;
 125
 126 def SDTSelectCC : SDTypeProfile<1, 5, [ // select_cc
 127   SDTCisSameAs<1, 2>, SDTCisSameAs<3, 4>, SDTCisSameAs<0, 3>,
 128   SDTCisVT<5, OtherVT>
 129 ]>;
 130
 131 def SDTBr : SDTypeProfile<0, 1, [ // br
 132   SDTCisVT<0, OtherVT>
 133 ]>;
 134
 135 def SDTBrcond : SDTypeProfile<0, 2, [ // brcond
 136   SDTCisInt<0>, SDTCisVT<1, OtherVT>
 137 ]>;
 138
 139 def SDTRet : SDTypeProfile<0, 0, []>; // ret
 140
 141 def SDTReadPort : SDTypeProfile<1, 1, [ // readport
 142   SDTCisInt<0>, SDTCisInt<1>
 143 ]>;
 144
 145 def SDTWritePort : SDTypeProfile<0, 2, [ // writeport
 146   SDTCisInt<0>, SDTCisInt<1>
 147 ]>;
 148
 149 def SDTLoad : SDTypeProfile<1, 1, [ // load
 150   SDTCisPtrTy<1>
 151 ]>;
 152
 153 def SDTStore : SDTypeProfile<0, 2, [ // store
 154   SDTCisPtrTy<1>
 155 ]>;
 156
 157 def SDTExtLoad : SDTypeProfile<1, 3, [  // extload
 158   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 159 ]>;
 160 def SDTIntExtLoad : SDTypeProfile<1, 3, [  // sextload, zextload
 161   SDTCisInt<0>, SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 162 ]>;
 163 def SDTTruncStore : SDTypeProfile<0, 4, [  // truncstore
 164   SDTCisPtrTy<1>, SDTCisVT<2, OtherVT>, SDTCisVT<3, OtherVT>
 165 ]>;
 166
 167 //===----------------------------------------------------------------------===//
 168 // Selection DAG Node Properties.
 169 //
 170 // Note: These are hard coded into tblgen.
 171 //
 172 class SDNodeProperty;
 173 def SDNPCommutative : SDNodeProperty;   // X op Y == Y op X
 174 def SDNPAssociative : SDNodeProperty;   // (X op Y) op Z == X op (Y op Z)
 175 def SDNPHasChain    : SDNodeProperty;   // R/W chain operand and result
 176 def SDNPOutFlag     : SDNodeProperty;   // Write a flag result
 177 def SDNPInFlag      : SDNodeProperty;   // Read a flag operand
 178 def SDNPOptInFlag   : SDNodeProperty;   // Optionally read a flag operand
 179
 180 //===----------------------------------------------------------------------===//
 181 // Selection DAG Node definitions.
 182 //
 183 class SDNode<string opcode, SDTypeProfile typeprof,
 184              list<SDNodeProperty> props = [], string sdclass = "SDNode"> {
 185   string Opcode  = opcode;
 186   string SDClass = sdclass;
 187   list<SDNodeProperty> Properties = props;
 188   SDTypeProfile TypeProfile = typeprof;
 189 }
 190
 191 def set;
 192 def node;
 193 def srcvalue;
 194
 195 def imm        : SDNode<"ISD::Constant"  , SDTIntLeaf , [], "ConstantSDNode">;
 196 def fpimm      : SDNode<"ISD::TargetConstantFP",
 197                          SDTFPLeaf, [], "ConstantFPSDNode">;
 198 def vt         : SDNode<"ISD::VALUETYPE" , SDTOther   , [], "VTSDNode">;
 199 def bb         : SDNode<"ISD::BasicBlock", SDTOther   , [], "BasicBlockSDNode">;
 200 def cond       : SDNode<"ISD::CONDCODE"  , SDTOther   , [], "CondCodeSDNode">;
 201 def undef      : SDNode<"ISD::UNDEF"     , SDTUNDEF   , []>;
 202 def globaladdr : SDNode<"ISD::GlobalAddress",         SDTPtrLeaf, [],
 203                         "GlobalAddressSDNode">;
 204 def tglobaladdr : SDNode<"ISD::TargetGlobalAddress",  SDTPtrLeaf, [],
 205                          "GlobalAddressSDNode">;
 206 def constpool   : SDNode<"ISD::ConstantPool",         SDTPtrLeaf, [],
 207                          "ConstantPoolSDNode">;
 208 def tconstpool  : SDNode<"ISD::TargetConstantPool",   SDTPtrLeaf, [],
 209                          "ConstantPoolSDNode">;
 210 def frameindex  : SDNode<"ISD::FrameIndex",           SDTPtrLeaf, [],
 211                          "FrameIndexSDNode">;
 212 def tframeindex : SDNode<"ISD::TargetFrameIndex",     SDTPtrLeaf, [],
 213                          "FrameIndexSDNode">;
 214 def externalsym : SDNode<"ISD::ExternalSymbol",       SDTPtrLeaf, [],
 215                          "ExternalSymbolSDNode">;
 216 def texternalsym: SDNode<"ISD::TargetExternalSymbol", SDTPtrLeaf, [],
 217                          "ExternalSymbolSDNode">;
 218
 219 def add        : SDNode<"ISD::ADD"       , SDTIntBinOp   ,
 220                         [SDNPCommutative, SDNPAssociative]>;
 221 def sub        : SDNode<"ISD::SUB"       , SDTIntBinOp>;
 222 def mul        : SDNode<"ISD::MUL"       , SDTIntBinOp,
 223                         [SDNPCommutative, SDNPAssociative]>;
 224 def mulhs      : SDNode<"ISD::MULHS"     , SDTIntBinOp, [SDNPCommutative]>;
 225 def mulhu      : SDNode<"ISD::MULHU"     , SDTIntBinOp, [SDNPCommutative]>;
 226 def sdiv       : SDNode<"ISD::SDIV"      , SDTIntBinOp>;
 227 def udiv       : SDNode<"ISD::UDIV"      , SDTIntBinOp>;
 228 def srem       : SDNode<"ISD::SREM"      , SDTIntBinOp>;
 229 def urem       : SDNode<"ISD::UREM"      , SDTIntBinOp>;
 230 def srl        : SDNode<"ISD::SRL"       , SDTIntShiftOp>;
 231 def sra        : SDNode<"ISD::SRA"       , SDTIntShiftOp>;
 232 def shl        : SDNode<"ISD::SHL"       , SDTIntShiftOp>;
 233 def rotl       : SDNode<"ISD::ROTL"      , SDTIntShiftOp>;
 234 def rotr       : SDNode<"ISD::ROTR"      , SDTIntShiftOp>;
 235 def and        : SDNode<"ISD::AND"       , SDTIntBinOp,
 236                         [SDNPCommutative, SDNPAssociative]>;
 237 def or         : SDNode<"ISD::OR"        , SDTIntBinOp,
 238                         [SDNPCommutative, SDNPAssociative]>;
 239 def xor        : SDNode<"ISD::XOR"       , SDTIntBinOp,
 240                         [SDNPCommutative, SDNPAssociative]>;
 241 def addc       : SDNode<"ISD::ADDC"      , SDTIntBinOp,
 242                         [SDNPCommutative, SDNPOutFlag]>;
 243 def adde       : SDNode<"ISD::ADDE"      , SDTIntBinOp,
 244                         [SDNPCommutative, SDNPOutFlag, SDNPInFlag]>;
 245 def subc       : SDNode<"ISD::SUBC"      , SDTIntBinOp,
 246                         [SDNPOutFlag]>;
 247 def sube       : SDNode<"ISD::SUBE"      , SDTIntBinOp,
 248                         [SDNPOutFlag, SDNPInFlag]>;
 249
 250 def sext_inreg : SDNode<"ISD::SIGN_EXTEND_INREG", SDTExtInreg>;
 251 def bswap      : SDNode<"ISD::BSWAP"      , SDTIntUnaryOp>;
 252 def ctlz       : SDNode<"ISD::CTLZ"       , SDTIntUnaryOp>;
 253 def cttz       : SDNode<"ISD::CTTZ"       , SDTIntUnaryOp>;
 254 def ctpop      : SDNode<"ISD::CTPOP"      , SDTIntUnaryOp>;
 255 def sext       : SDNode<"ISD::SIGN_EXTEND", SDTIntExtendOp>;
 256 def zext       : SDNode<"ISD::ZERO_EXTEND", SDTIntExtendOp>;
 257 def anyext     : SDNode<"ISD::ANY_EXTEND" , SDTIntExtendOp>;
 258 def trunc      : SDNode<"ISD::TRUNCATE"   , SDTIntTruncOp>;
 259
 260 def fadd       : SDNode<"ISD::FADD"       , SDTFPBinOp, [SDNPCommutative]>;
 261 def fsub       : SDNode<"ISD::FSUB"       , SDTFPBinOp>;
 262 def fmul       : SDNode<"ISD::FMUL"       , SDTFPBinOp, [SDNPCommutative]>;
 263 def fdiv       : SDNode<"ISD::FDIV"       , SDTFPBinOp>;
 264 def frem       : SDNode<"ISD::FREM"       , SDTFPBinOp>;
 265 def fabs       : SDNode<"ISD::FABS"       , SDTFPUnaryOp>;
 266 def fneg       : SDNode<"ISD::FNEG"       , SDTFPUnaryOp>;
 267 def fsqrt      : SDNode<"ISD::FSQRT"      , SDTFPUnaryOp>;
 268 def fsin       : SDNode<"ISD::FSIN"       , SDTFPUnaryOp>;
 269 def fcos       : SDNode<"ISD::FCOS"       , SDTFPUnaryOp>;
 270
 271 def fround     : SDNode<"ISD::FP_ROUND"   , SDTFPRoundOp>;
 272 def fextend    : SDNode<"ISD::FP_EXTEND"  , SDTFPExtendOp>;
 273
 274 def sint_to_fp : SDNode<"ISD::SINT_TO_FP" , SDTIntToFPOp>;
 275 def uint_to_fp : SDNode<"ISD::UINT_TO_FP" , SDTIntToFPOp>;
 276 def fp_to_sint : SDNode<"ISD::FP_TO_SINT" , SDTFPToIntOp>;
 277 def fp_to_uint : SDNode<"ISD::FP_TO_UINT" , SDTFPToIntOp>;
 278
 279 def setcc      : SDNode<"ISD::SETCC"      , SDTSetCC>;
 280 def select     : SDNode<"ISD::SELECT"     , SDTSelect>;
 281 def selectcc   : SDNode<"ISD::SELECT_CC"  , SDTSelectCC>;
 282
 283 def brcond     : SDNode<"ISD::BRCOND"     , SDTBrcond, [SDNPHasChain]>;
 284 def br         : SDNode<"ISD::BR"         , SDTBr,     [SDNPHasChain]>;
 285 def ret        : SDNode<"ISD::RET"        , SDTRet,    [SDNPHasChain]>;
 286
 287 def readport   : SDNode<"ISD::READPORT"   , SDTReadPort,  [SDNPHasChain]>;
 288 def writeport  : SDNode<"ISD::WRITEPORT"  , SDTWritePort, [SDNPHasChain]>;
 289
 290 def load       : SDNode<"ISD::LOAD"       , SDTLoad,  [SDNPHasChain]>;
 291 def store      : SDNode<"ISD::STORE"      , SDTStore, [SDNPHasChain]>;
 292
 293 // Do not use sextld and zextld directly. Use sextload and zextload (see
 294 // below) which pass in a dummy srcvalue node which tblgen will skip over.
 295 def sextld     : SDNode<"ISD::SEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 296 def zextld     : SDNode<"ISD::ZEXTLOAD"   , SDTIntExtLoad, [SDNPHasChain]>;
 297 def extld      : SDNode<"ISD::EXTLOAD"    , SDTExtLoad,    [SDNPHasChain]>;
 298 def truncst    : SDNode<"ISD::TRUNCSTORE" , SDTTruncStore, [SDNPHasChain]>;
 299
 300 //===----------------------------------------------------------------------===//
 301 // Selection DAG Condition Codes
 302
 303 class CondCode; // ISD::CondCode enums
 304 def SETOEQ : CondCode; def SETOGT : CondCode;
 305 def SETOGE : CondCode; def SETOLT : CondCode; def SETOLE : CondCode;
 306 def SETONE : CondCode; def SETO   : CondCode; def SETUO  : CondCode;
 307 def SETUEQ : CondCode; def SETUGT : CondCode; def SETUGE : CondCode;
 308 def SETULT : CondCode; def SETULE : CondCode; def SETUNE : CondCode;
 309
 310 def SETEQ : CondCode; def SETGT : CondCode; def SETGE : CondCode;
 311 def SETLT : CondCode; def SETLE : CondCode; def SETNE : CondCode;
 312
 313
 314 //===----------------------------------------------------------------------===//
 315 // Selection DAG Node Transformation Functions.
 316 //
 317 // This mechanism allows targets to manipulate nodes in the output DAG once a
 318 // match has been formed.  This is typically used to manipulate immediate
 319 // values.
 320 //
 321 class SDNodeXForm<SDNode opc, code xformFunction> {
 322   SDNode Opcode = opc;
 323   code XFormFunction = xformFunction;
 324 }
 325
 326 def NOOP_SDNodeXForm : SDNodeXForm<imm, [{}]>;
 327
 328
 329 //===----------------------------------------------------------------------===//
 330 // Selection DAG Pattern Fragments.
 331 //
 332 // Pattern fragments are reusable chunks of dags that match specific things.
 333 // They can take arguments and have C++ predicates that control whether they
 334 // match.  They are intended to make the patterns for common instructions more
 335 // compact and readable.
 336 //
 337
 338 /// PatFrag - Represents a pattern fragment.  This can match something on the
 339 /// DAG, frame a single node to multiply nested other fragments.
 340 ///
 341 class PatFrag<dag ops, dag frag, code pred = [{}],
 342               SDNodeXForm xform = NOOP_SDNodeXForm> {
 343   dag Operands = ops;
 344   dag Fragment = frag;
 345   code Predicate = pred;
 346   SDNodeXForm OperandTransform = xform;
 347 }
 348
 349 // PatLeaf's are pattern fragments that have no operands.  This is just a helper
 350 // to define immediates and other common things concisely.
 351 class PatLeaf<dag frag, code pred = [{}], SDNodeXForm xform = NOOP_SDNodeXForm>
 352  : PatFrag<(ops), frag, pred, xform>;
 353
 354 // Leaf fragments.
 355
 356 def immAllOnes : PatLeaf<(imm), [{ return N->isAllOnesValue(); }]>;
 357 def immZero    : PatLeaf<(imm), [{ return N->isNullValue(); }]>;
 358 def vtInt      : PatLeaf<(vt),  [{ return MVT::isInteger(N->getVT()); }]>;
 359 def vtFP       : PatLeaf<(vt),  [{ return MVT::isFloatingPoint(N->getVT()); }]>;
 360
 361 // Other helper fragments.
 362
 363 def not  : PatFrag<(ops node:$in), (xor node:$in, immAllOnes)>;
 364 def ineg : PatFrag<(ops node:$in), (sub 0, node:$in)>;
 365
 366 // extending load & truncstore fragments.
 367 def sextload      : PatFrag<(ops node:$ptr, node:$vt),
 368                             (sextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 369 def zextload      : PatFrag<(ops node:$ptr, node:$vt),
 370                             (zextld node:$ptr, srcvalue:$dummy, node:$vt)>;
 371 def extload       : PatFrag<(ops node:$ptr, node:$vt),
 372                             (extld node:$ptr, srcvalue:$dummy, node:$vt)>;
 373 def truncstore    : PatFrag<(ops node:$val, node:$ptr, node:$vt),
 374                             (truncst node:$val, node:$ptr, srcvalue:$dummy,
 375                             node:$vt)>;
 376
 377 // setcc convenience fragments.
 378 def setoeq : PatFrag<(ops node:$lhs, node:$rhs),
 379                      (setcc node:$lhs, node:$rhs, SETOEQ)>;
 380 def setogt : PatFrag<(ops node:$lhs, node:$rhs),
 381                      (setcc node:$lhs, node:$rhs, SETOGT)>;
 382 def setoge : PatFrag<(ops node:$lhs, node:$rhs),
 383                      (setcc node:$lhs, node:$rhs, SETOGE)>;
 384 def setolt : PatFrag<(ops node:$lhs, node:$rhs),
 385                      (setcc node:$lhs, node:$rhs, SETOLT)>;
 386 def setole : PatFrag<(ops node:$lhs, node:$rhs),
 387                      (setcc node:$lhs, node:$rhs, SETOLE)>;
 388 def setone : PatFrag<(ops node:$lhs, node:$rhs),
 389                      (setcc node:$lhs, node:$rhs, SETONE)>;
 390 def seto   : PatFrag<(ops node:$lhs, node:$rhs),
 391                      (setcc node:$lhs, node:$rhs, SETO)>;
 392 def setuo  : PatFrag<(ops node:$lhs, node:$rhs),
 393                      (setcc node:$lhs, node:$rhs, SETUO)>;
 394 def setueq : PatFrag<(ops node:$lhs, node:$rhs),
 395                      (setcc node:$lhs, node:$rhs, SETUEQ)>;
 396 def setugt : PatFrag<(ops node:$lhs, node:$rhs),
 397                      (setcc node:$lhs, node:$rhs, SETUGT)>;
 398 def setuge : PatFrag<(ops node:$lhs, node:$rhs),
 399                      (setcc node:$lhs, node:$rhs, SETUGE)>;
 400 def setult : PatFrag<(ops node:$lhs, node:$rhs),
 401                      (setcc node:$lhs, node:$rhs, SETULT)>;
 402 def setule : PatFrag<(ops node:$lhs, node:$rhs),
 403                      (setcc node:$lhs, node:$rhs, SETULE)>;
 404 def setune : PatFrag<(ops node:$lhs, node:$rhs),
 405                      (setcc node:$lhs, node:$rhs, SETUNE)>;
 406 def seteq  : PatFrag<(ops node:$lhs, node:$rhs),
 407                      (setcc node:$lhs, node:$rhs, SETEQ)>;
 408 def setgt  : PatFrag<(ops node:$lhs, node:$rhs),
 409                      (setcc node:$lhs, node:$rhs, SETGT)>;
 410 def setge  : PatFrag<(ops node:$lhs, node:$rhs),
 411                      (setcc node:$lhs, node:$rhs, SETGE)>;
 412 def setlt  : PatFrag<(ops node:$lhs, node:$rhs),
 413                      (setcc node:$lhs, node:$rhs, SETLT)>;
 414 def setle  : PatFrag<(ops node:$lhs, node:$rhs),
 415                      (setcc node:$lhs, node:$rhs, SETLE)>;
 416 def setne  : PatFrag<(ops node:$lhs, node:$rhs),
 417                      (setcc node:$lhs, node:$rhs, SETNE)>;
 418
 419 //===----------------------------------------------------------------------===//
 420 // Selection DAG Pattern Support.
 421 //
 422 // Patterns are what are actually matched against the target-flavored
 423 // instruction selection DAG.  Instructions defined by the target implicitly
 424 // define patterns in most cases, but patterns can also be explicitly added when
 425 // an operation is defined by a sequence of instructions (e.g. loading a large
 426 // immediate value on RISC targets that do not support immediates as large as
 427 // their GPRs).
 428 //
 429
 430 class Pattern<dag patternToMatch, list<dag> resultInstrs> {
 431   dag             PatternToMatch = patternToMatch;
 432   list<dag>       ResultInstrs   = resultInstrs;
 433   list<Predicate> Predicates     = [];  // See class Instruction in Target.td.
 434 }
 435
 436 // Pat - A simple (but common) form of a pattern, which produces a simple result
 437 // not needing a full list.
 438 class Pat<dag pattern, dag result> : Pattern<pattern, [result]>;
 439
 440 //===----------------------------------------------------------------------===//
 441 // Complex pattern definitions.
 442 //
 443 // Complex patterns, e.g. X86 addressing mode, requires pattern matching code
 444 // in C++. NumOperands is the number of operands returned by the select function;
 445 // SelectFunc is the name of the function used to pattern match the max. pattern;
 446 // RootNodes are the list of possible root nodes of the sub-dags to match.
 447 // e.g. X86 addressing mode - def addr : ComplexPattern<4, "SelectAddr", [add]>;
 448 //
 449 class ComplexPattern<ValueType ty, int numops, string fn, list<SDNode> roots = []> {
 450   ValueType Ty = ty;
 451   int NumOperands = numops;
 452   string SelectFunc = fn;
 453   list<SDNode> RootNodes = roots;
 454 }
 455
 456 //===----------------------------------------------------------------------===//
 457 // Dwarf support.
 458 //
 459 def SDT_dwarf_loc : SDTypeProfile<0, 3,
 460                       [SDTCisInt<0>, SDTCisInt<1>, SDTCisInt<2>]>;
 461 def dwarf_loc : SDNode<"ISD::DEBUG_LOC", SDT_dwarf_loc,[SDNPHasChain]>;
 462
 463 def SDT_dwarf_label : SDTypeProfile<0, 1, [SDTCisInt<0>]>;
 464 def dwarf_label : SDNode<"ISD::DEBUG_LABEL", SDT_dwarf_label,[SDNPHasChain]>;
 465
 466
 467