lib/Target/X86/X86InstrMMX.td

   1 //====- X86InstrMMX.td - Describe the X86 Instruction Set --*- tablegen -*-===//
   2 //
   3 //                     The LLVM Compiler Infrastructure
   4 //
   5 // This file was developed by the Evan Cheng and is distributed under
   6 // the University of Illinois Open Source License. See LICENSE.TXT for details.
   7 //
   8 //===----------------------------------------------------------------------===//
   9 //
  10 // This file describes the X86 MMX instruction set, defining the instructions,
  11 // and properties of the instructions which are needed for code generation,
  12 // machine code emission, and analysis.
  13 //
  14 //===----------------------------------------------------------------------===//
  15
  16 //===----------------------------------------------------------------------===//
  17 // Instruction templates
  18 //===----------------------------------------------------------------------===//
  19
  20 // MMXI   - MMX instructions with TB prefix.
  21 // MMX2I  - MMX / SSE2 instructions with TB and OpSize prefixes.
  22 // MMXIi8 - MMX instructions with ImmT == Imm8 and TB prefix.
  23 class MMXI<bits<8> o, Format F, dag ops, string asm, list<dag> pattern>
  24       : I<o, F, ops, asm, pattern>, TB, Requires<[HasMMX]>;
  25 class MMX2I<bits<8> o, Format F, dag ops, string asm, list<dag> pattern>
  26       : I<o, F, ops, asm, pattern>, TB, OpSize, Requires<[HasSSE2]>;
  27 class MMXIi8<bits<8> o, Format F, dag ops, string asm, list<dag> pattern>
  28       : Ii8<o, F, ops, asm, pattern>, TB, Requires<[HasMMX]>;
  29
  30 // Some 'special' instructions
  31 def IMPLICIT_DEF_VR64 : I<0, Pseudo, (ops VR64:$dst),
  32                           "#IMPLICIT_DEF $dst",
  33                           [(set VR64:$dst, (v8i8 (undef)))]>,
  34                         Requires<[HasMMX]>;
  35
  36 // 64-bit vector undef's.
  37 def : Pat<(v8i8  (undef)), (IMPLICIT_DEF_VR64)>;
  38 def : Pat<(v4i16 (undef)), (IMPLICIT_DEF_VR64)>;
  39 def : Pat<(v2i32 (undef)), (IMPLICIT_DEF_VR64)>;
  40
  41 //===----------------------------------------------------------------------===//
  42 // MMX Pattern Fragments
  43 //===----------------------------------------------------------------------===//
  44
  45 def loadv2i32 : PatFrag<(ops node:$ptr), (v2i32 (load node:$ptr))>;
  46
  47 def bc_v8i8  : PatFrag<(ops node:$in), (v8i8  (bitconvert node:$in))>;
  48 def bc_v4i16 : PatFrag<(ops node:$in), (v4i16 (bitconvert node:$in))>;
  49 def bc_v2i32 : PatFrag<(ops node:$in), (v2i32 (bitconvert node:$in))>;
  50
  51 //===----------------------------------------------------------------------===//
  52 // MMX Multiclasses
  53 //===----------------------------------------------------------------------===//
  54
  55 let isTwoAddress = 1 in {
  56   // MMXI_binop_rm - Simple MMX binary operator.
  57   multiclass MMXI_binop_rm<bits<8> opc, string OpcodeStr, SDNode OpNode,
  58                            ValueType OpVT, bit Commutable = 0> {
  59     def rr : MMXI<opc, MRMSrcReg, (ops VR64:$dst, VR64:$src1, VR64:$src2),
  60                   !strconcat(OpcodeStr, " {$src2, $dst|$dst, $src2}"),
  61                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1, VR64:$src2)))]> {
  62       let isCommutable = Commutable;
  63     }
  64     def rm : MMXI<opc, MRMSrcMem, (ops VR64:$dst, VR64:$src1, i64mem:$src2),
  65                   !strconcat(OpcodeStr, " {$src2, $dst|$dst, $src2}"),
  66                   [(set VR64:$dst, (OpVT (OpNode VR64:$src1,
  67                                          (bitconvert
  68                                           (loadv2i32 addr:$src2)))))]>;
  69   }
  70
  71   multiclass MMXI_binop_rm_int<bits<8> opc, string OpcodeStr, Intrinsic IntId,
  72                                bit Commutable = 0> {
  73     def rr : MMXI<opc, MRMSrcReg, (ops VR64:$dst, VR64:$src1, VR64:$src2),
  74                  !strconcat(OpcodeStr, " {$src2, $dst|$dst, $src2}"),
  75                  [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]> {
  76       let isCommutable = Commutable;
  77     }
  78     def rm : MMXI<opc, MRMSrcMem, (ops VR64:$dst, VR64:$src1, i64mem:$src2),
  79                  !strconcat(OpcodeStr, " {$src2, $dst|$dst, $src2}"),
  80                  [(set VR64:$dst, (IntId VR64:$src1,
  81                                    (bitconvert (loadv2i32 addr:$src2))))]>;
  82   }
  83
  84   // MMXI_binop_rm_v2i32 - Simple MMX binary operator whose type is v2i32.
  85   //
  86   // FIXME: we could eliminate this and use MMXI_binop_rm instead if tblgen knew
  87   // to collapse (bitconvert VT to VT) into its operand.
  88   //
  89   multiclass MMXI_binop_rm_v2i32<bits<8> opc, string OpcodeStr, SDNode OpNode,
  90                                  bit Commutable = 0> {
  91     def rr : MMXI<opc, MRMSrcReg, (ops VR64:$dst, VR64:$src1, VR64:$src2),
  92                   !strconcat(OpcodeStr, " {$src2, $dst|$dst, $src2}"),
  93                   [(set VR64:$dst, (v2i32 (OpNode VR64:$src1, VR64:$src2)))]> {
  94       let isCommutable = Commutable;
  95     }
  96     def rm : MMXI<opc, MRMSrcMem, (ops VR64:$dst, VR64:$src1, i64mem:$src2),
  97                   !strconcat(OpcodeStr, " {$src2, $dst|$dst, $src2}"),
  98                   [(set VR64:$dst,
  99                     (OpNode VR64:$src1,(loadv2i32 addr:$src2)))]>;
 100   }
 101
 102   multiclass MMXI_binop_rmi_int<bits<8> opc, bits<8> opc2, Format ImmForm,
 103                                 string OpcodeStr, Intrinsic IntId> {
 104     def rr : MMXI<opc, MRMSrcReg, (ops VR64:$dst, VR64:$src1, VR64:$src2),
 105                   !strconcat(OpcodeStr, " {$src2, $dst|$dst, $src2}"),
 106                   [(set VR64:$dst, (IntId VR64:$src1, VR64:$src2))]>;
 107     def rm : MMXI<opc, MRMSrcMem, (ops VR64:$dst, VR64:$src1, i64mem:$src2),
 108                   !strconcat(OpcodeStr, " {$src2, $dst|$dst, $src2}"),
 109                   [(set VR64:$dst, (IntId VR64:$src1,
 110                                     (bitconvert (loadv2i32 addr:$src2))))]>;
 111     def ri : MMXIi8<opc2, ImmForm, (ops VR64:$dst, VR64:$src1, i32i8imm:$src2),
 112                     !strconcat(OpcodeStr, " {$src2, $dst|$dst, $src2}"),
 113                     [(set VR64:$dst, (IntId VR64:$src1,
 114                                       (scalar_to_vector (i32 imm:$src2))))]>;
 115   }
 116 }
 117
 118 //===----------------------------------------------------------------------===//
 119 // MMX EMMS Instruction
 120 //===----------------------------------------------------------------------===//
 121
 122 def MMX_EMMS : MMXI<0x77, RawFrm, (ops), "emms", [(int_x86_mmx_emms)]>;
 123
 124 //===----------------------------------------------------------------------===//
 125 // MMX Scalar Instructions
 126 //===----------------------------------------------------------------------===//
 127
 128 // Arithmetic Instructions
 129 defm MMX_PADDB : MMXI_binop_rm<0xFC, "paddb", add, v8i8, 1>;
 130 defm MMX_PADDW : MMXI_binop_rm<0xFD, "paddw", add, v4i16, 1>;
 131 defm MMX_PADDD : MMXI_binop_rm<0xFE, "paddd", add, v2i32, 1>;
 132
 133 defm MMX_PADDSB  : MMXI_binop_rm_int<0xEC, "paddsb" , int_x86_mmx_padds_b, 1>;
 134 defm MMX_PADDSW  : MMXI_binop_rm_int<0xED, "paddsw" , int_x86_mmx_padds_w, 1>;
 135
 136 defm MMX_PADDUSB : MMXI_binop_rm_int<0xDC, "paddusb", int_x86_mmx_paddus_b, 1>;
 137 defm MMX_PADDUSW : MMXI_binop_rm_int<0xDD, "paddusw", int_x86_mmx_paddus_w, 1>;
 138
 139 defm MMX_PSUBB : MMXI_binop_rm<0xF8, "psubb", sub, v8i8>;
 140 defm MMX_PSUBW : MMXI_binop_rm<0xF9, "psubw", sub, v4i16>;
 141 defm MMX_PSUBD : MMXI_binop_rm<0xFA, "psubd", sub, v2i32>;
 142
 143 defm MMX_PSUBSB  : MMXI_binop_rm_int<0xE8, "psubsb" , int_x86_mmx_psubs_b>;
 144 defm MMX_PSUBSW  : MMXI_binop_rm_int<0xE9, "psubsw" , int_x86_mmx_psubs_w>;
 145
 146 defm MMX_PSUBUSB : MMXI_binop_rm_int<0xD8, "psubusb", int_x86_mmx_psubus_b>;
 147 defm MMX_PSUBUSW : MMXI_binop_rm_int<0xD9, "psubusw", int_x86_mmx_psubus_w>;
 148
 149 defm MMX_PMULLW  : MMXI_binop_rm<0xD5, "pmullw", mul, v4i16, 1>;
 150
 151 defm MMX_PMULHW  : MMXI_binop_rm_int<0xE5, "pmulhw" , int_x86_mmx_pmulh_w , 1>;
 152 defm MMX_PMADDWD : MMXI_binop_rm_int<0xF5, "pmaddwd", int_x86_mmx_pmadd_wd, 1>;
 153
 154
 155 def MMX_UNPCKH_shuffle_mask : PatLeaf<(build_vector), [{
 156   return X86::isUNPCKHMask(N);
 157 }]>;
 158
 159 let isTwoAddress = 1 in {
 160 def MMX_PUNPCKHBWrr : MMXI<0x68, MRMSrcReg,
 161                            (ops VR64:$dst, VR64:$src1, VR64:$src2),
 162                            "punpckhbw {$src2, $dst|$dst, $src2}",
 163                            [(set VR64:$dst,
 164                              (v8i8 (vector_shuffle VR64:$src1, VR64:$src2,
 165                                     MMX_UNPCKH_shuffle_mask)))]>;
 166 def MMX_PUNPCKHBWrm : MMXI<0x68, MRMSrcMem,
 167                            (ops VR64:$dst, VR64:$src1, i64mem:$src2),
 168                            "punpckhbw {$src2, $dst|$dst, $src2}",
 169                            [(set VR64:$dst,
 170                              (v8i8 (vector_shuffle VR64:$src1,
 171                                     (bc_v8i8 (loadv2i32 addr:$src2)),
 172                                     MMX_UNPCKH_shuffle_mask)))]>;
 173 def MMX_PUNPCKHWDrr : MMXI<0x69, MRMSrcReg,
 174                            (ops VR64:$dst, VR64:$src1, VR64:$src2),
 175                            "punpckhwd {$src2, $dst|$dst, $src2}",
 176                            [(set VR64:$dst,
 177                              (v4i16 (vector_shuffle VR64:$src1, VR64:$src2,
 178                                      MMX_UNPCKH_shuffle_mask)))]>;
 179 def MMX_PUNPCKHWDrm : MMXI<0x69, MRMSrcMem,
 180                            (ops VR64:$dst, VR64:$src1, i64mem:$src2),
 181                            "punpckhwd {$src2, $dst|$dst, $src2}",
 182                            [(set VR64:$dst,
 183                              (v4i16 (vector_shuffle VR64:$src1,
 184                                      (bc_v4i16 (loadv2i32 addr:$src2)),
 185                                      MMX_UNPCKH_shuffle_mask)))]>;
 186 def MMX_PUNPCKHDQrr : MMXI<0x6A, MRMSrcReg,
 187                            (ops VR64:$dst, VR64:$src1, VR64:$src2),
 188                            "punpckhdq {$src2, $dst|$dst, $src2}",
 189                            [(set VR64:$dst,
 190                              (v2i32 (vector_shuffle VR64:$src1, VR64:$src2,
 191                                      MMX_UNPCKH_shuffle_mask)))]>;
 192 def MMX_PUNPCKHDQrm : MMXI<0x6A, MRMSrcMem,
 193                            (ops VR64:$dst, VR64:$src1, i64mem:$src2),
 194                            "punpckhdq {$src2, $dst|$dst, $src2}",
 195                            [(set VR64:$dst,
 196                              (v2i32 (vector_shuffle VR64:$src1,
 197                                      (loadv2i32 addr:$src2),
 198                                      MMX_UNPCKH_shuffle_mask)))]>;
 199 }
 200
 201 // Logical Instructions
 202 defm MMX_PAND : MMXI_binop_rm_v2i32<0xDB, "pand", and, 1>;
 203 defm MMX_POR  : MMXI_binop_rm_v2i32<0xEB, "por" , or,  1>;
 204 defm MMX_PXOR : MMXI_binop_rm_v2i32<0xEF, "pxor", xor, 1>;
 205
 206 let isTwoAddress = 1 in {
 207   def MMX_PANDNrr : MMXI<0xDF, MRMSrcReg,
 208                          (ops VR64:$dst, VR64:$src1, VR64:$src2),
 209                          "pandn {$src2, $dst|$dst, $src2}",
 210                          [(set VR64:$dst, (v2i32 (and (vnot VR64:$src1),
 211                                                   VR64:$src2)))]>;
 212   def MMX_PANDNrm : MMXI<0xDF, MRMSrcMem,
 213                          (ops VR64:$dst, VR64:$src1, i64mem:$src2),
 214                          "pandn {$src2, $dst|$dst, $src2}",
 215                          [(set VR64:$dst, (v2i32 (and (vnot VR64:$src1),
 216                                                   (load addr:$src2))))]>;
 217 }
 218
 219 // Shift Instructions
 220 defm MMX_PSRLW : MMXI_binop_rmi_int<0xD1, 0x71, MRM2r, "psrlw",
 221                                     int_x86_mmx_psrl_w>;
 222 defm MMX_PSRLD : MMXI_binop_rmi_int<0xD2, 0x72, MRM2r, "psrld",
 223                                     int_x86_mmx_psrl_d>;
 224 defm MMX_PSRLQ : MMXI_binop_rmi_int<0xD3, 0x73, MRM2r, "psrlq",
 225                                     int_x86_mmx_psrl_q>;
 226
 227 defm MMX_PSLLW : MMXI_binop_rmi_int<0xF1, 0x71, MRM6r, "psllw",
 228                                     int_x86_mmx_psll_w>;
 229 defm MMX_PSLLD : MMXI_binop_rmi_int<0xF2, 0x72, MRM6r, "pslld",
 230                                     int_x86_mmx_psll_d>;
 231 defm MMX_PSLLQ : MMXI_binop_rmi_int<0xF3, 0x73, MRM6r, "psllq",
 232                                     int_x86_mmx_psll_q>;
 233
 234 defm MMX_PSRAW : MMXI_binop_rmi_int<0xE1, 0x71, MRM4r, "psraw",
 235                                     int_x86_mmx_psra_w>;
 236 defm MMX_PSRAD : MMXI_binop_rmi_int<0xE2, 0x72, MRM4r, "psrad",
 237                                     int_x86_mmx_psra_d>;
 238
 239 // Move Instructions
 240 def MOVD64rr : MMXI<0x6E, MRMSrcReg, (ops VR64:$dst, GR32:$src),
 241                     "movd {$src, $dst|$dst, $src}", []>;
 242 def MOVD64rm : MMXI<0x6E, MRMSrcMem, (ops VR64:$dst, i32mem:$src),
 243                     "movd {$src, $dst|$dst, $src}", []>;
 244 def MOVD64mr : MMXI<0x7E, MRMDestMem, (ops i32mem:$dst, VR64:$src),
 245                     "movd {$src, $dst|$dst, $src}", []>;
 246
 247 def MOVQ64rr : MMXI<0x6F, MRMSrcReg, (ops VR64:$dst, VR64:$src),
 248                     "movq {$src, $dst|$dst, $src}", []>;
 249 def MOVQ64rm : MMXI<0x6F, MRMSrcMem, (ops VR64:$dst, i64mem:$src),
 250                     "movq {$src, $dst|$dst, $src}",
 251                     [(set VR64:$dst, (loadv2i32 addr:$src))]>;
 252 def MOVQ64mr : MMXI<0x7F, MRMDestMem, (ops i64mem:$dst, VR64:$src),
 253                     "movq {$src, $dst|$dst, $src}",
 254                     [(store (v2i32 VR64:$src), addr:$dst)]>;
 255
 256 // Conversion instructions
 257 def CVTPI2PSrr : MMXI<0x2A, MRMSrcReg, (ops VR128:$dst, VR64:$src),
 258                       "cvtpi2ps {$src, $dst|$dst, $src}", []>;
 259 def CVTPI2PSrm : MMXI<0x2A, MRMSrcMem, (ops VR128:$dst, i64mem:$src),
 260                       "cvtpi2ps {$src, $dst|$dst, $src}", []>;
 261 def CVTPI2PDrr : MMX2I<0x2A, MRMSrcReg, (ops VR128:$dst, VR64:$src),
 262                        "cvtpi2pd {$src, $dst|$dst, $src}", []>;
 263 def CVTPI2PDrm : MMX2I<0x2A, MRMSrcMem, (ops VR128:$dst, i64mem:$src),
 264                        "cvtpi2pd {$src, $dst|$dst, $src}", []>;
 265 def CVTTPS2PIrr: I<0x2C, MRMSrcReg, (ops VR64:$dst, VR128:$src),
 266                    "cvttps2pi {$src, $dst|$dst, $src}", []>, TB,
 267                    Requires<[HasMMX]>;
 268 def CVTTPS2PIrm: I<0x2C, MRMSrcMem, (ops VR64:$dst, f64mem:$src),
 269                    "cvttps2pi {$src, $dst|$dst, $src}", []>, TB,
 270                  Requires<[HasMMX]>;
 271 def CVTPS2PIrr : MMXI<0x2D, MRMSrcReg, (ops VR64:$dst, VR128:$src),
 272                       "cvtps2pi {$src, $dst|$dst, $src}", []>;
 273 def CVTPS2PIrm : MMXI<0x2D, MRMSrcMem, (ops VR64:$dst, f64mem:$src),
 274                       "cvtps2pi {$src, $dst|$dst, $src}", []>;
 275 def CVTPD2PIrr : MMX2I<0x2D, MRMSrcReg, (ops VR64:$dst, VR128:$src),
 276                        "cvtpd2pi {$src, $dst|$dst, $src}", []>;
 277 def CVTPD2PIrm : MMX2I<0x2D, MRMSrcMem, (ops VR64:$dst, f128mem:$src),
 278                        "cvtpd2pi {$src, $dst|$dst, $src}", []>;
 279
 280 // Shuffle and unpack instructions
 281 def PSHUFWri : MMXIi8<0x70, MRMSrcReg,
 282                       (ops VR64:$dst, VR64:$src1, i8imm:$src2),
 283                       "pshufw {$src2, $src1, $dst|$dst, $src1, $src2}", []>;
 284 def PSHUFWmi : MMXIi8<0x70, MRMSrcMem,
 285                       (ops VR64:$dst, i64mem:$src1, i8imm:$src2),
 286                       "pshufw {$src2, $src1, $dst|$dst, $src1, $src2}", []>;
 287
 288 // Misc.
 289 def MOVNTQ   : I<0xE7, MRMDestMem, (ops i64mem:$dst, VR64:$src),
 290                  "movntq {$src, $dst|$dst, $src}", []>, TB,
 291                Requires<[HasMMX]>;
 292
 293 def MASKMOVQ : I<0xF7, MRMDestMem, (ops VR64:$src, VR64:$mask),
 294                  "maskmovq {$mask, $src|$src, $mask}", []>, TB,
 295                Requires<[HasMMX]>;
 296
 297 //===----------------------------------------------------------------------===//
 298 // Non-Instruction Patterns
 299 //===----------------------------------------------------------------------===//
 300
 301 // Store 64-bit integer vector values.
 302 def : Pat<(store (v8i8  VR64:$src), addr:$dst),
 303           (MOVQ64mr addr:$dst, VR64:$src)>;
 304 def : Pat<(store (v4i16 VR64:$src), addr:$dst),
 305           (MOVQ64mr addr:$dst, VR64:$src)>;
 306
 307 // Bit convert.
 308 def : Pat<(v8i8  (bitconvert (v2i32 VR64:$src))), (v8i8  VR64:$src)>;
 309 def : Pat<(v8i8  (bitconvert (v4i16 VR64:$src))), (v8i8  VR64:$src)>;
 310 def : Pat<(v4i16 (bitconvert (v2i32 VR64:$src))), (v4i16 VR64:$src)>;
 311 def : Pat<(v4i16 (bitconvert (v8i8  VR64:$src))), (v4i16 VR64:$src)>;
 312 def : Pat<(v2i32 (bitconvert (v4i16 VR64:$src))), (v2i32 VR64:$src)>;
 313 def : Pat<(v2i32 (bitconvert (v8i8  VR64:$src))), (v2i32 VR64:$src)>;
 314
 315 // Splat v2i32
 316 let AddedComplexity = 10 in {
 317   def : Pat<(vector_shuffle (v2i32 VR64:$src), (undef),
 318              MMX_UNPCKH_shuffle_mask:$sm),
 319             (MMX_PUNPCKHDQrr VR64:$src, VR64:$src)>;
 320 }
 321
 322 // FIXME: Temporary workaround because 2-wide shuffle is broken.
 323 def : Pat<(int_x86_mmx_punpckh_dq VR64:$src1, VR64:$src2),
 324           (v2i32 (MMX_PUNPCKHDQrr VR64:$src1, VR64:$src2))>;
 325 def : Pat<(int_x86_mmx_punpckh_dq VR64:$src1, (load addr:$src2)),
 326           (v2i32 (MMX_PUNPCKHDQrm VR64:$src1, addr:$src2))>;
 327
 328 def MMX_X86s2vec : SDNode<"X86ISD::S2VEC",  SDTypeProfile<1, 1, []>, []>;
 329
 330 // Scalar to v4i16 / v8i8. The source may be a GR32, but only the lower 8 or
 331 // 16-bits matter.
 332 def : Pat<(v4i16 (MMX_X86s2vec GR32:$src)), (MOVD64rr GR32:$src)>;
 333 def : Pat<(v8i8 (MMX_X86s2vec GR32:$src)), (MOVD64rr GR32:$src)>;