lib/Target/X86/X86InstrFormats.td

   1 //===- X86InstrFormats.td - X86 Instruction Formats --------*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file is distributed under the University of Illinois Open Source
   6 // License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9
  10 //===----------------------------------------------------------------------===//
  11 // X86 Instruction Format Definitions.
  12 //
  13
  14 // Format specifies the encoding used by the instruction.  This is part of the
  15 // ad-hoc solution used to emit machine instruction encodings by our machine
  16 // code emitter.
  17 class Format<bits<6> val> {
  18   bits<6> Value = val;
  19 }
  20
  21 def Pseudo     : Format<0>; def RawFrm     : Format<1>;
  22 def AddRegFrm  : Format<2>; def MRMDestReg : Format<3>;
  23 def MRMDestMem : Format<4>; def MRMSrcReg  : Format<5>;
  24 def MRMSrcMem  : Format<6>;
  25 def MRM0r  : Format<16>; def MRM1r  : Format<17>; def MRM2r  : Format<18>;
  26 def MRM3r  : Format<19>; def MRM4r  : Format<20>; def MRM5r  : Format<21>;
  27 def MRM6r  : Format<22>; def MRM7r  : Format<23>;
  28 def MRM0m  : Format<24>; def MRM1m  : Format<25>; def MRM2m  : Format<26>;
  29 def MRM3m  : Format<27>; def MRM4m  : Format<28>; def MRM5m  : Format<29>;
  30 def MRM6m  : Format<30>; def MRM7m  : Format<31>;
  31 def MRMInitReg : Format<32>;
  32 def MRM_C1 : Format<33>;
  33 def MRM_C2 : Format<34>;
  34 def MRM_C3 : Format<35>;
  35 def MRM_C4 : Format<36>;
  36 def MRM_C8 : Format<37>;
  37 def MRM_C9 : Format<38>;
  38 def MRM_E8 : Format<39>;
  39 def MRM_F0 : Format<40>;
  40 def MRM_F8 : Format<41>;
  41 def MRM_F9 : Format<42>;
  42
  43 // ImmType - This specifies the immediate type used by an instruction. This is
  44 // part of the ad-hoc solution used to emit machine instruction encodings by our
  45 // machine code emitter.
  46 class ImmType<bits<3> val> {
  47   bits<3> Value = val;
  48 }
  49 def NoImm      : ImmType<0>;
  50 def Imm8       : ImmType<1>;
  51 def Imm8PCRel  : ImmType<2>;
  52 def Imm16      : ImmType<3>;
  53 def Imm32      : ImmType<4>;
  54 def Imm32PCRel : ImmType<5>;
  55 def Imm64      : ImmType<6>;
  56
  57 // FPFormat - This specifies what form this FP instruction has.  This is used by
  58 // the Floating-Point stackifier pass.
  59 class FPFormat<bits<3> val> {
  60   bits<3> Value = val;
  61 }
  62 def NotFP      : FPFormat<0>;
  63 def ZeroArgFP  : FPFormat<1>;
  64 def OneArgFP   : FPFormat<2>;
  65 def OneArgFPRW : FPFormat<3>;
  66 def TwoArgFP   : FPFormat<4>;
  67 def CompareFP  : FPFormat<5>;
  68 def CondMovFP  : FPFormat<6>;
  69 def SpecialFP  : FPFormat<7>;
  70
  71 // Class specifying the SSE execution domain, used by the SSEDomainFix pass.
  72 // Keep in sync with tables in X86InstrInfo.cpp.
  73 class Domain<bits<2> val> {
  74   bits<2> Value = val;
  75 }
  76 def GenericDomain   : Domain<0>;
  77 def SSEPackedSingle : Domain<1>;
  78 def SSEPackedDouble : Domain<2>;
  79 def SSEPackedInt    : Domain<3>;
  80
  81 // Prefix byte classes which are used to indicate to the ad-hoc machine code
  82 // emitter that various prefix bytes are required.
  83 class OpSize { bit hasOpSizePrefix = 1; }
  84 class AdSize { bit hasAdSizePrefix = 1; }
  85 class REX_W  { bit hasREX_WPrefix = 1; }
  86 class LOCK   { bit hasLockPrefix = 1; }
  87 class SegFS  { bits<2> SegOvrBits = 1; }
  88 class SegGS  { bits<2> SegOvrBits = 2; }
  89 class TB     { bits<4> Prefix = 1; }
  90 class REP    { bits<4> Prefix = 2; }
  91 class D8     { bits<4> Prefix = 3; }
  92 class D9     { bits<4> Prefix = 4; }
  93 class DA     { bits<4> Prefix = 5; }
  94 class DB     { bits<4> Prefix = 6; }
  95 class DC     { bits<4> Prefix = 7; }
  96 class DD     { bits<4> Prefix = 8; }
  97 class DE     { bits<4> Prefix = 9; }
  98 class DF     { bits<4> Prefix = 10; }
  99 class XD     { bits<4> Prefix = 11; }
 100 class XS     { bits<4> Prefix = 12; }
 101 class T8     { bits<4> Prefix = 13; }
 102 class TA     { bits<4> Prefix = 14; }
 103 class TF     { bits<4> Prefix = 15; }
 104
 105 class X86Inst<bits<8> opcod, Format f, ImmType i, dag outs, dag ins,
 106               string AsmStr, Domain d = GenericDomain>
 107   : Instruction {
 108   let Namespace = "X86";
 109
 110   bits<8> Opcode = opcod;
 111   Format Form = f;
 112   bits<6> FormBits = Form.Value;
 113   ImmType ImmT = i;
 114
 115   dag OutOperandList = outs;
 116   dag InOperandList = ins;
 117   string AsmString = AsmStr;
 118
 119   //
 120   // Attributes specific to X86 instructions...
 121   //
 122   bit hasOpSizePrefix = 0;  // Does this inst have a 0x66 prefix?
 123   bit hasAdSizePrefix = 0;  // Does this inst have a 0x67 prefix?
 124
 125   bits<4> Prefix = 0;       // Which prefix byte does this inst have?
 126   bit hasREX_WPrefix  = 0;  // Does this inst requires the REX.W prefix?
 127   FPFormat FPForm = NotFP;  // What flavor of FP instruction is this?
 128   bit hasLockPrefix = 0;    // Does this inst have a 0xF0 prefix?
 129   bits<2> SegOvrBits = 0;   // Segment override prefix.
 130   Domain ExeDomain = d;
 131 }
 132
 133 class I<bits<8> o, Format f, dag outs, dag ins, string asm,
 134         list<dag> pattern, Domain d = GenericDomain>
 135   : X86Inst<o, f, NoImm, outs, ins, asm, d> {
 136   let Pattern = pattern;
 137   let CodeSize = 3;
 138 }
 139 class Ii8 <bits<8> o, Format f, dag outs, dag ins, string asm,
 140            list<dag> pattern, Domain d = GenericDomain>
 141   : X86Inst<o, f, Imm8, outs, ins, asm, d> {
 142   let Pattern = pattern;
 143   let CodeSize = 3;
 144 }
 145 class Ii8PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 146                list<dag> pattern>
 147   : X86Inst<o, f, Imm8PCRel, outs, ins, asm> {
 148   let Pattern = pattern;
 149   let CodeSize = 3;
 150 }
 151 class Ii16<bits<8> o, Format f, dag outs, dag ins, string asm,
 152            list<dag> pattern>
 153   : X86Inst<o, f, Imm16, outs, ins, asm> {
 154   let Pattern = pattern;
 155   let CodeSize = 3;
 156 }
 157 class Ii32<bits<8> o, Format f, dag outs, dag ins, string asm,
 158            list<dag> pattern>
 159   : X86Inst<o, f, Imm32, outs, ins, asm> {
 160   let Pattern = pattern;
 161   let CodeSize = 3;
 162 }
 163
 164 class Ii32PCRel<bits<8> o, Format f, dag outs, dag ins, string asm,
 165            list<dag> pattern>
 166   : X86Inst<o, f, Imm32PCRel, outs, ins, asm> {
 167   let Pattern = pattern;
 168   let CodeSize = 3;
 169 }
 170
 171 // FPStack Instruction Templates:
 172 // FPI - Floating Point Instruction template.
 173 class FPI<bits<8> o, Format F, dag outs, dag ins, string asm>
 174   : I<o, F, outs, ins, asm, []> {}
 175
 176 // FpI_ - Floating Point Psuedo Instruction template. Not Predicated.
 177 class FpI_<dag outs, dag ins, FPFormat fp, list<dag> pattern>
 178   : X86Inst<0, Pseudo, NoImm, outs, ins, ""> {
 179   let FPForm = fp;
 180   let Pattern = pattern;
 181 }
 182
 183 // Templates for instructions that use a 16- or 32-bit segmented address as
 184 //  their only operand: lcall (FAR CALL) and ljmp (FAR JMP)
 185 //
 186 //   Iseg16 - 16-bit segment selector, 16-bit offset
 187 //   Iseg32 - 16-bit segment selector, 32-bit offset
 188
 189 class Iseg16 <bits<8> o, Format f, dag outs, dag ins, string asm,
 190               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 191   let Pattern = pattern;
 192   let CodeSize = 3;
 193 }
 194
 195 class Iseg32 <bits<8> o, Format f, dag outs, dag ins, string asm,
 196               list<dag> pattern> : X86Inst<o, f, NoImm, outs, ins, asm> {
 197   let Pattern = pattern;
 198   let CodeSize = 3;
 199 }
 200
 201 // SSE1 Instruction Templates:
 202 //
 203 //   SSI   - SSE1 instructions with XS prefix.
 204 //   PSI   - SSE1 instructions with TB prefix.
 205 //   PSIi8 - SSE1 instructions with ImmT == Imm8 and TB prefix.
 206
 207 class SSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 208       : I<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 209 class SSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 210             list<dag> pattern>
 211       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE1]>;
 212 class PSI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 213       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 214         Requires<[HasSSE1]>;
 215 class PSIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 216             list<dag> pattern>
 217       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedSingle>, TB,
 218         Requires<[HasSSE1]>;
 219
 220 // SSE2 Instruction Templates:
 221 //
 222 //   SDI    - SSE2 instructions with XD prefix.
 223 //   SDIi8  - SSE2 instructions with ImmT == Imm8 and XD prefix.
 224 //   SSDIi8 - SSE2 instructions with ImmT == Imm8 and XS prefix.
 225 //   PDI    - SSE2 instructions with TB and OpSize prefixes.
 226 //   PDIi8  - SSE2 instructions with ImmT == Imm8 and TB and OpSize prefixes.
 227
 228 class SDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 229       : I<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 230 class SDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 231             list<dag> pattern>
 232       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasSSE2]>;
 233 class SSDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 234              list<dag> pattern>
 235       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasSSE2]>;
 236 class PDI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 237       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 238         Requires<[HasSSE2]>;
 239 class PDIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 240             list<dag> pattern>
 241       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 242         Requires<[HasSSE2]>;
 243
 244 // SSE3 Instruction Templates:
 245 //
 246 //   S3I   - SSE3 instructions with TB and OpSize prefixes.
 247 //   S3SI  - SSE3 instructions with XS prefix.
 248 //   S3DI  - SSE3 instructions with XD prefix.
 249
 250 class S3SI<bits<8> o, Format F, dag outs, dag ins, string asm,
 251            list<dag> pattern>
 252       : I<o, F, outs, ins, asm, pattern, SSEPackedSingle>, XS,
 253         Requires<[HasSSE3]>;
 254 class S3DI<bits<8> o, Format F, dag outs, dag ins, string asm,
 255            list<dag> pattern>
 256       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, XD,
 257         Requires<[HasSSE3]>;
 258 class S3I<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 259       : I<o, F, outs, ins, asm, pattern, SSEPackedDouble>, TB, OpSize,
 260         Requires<[HasSSE3]>;
 261
 262
 263 // SSSE3 Instruction Templates:
 264 //
 265 //   SS38I - SSSE3 instructions with T8 prefix.
 266 //   SS3AI - SSSE3 instructions with TA prefix.
 267 //
 268 // Note: SSSE3 instructions have 64-bit and 128-bit versions. The 64-bit version
 269 // uses the MMX registers. We put those instructions here because they better
 270 // fit into the SSSE3 instruction category rather than the MMX category.
 271
 272 class SS38I<bits<8> o, Format F, dag outs, dag ins, string asm,
 273             list<dag> pattern>
 274       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 275         Requires<[HasSSSE3]>;
 276 class SS3AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 277             list<dag> pattern>
 278       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 279         Requires<[HasSSSE3]>;
 280
 281 // SSE4.1 Instruction Templates:
 282 //
 283 //   SS48I - SSE 4.1 instructions with T8 prefix.
 284 //   SS41AIi8 - SSE 4.1 instructions with TA prefix and ImmT == Imm8.
 285 //
 286 class SS48I<bits<8> o, Format F, dag outs, dag ins, string asm,
 287             list<dag> pattern>
 288       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 289         Requires<[HasSSE41]>;
 290 class SS4AIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 291             list<dag> pattern>
 292       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 293         Requires<[HasSSE41]>;
 294
 295 // SSE4.2 Instruction Templates:
 296 //
 297 //   SS428I - SSE 4.2 instructions with T8 prefix.
 298 class SS428I<bits<8> o, Format F, dag outs, dag ins, string asm,
 299              list<dag> pattern>
 300       : I<o, F, outs, ins, asm, pattern, SSEPackedInt>, T8,
 301         Requires<[HasSSE42]>;
 302
 303 //   SS42FI - SSE 4.2 instructions with TF prefix.
 304 class SS42FI<bits<8> o, Format F, dag outs, dag ins, string asm,
 305               list<dag> pattern>
 306       : I<o, F, outs, ins, asm, pattern>, TF, Requires<[HasSSE42]>;
 307
 308 //   SS42AI = SSE 4.2 instructions with TA prefix
 309 class SS42AI<bits<8> o, Format F, dag outs, dag ins, string asm,
 310              list<dag> pattern>
 311       : Ii8<o, F, outs, ins, asm, pattern, SSEPackedInt>, TA,
 312         Requires<[HasSSE42]>;
 313
 314 // X86-64 Instruction templates...
 315 //
 316
 317 class RI<bits<8> o, Format F, dag outs, dag ins, string asm, list<dag> pattern>
 318       : I<o, F, outs, ins, asm, pattern>, REX_W;
 319 class RIi8 <bits<8> o, Format F, dag outs, dag ins, string asm,
 320             list<dag> pattern>
 321       : Ii8<o, F, outs, ins, asm, pattern>, REX_W;
 322 class RIi32 <bits<8> o, Format F, dag outs, dag ins, string asm,
 323              list<dag> pattern>
 324       : Ii32<o, F, outs, ins, asm, pattern>, REX_W;
 325
 326 class RIi64<bits<8> o, Format f, dag outs, dag ins, string asm,
 327             list<dag> pattern>
 328   : X86Inst<o, f, Imm64, outs, ins, asm>, REX_W {
 329   let Pattern = pattern;
 330   let CodeSize = 3;
 331 }
 332
 333 class RSSI<bits<8> o, Format F, dag outs, dag ins, string asm,
 334            list<dag> pattern>
 335       : SSI<o, F, outs, ins, asm, pattern>, REX_W;
 336 class RSDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 337            list<dag> pattern>
 338       : SDI<o, F, outs, ins, asm, pattern>, REX_W;
 339 class RPDI<bits<8> o, Format F, dag outs, dag ins, string asm,
 340            list<dag> pattern>
 341       : PDI<o, F, outs, ins, asm, pattern>, REX_W;
 342
 343 // MMX Instruction templates
 344 //
 345
 346 // MMXI   - MMX instructions with TB prefix.
 347 // MMXI64 - MMX instructions with TB prefix valid only in 64 bit mode.
 348 // MMX2I  - MMX / SSE2 instructions with TB and OpSize prefixes.
 349 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 350 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
 351 // MMXID  - MMX instructions with XD prefix.
 352 // MMXIS  - MMX instructions with XS prefix.
 353 class MMXI<bits<8> o, Format F, dag outs, dag ins, string asm,
 354            list<dag> pattern>
 355       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 356 class MMXI64<bits<8> o, Format F, dag outs, dag ins, string asm,
 357              list<dag> pattern>
 358       : I<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX,In64BitMode]>;
 359 class MMXRI<bits<8> o, Format F, dag outs, dag ins, string asm,
 360             list<dag> pattern>
 361       : I<o, F, outs, ins, asm, pattern>, TB, REX_W, Requires<[HasMMX]>;
 362 class MMX2I<bits<8> o, Format F, dag outs, dag ins, string asm,
 363             list<dag> pattern>
 364       : I<o, F, outs, ins, asm, pattern>, TB, OpSize, Requires<[HasMMX]>;
 365 class MMXIi8<bits<8> o, Format F, dag outs, dag ins, string asm,
 366              list<dag> pattern>
 367       : Ii8<o, F, outs, ins, asm, pattern>, TB, Requires<[HasMMX]>;
 368 class MMXID<bits<8> o, Format F, dag outs, dag ins, string asm,
 369             list<dag> pattern>
 370       : Ii8<o, F, outs, ins, asm, pattern>, XD, Requires<[HasMMX]>;
 371 class MMXIS<bits<8> o, Format F, dag outs, dag ins, string asm,
 372             list<dag> pattern>
 373       : Ii8<o, F, outs, ins, asm, pattern>, XS, Requires<[HasMMX]>;