lib/Target/X86/X86InstrFormats.td

   1 //===- X86InstrFormats.td - X86 Instruction Formats --------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // X86 Instruction Format Definitions.
  12 //
  13
  14 // Format specifies the encoding used by the instruction.  This is part of the
  15 // ad-hoc solution used to emit machine instruction encodings by our machine
  16 // code emitter.
  17 class Format<bits<6> val> {
  18   bits<6> Value = val;
  19 }
  20
  21 def Pseudo     : Format<0>; def RawFrm     : Format<1>;
  22 def AddRegFrm  : Format<2>; def MRMDestReg : Format<3>;
  23 def MRMDestMem : Format<4>; def MRMSrcReg  : Format<5>;
  24 def MRMSrcMem  : Format<6>;
  25 def MRM0r  : Format<16>; def MRM1r  : Format<17>; def MRM2r  : Format<18>;
  26 def MRM3r  : Format<19>; def MRM4r  : Format<20>; def MRM5r  : Format<21>;
  27 def MRM6r  : Format<22>; def MRM7r  : Format<23>;
  28 def MRM0m  : Format<24>; def MRM1m  : Format<25>; def MRM2m  : Format<26>;
  29 def MRM3m  : Format<27>; def MRM4m  : Format<28>; def MRM5m  : Format<29>;
  30 def MRM6m  : Format<30>; def MRM7m  : Format<31>;
  31 def MRMInitReg : Format<32>;
  32 def MRM_C1 : Format<33>;
  33 def MRM_C2 : Format<34>;
  34 def MRM_C3 : Format<35>;
  35 def MRM_C4 : Format<36>;
  36 def MRM_C8 : Format<37>;
  37 def MRM_C9 : Format<38>;
  38 def MRM_E8 : Format<39>;
  39 def MRM_F0 : Format<40>;
  40 def MRM_F8 : Format<41>;
  41 def MRM_F9 : Format<42>;
  42
  43 // ImmType - This specifies the immediate type used by an instruction. This is
  44 // part of the ad-hoc solution used to emit machine instruction encodings by our
  45 // machine code emitter.
  46 class ImmType<bits<3> val> {
  47   bits<3> Value = val;
  48 }
  49 def NoImm      : ImmType<0>;
  50 def Imm8       : ImmType<1>;
  51 def Imm8PCRel  : ImmType<2>;
  52 def Imm16      : ImmType<3>;
  53 def Imm32      : ImmType<4>;
  54 def Imm32PCRel : ImmType<5>;
  55 def Imm64      : ImmType<6>;
  56
  57 // FPFormat - This specifies what form this FP instruction has.  This is used by
  58 // the Floating-Point stackifier pass.
  59 class FPFormat<bits<3> val> {
  60   bits<3> Value = val;
  61 }
  62 def NotFP      : FPFormat<0>;
  63 def ZeroArgFP  : FPFormat<1>;
  64 def OneArgFP   : FPFormat<2>;
  65 def OneArgFPRW : FPFormat<3>;
  66 def TwoArgFP   : FPFormat<4>;
  67 def CompareFP  : FPFormat<5>;
  68 def CondMovFP  : FPFormat<6>;
  69 def SpecialFP  : FPFormat<7>;
  70
  71 // Class specifying the SSE execution domain, used by the SSEDomainFix pass.
  72 // Instruction execution domain.
  73 class Domain<bits<2> val> {
  74   bits<2> Value = val;
  75 }
  76 def GenericDomain   : Domain<0>;
  77 def SSEPackedInt    : Domain<1>;
  78 def SSEPackedSingle : Domain<2>;
  79 def SSEPackedDouble : Domain<3>;
  80
  81 // Prefix byte classes which are used to indicate to the ad-hoc machine code
  82 // emitter that various prefix bytes are required.
  83 class OpSize { bit hasOpSizePrefix = 1; }
  84 class AdSize { bit hasAdSizePrefix = 1; }
  85 class REX_W  { bit hasREX_WPrefix = 1; }
  86 class LOCK   { bit hasLockPrefix = 1; }
  87 class SegFS  { bits<2> SegOvrBits = 1; }
  88 class SegGS  { bits<2> SegOvrBits = 2; }
  89 class TB     { bits<4> Prefix = 1; }
  90 class REP    { bits<4> Prefix = 2; }
  91 class D8     { bits<4> Prefix = 3; }
  92 class D9     { bits<4> Prefix = 4; }
  93 class DA     { bits<4> Prefix = 5; }
  94 class DB     { bits<4> Prefix = 6; }
  95 class DC     { bits<4> Prefix = 7; }
  96 class DD     { bits<4> Prefix = 8; }
  97 class DE     { bits<4> Prefix = 9; }
  98 class DF     { bits<4> Prefix = 10; }
  99 class XD     { bits<4> Prefix = 11; }
 100 class XS     { bits<4> Prefix = 12; }
 101 class T8     { bits<4> Prefix = 13; }
 102 class TA     { bits<4> Prefix = 14; }
 103 class TF     { bits<4> Prefix = 15; }
 104
 105 class X86Inst<bits<8> opcod, Format f, ImmType i, dag outs, dag ins,
 106               string AsmStr, Domain d = GenericDomain>
 107   : Instruction {
 108   let Namespace = "X86";
 109
 110   bits<8> Opcode = opcod;
 111   Format Form = f;
 112   bits<6> FormBits = Form.Value;
 113   ImmType ImmT = i;
 114   bits<3> ImmTypeBits = ImmT.Value;
 115
 116   dag OutOperandList = outs;
 117   dag InOperandList = ins;
 118   string AsmString = AsmStr;
 119
 120   //
 121   // Attributes specific to X86 instructions...
 122   //
 123   bit hasOpSizePrefix = 0;  // Does this inst have a 0x66 prefix?
 124   bit hasAdSizePrefix = 0;  // Does this inst have a 0x67 prefix?
 125
 126   bits<4> Prefix = 0;       // Which prefix byte does this inst have?
 127   bit hasREX_WPrefix  = 0;  // Does this inst requires the REX.W prefix?
 128   FPFormat FPForm;          // What flavor of FP instruction is this?
 129   bits<3> FPFormBits = 0;
 130   bit hasLockPrefix = 0;    // Does this inst have a 0xF0 prefix?
 131   bits<2> SegOvrBits = 0;   // Segment override prefix.
 132   Domain Dom = d;
 133   bits<2> DomainBits = Dom.Value;
 134 }
 135
 136 class I<bits<8> o, Format f, dag outs, dag ins, string asm,
 137         list<dag> pattern, Domain d = GenericDomain>
 138   : X86Inst<o, f, NoImm, outs, ins, asm, d> {
 139   let Pattern = pattern;
 140   let CodeSize = 3;
 141 }
 142 class Ii8 <bits<8> o, Format f, dag outs, dag ins, string asm,
 143            list<dag> pattern, Domain d = GenericDomain>
 144   : X86Inst<o, f, Imm8, outs, ins, asm, d> {
 145   let Pattern = pattern;
 146   let CodeSize = 3;
 147 }
 148 class Ii8PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 149                list<dag> pattern>
 150   : X86Inst<o, f, Imm8PCRel, outs, ins, asm> {
 151   let Pattern = pattern;
 152   let CodeSize = 3;
 153 }
 154 class Ii16<bits<8> o, Format f, dag outs, dag ins, string asm,
 155            list<dag> pattern>
 156   : X86Inst<o, f, Imm16, outs, ins, asm> {
 157   let Pattern = pattern;
 158   let CodeSize = 3;
 159 }
 160 class Ii32<bits<8> o, Format f, dag outs, dag ins, string asm,
 161            list<dag> pattern>
 162   : X86Inst<o, f, Imm32, outs, ins, asm> {
 163   let Pattern = pattern;
 164   let CodeSize = 3;
 165 }
 166
 167 class Ii32PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 168            list<dag> pattern>
 169   : X86Inst<o, f, Imm32PCRel, outs, ins, asm> {
 170   let Pattern = pattern;
 171   let CodeSize = 3;
 172 }
 173
 174 // FPStack Instruction Templates:
 175 // FPI - Floating Point Instruction template.
 176 class FPI<bits<8> o, Format F, dag outs, dag ins, string asm>
 177   : I<o, F, outs, ins, asm, []> {}
 178
 179 // FpI_ - Floating Point Psuedo Instruction template. Not Predicated.
 180 class FpI_<dag outs, dag ins, FPFormat fp, list<dag> pattern>
 181   : X86Inst<0, Pseudo, NoImm, outs, ins, ""> {
 182   let FPForm = fp; let FPFormBits = FPForm.Value;
 183   let Pattern = pattern;
 184 }
 185
 186 // Templates for instructions that use a 16- or 32-bit segmented address as
 187 //  their only operand: lcall (FAR CALL) and ljmp (FAR JMP)
 188 //
 189 //   Iseg16 - 16-bit segment selector, 16-bit offset
 190 //   Iseg32 - 16-bit segment selector, 32-bit offset
 191
 192 class Iseg16 <bits<8> o, Format f, dag outs, dag ins, string asm,
 193               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 194   let Pattern = pattern;
 195   let CodeSize = 3;
 196 }
 197
 198 class Iseg32 <bits<8> o, Format f, dag outs, dag ins, string asm,
 199               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 200   let Pattern = pattern;
 201   let CodeSize = 3;
 202 }
 203
 204 // SSE1 Instruction Templates:
 205 //
 206 //   SSI   - SSE1 instructions with XS prefix.
 207 //   PSI   - SSE1 instructions with TB prefix.
 208 //   PSIi8 - SSE1 instructions with ImmT == Imm8 and TB prefix.
 209
 210 class SSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 211       : I<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 212 class SSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 213             list<dag> pattern>
 214       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 215 class PSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 216       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 217         Requires<[HasSSE1]>;
 218 class PSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 219             list<dag> pattern>
 220       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 221         Requires<[HasSSE1]>;
 222
 223 // SSE2 Instruction Templates:
 224 //
 225 //   SDI    - SSE2 instructions with XD prefix.
 226 //   SDIi8  - SSE2 instructions with ImmT == Imm8 and XD prefix.
 227 //   SSDIi8 - SSE2 instructions with ImmT == Imm8 and XS prefix.
 228 //   PDI    - SSE2 instructions with TB and OpSize prefixes.
 229 //   PDIi8  - SSE2 instructions with ImmT == Imm8 and TB and OpSize prefixes.
 230
 231 class SDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 232       : I<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 233 class SDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 234             list<dag> pattern>
 235       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 236 class SSDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 237              list<dag> pattern>
 238       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE2]>;
 239 class PDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 240       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 241         Requires<[HasSSE2]>;
 242 class PDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 243             list<dag> pattern>
 244       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 245         Requires<[HasSSE2]>;
 246
 247 // SSE3 Instruction Templates:
 248 //
 249 //   S3I   - SSE3 instructions with TB and OpSize prefixes.
 250 //   S3SI  - SSE3 instructions with XS prefix.
 251 //   S3DI  - SSE3 instructions with XD prefix.
 252
 253 class S3SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 254            list<dag> pattern>
 255       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, XS,
 256         Requires<[HasSSE3]>;
 257 class S3DI<bits<8> o, Format F, dag outs, dag ins, string asm,
 258            list<dag> pattern>
 259       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, XD,
 260         Requires<[HasSSE3]>;
 261 class S3I<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 262       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 263         Requires<[HasSSE3]>;
 264
 265
 266 // SSSE3 Instruction Templates:
 267 //
 268 //   SS38I - SSSE3 instructions with T8 prefix.
 269 //   SS3AI - SSSE3 instructions with TA prefix.
 270 //
 271 // Note: SSSE3 instructions have 64-bit and 128-bit versions. The 64-bit version
 272 // uses the MMX registers. We put those instructions here because they better
 273 // fit into the SSSE3 instruction category rather than the MMX category.
 274
 275 class SS38I<bits<8> o, Format F, dag outs, dag ins, string asm,
 276             list<dag> pattern>
 277       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 278         Requires<[HasSSSE3]>;
 279 class SS3AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 280             list<dag> pattern>
 281       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 282         Requires<[HasSSSE3]>;
 283
 284 // SSE4.1 Instruction Templates:
 285 //
 286 //   SS48I - SSE 4.1 instructions with T8 prefix.
 287 //   SS41AIi8 - SSE 4.1 instructions with TA prefix and ImmT == Imm8.
 288 //
 289 class SS48I<bits<8> o, Format F, dag outs, dag ins, string asm,
 290             list<dag> pattern>
 291       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 292         Requires<[HasSSE41]>;
 293 class SS4AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 294             list<dag> pattern>
 295       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 296         Requires<[HasSSE41]>;
 297
 298 // SSE4.2 Instruction Templates:
 299 //
 300 //   SS428I - SSE 4.2 instructions with T8 prefix.
 301 class SS428I<bits<8> o, Format F, dag outs, dag ins, string asm,
 302              list<dag> pattern>
 303       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 304         Requires<[HasSSE42]>;
 305
 306 //   SS42FI - SSE 4.2 instructions with TF prefix.
 307 class SS42FI<bits<8> o, Format F, dag outs, dag ins, string asm,
 308               list<dag> pattern>
 309       : I<o, F, outs, ins, asm, pattern>, TF, Requires<[HasSSE42]>;
 310
 311 //   SS42AI = SSE 4.2 instructions with TA prefix
 312 class SS42AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 313              list<dag> pattern>
 314       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 315         Requires<[HasSSE42]>;
 316
 317 // X86-64 Instruction templates...
 318 //
 319
 320 class RI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 321       : I<o, F, outs, ins, asm, pattern>, REX_W;
 322 class RIi8 <bits<8> o, Format F, dag outs, dag ins, string asm,
 323             list<dag> pattern>
 324       : Ii8<o, F, outs, ins, asm, pattern>, REX_W;
 325 class RIi32 <bits<8> o, Format F, dag outs, dag ins, string asm,
 326              list<dag> pattern>
 327       : Ii32<o, F, outs, ins, asm, pattern>, REX_W;
 328
 329 class RIi64<bits<8> o, Format f, dag outs, dag ins, string asm,
 330             list<dag> pattern>
 331   : X86Inst<o, f, Imm64, outs, ins, asm>, REX_W {
 332   let Pattern = pattern;
 333   let CodeSize = 3;
 334 }
 335
 336 class RSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 337            list<dag> pattern>
 338       : SSI<o, F, outs, ins, asm, pattern>, REX_W;
 339 class RSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 340            list<dag> pattern>
 341       : SDI<o, F, outs, ins, asm, pattern>, REX_W;
 342 class RPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 343            list<dag> pattern>
 344       : PDI<o, F, outs, ins, asm, pattern>, REX_W;
 345
 346 // MMX Instruction templates
 347 //
 348
 349 // MMXI   - MMX instructions with TB prefix.
 350 // MMXI64 - MMX instructions with TB prefix valid only in 64 bit mode.
 351 // MMX2I  - MMX / SSE2 instructions with TB and OpSize prefixes.
 352 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 353 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 354 // MMXID  - MMX instructions with XD prefix.
 355 // MMXIS  - MMX instructions with XS prefix.
 356 class MMXI<bits<8> o, Format F, dag outs, dag ins, string asm,
 357            list<dag> pattern>
 358       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 359 class MMXI64<bits<8> o, Format F, dag outs, dag ins, string asm,
 360              list<dag> pattern>
 361       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX,In64BitMode]>;
 362 class MMXRI<bits<8> o, Format F, dag outs, dag ins, string asm,
 363             list<dag> pattern>
 364       : I<o, F, outs, ins, asm, pattern>, TB, REX_W, Requires<[HasMMX]>;
 365 class MMX2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 366             list<dag> pattern>
 367       : I<o, F, outs, ins, asm, pattern>, TB, OpSize, Requires<[HasMMX]>;
 368 class MMXIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 369              list<dag> pattern>
 370       : Ii8<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 371 class MMXID<bits<8> o, Format F, dag outs, dag ins, string asm,
 372             list<dag> pattern>
 373       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasMMX]>;
 374 class MMXIS<bits<8> o, Format F, dag outs, dag ins, string asm,
 375             list<dag> pattern>
 376       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasMMX]>;