lib/Target/X86/X86CallingConv.td

   1 //===-- X86CallingConv.td - Calling Conventions X86 32/64 --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This describes the calling conventions for the X86-32 and X86-64
  11 // architectures.
  12 //
  13 //===----------------------------------------------------------------------===//
  14
  15 /// CCIfSubtarget - Match if the current subtarget has a feature F.
  16 class CCIfSubtarget<string F, CCAction A>
  17  : CCIf<!strconcat("State.getTarget().getSubtarget<X86Subtarget>().", F), A>;
  18
  19 //===----------------------------------------------------------------------===//
  20 // Return Value Calling Conventions
  21 //===----------------------------------------------------------------------===//
  22
  23 // Return-value conventions common to all X86 CC's.
  24 def RetCC_X86Common : CallingConv<[
  25   // Scalar values are returned in AX first, then DX.  For i8, the ABI
  26   // requires the values to be in AL and AH, however this code uses AL and DL
  27   // instead. This is because using AH for the second register conflicts with
  28   // the way LLVM does multiple return values -- a return of {i16,i8} would end
  29   // up in AX and AH, which overlap. Front-ends wishing to conform to the ABI
  30   // for functions that return two i8 values are currently expected to pack the
  31   // values into an i16 (which uses AX, and thus AL:AH).
  32   //
  33   // For code that doesn't care about the ABI, we allow returning more than two
  34   // integer values in registers.
  35   CCIfType<[i8] , CCAssignToReg<[AL, DL, CL]>>,
  36   CCIfType<[i16], CCAssignToReg<[AX, DX, CX]>>,
  37   CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>,
  38   CCIfType<[i64], CCAssignToReg<[RAX, RDX, RCX]>>,
  39
  40   // Vector types are returned in XMM0 and XMM1, when they fit.  XMM2 and XMM3
  41   // can only be used by ABI non-compliant code. If the target doesn't have XMM
  42   // registers, it won't have vector types.
  43   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
  44             CCAssignToReg<[XMM0,XMM1,XMM2,XMM3]>>,
  45
  46   // 256-bit vectors are returned in YMM0 and XMM1, when they fit. YMM2 and YMM3
  47   // can only be used by ABI non-compliant code. This vector type is only
  48   // supported while using the AVX target feature.
  49   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
  50             CCAssignToReg<[YMM0,YMM1,YMM2,YMM3]>>,
  51
  52   // MMX vector types are always returned in MM0. If the target doesn't have
  53   // MM0, it doesn't support these vector types.
  54   CCIfType<[x86mmx], CCAssignToReg<[MM0]>>,
  55
  56   // Long double types are always returned in ST0 (even with SSE).
  57   CCIfType<[f80], CCAssignToReg<[ST0, ST1]>>
  58 ]>;
  59
  60 // X86-32 C return-value convention.
  61 def RetCC_X86_32_C : CallingConv<[
  62   // The X86-32 calling convention returns FP values in ST0, unless marked
  63   // with "inreg" (used here to distinguish one kind of reg from another,
  64   // weirdly; this is really the sse-regparm calling convention) in which
  65   // case they use XMM0, otherwise it is the same as the common X86 calling
  66   // conv.
  67   CCIfInReg<CCIfSubtarget<"hasSSE2()",
  68     CCIfType<[f32, f64], CCAssignToReg<[XMM0,XMM1,XMM2]>>>>,
  69   CCIfType<[f32,f64], CCAssignToReg<[ST0, ST1]>>,
  70   CCDelegateTo<RetCC_X86Common>
  71 ]>;
  72
  73 // X86-32 FastCC return-value convention.
  74 def RetCC_X86_32_Fast : CallingConv<[
  75   // The X86-32 fastcc returns 1, 2, or 3 FP values in XMM0-2 if the target has
  76   // SSE2.
  77   // This can happen when a float, 2 x float, or 3 x float vector is split by
  78   // target lowering, and is returned in 1-3 sse regs.
  79   CCIfType<[f32], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  80   CCIfType<[f64], CCIfSubtarget<"hasSSE2()", CCAssignToReg<[XMM0,XMM1,XMM2]>>>,
  81
  82   // For integers, ECX can be used as an extra return register
  83   CCIfType<[i8],  CCAssignToReg<[AL, DL, CL]>>,
  84   CCIfType<[i16], CCAssignToReg<[AX, DX, CX]>>,
  85   CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>,
  86
  87   // Otherwise, it is the same as the common X86 calling convention.
  88   CCDelegateTo<RetCC_X86Common>
  89 ]>;
  90
  91 // Intel_OCL_BI return-value convention.
  92 def RetCC_Intel_OCL_BI : CallingConv<[
  93   // Vector types are returned in XMM0,XMM1,XMMM2 and XMM3.
  94   CCIfType<[f32, f64, v4i32, v2i64, v4f32, v2f64],
  95             CCAssignToReg<[XMM0,XMM1,XMM2,XMM3]>>,
  96
  97   // 256-bit FP vectors
  98   // No more than 4 registers
  99   CCIfType<[v8f32, v4f64, v8i32, v4i64],
 100             CCAssignToReg<[YMM0,YMM1,YMM2,YMM3]>>,
 101
 102   // i32, i64 in the standard way
 103   CCDelegateTo<RetCC_X86Common>
 104 ]>;
 105
 106 // X86-32 HiPE return-value convention.
 107 def RetCC_X86_32_HiPE : CallingConv<[
 108   // Promote all types to i32
 109   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 110
 111   // Return: HP, P, VAL1, VAL2
 112   CCIfType<[i32], CCAssignToReg<[ESI, EBP, EAX, EDX]>>
 113 ]>;
 114
 115 // X86-64 C return-value convention.
 116 def RetCC_X86_64_C : CallingConv<[
 117   // The X86-64 calling convention always returns FP values in XMM0.
 118   CCIfType<[f32], CCAssignToReg<[XMM0, XMM1]>>,
 119   CCIfType<[f64], CCAssignToReg<[XMM0, XMM1]>>,
 120
 121   // MMX vector types are always returned in XMM0.
 122   CCIfType<[x86mmx], CCAssignToReg<[XMM0, XMM1]>>,
 123   CCDelegateTo<RetCC_X86Common>
 124 ]>;
 125
 126 // X86-Win64 C return-value convention.
 127 def RetCC_X86_Win64_C : CallingConv<[
 128   // The X86-Win64 calling convention always returns __m64 values in RAX.
 129   CCIfType<[x86mmx], CCBitConvertToType<i64>>,
 130
 131   // Otherwise, everything is the same as 'normal' X86-64 C CC.
 132   CCDelegateTo<RetCC_X86_64_C>
 133 ]>;
 134
 135 // X86-64 HiPE return-value convention.
 136 def RetCC_X86_64_HiPE : CallingConv<[
 137   // Promote all types to i64
 138   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 139
 140   // Return: HP, P, VAL1, VAL2
 141   CCIfType<[i64], CCAssignToReg<[R15, RBP, RAX, RDX]>>
 142 ]>;
 143
 144 // This is the root return-value convention for the X86-32 backend.
 145 def RetCC_X86_32 : CallingConv<[
 146   // If FastCC, use RetCC_X86_32_Fast.
 147   CCIfCC<"CallingConv::Fast", CCDelegateTo<RetCC_X86_32_Fast>>,
 148   // If HiPE, use RetCC_X86_32_HiPE.
 149   CCIfCC<"CallingConv::HiPE", CCDelegateTo<RetCC_X86_32_HiPE>>,
 150
 151   // Otherwise, use RetCC_X86_32_C.
 152   CCDelegateTo<RetCC_X86_32_C>
 153 ]>;
 154
 155 // This is the root return-value convention for the X86-64 backend.
 156 def RetCC_X86_64 : CallingConv<[
 157   // HiPE uses RetCC_X86_64_HiPE
 158   CCIfCC<"CallingConv::HiPE", CCDelegateTo<RetCC_X86_64_HiPE>>,
 159   // Mingw64 and native Win64 use Win64 CC
 160   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<RetCC_X86_Win64_C>>,
 161
 162   // Otherwise, drop to normal X86-64 CC
 163   CCDelegateTo<RetCC_X86_64_C>
 164 ]>;
 165
 166 // This is the return-value convention used for the entire X86 backend.
 167 def RetCC_X86 : CallingConv<[
 168
 169   // Check if this is the Intel OpenCL built-ins calling convention
 170   CCIfCC<"CallingConv::Intel_OCL_BI", CCDelegateTo<RetCC_Intel_OCL_BI>>,
 171
 172   CCIfSubtarget<"is64Bit()", CCDelegateTo<RetCC_X86_64>>,
 173   CCDelegateTo<RetCC_X86_32>
 174 ]>;
 175
 176 //===----------------------------------------------------------------------===//
 177 // X86-64 Argument Calling Conventions
 178 //===----------------------------------------------------------------------===//
 179
 180 def CC_X86_64_C : CallingConv<[
 181   // Handles byval parameters.
 182   CCIfByVal<CCPassByVal<8, 8>>,
 183
 184   // Promote i8/i16 arguments to i32.
 185   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 186
 187   // The 'nest' parameter, if any, is passed in R10.
 188   CCIfNest<CCAssignToReg<[R10]>>,
 189
 190   // The first 6 integer arguments are passed in integer registers.
 191   CCIfType<[i32], CCAssignToReg<[EDI, ESI, EDX, ECX, R8D, R9D]>>,
 192   CCIfType<[i64], CCAssignToReg<[RDI, RSI, RDX, RCX, R8 , R9 ]>>,
 193
 194   // The first 8 MMX vector arguments are passed in XMM registers on Darwin.
 195   CCIfType<[x86mmx],
 196             CCIfSubtarget<"isTargetDarwin()",
 197             CCIfSubtarget<"hasSSE2()",
 198             CCPromoteToType<v2i64>>>>,
 199
 200   // The first 8 FP/Vector arguments are passed in XMM registers.
 201   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 202             CCIfSubtarget<"hasSSE1()",
 203             CCAssignToReg<[XMM0, XMM1, XMM2, XMM3, XMM4, XMM5, XMM6, XMM7]>>>,
 204
 205   // The first 8 256-bit vector arguments are passed in YMM registers, unless
 206   // this is a vararg function.
 207   // FIXME: This isn't precisely correct; the x86-64 ABI document says that
 208   // fixed arguments to vararg functions are supposed to be passed in
 209   // registers.  Actually modeling that would be a lot of work, though.
 210   CCIfNotVarArg<CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 211                           CCIfSubtarget<"hasAVX()",
 212                           CCAssignToReg<[YMM0, YMM1, YMM2, YMM3,
 213                                          YMM4, YMM5, YMM6, YMM7]>>>>,
 214
 215   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 216   // 8-byte aligned if there are no more registers to hold them.
 217   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 218
 219   // Long doubles get stack slots whose size and alignment depends on the
 220   // subtarget.
 221   CCIfType<[f80], CCAssignToStack<0, 0>>,
 222
 223   // Vectors get 16-byte stack slots that are 16-byte aligned.
 224   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 225
 226   // 256-bit vectors get 32-byte stack slots that are 32-byte aligned.
 227   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 228            CCAssignToStack<32, 32>>
 229 ]>;
 230
 231 // Calling convention used on Win64
 232 def CC_X86_Win64_C : CallingConv<[
 233   // FIXME: Handle byval stuff.
 234   // FIXME: Handle varargs.
 235
 236   // Promote i8/i16 arguments to i32.
 237   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 238
 239   // The 'nest' parameter, if any, is passed in R10.
 240   CCIfNest<CCAssignToReg<[R10]>>,
 241
 242   // 128 bit vectors are passed by pointer
 243   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCPassIndirect<i64>>,
 244
 245
 246   // 256 bit vectors are passed by pointer
 247   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64], CCPassIndirect<i64>>,
 248
 249   // The first 4 MMX vector arguments are passed in GPRs.
 250   CCIfType<[x86mmx], CCBitConvertToType<i64>>,
 251
 252   // The first 4 integer arguments are passed in integer registers.
 253   CCIfType<[i32], CCAssignToRegWithShadow<[ECX , EDX , R8D , R9D ],
 254                                           [XMM0, XMM1, XMM2, XMM3]>>,
 255
 256   // Do not pass the sret argument in RCX, the Win64 thiscall calling
 257   // convention requires "this" to be passed in RCX.
 258   CCIfCC<"CallingConv::X86_ThisCall",
 259     CCIfSRet<CCIfType<[i64], CCAssignToRegWithShadow<[RDX , R8  , R9  ],
 260                                                      [XMM1, XMM2, XMM3]>>>>,
 261
 262   CCIfType<[i64], CCAssignToRegWithShadow<[RCX , RDX , R8  , R9  ],
 263                                           [XMM0, XMM1, XMM2, XMM3]>>,
 264
 265   // The first 4 FP/Vector arguments are passed in XMM registers.
 266   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 267            CCAssignToRegWithShadow<[XMM0, XMM1, XMM2, XMM3],
 268                                    [RCX , RDX , R8  , R9  ]>>,
 269
 270   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 271   // 8-byte aligned if there are no more registers to hold them.
 272   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>,
 273
 274   // Long doubles get stack slots whose size and alignment depends on the
 275   // subtarget.
 276   CCIfType<[f80], CCAssignToStack<0, 0>>
 277 ]>;
 278
 279 // X86-64 Intel OpenCL built-ins calling convention.
 280 def CC_Intel_OCL_BI : CallingConv<[
 281   CCIfType<[i32], CCIfSubtarget<"isTargetWin32()", CCAssignToStack<4, 4>>>,
 282
 283   CCIfType<[i32], CCIfSubtarget<"isTargetWin64()", CCAssignToReg<[ECX, EDX, R8D, R9D]>>>,
 284   CCIfType<[i64], CCIfSubtarget<"isTargetWin64()", CCAssignToReg<[RCX, RDX, R8,  R9 ]>>>,
 285
 286   CCIfType<[i32], CCAssignToReg<[EDI, ESI, EDX, ECX]>>,
 287   CCIfType<[i64], CCAssignToReg<[RDI, RSI, RDX, RCX]>>,
 288
 289  // The SSE vector arguments are passed in XMM registers.
 290   CCIfType<[f32, f64, v4i32, v2i64, v4f32, v2f64],
 291            CCAssignToReg<[XMM0, XMM1, XMM2, XMM3]>>,
 292
 293   // The 256-bit vector arguments are passed in YMM registers.
 294   CCIfType<[v8f32, v4f64, v8i32, v4i64],
 295                 CCAssignToReg<[YMM0, YMM1, YMM2, YMM3]>>,
 296
 297   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<CC_X86_Win64_C>>,
 298   CCDelegateTo<CC_X86_64_C>
 299 ]>;
 300
 301
 302 def CC_X86_64_GHC : CallingConv<[
 303   // Promote i8/i16/i32 arguments to i64.
 304   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 305
 306   // Pass in STG registers: Base, Sp, Hp, R1, R2, R3, R4, R5, R6, SpLim
 307   CCIfType<[i64],
 308             CCAssignToReg<[R13, RBP, R12, RBX, R14, RSI, RDI, R8, R9, R15]>>,
 309
 310   // Pass in STG registers: F1, F2, F3, F4, D1, D2
 311   CCIfType<[f32, f64, v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 312             CCIfSubtarget<"hasSSE1()",
 313             CCAssignToReg<[XMM1, XMM2, XMM3, XMM4, XMM5, XMM6]>>>
 314 ]>;
 315
 316 def CC_X86_64_HiPE : CallingConv<[
 317   // Promote i8/i16/i32 arguments to i64.
 318   CCIfType<[i8, i16, i32], CCPromoteToType<i64>>,
 319
 320   // Pass in VM's registers: HP, P, ARG0, ARG1, ARG2, ARG3
 321   CCIfType<[i64], CCAssignToReg<[R15, RBP, RSI, RDX, RCX, R8]>>,
 322
 323   // Integer/FP values get stored in stack slots that are 8 bytes in size and
 324   // 8-byte aligned if there are no more registers to hold them.
 325   CCIfType<[i32, i64, f32, f64], CCAssignToStack<8, 8>>
 326 ]>;
 327
 328 //===----------------------------------------------------------------------===//
 329 // X86 C Calling Convention
 330 //===----------------------------------------------------------------------===//
 331
 332 /// CC_X86_32_Common - In all X86-32 calling conventions, extra integers and FP
 333 /// values are spilled on the stack, and the first 4 vector values go in XMM
 334 /// regs.
 335 def CC_X86_32_Common : CallingConv<[
 336   // Handles byval parameters.
 337   CCIfByVal<CCPassByVal<4, 4>>,
 338
 339   // The first 3 float or double arguments, if marked 'inreg' and if the call
 340   // is not a vararg call and if SSE2 is available, are passed in SSE registers.
 341   CCIfNotVarArg<CCIfInReg<CCIfType<[f32,f64],
 342                 CCIfSubtarget<"hasSSE2()",
 343                 CCAssignToReg<[XMM0,XMM1,XMM2]>>>>>,
 344
 345   // The first 3 __m64 vector arguments are passed in mmx registers if the
 346   // call is not a vararg call.
 347   CCIfNotVarArg<CCIfType<[x86mmx],
 348                 CCAssignToReg<[MM0, MM1, MM2]>>>,
 349
 350   // Integer/Float values get stored in stack slots that are 4 bytes in
 351   // size and 4-byte aligned.
 352   CCIfType<[i32, f32], CCAssignToStack<4, 4>>,
 353
 354   // Doubles get 8-byte slots that are 4-byte aligned.
 355   CCIfType<[f64], CCAssignToStack<8, 4>>,
 356
 357   // Long doubles get slots whose size depends on the subtarget.
 358   CCIfType<[f80], CCAssignToStack<0, 4>>,
 359
 360   // The first 4 SSE vector arguments are passed in XMM registers.
 361   CCIfNotVarArg<CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64],
 362                 CCAssignToReg<[XMM0, XMM1, XMM2, XMM3]>>>,
 363
 364   // The first 4 AVX 256-bit vector arguments are passed in YMM registers.
 365   CCIfNotVarArg<CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 366                 CCIfSubtarget<"hasAVX()",
 367                 CCAssignToReg<[YMM0, YMM1, YMM2, YMM3]>>>>,
 368
 369   // Other SSE vectors get 16-byte stack slots that are 16-byte aligned.
 370   CCIfType<[v16i8, v8i16, v4i32, v2i64, v4f32, v2f64], CCAssignToStack<16, 16>>,
 371
 372   // 256-bit AVX vectors get 32-byte stack slots that are 32-byte aligned.
 373   CCIfType<[v32i8, v16i16, v8i32, v4i64, v8f32, v4f64],
 374            CCAssignToStack<32, 32>>,
 375
 376   // __m64 vectors get 8-byte stack slots that are 4-byte aligned. They are
 377   // passed in the parameter area.
 378   CCIfType<[x86mmx], CCAssignToStack<8, 4>>]>;
 379
 380 def CC_X86_32_C : CallingConv<[
 381   // Promote i8/i16 arguments to i32.
 382   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 383
 384   // The 'nest' parameter, if any, is passed in ECX.
 385   CCIfNest<CCAssignToReg<[ECX]>>,
 386
 387   // The first 3 integer arguments, if marked 'inreg' and if the call is not
 388   // a vararg call, are passed in integer registers.
 389   CCIfNotVarArg<CCIfInReg<CCIfType<[i32], CCAssignToReg<[EAX, EDX, ECX]>>>>,
 390
 391   // Otherwise, same as everything else.
 392   CCDelegateTo<CC_X86_32_Common>
 393 ]>;
 394
 395 def CC_X86_32_FastCall : CallingConv<[
 396   // Promote i8/i16 arguments to i32.
 397   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 398
 399   // The 'nest' parameter, if any, is passed in EAX.
 400   CCIfNest<CCAssignToReg<[EAX]>>,
 401
 402   // The first 2 integer arguments are passed in ECX/EDX
 403   CCIfInReg<CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>>,
 404
 405   // Otherwise, same as everything else.
 406   CCDelegateTo<CC_X86_32_Common>
 407 ]>;
 408
 409 def CC_X86_32_ThisCall : CallingConv<[
 410   // Promote i8/i16 arguments to i32.
 411   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 412
 413   // Pass sret arguments indirectly through EAX
 414   CCIfSRet<CCAssignToReg<[EAX]>>,
 415
 416   // The first integer argument is passed in ECX
 417   CCIfType<[i32], CCAssignToReg<[ECX]>>,
 418
 419   // Otherwise, same as everything else.
 420   CCDelegateTo<CC_X86_32_Common>
 421 ]>;
 422
 423 def CC_X86_32_FastCC : CallingConv<[
 424   // Handles byval parameters.  Note that we can't rely on the delegation
 425   // to CC_X86_32_Common for this because that happens after code that
 426   // puts arguments in registers.
 427   CCIfByVal<CCPassByVal<4, 4>>,
 428
 429   // Promote i8/i16 arguments to i32.
 430   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 431
 432   // The 'nest' parameter, if any, is passed in EAX.
 433   CCIfNest<CCAssignToReg<[EAX]>>,
 434
 435   // The first 2 integer arguments are passed in ECX/EDX
 436   CCIfType<[i32], CCAssignToReg<[ECX, EDX]>>,
 437
 438   // The first 3 float or double arguments, if the call is not a vararg
 439   // call and if SSE2 is available, are passed in SSE registers.
 440   CCIfNotVarArg<CCIfType<[f32,f64],
 441                 CCIfSubtarget<"hasSSE2()",
 442                 CCAssignToReg<[XMM0,XMM1,XMM2]>>>>,
 443
 444   // Doubles get 8-byte slots that are 8-byte aligned.
 445   CCIfType<[f64], CCAssignToStack<8, 8>>,
 446
 447   // Otherwise, same as everything else.
 448   CCDelegateTo<CC_X86_32_Common>
 449 ]>;
 450
 451 def CC_X86_32_GHC : CallingConv<[
 452   // Promote i8/i16 arguments to i32.
 453   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 454
 455   // Pass in STG registers: Base, Sp, Hp, R1
 456   CCIfType<[i32], CCAssignToReg<[EBX, EBP, EDI, ESI]>>
 457 ]>;
 458
 459 def CC_X86_32_HiPE : CallingConv<[
 460   // Promote i8/i16 arguments to i32.
 461   CCIfType<[i8, i16], CCPromoteToType<i32>>,
 462
 463   // Pass in VM's registers: HP, P, ARG0, ARG1, ARG2
 464   CCIfType<[i32], CCAssignToReg<[ESI, EBP, EAX, EDX, ECX]>>,
 465
 466   // Integer/Float values get stored in stack slots that are 4 bytes in
 467   // size and 4-byte aligned.
 468   CCIfType<[i32, f32], CCAssignToStack<4, 4>>
 469 ]>;
 470
 471 //===----------------------------------------------------------------------===//
 472 // X86 Root Argument Calling Conventions
 473 //===----------------------------------------------------------------------===//
 474
 475 // This is the root argument convention for the X86-32 backend.
 476 def CC_X86_32 : CallingConv<[
 477   CCIfCC<"CallingConv::X86_FastCall", CCDelegateTo<CC_X86_32_FastCall>>,
 478   CCIfCC<"CallingConv::X86_ThisCall", CCDelegateTo<CC_X86_32_ThisCall>>,
 479   CCIfCC<"CallingConv::Fast", CCDelegateTo<CC_X86_32_FastCC>>,
 480   CCIfCC<"CallingConv::GHC", CCDelegateTo<CC_X86_32_GHC>>,
 481   CCIfCC<"CallingConv::HiPE", CCDelegateTo<CC_X86_32_HiPE>>,
 482
 483   // Otherwise, drop to normal X86-32 CC
 484   CCDelegateTo<CC_X86_32_C>
 485 ]>;
 486
 487 // This is the root argument convention for the X86-64 backend.
 488 def CC_X86_64 : CallingConv<[
 489   CCIfCC<"CallingConv::GHC", CCDelegateTo<CC_X86_64_GHC>>,
 490   CCIfCC<"CallingConv::HiPE", CCDelegateTo<CC_X86_64_HiPE>>,
 491
 492   // Mingw64 and native Win64 use Win64 CC
 493   CCIfSubtarget<"isTargetWin64()", CCDelegateTo<CC_X86_Win64_C>>,
 494
 495   // Otherwise, drop to normal X86-64 CC
 496   CCDelegateTo<CC_X86_64_C>
 497 ]>;
 498
 499 // This is the argument convention used for the entire X86 backend.
 500 def CC_X86 : CallingConv<[
 501   CCIfCC<"CallingConv::Intel_OCL_BI", CCDelegateTo<CC_Intel_OCL_BI>>,
 502   CCIfSubtarget<"is64Bit()", CCDelegateTo<CC_X86_64>>,
 503   CCDelegateTo<CC_X86_32>
 504 ]>;
 505
 506 //===----------------------------------------------------------------------===//
 507 // Callee-saved Registers.
 508 //===----------------------------------------------------------------------===//
 509
 510 def CSR_NoRegs : CalleeSavedRegs<(add)>;
 511
 512 def CSR_32 : CalleeSavedRegs<(add ESI, EDI, EBX, EBP)>;
 513 def CSR_64 : CalleeSavedRegs<(add RBX, R12, R13, R14, R15, RBP)>;
 514
 515 def CSR_32EHRet : CalleeSavedRegs<(add EAX, EDX, CSR_32)>;
 516 def CSR_64EHRet : CalleeSavedRegs<(add RAX, RDX, CSR_64)>;
 517
 518 def CSR_Win64 : CalleeSavedRegs<(add RBX, RBP, RDI, RSI, R12, R13, R14, R15,
 519                                      (sequence "XMM%u", 6, 15))>;
 520
 521
 522 // Standard C + YMM6-15
 523 def CSR_Win64_Intel_OCL_BI_AVX : CalleeSavedRegs<(add RBX, RBP, RDI, RSI, R12,
 524                                                   R13, R14, R15,
 525                                                   (sequence "YMM%u", 6, 15))>;
 526
 527 //Standard C + XMM 8-15
 528 def CSR_64_Intel_OCL_BI       : CalleeSavedRegs<(add CSR_64,
 529                                                  (sequence "XMM%u", 8, 15))>;
 530
 531 //Standard C + YMM 8-15
 532 def CSR_64_Intel_OCL_BI_AVX    : CalleeSavedRegs<(add CSR_64,
 533                                                   (sequence "YMM%u", 8, 15))>;