projects/sample/autoconf/configure.ac

   1 dnl **************************************************************************
   2 dnl * Initialize
   3 dnl **************************************************************************
   4 AC_INIT([[[SAMPLE]]],[[[x.xx]]],[bugs@yourdomain])
   5
   6 dnl Identify where LLVM source tree is
   7 LLVM_SRC_ROOT="../.."
   8 LLVM_OBJ_ROOT="../.."
   9
  10 dnl Find absolute paths to LLVM source and object trees
  11 LLVM_ABS_SRC_ROOT="`cd $srcdir ; cd $LLVM_SRC_ROOT ; pwd`"
  12 LLVM_ABS_OBJ_ROOT="`cd $LLVM_OBJ_ROOT ; pwd`"
  13
  14 dnl Tell autoconf that this is an LLVM project being configured
  15 dnl This provides the --with-llvmsrc and --with-llvmobj options
  16 LLVM_CONFIG_PROJECT($LLVM_ABS_SRC_ROOT,$LLVM_ABS_OBJ_ROOT)
  17
  18 dnl Try and find an llvm-config in the build directory. We are only using this
  19 dnl to detect the package level LLVM information (currently just the version),
  20 dnl so we just whatever one we find regardless of build mode.
  21 AC_MSG_CHECKING([llvm-config])
  22 llvm_config_path="`ls -1 $llvm_obj/*/bin/llvm-config 2> /dev/null | head -1`"
  23 if ! test -f "$llvm_config_path" ; then
  24    llvm_config_path="no"
  25 fi
  26 AC_MSG_RESULT([$llvm_config_path])
  27
  28 dnl Determine the LLVM version, which may be required by the current Makefile
  29 dnl rules.
  30 AC_MSG_CHECKING([LLVM package version])
  31 if test "$llvm_config_path" != no ; then
  32   llvm_package_version=`$llvm_config_path --version`
  33 else
  34   llvm_package_version="unknown";
  35 fi
  36 AC_MSG_RESULT([$llvm_package_version])
  37 AC_SUBST(LLVM_VERSION, [$llvm_package_version])
  38
  39 dnl Verify that the source directory is valid
  40 AC_CONFIG_SRCDIR(["Makefile.common.in"])
  41
  42 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  43 dnl various tools where the m4 autoconf macros are.
  44 AC_CONFIG_AUX_DIR([autoconf])
  45
  46 dnl **************************************************************************
  47 dnl Begin LLVM configure.ac Import
  48 dnl **************************************************************************
  49 dnl
  50 dnl Derived from LLVM's configure.ac. This was imported directly here so that we
  51 dnl could reuse LLVM's build infrastructure without introducing a direct source
  52 dnl dependency on the LLVM files.
  53
  54 dnl We need to check for the compiler up here to avoid anything else
  55 dnl starting with a different one.
  56 AC_PROG_CC(clang llvm-gcc gcc)
  57 AC_PROG_CXX(clang++ llvm-g++ g++)
  58 AC_PROG_CPP
  59
  60 dnl Configure all of the projects present in our source tree. While we could
  61 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  62 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  63 dnl Instead we match on the known projects.
  64
  65 dnl
  66 dnl One tricky part of doing this is that some projects depend upon other
  67 dnl projects.  For example, several projects rely upon the LLVM test suite.
  68 dnl We want to configure those projects first so that their object trees are
  69 dnl created before running the configure scripts of projects that depend upon
  70 dnl them.
  71 dnl
  72
  73 dnl Disable the build of polly, even if it is checked out into tools/polly.
  74 AC_ARG_ENABLE(polly,
  75               AS_HELP_STRING([--enable-polly],
  76                              [Use polly if available (default is YES)]),,
  77                              enableval=default)
  78 case "$enableval" in
  79   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
  80   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
  81   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
  82   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
  83 esac
  84
  85
  86 dnl Check if polly is checked out into tools/polly and configure it if
  87 dnl available.
  88 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
  89   AC_SUBST(LLVM_HAS_POLLY,1)
  90   AC_CONFIG_SUBDIRS([tools/polly])
  91 fi
  92
  93 dnl===-----------------------------------------------------------------------===
  94 dnl===
  95 dnl=== SECTION 2: Architecture, target, and host checks
  96 dnl===
  97 dnl===-----------------------------------------------------------------------===
  98
  99 dnl Check the target for which we're compiling and the host that will do the
 100 dnl compilations. This will tell us which LLVM compiler will be used for
 101 dnl compiling SSA into object code. This needs to be done early because
 102 dnl following tests depend on it.
 103 AC_CANONICAL_TARGET
 104
 105 dnl Determine the platform type and cache its value. This helps us configure
 106 dnl the System library to the correct build platform.
 107 AC_CACHE_CHECK([type of operating system we're going to host on],
 108                [llvm_cv_os_type],
 109 [case $host in
 110   *-*-aix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="AIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-irix*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="IRIX"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-cygwin*)
 121     llvm_cv_link_all_option="-Wl,--whole-archive"
 122     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 123     llvm_cv_os_type="Cygwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-darwin*)
 126     llvm_cv_link_all_option="-Wl,-all_load"
 127     llvm_cv_no_link_all_option="-Wl,-noall_load"
 128     llvm_cv_os_type="Darwin"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-minix*)
 131     llvm_cv_link_all_option="-Wl,-all_load"
 132     llvm_cv_no_link_all_option="-Wl,-noall_load"
 133     llvm_cv_os_type="Minix"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-freebsd*)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="FreeBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-openbsd*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="OpenBSD"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-netbsd*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="NetBSD"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-dragonfly*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="DragonFly"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-hpux*)
 156     llvm_cv_link_all_option="-Wl,--whole-archive"
 157     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 158     llvm_cv_os_type="HP-UX"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-interix*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Interix"
 164     llvm_cv_platform_type="Unix" ;;
 165   *-*-linux*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="Linux"
 169     llvm_cv_platform_type="Unix" ;;
 170   *-*-solaris*)
 171     llvm_cv_link_all_option="-Wl,-z,allextract"
 172     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 173     llvm_cv_os_type="SunOS"
 174     llvm_cv_platform_type="Unix" ;;
 175   *-*-auroraux*)
 176     llvm_cv_link_all_option="-Wl,-z,allextract"
 177     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 178     llvm_cv_os_type="AuroraUX"
 179     llvm_cv_platform_type="Unix" ;;
 180   *-*-win32*)
 181     llvm_cv_link_all_option="-Wl,--whole-archive"
 182     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 183     llvm_cv_os_type="Win32"
 184     llvm_cv_platform_type="Win32" ;;
 185   *-*-mingw*)
 186     llvm_cv_link_all_option="-Wl,--whole-archive"
 187     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 188     llvm_cv_os_type="MingW"
 189     llvm_cv_platform_type="Win32" ;;
 190   *-*-haiku*)
 191     llvm_cv_link_all_option="-Wl,--whole-archive"
 192     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 193     llvm_cv_os_type="Haiku"
 194     llvm_cv_platform_type="Unix" ;;
 195   *-unknown-eabi*)
 196     llvm_cv_link_all_option="-Wl,--whole-archive"
 197     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 198     llvm_cv_os_type="Freestanding"
 199     llvm_cv_platform_type="Unix" ;;
 200   *-unknown-elf*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="Freestanding"
 204     llvm_cv_platform_type="Unix" ;;
 205   *)
 206     llvm_cv_link_all_option=""
 207     llvm_cv_no_link_all_option=""
 208     llvm_cv_os_type="Unknown"
 209     llvm_cv_platform_type="Unknown" ;;
 210 esac])
 211
 212 AC_CACHE_CHECK([type of operating system we're going to target],
 213                [llvm_cv_target_os_type],
 214 [case $target in
 215   *-*-aix*)
 216     llvm_cv_target_os_type="AIX" ;;
 217   *-*-irix*)
 218     llvm_cv_target_os_type="IRIX" ;;
 219   *-*-cygwin*)
 220     llvm_cv_target_os_type="Cygwin" ;;
 221   *-*-darwin*)
 222     llvm_cv_target_os_type="Darwin" ;;
 223   *-*-minix*)
 224     llvm_cv_target_os_type="Minix" ;;
 225   *-*-freebsd*)
 226     llvm_cv_target_os_type="FreeBSD" ;;
 227   *-*-openbsd*)
 228     llvm_cv_target_os_type="OpenBSD" ;;
 229   *-*-netbsd*)
 230     llvm_cv_target_os_type="NetBSD" ;;
 231   *-*-dragonfly*)
 232     llvm_cv_target_os_type="DragonFly" ;;
 233   *-*-hpux*)
 234     llvm_cv_target_os_type="HP-UX" ;;
 235   *-*-interix*)
 236     llvm_cv_target_os_type="Interix" ;;
 237   *-*-linux*)
 238     llvm_cv_target_os_type="Linux" ;;
 239   *-*-solaris*)
 240     llvm_cv_target_os_type="SunOS" ;;
 241   *-*-auroraux*)
 242     llvm_cv_target_os_type="AuroraUX" ;;
 243   *-*-win32*)
 244     llvm_cv_target_os_type="Win32" ;;
 245   *-*-mingw*)
 246     llvm_cv_target_os_type="MingW" ;;
 247   *-*-haiku*)
 248     llvm_cv_target_os_type="Haiku" ;;
 249   *-*-rtems*)
 250     llvm_cv_target_os_type="RTEMS" ;;
 251   *-*-nacl*)
 252     llvm_cv_target_os_type="NativeClient" ;;
 253   *-unknown-eabi*)
 254     llvm_cv_target_os_type="Freestanding" ;;
 255   *)
 256     llvm_cv_target_os_type="Unknown" ;;
 257 esac])
 258
 259 dnl Make sure we aren't attempting to configure for an unknown system
 260 if test "$llvm_cv_os_type" = "Unknown" ; then
 261   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 262 fi
 263
 264 dnl Set the "OS" Makefile variable based on the platform type so the
 265 dnl makefile can configure itself to specific build hosts
 266 AC_SUBST(OS,$llvm_cv_os_type)
 267 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 268 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 269
 270 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 271 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 272 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 273
 274 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 275 dnl This is used by lib/Support to determine the basic kind of implementation
 276 dnl to use.
 277 case $llvm_cv_platform_type in
 278   Unix)
 279     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 280     AC_SUBST(LLVM_ON_UNIX,[1])
 281     AC_SUBST(LLVM_ON_WIN32,[0])
 282     ;;
 283   Win32)
 284     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 285     AC_SUBST(LLVM_ON_UNIX,[0])
 286     AC_SUBST(LLVM_ON_WIN32,[1])
 287     ;;
 288 esac
 289
 290 dnl Determine what our target architecture is and configure accordingly.
 291 dnl This will allow Makefiles to make a distinction between the hardware and
 292 dnl the OS.
 293 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 294 [case $target in
 295   i?86-*)                 llvm_cv_target_arch="x86" ;;
 296   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 297   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 298   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 299   alpha*-*)               llvm_cv_target_arch="Alpha" ;;
 300   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 301   mips-*)                 llvm_cv_target_arch="Mips" ;;
 302   xcore-*)                llvm_cv_target_arch="XCore" ;;
 303   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 304   bfin-*)                 llvm_cv_target_arch="Blackfin" ;;
 305   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 306   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 307   *)                      llvm_cv_target_arch="Unknown" ;;
 308 esac])
 309
 310 if test "$llvm_cv_target_arch" = "Unknown" ; then
 311   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 312 fi
 313
 314 # Determine the LLVM native architecture for the target
 315 case "$llvm_cv_target_arch" in
 316     x86)     LLVM_NATIVE_ARCH="X86" ;;
 317     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 318     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 319 esac
 320
 321 dnl Define a substitution, ARCH, for the target architecture
 322 AC_SUBST(ARCH,$llvm_cv_target_arch)
 323
 324 dnl Check for the endianness of the target
 325 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 326
 327 dnl Check for build platform executable suffix if we're crosscompiling
 328 if test "$cross_compiling" = yes; then
 329   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 330   AC_BUILD_EXEEXT
 331   ac_build_prefix=${build_alias}-
 332   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 333   if test -z "$BUILD_CXX"; then
 334      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 335      if test -z "$BUILD_CXX"; then
 336        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 337      fi
 338   fi
 339 else
 340   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 341 fi
 342
 343 dnl Check to see if there's a .svn or .git directory indicating that this
 344 dnl build is being done from a checkout. This sets up several defaults for
 345 dnl the command line switches. When we build with a checkout directory,
 346 dnl we get a debug with assertions turned on. Without, we assume a source
 347 dnl release and we get an optimized build without assertions.
 348 dnl See --enable-optimized and --enable-assertions below
 349 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 350   cvsbuild="yes"
 351   optimize="no"
 352   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 353 else
 354   cvsbuild="no"
 355   optimize="yes"
 356 fi
 357
 358 dnl===-----------------------------------------------------------------------===
 359 dnl===
 360 dnl=== SECTION 3: Command line arguments for the configure script.
 361 dnl===
 362 dnl===-----------------------------------------------------------------------===
 363
 364 dnl --enable-optimized : check whether they want to do an optimized build:
 365 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 366  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 367 if test ${enableval} = "no" ; then
 368   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 369 else
 370   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 371 fi
 372
 373 dnl --enable-profiling : check whether they want to do a profile build:
 374 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 375  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 376 if test ${enableval} = "no" ; then
 377   AC_SUBST(ENABLE_PROFILING,[[]])
 378 else
 379   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 380 fi
 381
 382 dnl --enable-assertions : check whether they want to turn on assertions or not:
 383 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 384   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 385 if test ${enableval} = "yes" ; then
 386   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 387 else
 388   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 389 fi
 390
 391 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 392 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 393   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 394 if test ${enableval} = "yes" ; then
 395   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 396   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 397 else
 398   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 399   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 400 fi
 401
 402 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 403 AC_ARG_ENABLE(debug-runtime,
 404    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 405 if test ${enableval} = "no" ; then
 406   AC_SUBST(DEBUG_RUNTIME,[[]])
 407 else
 408   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 409 fi
 410
 411 dnl --enable-debug-symbols : should even optimized compiler libraries
 412 dnl have debug symbols?
 413 AC_ARG_ENABLE(debug-symbols,
 414    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 415 if test ${enableval} = "no" ; then
 416   AC_SUBST(DEBUG_SYMBOLS,[[]])
 417 else
 418   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 419 fi
 420
 421 dnl --enable-jit: check whether they want to enable the jit
 422 AC_ARG_ENABLE(jit,
 423   AS_HELP_STRING(--enable-jit,
 424                  [Enable Just In Time Compiling (default is YES)]),,
 425   enableval=default)
 426 if test ${enableval} = "no"
 427 then
 428   AC_SUBST(JIT,[[]])
 429 else
 430   case "$llvm_cv_target_arch" in
 431     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 432     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 433     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 434     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 435     Alpha)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 436     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 437     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 438     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 439     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 440     Blackfin)    AC_SUBST(TARGET_HAS_JIT,0) ;;
 441     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 442     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 443     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 444   esac
 445 fi
 446
 447 dnl Allow enablement of building and installing docs
 448 AC_ARG_ENABLE(docs,
 449               AS_HELP_STRING([--enable-docs],
 450                              [Build documents (default is YES)]),,
 451                              enableval=default)
 452 case "$enableval" in
 453   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 454   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 455   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 456   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 457 esac
 458
 459 dnl Allow enablement of doxygen generated documentation
 460 AC_ARG_ENABLE(doxygen,
 461               AS_HELP_STRING([--enable-doxygen],
 462                              [Build doxygen documentation (default is NO)]),,
 463                              enableval=default)
 464 case "$enableval" in
 465   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 466   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 467   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 468   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 469 esac
 470
 471 dnl Allow disablement of threads
 472 AC_ARG_ENABLE(threads,
 473               AS_HELP_STRING([--enable-threads],
 474                              [Use threads if available (default is YES)]),,
 475                              enableval=default)
 476 case "$enableval" in
 477   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 478   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 479   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 480   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 481 esac
 482 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 483
 484 dnl Allow disablement of pthread.h
 485 AC_ARG_ENABLE(pthreads,
 486               AS_HELP_STRING([--enable-pthreads],
 487                              [Use pthreads if available (default is YES)]),,
 488                              enableval=default)
 489 case "$enableval" in
 490   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 491   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 492   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 493   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 494 esac
 495
 496 dnl Allow building without position independent code
 497 AC_ARG_ENABLE(pic,
 498   AS_HELP_STRING([--enable-pic],
 499                  [Build LLVM with Position Independent Code (default is YES)]),,
 500                  enableval=default)
 501 case "$enableval" in
 502   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 503   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 504   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 505   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 506 esac
 507 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 508                    [Define if position independent code is enabled])
 509
 510 dnl Allow building a shared library and linking tools against it.
 511 AC_ARG_ENABLE(shared,
 512   AS_HELP_STRING([--enable-shared],
 513                  [Build a shared library and link tools against it (default is NO)]),,
 514                  enableval=default)
 515 case "$enableval" in
 516   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 517   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 518   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 519   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 520 esac
 521
 522 dnl Allow libstdc++ is embedded in LLVM.dll.
 523 AC_ARG_ENABLE(embed-stdcxx,
 524   AS_HELP_STRING([--enable-embed-stdcxx],
 525                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is YES)]),,
 526                  enableval=default)
 527 case "$enableval" in
 528   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 529   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 530   default) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 531   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 532 esac
 533
 534 dnl Enable embedding timestamp information into build.
 535 AC_ARG_ENABLE(timestamps,
 536   AS_HELP_STRING([--enable-timestamps],
 537                  [Enable embedding timestamp information in build (default is YES)]),,
 538                  enableval=default)
 539 case "$enableval" in
 540   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 541   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 542   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 543   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 544 esac
 545 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 546                    [Define if timestamp information (e.g., __DATE___) is allowed])
 547
 548 dnl Allow specific targets to be specified for building (or not)
 549 TARGETS_TO_BUILD=""
 550 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 551     [Build specific host targets: all or target1,target2,... Valid targets are:
 552      host, x86, x86_64, sparc, powerpc, alpha, arm, mips, spu,
 553      xcore, msp430, blackfin, ptx, cbe, and cpp (default=all)]),,
 554     enableval=all)
 555 if test "$enableval" = host-only ; then
 556   enableval=host
 557 fi
 558 case "$enableval" in
 559   all) TARGETS_TO_BUILD="X86 Sparc PowerPC Alpha ARM Mips CellSPU XCore MSP430 Blackfin CBackend CppBackend MBlaze PTX" ;;
 560   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 561       case "$a_target" in
 562         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 563         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 564         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 565         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 566         alpha)    TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 567         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 568         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 569         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 570         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 571         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 572         blackfin) TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 573         cbe)      TARGETS_TO_BUILD="CBackend $TARGETS_TO_BUILD" ;;
 574         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 575         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 576         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 577         host) case "$llvm_cv_target_arch" in
 578             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 579             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 580             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 581             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 582             Alpha)       TARGETS_TO_BUILD="Alpha $TARGETS_TO_BUILD" ;;
 583             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 584             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 585             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 586             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 587             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 588             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 589             Blackfin)    TARGETS_TO_BUILD="Blackfin $TARGETS_TO_BUILD" ;;
 590             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 591             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 592           esac ;;
 593         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 594       esac
 595   done
 596   ;;
 597 esac
 598 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 599
 600 # Determine whether we are building LLVM support for the native architecture.
 601 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 602 for a_target in $TARGETS_TO_BUILD; do
 603   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 604     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 605       [LLVM architecture name for the native architecture, if available])
 606     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 607     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 608     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 609     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 610     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 611       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 612     fi
 613     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 614       [LLVM name for the native Target init function, if available])
 615     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 616       [LLVM name for the native TargetInfo init function, if available])
 617     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 618       [LLVM name for the native target MC init function, if available])
 619     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 620       [LLVM name for the native AsmPrinter init function, if available])
 621     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 622       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 623        [LLVM name for the native AsmParser init function, if available])
 624     fi
 625   fi
 626 done
 627
 628 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 629 # target feature def files.
 630 LLVM_ENUM_TARGETS=""
 631 LLVM_ENUM_ASM_PRINTERS=""
 632 LLVM_ENUM_ASM_PARSERS=""
 633 LLVM_ENUM_DISASSEMBLERS=""
 634 for target_to_build in $TARGETS_TO_BUILD; do
 635   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 636   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 637     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 638   fi
 639   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 640     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 641   fi
 642   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 643     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 644   fi
 645 done
 646 AC_SUBST(LLVM_ENUM_TARGETS)
 647 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 648 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 649 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 650
 651 dnl Prevent the CBackend from using printf("%a") for floating point so older
 652 dnl C compilers that cannot deal with the 0x0p+0 hex floating point format
 653 dnl can still compile the CBE's output
 654 AC_ARG_ENABLE([cbe-printf-a],AS_HELP_STRING([--enable-cbe-printf-a],
 655   [Enable C Backend output with hex floating point via %a  (default is YES)]),,
 656   enableval=default)
 657 case "$enableval" in
 658   yes) AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 659   no)  AC_SUBST(ENABLE_CBE_PRINTF_A,[0]) ;;
 660   default)  AC_SUBST(ENABLE_CBE_PRINTF_A,[1]) ;;
 661   *) AC_MSG_ERROR([Invalid setting for --enable-cbe-printf-a. Use "yes" or "no"]) ;;
 662 esac
 663 AC_DEFINE_UNQUOTED([ENABLE_CBE_PRINTF_A],$ENABLE_CBE_PRINTF_A,
 664                    [Define if CBE is enabled for printf %a output])
 665
 666 dnl Override the option to use for optimized builds.
 667 AC_ARG_WITH(optimize-option,
 668   AS_HELP_STRING([--with-optimize-option],
 669                  [Select the compiler options to use for optimized builds]),,
 670                  withval=default)
 671 AC_MSG_CHECKING([optimization flags])
 672 case "$withval" in
 673   default)
 674     case "$llvm_cv_os_type" in
 675     FreeBSD) optimize_option=-O2 ;;
 676     MingW) optimize_option=-O2 ;;
 677     *)     optimize_option=-O3 ;;
 678     esac ;;
 679   *) optimize_option="$withval" ;;
 680 esac
 681 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 682 AC_MSG_RESULT([$optimize_option])
 683
 684 dnl Specify extra build options
 685 AC_ARG_WITH(extra-options,
 686   AS_HELP_STRING([--with-extra-options],
 687                  [Specify additional options to compile LLVM with]),,
 688                  withval=default)
 689 case "$withval" in
 690   default) EXTRA_OPTIONS= ;;
 691   *) EXTRA_OPTIONS=$withval ;;
 692 esac
 693 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 694
 695 dnl Specify extra linker build options
 696 AC_ARG_WITH(extra-ld-options,
 697   AS_HELP_STRING([--with-extra-ld-options],
 698                  [Specify additional options to link LLVM with]),,
 699                  withval=default)
 700 case "$withval" in
 701   default) EXTRA_LD_OPTIONS= ;;
 702   *) EXTRA_LD_OPTIONS=$withval ;;
 703 esac
 704 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 705
 706 dnl Allow specific bindings to be specified for building (or not)
 707 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 708     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 709     enableval=default)
 710 BINDINGS_TO_BUILD=""
 711 case "$enableval" in
 712   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 713   all ) BINDINGS_TO_BUILD="ocaml" ;;
 714   none | no) BINDINGS_TO_BUILD="" ;;
 715   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 716       case "$a_binding" in
 717         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 718         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 719       esac
 720   done
 721   ;;
 722 esac
 723
 724 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 725 dnl script for bindings/ocaml/configure, except that its auto value depends on
 726 dnl OCAMLC, which is found here to support tests.
 727 AC_ARG_WITH([ocaml-libdir],
 728   [AS_HELP_STRING([--with-ocaml-libdir],
 729     [Specify install location for ocaml bindings (default is stdlib)])],
 730   [],
 731   [withval=auto])
 732 case "$withval" in
 733   auto) with_ocaml_libdir="$withval" ;;
 734   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 735   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 736 esac
 737
 738 AC_ARG_WITH(clang-resource-dir,
 739   AS_HELP_STRING([--with-clang-resource-dir],
 740     [Relative directory from the Clang binary for resource files]),,
 741     withval="")
 742 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 743                    [Relative directory for resource files])
 744
 745 AC_ARG_WITH(c-include-dirs,
 746   AS_HELP_STRING([--with-c-include-dirs],
 747     [Colon separated list of directories clang will search for headers]),,
 748     withval="")
 749 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 750                    [Directories clang will search for headers])
 751
 752 AC_ARG_WITH(cxx-include-root,
 753   AS_HELP_STRING([--with-cxx-include-root],
 754     [Directory with the libstdc++ headers.]),,
 755     withval="")
 756 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ROOT,"$withval",
 757                    [Directory with the libstdc++ headers.])
 758
 759 AC_ARG_WITH(cxx-include-arch,
 760   AS_HELP_STRING([--with-cxx-include-arch],
 761     [Architecture of the libstdc++ headers.]),,
 762     withval="")
 763 AC_DEFINE_UNQUOTED(CXX_INCLUDE_ARCH,"$withval",
 764                    [Arch the libstdc++ headers.])
 765
 766 AC_ARG_WITH(cxx-include-32bit-dir,
 767   AS_HELP_STRING([--with-cxx-include-32bit-dir],
 768     [32 bit multilib dir.]),,
 769     withval="")
 770 AC_DEFINE_UNQUOTED(CXX_INCLUDE_32BIT_DIR,"$withval",
 771                    [32 bit multilib directory.])
 772
 773 AC_ARG_WITH(cxx-include-64bit-dir,
 774   AS_HELP_STRING([--with-cxx-include-64bit-dir],
 775     [64 bit multilib directory.]),,
 776     withval="")
 777 AC_DEFINE_UNQUOTED(CXX_INCLUDE_64BIT_DIR,"$withval",
 778                    [64 bit multilib directory.])
 779
 780 dnl Allow linking of LLVM with GPLv3 binutils code.
 781 AC_ARG_WITH(binutils-include,
 782   AS_HELP_STRING([--with-binutils-include],
 783     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 784   withval=default)
 785 case "$withval" in
 786   default) WITH_BINUTILS_INCDIR=default ;;
 787   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 788   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 789 esac
 790 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 791   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 792   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 793      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 794      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 795   fi
 796 fi
 797
 798 dnl Specify the URL where bug reports should be submitted.
 799 AC_ARG_WITH(bug-report-url,
 800   AS_HELP_STRING([--with-bug-report-url],
 801     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 802     withval="http://llvm.org/bugs/")
 803 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 804                    [Bug report URL.])
 805
 806 dnl --enable-libffi : check whether the user wants to turn off libffi:
 807 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 808   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 809   [case "$enableval" in
 810     yes) llvm_cv_enable_libffi="yes" ;;
 811     no)  llvm_cv_enable_libffi="no"  ;;
 812     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 813   esac],
 814   llvm_cv_enable_libffi=no)
 815
 816 dnl===-----------------------------------------------------------------------===
 817 dnl===
 818 dnl=== SECTION 4: Check for programs we need and that they are the right version
 819 dnl===
 820 dnl===-----------------------------------------------------------------------===
 821
 822 AC_PROG_NM
 823 AC_SUBST(NM)
 824
 825 dnl Check for the tools that the makefiles require
 826 AC_CHECK_GNU_MAKE
 827 AC_PROG_LN_S
 828 AC_PATH_PROG(CMP, [cmp], [cmp])
 829 AC_PATH_PROG(CP, [cp], [cp])
 830 AC_PATH_PROG(DATE, [date], [date])
 831 AC_PATH_PROG(FIND, [find], [find])
 832 AC_PATH_PROG(GREP, [grep], [grep])
 833 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 834 AC_PATH_PROG(MV,   [mv],   [mv])
 835 AC_PROG_RANLIB
 836 AC_CHECK_TOOL(AR, ar, false)
 837 AC_PATH_PROG(RM,   [rm],   [rm])
 838 AC_PATH_PROG(SED,  [sed],  [sed])
 839 AC_PATH_PROG(TAR,  [tar],  [gtar])
 840 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 841
 842 dnl Looking for misc. graph plotting software
 843 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 844 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 845   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 846   dnl If we're targeting for mingw we should emit windows paths, not msys
 847   if test "$llvm_cv_os_type" = "MingW" ; then
 848     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 849   fi
 850   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 851    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 852 fi
 853 AC_PATH_PROG(DOT, [dot], [echo dot])
 854 if test "$DOT" != "echo dot" ; then
 855   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 856   dnl If we're targeting for mingw we should emit windows paths, not msys
 857   if test "$llvm_cv_os_type" = "MingW" ; then
 858     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 859   fi
 860   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 861    [Define to path to dot program if found or 'echo dot' otherwise])
 862 fi
 863 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 864 if test "$FDP" != "echo fdp" ; then
 865   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 866   dnl If we're targeting for mingw we should emit windows paths, not msys
 867   if test "$llvm_cv_os_type" = "MingW" ; then
 868     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 869   fi
 870   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 871    [Define to path to fdp program if found or 'echo fdp' otherwise])
 872 fi
 873 AC_PATH_PROG(NEATO, [neato], [echo neato])
 874 if test "$NEATO" != "echo neato" ; then
 875   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 876   dnl If we're targeting for mingw we should emit windows paths, not msys
 877   if test "$llvm_cv_os_type" = "MingW" ; then
 878     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 879   fi
 880   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 881    [Define to path to neato program if found or 'echo neato' otherwise])
 882 fi
 883 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 884 if test "$TWOPI" != "echo twopi" ; then
 885   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 886   dnl If we're targeting for mingw we should emit windows paths, not msys
 887   if test "$llvm_cv_os_type" = "MingW" ; then
 888     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 889   fi
 890   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 891    [Define to path to twopi program if found or 'echo twopi' otherwise])
 892 fi
 893 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 894 if test "$CIRCO" != "echo circo" ; then
 895   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 896   dnl If we're targeting for mingw we should emit windows paths, not msys
 897   if test "$llvm_cv_os_type" = "MingW" ; then
 898     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 899   fi
 900   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 901    [Define to path to circo program if found or 'echo circo' otherwise])
 902 fi
 903 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 904 if test "$GV" != "echo gv" ; then
 905   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 906   dnl If we're targeting for mingw we should emit windows paths, not msys
 907   if test "$llvm_cv_os_type" = "MingW" ; then
 908     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 909   fi
 910   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 911    [Define to path to gv program if found or 'echo gv' otherwise])
 912 fi
 913 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 914 if test "$DOTTY" != "echo dotty" ; then
 915   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 916   dnl If we're targeting for mingw we should emit windows paths, not msys
 917   if test "$llvm_cv_os_type" = "MingW" ; then
 918     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 919   fi
 920   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 921    [Define to path to dotty program if found or 'echo dotty' otherwise])
 922 fi
 923 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 924 if test "$XDOT_PY" != "echo xdot.py" ; then
 925   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 926   dnl If we're targeting for mingw we should emit windows paths, not msys
 927   if test "$llvm_cv_os_type" = "MingW" ; then
 928     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 929   fi
 930   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 931    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 932 fi
 933
 934 dnl Look for a sufficiently recent version of Perl.
 935 LLVM_PROG_PERL([5.006])
 936 AC_SUBST(PERL)
 937 if test x"$PERL" = xnone; then
 938    AC_SUBST(HAVE_PERL,0)
 939    AC_MSG_ERROR([perl is required but was not found, please install it])
 940 else
 941    AC_SUBST(HAVE_PERL,1)
 942 fi
 943
 944 dnl Find the install program
 945 AC_PROG_INSTALL
 946 dnl Prepend src dir to install path dir if it's a relative path
 947 dnl This is a hack for installs that take place in something other
 948 dnl than the top level.
 949 case "$INSTALL" in
 950  [[\\/$]]* | ?:[[\\/]]* ) ;;
 951  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 952 esac
 953
 954 dnl Checks for documentation and testing tools that we can do without. If these
 955 dnl are not found then they are set to "true" which always succeeds but does
 956 dnl nothing. This just lets the build output show that we could have done
 957 dnl something if the tool was available.
 958 AC_PATH_PROG(BZIP2, [bzip2])
 959 AC_PATH_PROG(CAT, [cat])
 960 AC_PATH_PROG(DOXYGEN, [doxygen])
 961 AC_PATH_PROG(GROFF, [groff])
 962 AC_PATH_PROG(GZIPBIN, [gzip])
 963 AC_PATH_PROG(POD2HTML, [pod2html])
 964 AC_PATH_PROG(POD2MAN, [pod2man])
 965 AC_PATH_PROG(PDFROFF, [pdfroff])
 966 AC_PATH_PROG(RUNTEST, [runtest])
 967 DJ_AC_PATH_TCLSH
 968 AC_PATH_PROG(ZIP, [zip])
 969 AC_PATH_PROGS(OCAMLC, [ocamlc])
 970 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 971 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 972 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 973 AC_PATH_PROGS(GAS, [gas as])
 974
 975 dnl Get the version of the linker in use.
 976 AC_LINK_GET_VERSION
 977
 978 dnl Determine whether the linker supports the -R option.
 979 AC_LINK_USE_R
 980
 981 dnl Determine whether the linker supports the -export-dynamic option.
 982 AC_LINK_EXPORT_DYNAMIC
 983
 984 dnl Determine whether the linker supports the --version-script option.
 985 AC_LINK_VERSION_SCRIPT
 986
 987 dnl Check for libtool and the library that has dlopen function (which must come
 988 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 989 dnl libtool).
 990 AC_LIBTOOL_DLOPEN
 991 AC_LIB_LTDL
 992
 993 AC_MSG_CHECKING([tool compatibility])
 994
 995 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 996 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 997 dnl to support those options.
 998 dnl "icc" emits gcc signatures
 999 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
1000 ICC=no
1001 IXX=no
1002 case $CC in
1003   icc*|icpc*)
1004     ICC=yes
1005     IXX=yes
1006     ;;
1007    *)
1008     ;;
1009 esac
1010
1011 if test "$GCC" != "yes" && test "$ICC" != "yes"
1012 then
1013   AC_MSG_ERROR([gcc|icc required but not found])
1014 fi
1015
1016 dnl Ensure that compilation tools are compatible with GCC extensions
1017 if test "$GXX" != "yes" && test "$IXX" != "yes"
1018 then
1019   AC_MSG_ERROR([g++|clang++|icc required but not found])
1020 fi
1021
1022 dnl Verify that GCC is version 3.0 or higher
1023 if test "$GCC" = "yes"
1024 then
1025   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
1026 #error Unsupported GCC version
1027 #endif
1028 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
1029 fi
1030
1031 dnl Check for GNU Make.  We use its extensions, so don't build without it
1032 if test -z "$llvm_cv_gnu_make_command"
1033 then
1034   AC_MSG_ERROR([GNU Make required but not found])
1035 fi
1036
1037 dnl Tool compatibility is okay if we make it here.
1038 AC_MSG_RESULT([ok])
1039
1040 dnl Check optional compiler flags.
1041 AC_MSG_CHECKING([optional compiler flags])
1042 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
1043 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
1044 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS])
1045
1046 dnl===-----------------------------------------------------------------------===
1047 dnl===
1048 dnl=== SECTION 5: Check for libraries
1049 dnl===
1050 dnl===-----------------------------------------------------------------------===
1051
1052 AC_CHECK_LIB(m,sin)
1053 if test "$llvm_cv_os_type" = "MingW" ; then
1054   AC_CHECK_LIB(imagehlp, main)
1055   AC_CHECK_LIB(psapi, main)
1056 fi
1057
1058 dnl dlopen() is required for plugin support.
1059 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1060                [Define if dlopen() is available on this platform.]),
1061                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1062
1063 dnl libffi is optional; used to call external functions from the interpreter
1064 if test "$llvm_cv_enable_libffi" = "yes" ; then
1065   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1066                  [Define if libffi is available on this platform.]),
1067                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1068 fi
1069
1070 dnl mallinfo is optional; the code can compile (minus features) without it
1071 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1072                [Define if mallinfo() is available on this platform.]))
1073
1074 dnl pthread locking functions are optional - but llvm will not be thread-safe
1075 dnl without locks.
1076 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1077   AC_CHECK_LIB(pthread, pthread_mutex_init)
1078   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1079                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1080                            [Have pthread_mutex_lock]))
1081   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1082                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1083                  [Have pthread_rwlock_init]))
1084   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1085                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1086                  [Have pthread_getspecific]))
1087 fi
1088
1089 dnl Allow extra x86-disassembler library
1090 AC_ARG_WITH(udis86,
1091   AS_HELP_STRING([--with-udis86=<path>],
1092     [Use udis86 external x86 disassembler library]),
1093     [
1094       AC_SUBST(USE_UDIS86, [1])
1095       case "$withval" in
1096         /usr/lib|yes) ;;
1097         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1098       esac
1099       AC_CHECK_LIB(udis86, ud_init, [], [
1100         echo "Error! You need to have libudis86 around."
1101         exit -1
1102       ])
1103     ],
1104     AC_SUBST(USE_UDIS86, [0]))
1105 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1106                    [Define if use udis86 library])
1107
1108 dnl Allow OProfile support for JIT output.
1109 AC_ARG_WITH(oprofile,
1110   AS_HELP_STRING([--with-oprofile=<prefix>],
1111     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1112     [
1113       AC_SUBST(USE_OPROFILE, [1])
1114       case "$withval" in
1115         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1116         no) llvm_cv_oppath=
1117             AC_SUBST(USE_OPROFILE, [0]) ;;
1118         *) llvm_cv_oppath="${withval}/lib/oprofile"
1119            CPPFLAGS="-I${withval}/include";;
1120       esac
1121       if test -n "$llvm_cv_oppath" ; then
1122         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1123         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1124         dnl libbfd is not included properly in libopagent in some Debian
1125         dnl versions.  If libbfd isn't found at all, we assume opagent works
1126         dnl anyway.
1127         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1128         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1129           echo "Error! You need to have libopagent around."
1130           exit -1
1131         ])
1132         AC_CHECK_HEADER([opagent.h], [], [
1133           echo "Error! You need to have opagent.h around."
1134           exit -1
1135           ])
1136       fi
1137     ],
1138     [
1139       AC_SUBST(USE_OPROFILE, [0])
1140     ])
1141 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1142                    [Define if we have the oprofile JIT-support library])
1143
1144 dnl===-----------------------------------------------------------------------===
1145 dnl===
1146 dnl=== SECTION 6: Check for header files
1147 dnl===
1148 dnl===-----------------------------------------------------------------------===
1149
1150 dnl First, use autoconf provided macros for specific headers that we need
1151 dnl We don't check for ancient stuff or things that are guaranteed to be there
1152 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1153 dnl Generally we're looking for POSIX headers.
1154 AC_HEADER_DIRENT
1155 AC_HEADER_MMAP_ANONYMOUS
1156 AC_HEADER_STAT
1157 AC_HEADER_SYS_WAIT
1158 AC_HEADER_TIME
1159
1160 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1161 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1162 AC_CHECK_HEADERS([utime.h windows.h])
1163 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1164 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1165 AC_CHECK_HEADERS([valgrind/valgrind.h])
1166 AC_CHECK_HEADERS([fenv.h])
1167 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1168   AC_CHECK_HEADERS(pthread.h,
1169                    AC_SUBST(HAVE_PTHREAD, 1),
1170                    AC_SUBST(HAVE_PTHREAD, 0))
1171 else
1172   AC_SUBST(HAVE_PTHREAD, 0)
1173 fi
1174
1175 dnl Try to find ffi.h.
1176 if test "$llvm_cv_enable_libffi" = "yes" ; then
1177   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1178 fi
1179
1180 dnl Try to find Darwin specific crash reporting libraries.
1181 AC_CHECK_HEADERS([CrashReporterClient.h])
1182
1183 dnl Try to find Darwin specific crash reporting global.
1184 AC_MSG_CHECKING([__crashreporter_info__])
1185 AC_LINK_IFELSE(
1186   AC_LANG_SOURCE(
1187     [[extern const char *__crashreporter_info__;
1188       int main() {
1189         __crashreporter_info__ = "test";
1190         return 0;
1191       }
1192     ]]),
1193   AC_MSG_RESULT(yes)
1194   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1195   AC_MSG_RESULT(no)
1196   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1197             Define if __crashreporter_info__ exists.))
1198
1199 dnl===-----------------------------------------------------------------------===
1200 dnl===
1201 dnl=== SECTION 7: Check for types and structures
1202 dnl===
1203 dnl===-----------------------------------------------------------------------===
1204
1205 AC_HUGE_VAL_CHECK
1206 AC_TYPE_PID_T
1207 AC_TYPE_SIZE_T
1208 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1209 AC_STRUCT_TM
1210 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1211 AC_CHECK_TYPES([uint64_t],,
1212          AC_CHECK_TYPES([u_int64_t],,
1213          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1214
1215 dnl===-----------------------------------------------------------------------===
1216 dnl===
1217 dnl=== SECTION 8: Check for specific functions needed
1218 dnl===
1219 dnl===-----------------------------------------------------------------------===
1220
1221 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1222 AC_CHECK_FUNCS([powf fmodf strtof round ])
1223 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1224 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1225 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1226 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1227 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1228 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1229 AC_C_PRINTF_A
1230 AC_FUNC_RAND48
1231
1232 dnl Check the declaration "Secure API" on Windows environments.
1233 AC_CHECK_DECLS([strerror_s])
1234
1235 dnl Check symbols in libgcc.a for JIT on Mingw.
1236 if test "$llvm_cv_os_type" = "MingW" ; then
1237   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1238   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1239   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1240   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1241
1242   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1243   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1244   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1245   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1246   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1247   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1248   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1249   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1250   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1251   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1252
1253   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1254   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1255 fi
1256
1257 dnl Check Win32 API EnumerateLoadedModules.
1258 if test "$llvm_cv_os_type" = "MingW" ; then
1259   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1260   AC_COMPILE_IFELSE([[#include <windows.h>
1261 #include <imagehlp.h>
1262 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1263 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1264 [
1265   AC_MSG_RESULT([yes])
1266   llvm_cv_win32_elmcb_pcstr="PCSTR"
1267 ],
1268 [
1269   AC_MSG_RESULT([no])
1270   llvm_cv_win32_elmcb_pcstr="PSTR"
1271 ])
1272   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1273 fi
1274
1275 dnl Check for variations in the Standard C++ library and STL. These macros are
1276 dnl provided by LLVM in the autoconf/m4 directory.
1277 AC_FUNC_ISNAN
1278 AC_FUNC_ISINF
1279
1280 dnl Check for mmap support.We also need to know if /dev/zero is required to
1281 dnl be opened for allocating RWX memory.
1282 dnl Make sure we aren't attempting to configure for an unknown system
1283 if test "$llvm_cv_platform_type" = "Unix" ; then
1284   AC_FUNC_MMAP
1285   AC_FUNC_MMAP_FILE
1286   AC_NEED_DEV_ZERO_FOR_MMAP
1287
1288   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1289   then
1290     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1291   fi
1292   if test "$ac_cv_func_mmap_file" = "no"
1293   then
1294     AC_MSG_WARN([mmap() of files required but not found])
1295   fi
1296 fi
1297
1298 dnl atomic builtins are required for threading support.
1299 AC_MSG_CHECKING(for GCC atomic builtins)
1300 dnl Since we'll be using these atomic builtins in C++ files we should test
1301 dnl the C++ compiler.
1302 AC_LANG_PUSH([C++])
1303 AC_LINK_IFELSE(
1304   AC_LANG_SOURCE(
1305     [[int main() {
1306         volatile unsigned long val = 1;
1307         __sync_synchronize();
1308         __sync_val_compare_and_swap(&val, 1, 0);
1309         __sync_add_and_fetch(&val, 1);
1310         __sync_sub_and_fetch(&val, 1);
1311         return 0;
1312       }
1313     ]]),
1314   AC_LANG_POP([C++])
1315   AC_MSG_RESULT(yes)
1316   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1317   AC_MSG_RESULT(no)
1318   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1319   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1320
1321 dnl===-----------------------------------------------------------------------===
1322 dnl===
1323 dnl=== SECTION 9: Additional checks, variables, etc.
1324 dnl===
1325 dnl===-----------------------------------------------------------------------===
1326
1327 dnl Handle 32-bit linux systems running a 64-bit kernel.
1328 dnl This has to come after section 4 because it invokes the compiler.
1329 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1330   AC_IS_LINUX_MIXED
1331   if test "$llvm_cv_linux_mixed" = "yes"; then
1332     llvm_cv_target_arch="x86"
1333     ARCH="x86"
1334   fi
1335 fi
1336
1337 dnl Check whether __dso_handle is present
1338 AC_CHECK_FUNCS([__dso_handle])
1339
1340 dnl Propagate the shared library extension that the libltdl checks did to
1341 dnl the Makefiles so we can use it there too
1342 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1343
1344 dnl Propagate the run-time library path variable that the libltdl
1345 dnl checks found to the Makefiles so we can use it there too
1346 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1347
1348 # Translate the various configuration directories and other basic
1349 # information into substitutions that will end up in Makefile.config.in
1350 # that these configured values can be used by the makefiles
1351 if test "${prefix}" = "NONE" ; then
1352   prefix="/usr/local"
1353 fi
1354 eval LLVM_PREFIX="${prefix}";
1355 eval LLVM_BINDIR="${prefix}/bin";
1356 eval LLVM_LIBDIR="${prefix}/lib";
1357 eval LLVM_DATADIR="${prefix}/share/llvm";
1358 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1359 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1360 eval LLVM_INCLUDEDIR="${prefix}/include";
1361 eval LLVM_INFODIR="${prefix}/info";
1362 eval LLVM_MANDIR="${prefix}/man";
1363 LLVM_CONFIGTIME=`date`
1364 AC_SUBST(LLVM_PREFIX)
1365 AC_SUBST(LLVM_BINDIR)
1366 AC_SUBST(LLVM_LIBDIR)
1367 AC_SUBST(LLVM_DATADIR)
1368 AC_SUBST(LLVM_DOCSDIR)
1369 AC_SUBST(LLVM_ETCDIR)
1370 AC_SUBST(LLVM_INCLUDEDIR)
1371 AC_SUBST(LLVM_INFODIR)
1372 AC_SUBST(LLVM_MANDIR)
1373 AC_SUBST(LLVM_CONFIGTIME)
1374
1375 # Place the various directores into the config.h file as #defines so that we
1376 # can know about the installation paths within LLVM.
1377 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1378                    [Installation prefix directory])
1379 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1380                    [Installation directory for binary executables])
1381 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1382                    [Installation directory for libraries])
1383 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1384                    [Installation directory for data files])
1385 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1386                    [Installation directory for documentation])
1387 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1388                    [Installation directory for config files])
1389 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1390                    [Installation directory for include files])
1391 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1392                    [Installation directory for .info files])
1393 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1394                    [Installation directory for man pages])
1395 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1396                    [Time at which LLVM was configured])
1397 AC_DEFINE_UNQUOTED(LLVM_HOSTTRIPLE, "$host",
1398                    [Host triple we were built on])
1399
1400 # Determine which bindings to build.
1401 if test "$BINDINGS_TO_BUILD" = auto ; then
1402   BINDINGS_TO_BUILD=""
1403   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1404     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1405   fi
1406 fi
1407 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1408
1409 # This isn't really configurey, but it avoids having to repeat the list in
1410 # other files.
1411 AC_SUBST(ALL_BINDINGS,ocaml)
1412
1413 # Do any work necessary to ensure that bindings have what they need.
1414 binding_prereqs_failed=0
1415 for a_binding in $BINDINGS_TO_BUILD ; do
1416   case "$a_binding" in
1417   ocaml)
1418     if test "x$OCAMLC" = x ; then
1419       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1420       binding_prereqs_failed=1
1421     fi
1422     if test "x$OCAMLDEP" = x ; then
1423       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1424       binding_prereqs_failed=1
1425     fi
1426     if test "x$OCAMLOPT" = x ; then
1427       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1428       dnl ocamlopt is optional!
1429     fi
1430     if test "x$with_ocaml_libdir" != xauto ; then
1431       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1432     else
1433       ocaml_stdlib="`"$OCAMLC" -where`"
1434       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1435       then
1436         # ocaml stdlib is beneath our prefix; use stdlib
1437         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1438       else
1439         # ocaml stdlib is outside our prefix; use libdir/ocaml
1440         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1441       fi
1442     fi
1443     ;;
1444   esac
1445 done
1446 if test "$binding_prereqs_failed" = 1 ; then
1447   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1448 fi
1449
1450 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1451 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1452
1453 dnl Determine linker rpath flag
1454 if test "$llvm_cv_link_use_r" = "yes" ; then
1455   RPATH="-Wl,-R"
1456 else
1457   RPATH="-Wl,-rpath"
1458 fi
1459 AC_SUBST(RPATH)
1460
1461 dnl Determine linker rdynamic flag
1462 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1463   RDYNAMIC="-Wl,-export-dynamic"
1464 else
1465   RDYNAMIC=""
1466 fi
1467 AC_SUBST(RDYNAMIC)
1468
1469 dnl===-----------------------------------------------------------------------===
1470 dnl===
1471 dnl=== SECTION 10: Specify the output files and generate it
1472 dnl===
1473 dnl===-----------------------------------------------------------------------===
1474
1475 dnl **************************************************************************
1476 dnl End LLVM configure.ac Import
1477 dnl **************************************************************************
1478
1479 dnl Configure a common Makefile
1480 AC_CONFIG_FILES(Makefile.common)
1481 AC_CONFIG_FILES(Makefile.llvm.config)
1482
1483 dnl Configure project makefiles
1484 dnl List every Makefile that exists within your source tree
1485 AC_CONFIG_MAKEFILE(Makefile)
1486 AC_CONFIG_MAKEFILE(lib/Makefile)
1487 AC_CONFIG_MAKEFILE(lib/sample/Makefile)
1488 AC_CONFIG_MAKEFILE(tools/Makefile)
1489 AC_CONFIG_MAKEFILE(tools/sample/Makefile)
1490
1491 dnl This must be last
1492 AC_OUTPUT