lib/Target/X86/X86InstrFPStack.td

   1 //==- X86InstrFPStack.td - Describe the X86 Instruction Set -------*- C++ -*-=//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the Evan Cheng and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 x87 FPU instruction set, defining the
  11 // instructions, and properties of the instructions which are needed for code
  12 // generation, machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // FPStack specific DAG Nodes.
  18 //===----------------------------------------------------------------------===//
  19
  20 def SDTX86FpGet     : SDTypeProfile<1, 0, [SDTCisFP<0>]>;
  21 def SDTX86FpSet     : SDTypeProfile<0, 1, [SDTCisFP<0>]>;
  22 def SDTX86Fld       : SDTypeProfile<1, 2, [SDTCisFP<0>,
  23                                            SDTCisPtrTy<1>,
  24                                            SDTCisVT<2, OtherVT>]>;
  25 def SDTX86Fst       : SDTypeProfile<0, 3, [SDTCisFP<0>,
  26                                            SDTCisPtrTy<1>,
  27                                            SDTCisVT<2, OtherVT>]>;
  28 def SDTX86Fild      : SDTypeProfile<1, 2, [SDTCisFP<0>, SDTCisPtrTy<1>,
  29                                            SDTCisVT<2, OtherVT>]>;
  30 def SDTX86FpToIMem  : SDTypeProfile<0, 2, [SDTCisFP<0>, SDTCisPtrTy<1>]>;
  31
  32 def X86fpget        : SDNode<"X86ISD::FP_GET_RESULT", SDTX86FpGet,
  33                         [SDNPHasChain, SDNPInFlag, SDNPOutFlag]>;
  34 def X86fpset        : SDNode<"X86ISD::FP_SET_RESULT", SDTX86FpSet,
  35                         [SDNPHasChain, SDNPOutFlag]>;
  36 def X86fld          : SDNode<"X86ISD::FLD",      SDTX86Fld,
  37                         [SDNPHasChain]>;
  38 def X86fst          : SDNode<"X86ISD::FST",      SDTX86Fst,
  39                         [SDNPHasChain, SDNPInFlag]>;
  40 def X86fild         : SDNode<"X86ISD::FILD",     SDTX86Fild,
  41                         [SDNPHasChain]>;
  42 def X86fildflag     : SDNode<"X86ISD::FILD_FLAG",SDTX86Fild,
  43                         [SDNPHasChain, SDNPOutFlag]>;
  44 def X86fp_to_i16mem : SDNode<"X86ISD::FP_TO_INT16_IN_MEM", SDTX86FpToIMem,
  45                         [SDNPHasChain]>;
  46 def X86fp_to_i32mem : SDNode<"X86ISD::FP_TO_INT32_IN_MEM", SDTX86FpToIMem,
  47                         [SDNPHasChain]>;
  48 def X86fp_to_i64mem : SDNode<"X86ISD::FP_TO_INT64_IN_MEM", SDTX86FpToIMem,
  49                         [SDNPHasChain]>;
  50
  51 //===----------------------------------------------------------------------===//
  52 // FPStack pattern fragments
  53 //===----------------------------------------------------------------------===//
  54
  55 def fpimm0 : PatLeaf<(fpimm), [{
  56   return N->isExactlyValue(+0.0);
  57 }]>;
  58
  59 def fpimmneg0 : PatLeaf<(fpimm), [{
  60   return N->isExactlyValue(-0.0);
  61 }]>;
  62
  63 def fpimm1 : PatLeaf<(fpimm), [{
  64   return N->isExactlyValue(+1.0);
  65 }]>;
  66
  67 def fpimmneg1 : PatLeaf<(fpimm), [{
  68   return N->isExactlyValue(-1.0);
  69 }]>;
  70
  71 // Some 'special' instructions
  72 let usesCustomDAGSchedInserter = 1 in {  // Expanded by the scheduler.
  73   def FP32_TO_INT16_IN_MEM : I<0, Pseudo,
  74                               (outs), (ins i16mem:$dst, RFP32:$src),
  75                               "#FP32_TO_INT16_IN_MEM PSEUDO!",
  76                               [(X86fp_to_i16mem RFP32:$src, addr:$dst)]>;
  77   def FP32_TO_INT32_IN_MEM : I<0, Pseudo,
  78                               (outs), (ins i32mem:$dst, RFP32:$src),
  79                               "#FP32_TO_INT32_IN_MEM PSEUDO!",
  80                               [(X86fp_to_i32mem RFP32:$src, addr:$dst)]>;
  81   def FP32_TO_INT64_IN_MEM : I<0, Pseudo,
  82                               (outs), (ins i64mem:$dst, RFP32:$src),
  83                               "#FP32_TO_INT64_IN_MEM PSEUDO!",
  84                               [(X86fp_to_i64mem RFP32:$src, addr:$dst)]>;
  85   def FP64_TO_INT16_IN_MEM : I<0, Pseudo,
  86                               (outs), (ins i16mem:$dst, RFP64:$src),
  87                               "#FP64_TO_INT16_IN_MEM PSEUDO!",
  88                               [(X86fp_to_i16mem RFP64:$src, addr:$dst)]>;
  89   def FP64_TO_INT32_IN_MEM : I<0, Pseudo,
  90                               (outs), (ins i32mem:$dst, RFP64:$src),
  91                               "#FP64_TO_INT32_IN_MEM PSEUDO!",
  92                               [(X86fp_to_i32mem RFP64:$src, addr:$dst)]>;
  93   def FP64_TO_INT64_IN_MEM : I<0, Pseudo,
  94                               (outs), (ins i64mem:$dst, RFP64:$src),
  95                               "#FP64_TO_INT64_IN_MEM PSEUDO!",
  96                               [(X86fp_to_i64mem RFP64:$src, addr:$dst)]>;
  97 }
  98
  99 let isTerminator = 1 in
 100   let Defs = [FP0, FP1, FP2, FP3, FP4, FP5, FP6] in
 101     def FP_REG_KILL  : I<0, Pseudo, (outs), (ins), "#FP_REG_KILL", []>;
 102
 103 // All FP Stack operations are represented with three instructions here.  The
 104 // first two instructions, generated by the instruction selector, uses "RFP32"
 105 // or "RFP64" registers: traditional register files to reference 32-bit or
 106 // 64-bit floating point values.  These sizes apply to the values, not the
 107 // registers, which are always 64 bits; RFP32 and RFP64 can be copied to
 108 // each other without losing information.  These instructions are all psuedo
 109 // instructions and use the "_Fp" suffix.
 110 // In some cases there are additional variants with a mixture of 32-bit and
 111 // 64-bit registers.
 112 // The second instruction is defined with FPI, which is the actual instruction
 113 // emitted by the assembler.  These use "RST" registers, although frequently
 114 // the actual register(s) used are implicit.  These are always 64-bits.
 115 // The FP stackifier pass converts one to the other after register allocation
 116 // occurs.
 117 //
 118 // Note that the FpI instruction should have instruction selection info (e.g.
 119 // a pattern) and the FPI instruction should have emission info (e.g. opcode
 120 // encoding and asm printing info).
 121
 122 // FPI - Floating Point Instruction template.
 123 class FPI<bits<8> o, Format F, dag outs, dag ins, string asm>
 124   : I<o, F, outs, ins, asm, []> {}
 125
 126 // FpI_ - Floating Point Psuedo Instruction template. Not Predicated.
 127 class FpI_<dag outs, dag ins, FPFormat fp, list<dag> pattern>
 128   : X86Inst<0, Pseudo, NoImm, outs, ins, ""> {
 129   let FPForm = fp; let FPFormBits = FPForm.Value;
 130   let Pattern = pattern;
 131 }
 132
 133 // Random Pseudo Instructions.
 134 def FpGETRESULT32 : FpI_<(outs RFP32:$dst), (ins), SpecialFP,
 135                       [(set RFP32:$dst, X86fpget)]>;           // FPR = ST(0)
 136
 137 def FpGETRESULT64 : FpI_<(outs RFP64:$dst), (ins), SpecialFP,
 138                       [(set RFP64:$dst, X86fpget)]>;           // FPR = ST(0)
 139
 140 let noResults = 1 in {
 141   def FpSETRESULT32 : FpI_<(outs), (ins RFP32:$src), SpecialFP,
 142                         [(X86fpset RFP32:$src)]>, Imp<[], [ST0]>;// ST(0) = FPR
 143
 144   def FpSETRESULT64 : FpI_<(outs), (ins RFP64:$src), SpecialFP,
 145                         [(X86fpset RFP64:$src)]>, Imp<[], [ST0]>;// ST(0) = FPR
 146 }
 147 // FpI - Floating Point Psuedo Instruction template. Predicated on FPStack.
 148 class FpI<dag outs, dag ins, FPFormat fp, list<dag> pattern> :
 149   FpI_<outs, ins, fp, pattern>, Requires<[FPStack]>;
 150
 151 // Register copies.  Just copies, the 64->32 version does not truncate.
 152 def MOV_Fp3232       : FpI<(outs RFP32:$dst), (ins RFP32:$src), SpecialFP, []>;
 153 def MOV_Fp3264       : FpI<(outs RFP64:$dst), (ins RFP32:$src), SpecialFP, []>;
 154 def MOV_Fp6432       : FpI<(outs RFP32:$dst), (ins RFP64:$src), SpecialFP, []>;
 155 def MOV_Fp6464       : FpI<(outs RFP64:$dst), (ins RFP64:$src), SpecialFP, []>;
 156
 157 // Factoring for arithmetic.
 158 multiclass FPBinary_rr<SDNode OpNode> {
 159 // Register op register -> register
 160 // These are separated out because they have no reversed form.
 161 def _Fp32 : FpI<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), TwoArgFP,
 162                 [(set RFP32:$dst, (OpNode RFP32:$src1, RFP32:$src2))]>;
 163 def _Fp64 : FpI<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), TwoArgFP,
 164                 [(set RFP64:$dst, (OpNode RFP64:$src1, RFP64:$src2))]>;
 165 }
 166 // The FopST0 series are not included here because of the irregularities
 167 // in where the 'r' goes in assembly output.
 168 multiclass FPBinary<SDNode OpNode, Format fp, string asmstring> {
 169 // ST(0) = ST(0) + [mem]
 170 def _Fp32m  : FpI<(outs RFP32:$dst), (ins RFP32:$src1, f32mem:$src2), OneArgFPRW,
 171                   [(set RFP32:$dst,
 172                     (OpNode RFP32:$src1, (loadf32 addr:$src2)))]>;
 173 def _Fp64m  : FpI<(outs RFP64:$dst), (ins RFP64:$src1, f64mem:$src2), OneArgFPRW,
 174                   [(set RFP64:$dst,
 175                     (OpNode RFP64:$src1, (loadf64 addr:$src2)))]>;
 176 def _Fp64m32: FpI<(outs RFP64:$dst), (ins RFP64:$src1, f32mem:$src2), OneArgFPRW,
 177                   [(set RFP64:$dst,
 178                     (OpNode RFP64:$src1, (extloadf32 addr:$src2)))]>;
 179 def _F32m  : FPI<0xD8, fp, (outs), (ins f32mem:$src),
 180                  !strconcat("f", !strconcat(asmstring, "{s} $src"))>;
 181 def _F64m  : FPI<0xDC, fp, (outs), (ins f64mem:$src),
 182                  !strconcat("f", !strconcat(asmstring, "{l} $src"))>;
 183 // ST(0) = ST(0) + [memint]
 184 def _FpI16m32 : FpI<(outs RFP32:$dst), (ins RFP32:$src1, i16mem:$src2), OneArgFPRW,
 185                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 186                                        (X86fild addr:$src2, i16)))]>;
 187 def _FpI32m32 : FpI<(outs RFP32:$dst), (ins RFP32:$src1, i32mem:$src2), OneArgFPRW,
 188                     [(set RFP32:$dst, (OpNode RFP32:$src1,
 189                                        (X86fild addr:$src2, i32)))]>;
 190 def _FpI16m64 : FpI<(outs RFP64:$dst), (ins RFP64:$src1, i16mem:$src2), OneArgFPRW,
 191                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 192                                        (X86fild addr:$src2, i16)))]>;
 193 def _FpI32m64 : FpI<(outs RFP64:$dst), (ins RFP64:$src1, i32mem:$src2), OneArgFPRW,
 194                     [(set RFP64:$dst, (OpNode RFP64:$src1,
 195                                        (X86fild addr:$src2, i32)))]>;
 196 def _FI16m  : FPI<0xDE, fp, (outs), (ins i16mem:$src),
 197                   !strconcat("fi", !strconcat(asmstring, "{s} $src"))>;
 198 def _FI32m  : FPI<0xDA, fp, (outs), (ins i32mem:$src),
 199                   !strconcat("fi", !strconcat(asmstring, "{l} $src"))>;
 200 }
 201
 202 defm ADD : FPBinary_rr<fadd>;
 203 defm SUB : FPBinary_rr<fsub>;
 204 defm MUL : FPBinary_rr<fmul>;
 205 defm DIV : FPBinary_rr<fdiv>;
 206 defm ADD : FPBinary<fadd, MRM0m, "add">;
 207 defm SUB : FPBinary<fsub, MRM4m, "sub">;
 208 defm SUBR: FPBinary<fsub ,MRM5m, "subr">;
 209 defm MUL : FPBinary<fmul, MRM1m, "mul">;
 210 defm DIV : FPBinary<fdiv, MRM6m, "div">;
 211 defm DIVR: FPBinary<fdiv, MRM7m, "divr">;
 212
 213 class FPST0rInst<bits<8> o, string asm>
 214   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, D8;
 215 class FPrST0Inst<bits<8> o, string asm>
 216   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DC;
 217 class FPrST0PInst<bits<8> o, string asm>
 218   : FPI<o, AddRegFrm, (outs), (ins RST:$op), asm>, DE;
 219
 220 // NOTE: GAS and apparently all other AT&T style assemblers have a broken notion
 221 // of some of the 'reverse' forms of the fsub and fdiv instructions.  As such,
 222 // we have to put some 'r's in and take them out of weird places.
 223 def ADD_FST0r   : FPST0rInst <0xC0, "fadd $op">;
 224 def ADD_FrST0   : FPrST0Inst <0xC0, "fadd {%st(0), $op|$op, %ST(0)}">;
 225 def ADD_FPrST0  : FPrST0PInst<0xC0, "faddp $op">;
 226 def SUBR_FST0r  : FPST0rInst <0xE8, "fsubr $op">;
 227 def SUB_FrST0   : FPrST0Inst <0xE8, "fsub{r} {%st(0), $op|$op, %ST(0)}">;
 228 def SUB_FPrST0  : FPrST0PInst<0xE8, "fsub{r}p $op">;
 229 def SUB_FST0r   : FPST0rInst <0xE0, "fsub $op">;
 230 def SUBR_FrST0  : FPrST0Inst <0xE0, "fsub{|r} {%st(0), $op|$op, %ST(0)}">;
 231 def SUBR_FPrST0 : FPrST0PInst<0xE0, "fsub{|r}p $op">;
 232 def MUL_FST0r   : FPST0rInst <0xC8, "fmul $op">;
 233 def MUL_FrST0   : FPrST0Inst <0xC8, "fmul {%st(0), $op|$op, %ST(0)}">;
 234 def MUL_FPrST0  : FPrST0PInst<0xC8, "fmulp $op">;
 235 def DIVR_FST0r  : FPST0rInst <0xF8, "fdivr $op">;
 236 def DIV_FrST0   : FPrST0Inst <0xF8, "fdiv{r} {%st(0), $op|$op, %ST(0)}">;
 237 def DIV_FPrST0  : FPrST0PInst<0xF8, "fdiv{r}p $op">;
 238 def DIV_FST0r   : FPST0rInst <0xF0, "fdiv $op">;
 239 def DIVR_FrST0  : FPrST0Inst <0xF0, "fdiv{|r} {%st(0), $op|$op, %ST(0)}">;
 240 def DIVR_FPrST0 : FPrST0PInst<0xF0, "fdiv{|r}p $op">;
 241
 242 // Unary operations.
 243 multiclass FPUnary<SDNode OpNode, bits<8> opcode, string asmstring> {
 244 def _Fp32  : FpI<(outs RFP32:$dst), (ins RFP32:$src), OneArgFPRW,
 245                  [(set RFP32:$dst, (OpNode RFP32:$src))]>;
 246 def _Fp64  : FpI<(outs RFP64:$dst), (ins RFP64:$src), OneArgFPRW,
 247                  [(set RFP64:$dst, (OpNode RFP64:$src))]>;
 248 def _F     : FPI<opcode, RawFrm, (outs), (ins), asmstring>, D9;
 249 }
 250
 251 defm CHS : FPUnary<fneg, 0xE0, "fchs">;
 252 defm ABS : FPUnary<fabs, 0xE1, "fabs">;
 253 defm SQRT: FPUnary<fsqrt,0xFA, "fsqrt">;
 254 defm SIN : FPUnary<fsin, 0xFE, "fsin">;
 255 defm COS : FPUnary<fcos, 0xFF, "fcos">;
 256
 257 def TST_Fp32  : FpI<(outs), (ins RFP32:$src), OneArgFP,
 258                  []>;
 259 def TST_Fp64  : FpI<(outs), (ins RFP64:$src), OneArgFP,
 260                  []>;
 261 def TST_F  : FPI<0xE4, RawFrm, (outs), (ins), "ftst">, D9;
 262
 263 // Floating point cmovs.
 264 multiclass FPCMov<PatLeaf cc> {
 265   def _Fp32  : FpI<(outs RFP32:$dst), (ins RFP32:$src1, RFP32:$src2), CondMovFP,
 266                      [(set RFP32:$dst, (X86cmov RFP32:$src1, RFP32:$src2,
 267                                         cc))]>;
 268   def _Fp64  : FpI<(outs RFP64:$dst), (ins RFP64:$src1, RFP64:$src2), CondMovFP,
 269                      [(set RFP64:$dst, (X86cmov RFP64:$src1, RFP64:$src2,
 270                                         cc))]>;
 271 }
 272 let isTwoAddress = 1 in {
 273 defm CMOVB  : FPCMov<X86_COND_B>;
 274 defm CMOVBE : FPCMov<X86_COND_BE>;
 275 defm CMOVE  : FPCMov<X86_COND_E>;
 276 defm CMOVP  : FPCMov<X86_COND_P>;
 277 defm CMOVNB : FPCMov<X86_COND_AE>;
 278 defm CMOVNBE: FPCMov<X86_COND_A>;
 279 defm CMOVNE : FPCMov<X86_COND_NE>;
 280 defm CMOVNP : FPCMov<X86_COND_NP>;
 281 }
 282
 283 // These are not factored because there's no clean way to pass DA/DB.
 284 def CMOVB_F  : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 285                   "fcmovb {$op, %st(0)|%ST(0), $op}">, DA;
 286 def CMOVBE_F : FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 287                   "fcmovbe {$op, %st(0)|%ST(0), $op}">, DA;
 288 def CMOVE_F  : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 289                   "fcmove {$op, %st(0)|%ST(0), $op}">, DA;
 290 def CMOVP_F  : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 291                   "fcmovu  {$op, %st(0)|%ST(0), $op}">, DA;
 292 def CMOVNB_F : FPI<0xC0, AddRegFrm, (outs RST:$op), (ins),
 293                   "fcmovnb {$op, %st(0)|%ST(0), $op}">, DB;
 294 def CMOVNBE_F: FPI<0xD0, AddRegFrm, (outs RST:$op), (ins),
 295                   "fcmovnbe {$op, %st(0)|%ST(0), $op}">, DB;
 296 def CMOVNE_F : FPI<0xC8, AddRegFrm, (outs RST:$op), (ins),
 297                   "fcmovne {$op, %st(0)|%ST(0), $op}">, DB;
 298 def CMOVNP_F : FPI<0xD8, AddRegFrm, (outs RST:$op), (ins),
 299                   "fcmovnu {$op, %st(0)|%ST(0), $op}">, DB;
 300
 301 // Floating point loads & stores.
 302 def LD_Fp32m   : FpI<(outs RFP32:$dst), (ins f32mem:$src), ZeroArgFP,
 303                   [(set RFP32:$dst, (loadf32 addr:$src))]>;
 304 def LD_Fp64m   : FpI<(outs RFP64:$dst), (ins f64mem:$src), ZeroArgFP,
 305                   [(set RFP64:$dst, (loadf64 addr:$src))]>;
 306 def ILD_Fp16m32: FpI<(outs RFP32:$dst), (ins i16mem:$src), ZeroArgFP,
 307                   [(set RFP32:$dst, (X86fild addr:$src, i16))]>;
 308 def ILD_Fp32m32: FpI<(outs RFP32:$dst), (ins i32mem:$src), ZeroArgFP,
 309                   [(set RFP32:$dst, (X86fild addr:$src, i32))]>;
 310 def ILD_Fp64m32: FpI<(outs RFP32:$dst), (ins i64mem:$src), ZeroArgFP,
 311                   [(set RFP32:$dst, (X86fild addr:$src, i64))]>;
 312 def ILD_Fp16m64: FpI<(outs RFP64:$dst), (ins i16mem:$src), ZeroArgFP,
 313                   [(set RFP64:$dst, (X86fild addr:$src, i16))]>;
 314 def ILD_Fp32m64: FpI<(outs RFP64:$dst), (ins i32mem:$src), ZeroArgFP,
 315                   [(set RFP64:$dst, (X86fild addr:$src, i32))]>;
 316 def ILD_Fp64m64: FpI<(outs RFP64:$dst), (ins i64mem:$src), ZeroArgFP,
 317                   [(set RFP64:$dst, (X86fild addr:$src, i64))]>;
 318
 319 def ST_Fp32m   : FpI<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP,
 320                   [(store RFP32:$src, addr:$op)]>;
 321 def ST_Fp64m32 : FpI<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP,
 322                   [(truncstoref32 RFP64:$src, addr:$op)]>;
 323 def ST_Fp64m   : FpI<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP,
 324                   [(store RFP64:$src, addr:$op)]>;
 325
 326 def ST_FpP32m    : FpI<(outs), (ins f32mem:$op, RFP32:$src), OneArgFP, []>;
 327 def ST_FpP64m32  : FpI<(outs), (ins f32mem:$op, RFP64:$src), OneArgFP, []>;
 328 def ST_FpP64m    : FpI<(outs), (ins f64mem:$op, RFP64:$src), OneArgFP, []>;
 329 def IST_Fp16m32  : FpI<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP, []>;
 330 def IST_Fp32m32  : FpI<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP, []>;
 331 def IST_Fp64m32  : FpI<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP, []>;
 332 def IST_Fp16m64  : FpI<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP, []>;
 333 def IST_Fp32m64  : FpI<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP, []>;
 334 def IST_Fp64m64  : FpI<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP, []>;
 335
 336 def LD_F32m   : FPI<0xD9, MRM0m, (outs), (ins f32mem:$src), "fld{s} $src">;
 337 def LD_F64m   : FPI<0xDD, MRM0m, (outs), (ins f64mem:$src), "fld{l} $src">;
 338 def ILD_F16m  : FPI<0xDF, MRM0m, (outs), (ins i16mem:$src), "fild{s} $src">;
 339 def ILD_F32m  : FPI<0xDB, MRM0m, (outs), (ins i32mem:$src), "fild{l} $src">;
 340 def ILD_F64m  : FPI<0xDF, MRM5m, (outs), (ins i64mem:$src), "fild{ll} $src">;
 341 def ST_F32m   : FPI<0xD9, MRM2m, (outs), (ins f32mem:$dst), "fst{s} $dst">;
 342 def ST_F64m   : FPI<0xDD, MRM2m, (outs), (ins f64mem:$dst), "fst{l} $dst">;
 343 def ST_FP32m  : FPI<0xD9, MRM3m, (outs), (ins f32mem:$dst), "fstp{s} $dst">;
 344 def ST_FP64m  : FPI<0xDD, MRM3m, (outs), (ins f64mem:$dst), "fstp{l} $dst">;
 345 def IST_F16m  : FPI<0xDF, MRM2m, (outs), (ins i16mem:$dst), "fist{s} $dst">;
 346 def IST_F32m  : FPI<0xDB, MRM2m, (outs), (ins i32mem:$dst), "fist{l} $dst">;
 347 def IST_FP16m : FPI<0xDF, MRM3m, (outs), (ins i16mem:$dst), "fistp{s} $dst">;
 348 def IST_FP32m : FPI<0xDB, MRM3m, (outs), (ins i32mem:$dst), "fistp{l} $dst">;
 349 def IST_FP64m : FPI<0xDF, MRM7m, (outs), (ins i64mem:$dst), "fistp{ll} $dst">;
 350
 351 // FISTTP requires SSE3 even though it's a FPStack op.
 352 def ISTT_Fp16m32 : FpI_<(outs), (ins i16mem:$op, RFP32:$src), OneArgFP,
 353                     [(X86fp_to_i16mem RFP32:$src, addr:$op)]>,
 354                     Requires<[HasSSE3]>;
 355 def ISTT_Fp32m32 : FpI_<(outs), (ins i32mem:$op, RFP32:$src), OneArgFP,
 356                     [(X86fp_to_i32mem RFP32:$src, addr:$op)]>,
 357                     Requires<[HasSSE3]>;
 358 def ISTT_Fp64m32 : FpI_<(outs), (ins i64mem:$op, RFP32:$src), OneArgFP,
 359                     [(X86fp_to_i64mem RFP32:$src, addr:$op)]>,
 360                     Requires<[HasSSE3]>;
 361 def ISTT_Fp16m64 : FpI_<(outs), (ins i16mem:$op, RFP64:$src), OneArgFP,
 362                     [(X86fp_to_i16mem RFP64:$src, addr:$op)]>,
 363                     Requires<[HasSSE3]>;
 364 def ISTT_Fp32m64 : FpI_<(outs), (ins i32mem:$op, RFP64:$src), OneArgFP,
 365                     [(X86fp_to_i32mem RFP64:$src, addr:$op)]>,
 366                     Requires<[HasSSE3]>;
 367 def ISTT_Fp64m64 : FpI_<(outs), (ins i64mem:$op, RFP64:$src), OneArgFP,
 368                     [(X86fp_to_i64mem RFP64:$src, addr:$op)]>,
 369                     Requires<[HasSSE3]>;
 370
 371 def ISTT_FP16m : FPI<0xDF, MRM1m, (outs), (ins i16mem:$dst), "fisttp{s} $dst">;
 372 def ISTT_FP32m : FPI<0xDB, MRM1m, (outs), (ins i32mem:$dst), "fisttp{l} $dst">;
 373 def ISTT_FP64m : FPI<0xDD, MRM1m, (outs), (ins i64mem:$dst), "fisttp{ll} $dst">;
 374
 375 // FP Stack manipulation instructions.
 376 def LD_Frr   : FPI<0xC0, AddRegFrm, (outs), (ins RST:$op), "fld $op">, D9;
 377 def ST_Frr   : FPI<0xD0, AddRegFrm, (outs), (ins RST:$op), "fst $op">, DD;
 378 def ST_FPrr  : FPI<0xD8, AddRegFrm, (outs), (ins RST:$op), "fstp $op">, DD;
 379 def XCH_F    : FPI<0xC8, AddRegFrm, (outs), (ins RST:$op), "fxch $op">, D9;
 380
 381 // Floating point constant loads.
 382 let isReMaterializable = 1 in {
 383 def LD_Fp032 : FpI<(outs RFP32:$dst), (ins), ZeroArgFP,
 384                 [(set RFP32:$dst, fpimm0)]>;
 385 def LD_Fp132 : FpI<(outs RFP32:$dst), (ins), ZeroArgFP,
 386                 [(set RFP32:$dst, fpimm1)]>;
 387 def LD_Fp064 : FpI<(outs RFP64:$dst), (ins), ZeroArgFP,
 388                 [(set RFP64:$dst, fpimm0)]>;
 389 def LD_Fp164 : FpI<(outs RFP64:$dst), (ins), ZeroArgFP,
 390                 [(set RFP64:$dst, fpimm1)]>;
 391 }
 392
 393 def LD_F0 : FPI<0xEE, RawFrm, (outs), (ins), "fldz">, D9;
 394 def LD_F1 : FPI<0xE8, RawFrm, (outs), (ins), "fld1">, D9;
 395
 396
 397 // Floating point compares.
 398 def UCOM_Fpr32 : FpI<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 399                   []>;  // FPSW = cmp ST(0) with ST(i)
 400 def UCOM_FpIr32: FpI<(outs), (ins RFP32:$lhs, RFP32:$rhs), CompareFP,
 401                   [(X86cmp RFP32:$lhs, RFP32:$rhs)]>; // CC = ST(0) cmp ST(i)
 402 def UCOM_Fpr64 : FpI<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 403                   []>;  // FPSW = cmp ST(0) with ST(i)
 404 def UCOM_FpIr64: FpI<(outs), (ins RFP64:$lhs, RFP64:$rhs), CompareFP,
 405                   [(X86cmp RFP64:$lhs, RFP64:$rhs)]>; // CC = ST(0) cmp ST(i)
 406
 407 def UCOM_Fr    : FPI<0xE0, AddRegFrm,    // FPSW = cmp ST(0) with ST(i)
 408                     (outs), (ins RST:$reg),
 409                     "fucom $reg">, DD, Imp<[ST0],[]>;
 410 def UCOM_FPr   : FPI<0xE8, AddRegFrm,    // FPSW = cmp ST(0) with ST(i), pop
 411                     (outs), (ins RST:$reg),
 412                     "fucomp $reg">, DD, Imp<[ST0],[]>;
 413 def UCOM_FPPr  : FPI<0xE9, RawFrm,       // cmp ST(0) with ST(1), pop, pop
 414                     (outs), (ins),
 415                     "fucompp">, DA, Imp<[ST0],[]>;
 416
 417 def UCOM_FIr   : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i)
 418                     (outs), (ins RST:$reg),
 419                     "fucomi {$reg, %st(0)|%ST(0), $reg}">, DB, Imp<[ST0],[]>;
 420 def UCOM_FIPr  : FPI<0xE8, AddRegFrm,     // CC = cmp ST(0) with ST(i), pop
 421                     (outs), (ins RST:$reg),
 422                     "fucomip {$reg, %st(0)|%ST(0), $reg}">, DF, Imp<[ST0],[]>;
 423
 424 // Floating point flag ops.
 425 def FNSTSW8r  : I<0xE0, RawFrm,                  // AX = fp flags
 426                   (outs), (ins), "fnstsw", []>, DF, Imp<[],[AX]>;
 427
 428 def FNSTCW16m : I<0xD9, MRM7m,                   // [mem16] = X87 control world
 429                   (outs), (ins i16mem:$dst), "fnstcw $dst", []>;
 430 def FLDCW16m  : I<0xD9, MRM5m,                   // X87 control world = [mem16]
 431                   (outs), (ins i16mem:$dst), "fldcw $dst", []>;
 432
 433 //===----------------------------------------------------------------------===//
 434 // Non-Instruction Patterns
 435 //===----------------------------------------------------------------------===//
 436
 437 // Required for RET of f32 / f64 values.
 438 def : Pat<(X86fld addr:$src, f32), (LD_Fp32m addr:$src)>;
 439 def : Pat<(X86fld addr:$src, f64), (LD_Fp64m addr:$src)>;
 440
 441 // Required for CALL which return f32 / f64 values.
 442 def : Pat<(X86fst RFP32:$src, addr:$op, f32), (ST_Fp32m addr:$op, RFP32:$src)>;
 443 def : Pat<(X86fst RFP64:$src, addr:$op, f32), (ST_Fp64m32 addr:$op, RFP64:$src)>;
 444 def : Pat<(X86fst RFP64:$src, addr:$op, f64), (ST_Fp64m addr:$op, RFP64:$src)>;
 445
 446 // Floating point constant -0.0 and -1.0
 447 def : Pat<(f32 fpimmneg0), (CHS_Fp32 (LD_Fp032))>, Requires<[FPStack]>;
 448 def : Pat<(f32 fpimmneg1), (CHS_Fp32 (LD_Fp132))>, Requires<[FPStack]>;
 449 def : Pat<(f64 fpimmneg0), (CHS_Fp64 (LD_Fp064))>, Requires<[FPStack]>;
 450 def : Pat<(f64 fpimmneg1), (CHS_Fp64 (LD_Fp164))>, Requires<[FPStack]>;
 451
 452 // Used to conv. i64 to f64 since there isn't a SSE version.
 453 def : Pat<(X86fildflag addr:$src, i64), (ILD_Fp64m64 addr:$src)>;
 454
 455 def : Pat<(extloadf32 addr:$src),
 456            (MOV_Fp3264 (LD_Fp32m addr:$src))>, Requires<[FPStack]>;
 457 def : Pat<(fextend RFP32:$src), (MOV_Fp3264 RFP32:$src)>, Requires<[FPStack]>;