lib/Target/X86/X86CallingConv.td

   1 //===-- X86CallingConv.td - Calling Conventions X86 32/64 --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This describes the calling conventions for the X86-32 and X86-64
  11 // architectures.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  16 class CCIfSubtarget<string F, CCAction A>
  17     : CCIf<!strconcat("static_cast<const X86Subtarget&>"
  18                        "(State.getMachineFunction().getSubtarget()).", F),
  19            A>;
  20
  21 //===----------------------------------------------------------------------===//
  22 // Return Value Calling Conventions
  23 //===----------------------------------------------------------------------===//
  24
  25 // Return-value conventions common to all X86 CC's.
  26 def RetCC_X86Common : CallingConv<[
  27   // Scalar values are returned in AX first, then DX.  For i8, the ABI
  28   // requires the values to be in AL and AH, however this code uses AL and DL
  29   // instead. This is because using AH for the second register conflicts with
  30   // the way LLVM does multiple return values -- a return of {i16,i8} would end
  31   // up in AX and AH, which overlap. Front-ends wishing to conform to the ABI
  32   // for functions that return two i8 values are currently expected to pack the
  33   // values into an i16 (which uses AX, and thus AL:AH).
  34   //
  35   // For code that doesn't care about the ABI, we allow returning more than two
  36   // integer values in registers.
  37   CCIfType<[i1],  CCPromoteToType<i8>>,
  38   CCIfType<[i8] , CCAssignToReg<[AL, DL, CL]>>,
  39   CCIfType<[i16], CCAssignToReg<[AX, DX, CX]>>,
  40   CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>,
  41   CCIfType<[i64], CCAssignToReg<[RAX, RDX, RCX]>>,
  42
  43   // Boolean vectors of AVX-512 are returned in SIMD registers.
  44   // The call from AVX to AVX-512 function should work,
  45   // since the boolean types in AVX/AVX2 are promoted by default.
  46   CCIfType<[v2i1],  CCPromoteToType<v2i64>>,
  47   CCIfType<[v4i1],  CCPromoteToType<v4i32>>,
  48   CCIfType<[v8i1],  CCPromoteToType<v8i16>>,
  49   CCIfType<[v16i1], CCPromoteToType<v16i8>>,
  50   CCIfType<[v32i1], CCPromoteToType<v32i8>>,
  51   CCIfType<[v64i1], CCPromoteToType<v64i8>>,
  52
  53   // Vector types are returned in XMM0 and XMM1, when they fit.  XMM2 and XMM3
  54   // can only be used by ABI non-compliant code. If the target doesn't have XMM
  55   // registers, it won't have vector types.
  56   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
  57             CCAssignToReg<[XMM0,XMM1,XMM2,XMM3]>>,
  58
  59   // 256-bit vectors are returned in YMM0 and XMM1, when they fit. YMM2 and YMM3
  60   // can only be used by ABI non-compliant code. This vector type is only
  61   // supported while using the AVX target feature.
  62   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
  63             CCAssignToReg<[YMM0,YMM1,YMM2,YMM3]>>,
  64
  65   // 512-bit vectors are returned in ZMM0 and ZMM1, when they fit. ZMM2 and ZMM3
  66   // can only be used by ABI non-compliant code. This vector type is only
  67   // supported while using the AVX-512 target feature.
  68   CCIfType<[v64i8, v32i16, v16i32, v8i64, v16f32, v8f64],
  69             CCAssignToReg<[ZMM0,ZMM1,ZMM2,ZMM3]>>,
  70
  71   // MMX vector types are always returned in MM0. If the target doesn't have
  72   // MM0, it doesn't support these vector types.
  73   CCIfType<[x86mmx], CCAssignToReg<[MM0]>>,
  74
  75   // Long double types are always returned in FP0 (even with SSE).
  76   CCIfType<[f80], CCAssignToReg<[FP0, FP1]>>
  77 ]>;
  78
  79 // X86-32 C return-value convention.
  80 def RetCC_X86_32_C : CallingConv<[
  81   // The X86-32 calling convention returns FP values in FP0, unless marked
  82   // with "inreg" (used here to distinguish one kind of reg from another,
  83   // weirdly; this is really the sse-regparm calling convention) in which
  84   // case they use XMM0, otherwise it is the same as the common X86 calling
  85   // conv.
  86   CCIfInReg<CCIfSubtarget<"hasSSE2()",
  87     CCIfType<[f32, f64], CCAssignToReg<[XMM0,XMM1,XMM2]>>>>,
  88   CCIfType<[f32,f64], CCAssignToReg<[FP0, FP1]>>,
  89   CCDelegateTo<RetCC_X86Common>
  90 ]>;
  91
  92 // X86-32 FastCC return-value convention.
  93 def RetCC_X86_32_Fast : CallingConv<[
  94   // The X86-32 fastcc returns 1, 2, or 3 FP values in XMM0-2 if the target has
  95   // SSE2.
  96   // This can happen when a float, 2 x float, or 3 x float vector is split by
  97   // target lowering, and is returned in 1-3 sse regs.
  98   CCIfType<[f32], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  99   CCIfType<[f64], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
 100
 101   // For integers, ECX can be used as an extra return register
 102   CCIfType<[i8],  CCAssignToReg<[AL, DL, CL]>>,
 103   CCIfType<[i16], CCAssignToReg<[AX, DX, CX]>>,
 104   CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>,
 105
 106   // Otherwise, it is the same as the common X86 calling convention.
 107   CCDelegateTo<RetCC_X86Common>
 108 ]>;
 109
 110 // Intel_OCL_BI return-value convention.
 111 def RetCC_Intel_OCL_BI : CallingConv<[
 112   // Vector types are returned in XMM0,XMM1,XMMM2 and XMM3.
 113   CCIfType<[f32, f64, v4i32, v2i64, v4f32, v2f64],
 114             CCAssignToReg<[XMM0,XMM1,XMM2,XMM3]>>,
 115
 116   // 256-bit FP vectors
 117   // No more than 4 registers
 118   CCIfType<[v8f32, v4f64, v8i32, v4i64],
 119             CCAssignToReg<[YMM0,YMM1,YMM2,YMM3]>>,
 120
 121   // 512-bit FP vectors
 122   CCIfType<[v16f32, v8f64, v16i32, v8i64],
 123             CCAssignToReg<[ZMM0,ZMM1,ZMM2,ZMM3]>>,
 124
 125   // i32, i64 in the standard way
 126   CCDelegateTo<RetCC_X86Common>
 127 ]>;
 128
 129 // X86-32 HiPE return-value convention.
 130 def RetCC_X86_32_HiPE : CallingConv<[
 131   // Promote all types to i32
 132   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 133
 134   // Return: HP, P, VAL1, VAL2
 135   CCIfType<[i32], CCAssignToReg<[ESI, EBP, EAX, EDX]>>
 136 ]>;
 137
 138 // X86-32 HiPE return-value convention.
 139 def RetCC_X86_32_VectorCall : CallingConv<[
 140   // Vector types are returned in XMM0,XMM1,XMMM2 and XMM3.
 141   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 142             CCAssignToReg<[XMM0,XMM1,XMM2,XMM3]>>,
 143
 144   // 256-bit FP vectors
 145   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 146             CCAssignToReg<[YMM0,YMM1,YMM2,YMM3]>>,
 147
 148   // 512-bit FP vectors
 149   CCIfType<[v64i8, v32i16, v16i32, v8i64, v16f32, v8f64],
 150             CCAssignToReg<[ZMM0,ZMM1,ZMM2,ZMM3]>>,
 151
 152   // Return integers in the standard way.
 153   CCDelegateTo<RetCC_X86Common>
 154 ]>;
 155
 156 // X86-64 C return-value convention.
 157 def RetCC_X86_64_C : CallingConv<[
 158   // The X86-64 calling convention always returns FP values in XMM0.
 159   CCIfType<[f32], CCAssignToReg<[XMM0, XMM1]>>,
 160   CCIfType<[f64], CCAssignToReg<[XMM0, XMM1]>>,
 161
 162   // MMX vector types are always returned in XMM0.
 163   CCIfType<[x86mmx], CCAssignToReg<[XMM0, XMM1]>>,
 164   CCDelegateTo<RetCC_X86Common>
 165 ]>;
 166
 167 // X86-Win64 C return-value convention.
 168 def RetCC_X86_Win64_C : CallingConv<[
 169   // The X86-Win64 calling convention always returns __m64 values in RAX.
 170   CCIfType<[x86mmx], CCBitConvertToType<i64>>,
 171
 172   // Otherwise, everything is the same as 'normal' X86-64 C CC.
 173   CCDelegateTo<RetCC_X86_64_C>
 174 ]>;
 175
 176 // X86-64 HiPE return-value convention.
 177 def RetCC_X86_64_HiPE : CallingConv<[
 178   // Promote all types to i64
 179   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 180
 181   // Return: HP, P, VAL1, VAL2
 182   CCIfType<[i64], CCAssignToReg<[R15, RBP, RAX, RDX]>>
 183 ]>;
 184
 185 // X86-64 WebKit_JS return-value convention.
 186 def RetCC_X86_64_WebKit_JS : CallingConv<[
 187   // Promote all types to i64
 188   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 189
 190   // Return: RAX
 191   CCIfType<[i64], CCAssignToReg<[RAX]>>
 192 ]>;
 193
 194 // X86-64 AnyReg return-value convention. No explicit register is specified for
 195 // the return-value. The register allocator is allowed and expected to choose
 196 // any free register.
 197 //
 198 // This calling convention is currently only supported by the stackmap and
 199 // patchpoint intrinsics. All other uses will result in an assert on Debug
 200 // builds. On Release builds we fallback to the X86 C calling convention.
 201 def RetCC_X86_64_AnyReg : CallingConv<[
 202   CCCustom<"CC_X86_AnyReg_Error">
 203 ]>;
 204
 205 // This is the root return-value convention for the X86-32 backend.
 206 def RetCC_X86_32 : CallingConv<[
 207   // If FastCC, use RetCC_X86_32_Fast.
 208   CCIfCC<"CallingConv::Fast", CCDelegateTo<RetCC_X86_32_Fast>>,
 209   // If HiPE, use RetCC_X86_32_HiPE.
 210   CCIfCC<"CallingConv::HiPE", CCDelegateTo<RetCC_X86_32_HiPE>>,
 211   CCIfCC<"CallingConv::X86_VectorCall", CCDelegateTo<RetCC_X86_32_VectorCall>>,
 212
 213   // Otherwise, use RetCC_X86_32_C.
 214   CCDelegateTo<RetCC_X86_32_C>
 215 ]>;
 216
 217 // This is the root return-value convention for the X86-64 backend.
 218 def RetCC_X86_64 : CallingConv<[
 219   // HiPE uses RetCC_X86_64_HiPE
 220   CCIfCC<"CallingConv::HiPE", CCDelegateTo<RetCC_X86_64_HiPE>>,
 221
 222   // Handle JavaScript calls.
 223   CCIfCC<"CallingConv::WebKit_JS", CCDelegateTo<RetCC_X86_64_WebKit_JS>>,
 224   CCIfCC<"CallingConv::AnyReg", CCDelegateTo<RetCC_X86_64_AnyReg>>,
 225
 226   // Handle explicit CC selection
 227   CCIfCC<"CallingConv::X86_64_Win64", CCDelegateTo<RetCC_X86_Win64_C>>,
 228   CCIfCC<"CallingConv::X86_64_SysV", CCDelegateTo<RetCC_X86_64_C>>,
 229
 230   // Mingw64 and native Win64 use Win64 CC
 231   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<RetCC_X86_Win64_C>>,
 232
 233   // Otherwise, drop to normal X86-64 CC
 234   CCDelegateTo<RetCC_X86_64_C>
 235 ]>;
 236
 237 // This is the return-value convention used for the entire X86 backend.
 238 def RetCC_X86 : CallingConv<[
 239
 240   // Check if this is the Intel OpenCL built-ins calling convention
 241   CCIfCC<"CallingConv::Intel_OCL_BI", CCDelegateTo<RetCC_Intel_OCL_BI>>,
 242
 243   CCIfSubtarget<"is64Bit()", CCDelegateTo<RetCC_X86_64>>,
 244   CCDelegateTo<RetCC_X86_32>
 245 ]>;
 246
 247 //===----------------------------------------------------------------------===//
 248 // X86-64 Argument Calling Conventions
 249 //===----------------------------------------------------------------------===//
 250
 251 def CC_X86_64_C : CallingConv<[
 252   // Handles byval parameters.
 253   CCIfByVal<CCPassByVal<8, 8>>,
 254
 255   // Promote i1/i8/i16 arguments to i32.
 256   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 257
 258   // The 'nest' parameter, if any, is passed in R10.
 259   CCIfNest<CCIfSubtarget<"isTarget64BitILP32()", CCAssignToReg<[R10D]>>>,
 260   CCIfNest<CCAssignToReg<[R10]>>,
 261
 262   // The first 6 integer arguments are passed in integer registers.
 263   CCIfType<[i32], CCAssignToReg<[EDI, ESI, EDX, ECX, R8D, R9D]>>,
 264   CCIfType<[i64], CCAssignToReg<[RDI, RSI, RDX, RCX, R8 , R9 ]>>,
 265
 266   // The first 8 MMX vector arguments are passed in XMM registers on Darwin.
 267   CCIfType<[x86mmx],
 268             CCIfSubtarget<"isTargetDarwin()",
 269             CCIfSubtarget<"hasSSE2()",
 270             CCPromoteToType<v2i64>>>>,
 271
 272   // Boolean vectors of AVX-512 are passed in SIMD registers.
 273   // The call from AVX to AVX-512 function should work,
 274   // since the boolean types in AVX/AVX2 are promoted by default.
 275   CCIfType<[v2i1],  CCPromoteToType<v2i64>>,
 276   CCIfType<[v4i1],  CCPromoteToType<v4i32>>,
 277   CCIfType<[v8i1],  CCPromoteToType<v8i16>>,
 278   CCIfType<[v16i1], CCPromoteToType<v16i8>>,
 279   CCIfType<[v32i1], CCPromoteToType<v32i8>>,
 280   CCIfType<[v64i1], CCPromoteToType<v64i8>>,
 281
 282   // The first 8 FP/Vector arguments are passed in XMM registers.
 283   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 284             CCIfSubtarget<"hasSSE1()",
 285             CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>>,
 286
 287   // The first 8 256-bit vector arguments are passed in YMM registers, unless
 288   // this is a vararg function.
 289   // FIXME: This isn't precisely correct; the x86-64 ABI document says that
 290   // fixed arguments to vararg functions are supposed to be passed in
 291   // registers.  Actually modeling that would be a lot of work, though.
 292   CCIfNotVarArg<CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 293                           CCIfSubtarget<"hasFp256()",
 294                           CCAssignToReg<[YMM0, YMM1, YMM2, YMM3,
 295                                          YMM4, YMM5, YMM6, YMM7]>>>>,
 296
 297   // The first 8 512-bit vector arguments are passed in ZMM registers.
 298   CCIfNotVarArg<CCIfType<[v64i8, v32i16, v16i32, v8i64, v16f32, v8f64],
 299             CCIfSubtarget<"hasAVX512()",
 300             CCAssignToReg<[ZMM0, ZMM1, ZMM2, ZMM3, ZMM4, ZMM5, ZMM6, ZMM7]>>>>,
 301
 302   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 303   // 8-byte aligned if there are no more registers to hold them.
 304   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 305
 306   // Long doubles get stack slots whose size and alignment depends on the
 307   // subtarget.
 308   CCIfType<[f80], CCAssignToStack<0, 0>>,
 309
 310   // Vectors get 16-byte stack slots that are 16-byte aligned.
 311   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 312
 313   // 256-bit vectors get 32-byte stack slots that are 32-byte aligned.
 314   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 315            CCAssignToStack<32, 32>>,
 316
 317   // 512-bit vectors get 64-byte stack slots that are 64-byte aligned.
 318   CCIfType<[v16i32, v8i64, v16f32, v8f64],
 319            CCAssignToStack<64, 64>>
 320 ]>;
 321
 322 // Calling convention used on Win64
 323 def CC_X86_Win64_C : CallingConv<[
 324   // FIXME: Handle byval stuff.
 325   // FIXME: Handle varargs.
 326
 327   // Promote i1/i8/i16 arguments to i32.
 328   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 329
 330   // The 'nest' parameter, if any, is passed in R10.
 331   CCIfNest<CCAssignToReg<[R10]>>,
 332
 333   // 128 bit vectors are passed by pointer
 334   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCPassIndirect<i64>>,
 335
 336
 337   // 256 bit vectors are passed by pointer
 338   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64], CCPassIndirect<i64>>,
 339
 340   // 512 bit vectors are passed by pointer
 341   CCIfType<[v16i32, v16f32, v8f64, v8i64], CCPassIndirect<i64>>,
 342
 343   // The first 4 MMX vector arguments are passed in GPRs.
 344   CCIfType<[x86mmx], CCBitConvertToType<i64>>,
 345
 346   // The first 4 integer arguments are passed in integer registers.
 347   CCIfType<[i32], CCAssignToRegWithShadow<[ECX , EDX , R8D , R9D ],
 348                                           [XMM0, XMM1, XMM2, XMM3]>>,
 349
 350   // Do not pass the sret argument in RCX, the Win64 thiscall calling
 351   // convention requires "this" to be passed in RCX.
 352   CCIfCC<"CallingConv::X86_ThisCall",
 353     CCIfSRet<CCIfType<[i64], CCAssignToRegWithShadow<[RDX , R8  , R9  ],
 354                                                      [XMM1, XMM2, XMM3]>>>>,
 355
 356   CCIfType<[i64], CCAssignToRegWithShadow<[RCX , RDX , R8  , R9  ],
 357                                           [XMM0, XMM1, XMM2, XMM3]>>,
 358
 359   // The first 4 FP/Vector arguments are passed in XMM registers.
 360   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 361            CCAssignToRegWithShadow<[XMM0, XMM1, XMM2, XMM3],
 362                                    [RCX , RDX , R8  , R9  ]>>,
 363
 364   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 365   // 8-byte aligned if there are no more registers to hold them.
 366   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 367
 368   // Long doubles get stack slots whose size and alignment depends on the
 369   // subtarget.
 370   CCIfType<[f80], CCAssignToStack<0, 0>>
 371 ]>;
 372
 373 def CC_X86_Win64_VectorCall : CallingConv<[
 374   // The first 6 floating point and vector types of 128 bits or less use
 375   // XMM0-XMM5.
 376   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 377            CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5]>>,
 378
 379   // 256-bit vectors use YMM registers.
 380   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 381            CCAssignToReg<[YMM0, YMM1, YMM2, YMM3, YMM4, YMM5]>>,
 382
 383   // 512-bit vectors use ZMM registers.
 384   CCIfType<[v64i8, v32i16, v16i32, v8i64, v16f32, v8f64],
 385            CCAssignToReg<[ZMM0, ZMM1, ZMM2, ZMM3, ZMM4, ZMM5]>>,
 386
 387   // Delegate to fastcall to handle integer types.
 388   CCDelegateTo<CC_X86_Win64_C>
 389 ]>;
 390
 391
 392 def CC_X86_64_GHC : CallingConv<[
 393   // Promote i8/i16/i32 arguments to i64.
 394   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 395
 396   // Pass in STG registers: Base, Sp, Hp, R1, R2, R3, R4, R5, R6, SpLim
 397   CCIfType<[i64],
 398             CCAssignToReg<[R13, RBP, R12, RBX, R14, RSI, RDI, R8, R9, R15]>>,
 399
 400   // Pass in STG registers: F1, F2, F3, F4, D1, D2
 401   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 402             CCIfSubtarget<"hasSSE1()",
 403             CCAssignToReg<[XMM1, XMM2, XMM3, XMM4, XMM5, XMM6]>>>
 404 ]>;
 405
 406 def CC_X86_64_HiPE : CallingConv<[
 407   // Promote i8/i16/i32 arguments to i64.
 408   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 409
 410   // Pass in VM's registers: HP, P, ARG0, ARG1, ARG2, ARG3
 411   CCIfType<[i64], CCAssignToReg<[R15, RBP, RSI, RDX, RCX, R8]>>,
 412
 413   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 414   // 8-byte aligned if there are no more registers to hold them.
 415   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>
 416 ]>;
 417
 418 def CC_X86_64_WebKit_JS : CallingConv<[
 419   // Promote i8/i16 arguments to i32.
 420   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 421
 422   // Only the first integer argument is passed in register.
 423   CCIfType<[i32], CCAssignToReg<[EAX]>>,
 424   CCIfType<[i64], CCAssignToReg<[RAX]>>,
 425
 426   // The remaining integer arguments are passed on the stack. 32bit integer and
 427   // floating-point arguments are aligned to 4 byte and stored in 4 byte slots.
 428   // 64bit integer and floating-point arguments are aligned to 8 byte and stored
 429   // in 8 byte stack slots.
 430   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 431   CCIfType<[i64, f64], CCAssignToStack<8, 8>>
 432 ]>;
 433
 434 // No explicit register is specified for the AnyReg calling convention. The
 435 // register allocator may assign the arguments to any free register.
 436 //
 437 // This calling convention is currently only supported by the stackmap and
 438 // patchpoint intrinsics. All other uses will result in an assert on Debug
 439 // builds. On Release builds we fallback to the X86 C calling convention.
 440 def CC_X86_64_AnyReg : CallingConv<[
 441   CCCustom<"CC_X86_AnyReg_Error">
 442 ]>;
 443
 444 //===----------------------------------------------------------------------===//
 445 // X86 C Calling Convention
 446 //===----------------------------------------------------------------------===//
 447
 448 /// CC_X86_32_Common - In all X86-32 calling conventions, extra integers and FP
 449 /// values are spilled on the stack, and the first 4 vector values go in XMM
 450 /// regs.
 451 def CC_X86_32_Common : CallingConv<[
 452   // Handles byval parameters.
 453   CCIfByVal<CCPassByVal<4, 4>>,
 454
 455   // The first 3 float or double arguments, if marked 'inreg' and if the call
 456   // is not a vararg call and if SSE2 is available, are passed in SSE registers.
 457   CCIfNotVarArg<CCIfInReg<CCIfType<[f32,f64],
 458                 CCIfSubtarget<"hasSSE2()",
 459                 CCAssignToReg<[XMM0,XMM1,XMM2]>>>>>,
 460
 461   // The first 3 __m64 vector arguments are passed in mmx registers if the
 462   // call is not a vararg call.
 463   CCIfNotVarArg<CCIfType<[x86mmx],
 464                 CCAssignToReg<[MM0, MM1, MM2]>>>,
 465
 466   // Integer/Float values get stored in stack slots that are 4 bytes in
 467   // size and 4-byte aligned.
 468   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 469
 470   // Doubles get 8-byte slots that are 4-byte aligned.
 471   CCIfType<[f64], CCAssignToStack<8, 4>>,
 472
 473   // Long doubles get slots whose size depends on the subtarget.
 474   CCIfType<[f80], CCAssignToStack<0, 4>>,
 475
 476   // Boolean vectors of AVX-512 are passed in SIMD registers.
 477   // The call from AVX to AVX-512 function should work,
 478   // since the boolean types in AVX/AVX2 are promoted by default.
 479   CCIfType<[v2i1],  CCPromoteToType<v2i64>>,
 480   CCIfType<[v4i1],  CCPromoteToType<v4i32>>,
 481   CCIfType<[v8i1],  CCPromoteToType<v8i16>>,
 482   CCIfType<[v16i1], CCPromoteToType<v16i8>>,
 483   CCIfType<[v32i1], CCPromoteToType<v32i8>>,
 484   CCIfType<[v64i1], CCPromoteToType<v64i8>>,
 485
 486   // The first 4 SSE vector arguments are passed in XMM registers.
 487   CCIfNotVarArg<CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 488                 CCAssignToReg<[XMM0, XMM1, XMM2, XMM3]>>>,
 489
 490   // The first 4 AVX 256-bit vector arguments are passed in YMM registers.
 491   CCIfNotVarArg<CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 492                 CCIfSubtarget<"hasFp256()",
 493                 CCAssignToReg<[YMM0, YMM1, YMM2, YMM3]>>>>,
 494
 495   // The first 4 AVX 512-bit vector arguments are passed in ZMM registers.
 496   CCIfNotVarArg<CCIfType<[v64i8, v32i16, v16i32, v8i64, v16f32, v8f64],
 497                 CCAssignToReg<[ZMM0, ZMM1, ZMM2, ZMM3]>>>,
 498
 499   // Other SSE vectors get 16-byte stack slots that are 16-byte aligned.
 500   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 501
 502   // 256-bit AVX vectors get 32-byte stack slots that are 32-byte aligned.
 503   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 504            CCAssignToStack<32, 32>>,
 505
 506   // 512-bit AVX 512-bit vectors get 64-byte stack slots that are 64-byte aligned.
 507   CCIfType<[v64i8, v32i16, v16i32, v8i64, v16f32, v8f64],
 508            CCAssignToStack<64, 64>>,
 509
 510   // __m64 vectors get 8-byte stack slots that are 4-byte aligned. They are
 511   // passed in the parameter area.
 512   CCIfType<[x86mmx], CCAssignToStack<8, 4>>]>;
 513
 514 def CC_X86_32_C : CallingConv<[
 515   // Promote i1/i8/i16 arguments to i32.
 516   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 517
 518   // The 'nest' parameter, if any, is passed in ECX.
 519   CCIfNest<CCAssignToReg<[ECX]>>,
 520
 521   // The first 3 integer arguments, if marked 'inreg' and if the call is not
 522   // a vararg call, are passed in integer registers.
 523   CCIfNotVarArg<CCIfInReg<CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>>>,
 524
 525   // Otherwise, same as everything else.
 526   CCDelegateTo<CC_X86_32_Common>
 527 ]>;
 528
 529 def CC_X86_32_FastCall : CallingConv<[
 530   // Promote i1/i8/i16 arguments to i32.
 531   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 532
 533   // The 'nest' parameter, if any, is passed in EAX.
 534   CCIfNest<CCAssignToReg<[EAX]>>,
 535
 536   // The first 2 integer arguments are passed in ECX/EDX
 537   CCIfInReg<CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>>,
 538
 539   // Otherwise, same as everything else.
 540   CCDelegateTo<CC_X86_32_Common>
 541 ]>;
 542
 543 def CC_X86_32_VectorCall : CallingConv<[
 544   // The first 6 floating point and vector types of 128 bits or less use
 545   // XMM0-XMM5.
 546   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 547            CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5]>>,
 548
 549   // 256-bit vectors use YMM registers.
 550   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 551            CCAssignToReg<[YMM0, YMM1, YMM2, YMM3, YMM4, YMM5]>>,
 552
 553   // 512-bit vectors use ZMM registers.
 554   CCIfType<[v64i8, v32i16, v16i32, v8i64, v16f32, v8f64],
 555            CCAssignToReg<[ZMM0, ZMM1, ZMM2, ZMM3, ZMM4, ZMM5]>>,
 556
 557   // Otherwise, pass it indirectly.
 558   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64,
 559             v32i8, v16i16, v8i32, v4i64, v8f32, v4f64,
 560             v64i8, v32i16, v16i32, v8i64, v16f32, v8f64],
 561            CCCustom<"CC_X86_32_VectorCallIndirect">>,
 562
 563   // Delegate to fastcall to handle integer types.
 564   CCDelegateTo<CC_X86_32_FastCall>
 565 ]>;
 566
 567 def CC_X86_32_ThisCall_Common : CallingConv<[
 568   // The first integer argument is passed in ECX
 569   CCIfType<[i32], CCAssignToReg<[ECX]>>,
 570
 571   // Otherwise, same as everything else.
 572   CCDelegateTo<CC_X86_32_Common>
 573 ]>;
 574
 575 def CC_X86_32_ThisCall_Mingw : CallingConv<[
 576   // Promote i1/i8/i16 arguments to i32.
 577   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 578
 579   CCDelegateTo<CC_X86_32_ThisCall_Common>
 580 ]>;
 581
 582 def CC_X86_32_ThisCall_Win : CallingConv<[
 583   // Promote i1/i8/i16 arguments to i32.
 584   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 585
 586   // Pass sret arguments indirectly through stack.
 587   CCIfSRet<CCAssignToStack<4, 4>>,
 588
 589   CCDelegateTo<CC_X86_32_ThisCall_Common>
 590 ]>;
 591
 592 def CC_X86_32_ThisCall : CallingConv<[
 593   CCIfSubtarget<"isTargetCygMing()", CCDelegateTo<CC_X86_32_ThisCall_Mingw>>,
 594   CCDelegateTo<CC_X86_32_ThisCall_Win>
 595 ]>;
 596
 597 def CC_X86_32_FastCC : CallingConv<[
 598   // Handles byval parameters.  Note that we can't rely on the delegation
 599   // to CC_X86_32_Common for this because that happens after code that
 600   // puts arguments in registers.
 601   CCIfByVal<CCPassByVal<4, 4>>,
 602
 603   // Promote i1/i8/i16 arguments to i32.
 604   CCIfType<[i1, i8, i16], CCPromoteToType<i32>>,
 605
 606   // The 'nest' parameter, if any, is passed in EAX.
 607   CCIfNest<CCAssignToReg<[EAX]>>,
 608
 609   // The first 2 integer arguments are passed in ECX/EDX
 610   CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>,
 611
 612   // The first 3 float or double arguments, if the call is not a vararg
 613   // call and if SSE2 is available, are passed in SSE registers.
 614   CCIfNotVarArg<CCIfType<[f32,f64],
 615                 CCIfSubtarget<"hasSSE2()",
 616                 CCAssignToReg<[XMM0,XMM1,XMM2]>>>>,
 617
 618   // Doubles get 8-byte slots that are 8-byte aligned.
 619   CCIfType<[f64], CCAssignToStack<8, 8>>,
 620
 621   // Otherwise, same as everything else.
 622   CCDelegateTo<CC_X86_32_Common>
 623 ]>;
 624
 625 def CC_X86_32_GHC : CallingConv<[
 626   // Promote i8/i16 arguments to i32.
 627   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 628
 629   // Pass in STG registers: Base, Sp, Hp, R1
 630   CCIfType<[i32], CCAssignToReg<[EBX, EBP, EDI, ESI]>>
 631 ]>;
 632
 633 def CC_X86_32_HiPE : CallingConv<[
 634   // Promote i8/i16 arguments to i32.
 635   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 636
 637   // Pass in VM's registers: HP, P, ARG0, ARG1, ARG2
 638   CCIfType<[i32], CCAssignToReg<[ESI, EBP, EAX, EDX, ECX]>>,
 639
 640   // Integer/Float values get stored in stack slots that are 4 bytes in
 641   // size and 4-byte aligned.
 642   CCIfType<[i32, f32], CCAssignToStack<4, 4>>
 643 ]>;
 644
 645 // X86-64 Intel OpenCL built-ins calling convention.
 646 def CC_Intel_OCL_BI : CallingConv<[
 647
 648   CCIfType<[i32], CCIfSubtarget<"isTargetWin64()", CCAssignToReg<[ECX, EDX, R8D, R9D]>>>,
 649   CCIfType<[i64], CCIfSubtarget<"isTargetWin64()", CCAssignToReg<[RCX, RDX, R8,  R9 ]>>>,
 650
 651   CCIfType<[i32], CCIfSubtarget<"is64Bit()", CCAssignToReg<[EDI, ESI, EDX, ECX]>>>,
 652   CCIfType<[i64], CCIfSubtarget<"is64Bit()", CCAssignToReg<[RDI, RSI, RDX, RCX]>>>,
 653
 654   CCIfType<[i32], CCAssignToStack<4, 4>>,
 655
 656   // The SSE vector arguments are passed in XMM registers.
 657   CCIfType<[f32, f64, v4i32, v2i64, v4f32, v2f64],
 658            CCAssignToReg<[XMM0, XMM1, XMM2, XMM3]>>,
 659
 660   // The 256-bit vector arguments are passed in YMM registers.
 661   CCIfType<[v8f32, v4f64, v8i32, v4i64],
 662            CCAssignToReg<[YMM0, YMM1, YMM2, YMM3]>>,
 663
 664   // The 512-bit vector arguments are passed in ZMM registers.
 665   CCIfType<[v16f32, v8f64, v16i32, v8i64],
 666            CCAssignToReg<[ZMM0, ZMM1, ZMM2, ZMM3]>>,
 667
 668   // Pass masks in mask registers
 669   CCIfType<[v16i1, v8i1], CCAssignToReg<[K1]>>,
 670
 671   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<CC_X86_Win64_C>>,
 672   CCIfSubtarget<"is64Bit()",       CCDelegateTo<CC_X86_64_C>>,
 673   CCDelegateTo<CC_X86_32_C>
 674 ]>;
 675
 676 //===----------------------------------------------------------------------===//
 677 // X86 Root Argument Calling Conventions
 678 //===----------------------------------------------------------------------===//
 679
 680 // This is the root argument convention for the X86-32 backend.
 681 def CC_X86_32 : CallingConv<[
 682   CCIfCC<"CallingConv::X86_FastCall", CCDelegateTo<CC_X86_32_FastCall>>,
 683   CCIfCC<"CallingConv::X86_VectorCall", CCDelegateTo<CC_X86_32_VectorCall>>,
 684   CCIfCC<"CallingConv::X86_ThisCall", CCDelegateTo<CC_X86_32_ThisCall>>,
 685   CCIfCC<"CallingConv::Fast", CCDelegateTo<CC_X86_32_FastCC>>,
 686   CCIfCC<"CallingConv::GHC", CCDelegateTo<CC_X86_32_GHC>>,
 687   CCIfCC<"CallingConv::HiPE", CCDelegateTo<CC_X86_32_HiPE>>,
 688
 689   // Otherwise, drop to normal X86-32 CC
 690   CCDelegateTo<CC_X86_32_C>
 691 ]>;
 692
 693 // This is the root argument convention for the X86-64 backend.
 694 def CC_X86_64 : CallingConv<[
 695   CCIfCC<"CallingConv::GHC", CCDelegateTo<CC_X86_64_GHC>>,
 696   CCIfCC<"CallingConv::HiPE", CCDelegateTo<CC_X86_64_HiPE>>,
 697   CCIfCC<"CallingConv::WebKit_JS", CCDelegateTo<CC_X86_64_WebKit_JS>>,
 698   CCIfCC<"CallingConv::AnyReg", CCDelegateTo<CC_X86_64_AnyReg>>,
 699   CCIfCC<"CallingConv::X86_64_Win64", CCDelegateTo<CC_X86_Win64_C>>,
 700   CCIfCC<"CallingConv::X86_64_SysV", CCDelegateTo<CC_X86_64_C>>,
 701   CCIfCC<"CallingConv::X86_VectorCall", CCDelegateTo<CC_X86_Win64_VectorCall>>,
 702
 703   // Mingw64 and native Win64 use Win64 CC
 704   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<CC_X86_Win64_C>>,
 705
 706   // Otherwise, drop to normal X86-64 CC
 707   CCDelegateTo<CC_X86_64_C>
 708 ]>;
 709
 710 // This is the argument convention used for the entire X86 backend.
 711 def CC_X86 : CallingConv<[
 712   CCIfCC<"CallingConv::Intel_OCL_BI", CCDelegateTo<CC_Intel_OCL_BI>>,
 713   CCIfSubtarget<"is64Bit()", CCDelegateTo<CC_X86_64>>,
 714   CCDelegateTo<CC_X86_32>
 715 ]>;
 716
 717 //===----------------------------------------------------------------------===//
 718 // Callee-saved Registers.
 719 //===----------------------------------------------------------------------===//
 720
 721 def CSR_NoRegs : CalleeSavedRegs<(add)>;
 722
 723 def CSR_32 : CalleeSavedRegs<(add ESI, EDI, EBX, EBP)>;
 724 def CSR_64 : CalleeSavedRegs<(add RBX, R12, R13, R14, R15, RBP)>;
 725
 726 def CSR_32EHRet : CalleeSavedRegs<(add EAX, EDX, CSR_32)>;
 727 def CSR_64EHRet : CalleeSavedRegs<(add RAX, RDX, CSR_64)>;
 728
 729 def CSR_Win64 : CalleeSavedRegs<(add RBX, RBP, RDI, RSI, R12, R13, R14, R15,
 730                                      (sequence "XMM%u", 6, 15))>;
 731
 732 // All GPRs - except r11
 733 def CSR_64_RT_MostRegs : CalleeSavedRegs<(add CSR_64, RAX, RCX, RDX, RSI, RDI,
 734                                               R8, R9, R10, RSP)>;
 735
 736 // All registers - except r11
 737 def CSR_64_RT_AllRegs     : CalleeSavedRegs<(add CSR_64_RT_MostRegs,
 738                                                  (sequence "XMM%u", 0, 15))>;
 739 def CSR_64_RT_AllRegs_AVX : CalleeSavedRegs<(add CSR_64_RT_MostRegs,
 740                                                  (sequence "YMM%u", 0, 15))>;
 741
 742 def CSR_64_MostRegs : CalleeSavedRegs<(add RBX, RCX, RDX, RSI, RDI, R8, R9, R10,
 743                                            R11, R12, R13, R14, R15, RBP,
 744                                            (sequence "XMM%u", 0, 15))>;
 745
 746 def CSR_64_AllRegs     : CalleeSavedRegs<(add CSR_64_MostRegs, RAX, RSP,
 747                                               (sequence "XMM%u", 16, 31))>;
 748 def CSR_64_AllRegs_AVX : CalleeSavedRegs<(sub (add CSR_64_MostRegs, RAX, RSP,
 749                                                    (sequence "YMM%u", 0, 31)),
 750                                               (sequence "XMM%u", 0, 15))>;
 751
 752 // Standard C + YMM6-15
 753 def CSR_Win64_Intel_OCL_BI_AVX : CalleeSavedRegs<(add RBX, RBP, RDI, RSI, R12,
 754                                                   R13, R14, R15,
 755                                                   (sequence "YMM%u", 6, 15))>;
 756
 757 def CSR_Win64_Intel_OCL_BI_AVX512 : CalleeSavedRegs<(add RBX, RBP, RDI, RSI,
 758                                                      R12, R13, R14, R15,
 759                                                      (sequence "ZMM%u", 6, 21),
 760                                                      K4, K5, K6, K7)>;
 761 //Standard C + XMM 8-15
 762 def CSR_64_Intel_OCL_BI       : CalleeSavedRegs<(add CSR_64,
 763                                                  (sequence "XMM%u", 8, 15))>;
 764
 765 //Standard C + YMM 8-15
 766 def CSR_64_Intel_OCL_BI_AVX    : CalleeSavedRegs<(add CSR_64,
 767                                                   (sequence "YMM%u", 8, 15))>;
 768
 769 def CSR_64_Intel_OCL_BI_AVX512 : CalleeSavedRegs<(add RBX, RDI, RSI, R14, R15,
 770                                                   (sequence "ZMM%u", 16, 31),
 771                                                   K4, K5, K6, K7)>;