projects/sample/autoconf/configure.ac

   1 dnl **************************************************************************
   2 dnl * Initialize
   3 dnl **************************************************************************
   4 AC_INIT([[[SAMPLE]]],[[[x.xx]]],[bugs@yourdomain])
   5
   6 dnl Identify where LLVM source tree is
   7 LLVM_SRC_ROOT="../.."
   8 LLVM_OBJ_ROOT="../.."
   9
  10 dnl Find absolute paths to LLVM source and object trees
  11 LLVM_ABS_SRC_ROOT="`cd $srcdir ; cd $LLVM_SRC_ROOT ; pwd`"
  12 LLVM_ABS_OBJ_ROOT="`cd $LLVM_OBJ_ROOT ; pwd`"
  13
  14 dnl Tell autoconf that this is an LLVM project being configured
  15 dnl This provides the --with-llvmsrc and --with-llvmobj options
  16 LLVM_CONFIG_PROJECT($LLVM_ABS_SRC_ROOT,$LLVM_ABS_OBJ_ROOT)
  17
  18 dnl Try and find an llvm-config in the build directory. We are only using this
  19 dnl to detect the package level LLVM information (currently just the version),
  20 dnl so we just whatever one we find regardless of build mode.
  21 AC_MSG_CHECKING([llvm-config])
  22 llvm_config_path="`ls -1 $llvm_obj/*/bin/llvm-config 2> /dev/null | head -1`"
  23 if ! test -f "$llvm_config_path" ; then
  24    llvm_config_path="no"
  25 fi
  26 AC_MSG_RESULT([$llvm_config_path])
  27
  28 dnl Determine the LLVM version, which may be required by the current Makefile
  29 dnl rules.
  30 AC_MSG_CHECKING([LLVM package version])
  31 if test "$llvm_config_path" != no ; then
  32   llvm_package_version=`$llvm_config_path --version`
  33 else
  34   llvm_package_version="unknown";
  35 fi
  36 AC_MSG_RESULT([$llvm_package_version])
  37 AC_SUBST(LLVM_VERSION, [$llvm_package_version])
  38
  39 dnl Verify that the source directory is valid
  40 AC_CONFIG_SRCDIR(["Makefile.common.in"])
  41
  42 dnl Place all of the extra autoconf files into the config subdirectory. Tell
  43 dnl various tools where the m4 autoconf macros are.
  44 AC_CONFIG_AUX_DIR([autoconf])
  45
  46 dnl **************************************************************************
  47 dnl Begin LLVM configure.ac Import
  48 dnl **************************************************************************
  49 dnl
  50 dnl Derived from LLVM's configure.ac. This was imported directly here so that we
  51 dnl could reuse LLVM's build infrastructure without introducing a direct source
  52 dnl dependency on the LLVM files.
  53
  54 dnl We need to check for the compiler up here to avoid anything else
  55 dnl starting with a different one.
  56 AC_PROG_CC(clang llvm-gcc gcc)
  57 AC_PROG_CXX(clang++ llvm-g++ g++)
  58 AC_PROG_CPP
  59
  60 dnl Configure all of the projects present in our source tree. While we could
  61 dnl just AC_CONFIG_SUBDIRS on the set of directories in projects that have a
  62 dnl configure script, that usage of the AC_CONFIG_SUBDIRS macro is deprecated.
  63 dnl Instead we match on the known projects.
  64
  65 dnl
  66 dnl One tricky part of doing this is that some projects depend upon other
  67 dnl projects.  For example, several projects rely upon the LLVM test suite.
  68 dnl We want to configure those projects first so that their object trees are
  69 dnl created before running the configure scripts of projects that depend upon
  70 dnl them.
  71 dnl
  72
  73 dnl Disable the build of polly, even if it is checked out into tools/polly.
  74 AC_ARG_ENABLE(polly,
  75               AS_HELP_STRING([--enable-polly],
  76                              [Use polly if available (default is YES)]),,
  77                              enableval=default)
  78 case "$enableval" in
  79   yes) AC_SUBST(ENABLE_POLLY,[1]) ;;
  80   no)  AC_SUBST(ENABLE_POLLY,[0]) ;;
  81   default) AC_SUBST(ENABLE_POLLY,[1]) ;;
  82   *) AC_MSG_ERROR([Invalid setting for --enable-polly. Use "yes" or "no"]) ;;
  83 esac
  84
  85
  86 dnl Check if polly is checked out into tools/polly and configure it if
  87 dnl available.
  88 if (test -d ${srcdir}/tools/polly) && (test $ENABLE_POLLY -eq 1) ; then
  89   AC_SUBST(LLVM_HAS_POLLY,1)
  90   AC_CONFIG_SUBDIRS([tools/polly])
  91 fi
  92
  93 dnl===-----------------------------------------------------------------------===
  94 dnl===
  95 dnl=== SECTION 2: Architecture, target, and host checks
  96 dnl===
  97 dnl===-----------------------------------------------------------------------===
  98
  99 dnl Check the target for which we're compiling and the host that will do the
 100 dnl compilations. This will tell us which LLVM compiler will be used for
 101 dnl compiling SSA into object code. This needs to be done early because
 102 dnl following tests depend on it.
 103 AC_CANONICAL_TARGET
 104
 105 dnl Determine the platform type and cache its value. This helps us configure
 106 dnl the System library to the correct build platform.
 107 AC_CACHE_CHECK([type of operating system we're going to host on],
 108                [llvm_cv_os_type],
 109 [case $host in
 110   *-*-aix*)
 111     llvm_cv_link_all_option="-Wl,--whole-archive"
 112     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 113     llvm_cv_os_type="AIX"
 114     llvm_cv_platform_type="Unix" ;;
 115   *-*-irix*)
 116     llvm_cv_link_all_option="-Wl,--whole-archive"
 117     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 118     llvm_cv_os_type="IRIX"
 119     llvm_cv_platform_type="Unix" ;;
 120   *-*-cygwin*)
 121     llvm_cv_link_all_option="-Wl,--whole-archive"
 122     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 123     llvm_cv_os_type="Cygwin"
 124     llvm_cv_platform_type="Unix" ;;
 125   *-*-darwin*)
 126     llvm_cv_link_all_option="-Wl,-all_load"
 127     llvm_cv_no_link_all_option="-Wl,-noall_load"
 128     llvm_cv_os_type="Darwin"
 129     llvm_cv_platform_type="Unix" ;;
 130   *-*-minix*)
 131     llvm_cv_link_all_option="-Wl,-all_load"
 132     llvm_cv_no_link_all_option="-Wl,-noall_load"
 133     llvm_cv_os_type="Minix"
 134     llvm_cv_platform_type="Unix" ;;
 135   *-*-freebsd*)
 136     llvm_cv_link_all_option="-Wl,--whole-archive"
 137     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 138     llvm_cv_os_type="FreeBSD"
 139     llvm_cv_platform_type="Unix" ;;
 140   *-*-openbsd*)
 141     llvm_cv_link_all_option="-Wl,--whole-archive"
 142     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 143     llvm_cv_os_type="OpenBSD"
 144     llvm_cv_platform_type="Unix" ;;
 145   *-*-netbsd*)
 146     llvm_cv_link_all_option="-Wl,--whole-archive"
 147     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 148     llvm_cv_os_type="NetBSD"
 149     llvm_cv_platform_type="Unix" ;;
 150   *-*-dragonfly*)
 151     llvm_cv_link_all_option="-Wl,--whole-archive"
 152     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 153     llvm_cv_os_type="DragonFly"
 154     llvm_cv_platform_type="Unix" ;;
 155   *-*-hpux*)
 156     llvm_cv_link_all_option="-Wl,--whole-archive"
 157     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 158     llvm_cv_os_type="HP-UX"
 159     llvm_cv_platform_type="Unix" ;;
 160   *-*-interix*)
 161     llvm_cv_link_all_option="-Wl,--whole-archive"
 162     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 163     llvm_cv_os_type="Interix"
 164     llvm_cv_platform_type="Unix" ;;
 165   *-*-linux*)
 166     llvm_cv_link_all_option="-Wl,--whole-archive"
 167     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 168     llvm_cv_os_type="Linux"
 169     llvm_cv_platform_type="Unix" ;;
 170   *-*-solaris*)
 171     llvm_cv_link_all_option="-Wl,-z,allextract"
 172     llvm_cv_no_link_all_option="-Wl,-z,defaultextract"
 173     llvm_cv_os_type="SunOS"
 174     llvm_cv_platform_type="Unix" ;;
 175   *-*-auroraux*)
 176     llvm_cv_link_all_option="-Wl,-z,allextract"
 177     llvm_cv_link_all_option="-Wl,-z,defaultextract"
 178     llvm_cv_os_type="AuroraUX"
 179     llvm_cv_platform_type="Unix" ;;
 180   *-*-win32*)
 181     llvm_cv_link_all_option="-Wl,--whole-archive"
 182     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 183     llvm_cv_os_type="Win32"
 184     llvm_cv_platform_type="Win32" ;;
 185   *-*-mingw*)
 186     llvm_cv_link_all_option="-Wl,--whole-archive"
 187     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 188     llvm_cv_os_type="MingW"
 189     llvm_cv_platform_type="Win32" ;;
 190   *-*-haiku*)
 191     llvm_cv_link_all_option="-Wl,--whole-archive"
 192     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 193     llvm_cv_os_type="Haiku"
 194     llvm_cv_platform_type="Unix" ;;
 195   *-unknown-eabi*)
 196     llvm_cv_link_all_option="-Wl,--whole-archive"
 197     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 198     llvm_cv_os_type="Freestanding"
 199     llvm_cv_platform_type="Unix" ;;
 200   *-unknown-elf*)
 201     llvm_cv_link_all_option="-Wl,--whole-archive"
 202     llvm_cv_no_link_all_option="-Wl,--no-whole-archive"
 203     llvm_cv_os_type="Freestanding"
 204     llvm_cv_platform_type="Unix" ;;
 205   *)
 206     llvm_cv_link_all_option=""
 207     llvm_cv_no_link_all_option=""
 208     llvm_cv_os_type="Unknown"
 209     llvm_cv_platform_type="Unknown" ;;
 210 esac])
 211
 212 AC_CACHE_CHECK([type of operating system we're going to target],
 213                [llvm_cv_target_os_type],
 214 [case $target in
 215   *-*-aix*)
 216     llvm_cv_target_os_type="AIX" ;;
 217   *-*-irix*)
 218     llvm_cv_target_os_type="IRIX" ;;
 219   *-*-cygwin*)
 220     llvm_cv_target_os_type="Cygwin" ;;
 221   *-*-darwin*)
 222     llvm_cv_target_os_type="Darwin" ;;
 223   *-*-minix*)
 224     llvm_cv_target_os_type="Minix" ;;
 225   *-*-freebsd*)
 226     llvm_cv_target_os_type="FreeBSD" ;;
 227   *-*-openbsd*)
 228     llvm_cv_target_os_type="OpenBSD" ;;
 229   *-*-netbsd*)
 230     llvm_cv_target_os_type="NetBSD" ;;
 231   *-*-dragonfly*)
 232     llvm_cv_target_os_type="DragonFly" ;;
 233   *-*-hpux*)
 234     llvm_cv_target_os_type="HP-UX" ;;
 235   *-*-interix*)
 236     llvm_cv_target_os_type="Interix" ;;
 237   *-*-linux*)
 238     llvm_cv_target_os_type="Linux" ;;
 239   *-*-solaris*)
 240     llvm_cv_target_os_type="SunOS" ;;
 241   *-*-auroraux*)
 242     llvm_cv_target_os_type="AuroraUX" ;;
 243   *-*-win32*)
 244     llvm_cv_target_os_type="Win32" ;;
 245   *-*-mingw*)
 246     llvm_cv_target_os_type="MingW" ;;
 247   *-*-haiku*)
 248     llvm_cv_target_os_type="Haiku" ;;
 249   *-*-rtems*)
 250     llvm_cv_target_os_type="RTEMS" ;;
 251   *-*-nacl*)
 252     llvm_cv_target_os_type="NativeClient" ;;
 253   *-unknown-eabi*)
 254     llvm_cv_target_os_type="Freestanding" ;;
 255   *)
 256     llvm_cv_target_os_type="Unknown" ;;
 257 esac])
 258
 259 dnl Make sure we aren't attempting to configure for an unknown system
 260 if test "$llvm_cv_os_type" = "Unknown" ; then
 261   AC_MSG_ERROR([Operating system is unknown, configure can't continue])
 262 fi
 263
 264 dnl Set the "OS" Makefile variable based on the platform type so the
 265 dnl makefile can configure itself to specific build hosts
 266 AC_SUBST(OS,$llvm_cv_os_type)
 267 AC_SUBST(HOST_OS,$llvm_cv_os_type)
 268 AC_SUBST(TARGET_OS,$llvm_cv_target_os_type)
 269
 270 dnl Set the LINKALL and NOLINKALL Makefile variables based on the platform
 271 AC_SUBST(LINKALL,$llvm_cv_link_all_option)
 272 AC_SUBST(NOLINKALL,$llvm_cv_no_link_all_option)
 273
 274 dnl Set the "LLVM_ON_*" variables based on llvm_cv_platform_type
 275 dnl This is used by lib/Support to determine the basic kind of implementation
 276 dnl to use.
 277 case $llvm_cv_platform_type in
 278   Unix)
 279     AC_DEFINE([LLVM_ON_UNIX],[1],[Define if this is Unixish platform])
 280     AC_SUBST(LLVM_ON_UNIX,[1])
 281     AC_SUBST(LLVM_ON_WIN32,[0])
 282     ;;
 283   Win32)
 284     AC_DEFINE([LLVM_ON_WIN32],[1],[Define if this is Win32ish platform])
 285     AC_SUBST(LLVM_ON_UNIX,[0])
 286     AC_SUBST(LLVM_ON_WIN32,[1])
 287     ;;
 288 esac
 289
 290 dnl Determine what our target architecture is and configure accordingly.
 291 dnl This will allow Makefiles to make a distinction between the hardware and
 292 dnl the OS.
 293 AC_CACHE_CHECK([target architecture],[llvm_cv_target_arch],
 294 [case $target in
 295   i?86-*)                 llvm_cv_target_arch="x86" ;;
 296   amd64-* | x86_64-*)     llvm_cv_target_arch="x86_64" ;;
 297   sparc*-*)               llvm_cv_target_arch="Sparc" ;;
 298   powerpc*-*)             llvm_cv_target_arch="PowerPC" ;;
 299   arm*-*)                 llvm_cv_target_arch="ARM" ;;
 300   mips-*)                 llvm_cv_target_arch="Mips" ;;
 301   xcore-*)                llvm_cv_target_arch="XCore" ;;
 302   msp430-*)               llvm_cv_target_arch="MSP430" ;;
 303   hexagon-*)              llvm_cv_target_arch="Hexagon" ;;
 304   mblaze-*)               llvm_cv_target_arch="MBlaze" ;;
 305   ptx-*)                  llvm_cv_target_arch="PTX" ;;
 306   *)                      llvm_cv_target_arch="Unknown" ;;
 307 esac])
 308
 309 if test "$llvm_cv_target_arch" = "Unknown" ; then
 310   AC_MSG_WARN([Configuring LLVM for an unknown target archicture])
 311 fi
 312
 313 # Determine the LLVM native architecture for the target
 314 case "$llvm_cv_target_arch" in
 315     x86)     LLVM_NATIVE_ARCH="X86" ;;
 316     x86_64)  LLVM_NATIVE_ARCH="X86" ;;
 317     *)       LLVM_NATIVE_ARCH="$llvm_cv_target_arch" ;;
 318 esac
 319
 320 dnl Define a substitution, ARCH, for the target architecture
 321 AC_SUBST(ARCH,$llvm_cv_target_arch)
 322
 323 dnl Check for the endianness of the target
 324 AC_C_BIGENDIAN(AC_SUBST([ENDIAN],[big]),AC_SUBST([ENDIAN],[little]))
 325
 326 dnl Check for build platform executable suffix if we're crosscompiling
 327 if test "$cross_compiling" = yes; then
 328   AC_SUBST(LLVM_CROSS_COMPILING, [1])
 329   AC_BUILD_EXEEXT
 330   ac_build_prefix=${build_alias}-
 331   AC_CHECK_PROG(BUILD_CXX, ${ac_build_prefix}g++, ${ac_build_prefix}g++)
 332   if test -z "$BUILD_CXX"; then
 333      AC_CHECK_PROG(BUILD_CXX, g++, g++)
 334      if test -z "$BUILD_CXX"; then
 335        AC_CHECK_PROG(BUILD_CXX, c++, c++, , , /usr/ucb/c++)
 336      fi
 337   fi
 338 else
 339   AC_SUBST(LLVM_CROSS_COMPILING, [0])
 340 fi
 341
 342 dnl Check to see if there's a .svn or .git directory indicating that this
 343 dnl build is being done from a checkout. This sets up several defaults for
 344 dnl the command line switches. When we build with a checkout directory,
 345 dnl we get a debug with assertions turned on. Without, we assume a source
 346 dnl release and we get an optimized build without assertions.
 347 dnl See --enable-optimized and --enable-assertions below
 348 if test -d ".svn" -o -d "${srcdir}/.svn" -o -d ".git" -o -d "${srcdir}/.git"; then
 349   cvsbuild="yes"
 350   optimize="no"
 351   AC_SUBST(CVSBUILD,[[CVSBUILD=1]])
 352 else
 353   cvsbuild="no"
 354   optimize="yes"
 355 fi
 356
 357 dnl===-----------------------------------------------------------------------===
 358 dnl===
 359 dnl=== SECTION 3: Command line arguments for the configure script.
 360 dnl===
 361 dnl===-----------------------------------------------------------------------===
 362
 363 dnl --enable-optimized : check whether they want to do an optimized build:
 364 AC_ARG_ENABLE(optimized, AS_HELP_STRING(
 365  --enable-optimized,[Compile with optimizations enabled (default is NO)]),,enableval=$optimize)
 366 if test ${enableval} = "no" ; then
 367   AC_SUBST(ENABLE_OPTIMIZED,[[]])
 368 else
 369   AC_SUBST(ENABLE_OPTIMIZED,[[ENABLE_OPTIMIZED=1]])
 370 fi
 371
 372 dnl --enable-profiling : check whether they want to do a profile build:
 373 AC_ARG_ENABLE(profiling, AS_HELP_STRING(
 374  --enable-profiling,[Compile with profiling enabled (default is NO)]),,enableval="no")
 375 if test ${enableval} = "no" ; then
 376   AC_SUBST(ENABLE_PROFILING,[[]])
 377 else
 378   AC_SUBST(ENABLE_PROFILING,[[ENABLE_PROFILING=1]])
 379 fi
 380
 381 dnl --enable-assertions : check whether they want to turn on assertions or not:
 382 AC_ARG_ENABLE(assertions,AS_HELP_STRING(
 383   --enable-assertions,[Compile with assertion checks enabled (default is YES)]),, enableval="yes")
 384 if test ${enableval} = "yes" ; then
 385   AC_SUBST(DISABLE_ASSERTIONS,[[]])
 386 else
 387   AC_SUBST(DISABLE_ASSERTIONS,[[DISABLE_ASSERTIONS=1]])
 388 fi
 389
 390 dnl --enable-expensive-checks : check whether they want to turn on expensive debug checks:
 391 AC_ARG_ENABLE(expensive-checks,AS_HELP_STRING(
 392   --enable-expensive-checks,[Compile with expensive debug checks enabled (default is NO)]),, enableval="no")
 393 if test ${enableval} = "yes" ; then
 394   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[ENABLE_EXPENSIVE_CHECKS=1]])
 395   AC_SUBST(EXPENSIVE_CHECKS,[[yes]])
 396 else
 397   AC_SUBST(ENABLE_EXPENSIVE_CHECKS,[[]])
 398   AC_SUBST(EXPENSIVE_CHECKS,[[no]])
 399 fi
 400
 401 dnl --enable-debug-runtime : should runtime libraries have debug symbols?
 402 AC_ARG_ENABLE(debug-runtime,
 403    AS_HELP_STRING(--enable-debug-runtime,[Build runtime libs with debug symbols (default is NO)]),,enableval=no)
 404 if test ${enableval} = "no" ; then
 405   AC_SUBST(DEBUG_RUNTIME,[[]])
 406 else
 407   AC_SUBST(DEBUG_RUNTIME,[[DEBUG_RUNTIME=1]])
 408 fi
 409
 410 dnl --enable-debug-symbols : should even optimized compiler libraries
 411 dnl have debug symbols?
 412 AC_ARG_ENABLE(debug-symbols,
 413    AS_HELP_STRING(--enable-debug-symbols,[Build compiler with debug symbols (default is NO if optimization is on and YES if it's off)]),,enableval=no)
 414 if test ${enableval} = "no" ; then
 415   AC_SUBST(DEBUG_SYMBOLS,[[]])
 416 else
 417   AC_SUBST(DEBUG_SYMBOLS,[[DEBUG_SYMBOLS=1]])
 418 fi
 419
 420 dnl --enable-jit: check whether they want to enable the jit
 421 AC_ARG_ENABLE(jit,
 422   AS_HELP_STRING(--enable-jit,
 423                  [Enable Just In Time Compiling (default is YES)]),,
 424   enableval=default)
 425 if test ${enableval} = "no"
 426 then
 427   AC_SUBST(JIT,[[]])
 428 else
 429   case "$llvm_cv_target_arch" in
 430     x86)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 431     Sparc)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 432     PowerPC)     AC_SUBST(TARGET_HAS_JIT,1) ;;
 433     x86_64)      AC_SUBST(TARGET_HAS_JIT,1) ;;
 434     ARM)         AC_SUBST(TARGET_HAS_JIT,1) ;;
 435     Mips)        AC_SUBST(TARGET_HAS_JIT,1) ;;
 436     XCore)       AC_SUBST(TARGET_HAS_JIT,0) ;;
 437     MSP430)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 438     Hexagon)     AC_SUBST(TARGET_HAS_JIT,0) ;;
 439     MBlaze)      AC_SUBST(TARGET_HAS_JIT,0) ;;
 440     PTX)         AC_SUBST(TARGET_HAS_JIT,0) ;;
 441     *)           AC_SUBST(TARGET_HAS_JIT,0) ;;
 442   esac
 443 fi
 444
 445 dnl Allow enablement of building and installing docs
 446 AC_ARG_ENABLE(docs,
 447               AS_HELP_STRING([--enable-docs],
 448                              [Build documents (default is YES)]),,
 449                              enableval=default)
 450 case "$enableval" in
 451   yes) AC_SUBST(ENABLE_DOCS,[1]) ;;
 452   no)  AC_SUBST(ENABLE_DOCS,[0]) ;;
 453   default) AC_SUBST(ENABLE_DOCS,[1]) ;;
 454   *) AC_MSG_ERROR([Invalid setting for --enable-docs. Use "yes" or "no"]) ;;
 455 esac
 456
 457 dnl Allow enablement of doxygen generated documentation
 458 AC_ARG_ENABLE(doxygen,
 459               AS_HELP_STRING([--enable-doxygen],
 460                              [Build doxygen documentation (default is NO)]),,
 461                              enableval=default)
 462 case "$enableval" in
 463   yes) AC_SUBST(ENABLE_DOXYGEN,[1]) ;;
 464   no)  AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 465   default) AC_SUBST(ENABLE_DOXYGEN,[0]) ;;
 466   *) AC_MSG_ERROR([Invalid setting for --enable-doxygen. Use "yes" or "no"]) ;;
 467 esac
 468
 469 dnl Allow disablement of threads
 470 AC_ARG_ENABLE(threads,
 471               AS_HELP_STRING([--enable-threads],
 472                              [Use threads if available (default is YES)]),,
 473                              enableval=default)
 474 case "$enableval" in
 475   yes) AC_SUBST(ENABLE_THREADS,[1]) ;;
 476   no)  AC_SUBST(ENABLE_THREADS,[0]) ;;
 477   default) AC_SUBST(ENABLE_THREADS,[1]) ;;
 478   *) AC_MSG_ERROR([Invalid setting for --enable-threads. Use "yes" or "no"]) ;;
 479 esac
 480 AC_DEFINE_UNQUOTED([ENABLE_THREADS],$ENABLE_THREADS,[Define if threads enabled])
 481
 482 dnl Allow disablement of pthread.h
 483 AC_ARG_ENABLE(pthreads,
 484               AS_HELP_STRING([--enable-pthreads],
 485                              [Use pthreads if available (default is YES)]),,
 486                              enableval=default)
 487 case "$enableval" in
 488   yes) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 489   no)  AC_SUBST(ENABLE_PTHREADS,[0]) ;;
 490   default) AC_SUBST(ENABLE_PTHREADS,[1]) ;;
 491   *) AC_MSG_ERROR([Invalid setting for --enable-pthreads. Use "yes" or "no"]) ;;
 492 esac
 493
 494 dnl Allow building without position independent code
 495 AC_ARG_ENABLE(pic,
 496   AS_HELP_STRING([--enable-pic],
 497                  [Build LLVM with Position Independent Code (default is YES)]),,
 498                  enableval=default)
 499 case "$enableval" in
 500   yes) AC_SUBST(ENABLE_PIC,[1]) ;;
 501   no)  AC_SUBST(ENABLE_PIC,[0]) ;;
 502   default) AC_SUBST(ENABLE_PIC,[1]) ;;
 503   *) AC_MSG_ERROR([Invalid setting for --enable-pic. Use "yes" or "no"]) ;;
 504 esac
 505 AC_DEFINE_UNQUOTED([ENABLE_PIC],$ENABLE_PIC,
 506                    [Define if position independent code is enabled])
 507
 508 dnl Allow building a shared library and linking tools against it.
 509 AC_ARG_ENABLE(shared,
 510   AS_HELP_STRING([--enable-shared],
 511                  [Build a shared library and link tools against it (default is NO)]),,
 512                  enableval=default)
 513 case "$enableval" in
 514   yes) AC_SUBST(ENABLE_SHARED,[1]) ;;
 515   no)  AC_SUBST(ENABLE_SHARED,[0]) ;;
 516   default) AC_SUBST(ENABLE_SHARED,[0]) ;;
 517   *) AC_MSG_ERROR([Invalid setting for --enable-shared. Use "yes" or "no"]) ;;
 518 esac
 519
 520 dnl Allow libstdc++ is embedded in LLVM.dll.
 521 AC_ARG_ENABLE(embed-stdcxx,
 522   AS_HELP_STRING([--enable-embed-stdcxx],
 523                  [Build a shared library with embedded libstdc++ for Win32 DLL (default is YES)]),,
 524                  enableval=default)
 525 case "$enableval" in
 526   yes) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 527   no)  AC_SUBST(ENABLE_EMBED_STDCXX,[0]) ;;
 528   default) AC_SUBST(ENABLE_EMBED_STDCXX,[1]) ;;
 529   *) AC_MSG_ERROR([Invalid setting for --enable-embed-stdcxx. Use "yes" or "no"]) ;;
 530 esac
 531
 532 dnl Enable embedding timestamp information into build.
 533 AC_ARG_ENABLE(timestamps,
 534   AS_HELP_STRING([--enable-timestamps],
 535                  [Enable embedding timestamp information in build (default is YES)]),,
 536                  enableval=default)
 537 case "$enableval" in
 538   yes) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 539   no)  AC_SUBST(ENABLE_TIMESTAMPS,[0]) ;;
 540   default) AC_SUBST(ENABLE_TIMESTAMPS,[1]) ;;
 541   *) AC_MSG_ERROR([Invalid setting for --enable-timestamps. Use "yes" or "no"]) ;;
 542 esac
 543 AC_DEFINE_UNQUOTED([ENABLE_TIMESTAMPS],$ENABLE_TIMESTAMPS,
 544                    [Define if timestamp information (e.g., __DATE___) is allowed])
 545
 546 dnl Allow specific targets to be specified for building (or not)
 547 TARGETS_TO_BUILD=""
 548 AC_ARG_ENABLE([targets],AS_HELP_STRING([--enable-targets],
 549     [Build specific host targets: all or target1,target2,... Valid targets are:
 550      host, x86, x86_64, sparc, powerpc, arm, mips, spu, hexagon,
 551      xcore, msp430, ptx, cbe, and cpp (default=all)]),,
 552     enableval=all)
 553 if test "$enableval" = host-only ; then
 554   enableval=host
 555 fi
 556 case "$enableval" in
 557   all) TARGETS_TO_BUILD="X86 Sparc PowerPC ARM Mips CellSPU XCore MSP430 Hexagon CppBackend MBlaze PTX" ;;
 558   *)for a_target in `echo $enableval|sed -e 's/,/ /g' ` ; do
 559       case "$a_target" in
 560         x86)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 561         x86_64)   TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 562         sparc)    TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 563         powerpc)  TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 564         arm)      TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 565         mips)     TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 566         spu)      TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 567         xcore)    TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 568         msp430)   TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 569         hexagon)  TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 570         cpp)      TARGETS_TO_BUILD="CppBackend $TARGETS_TO_BUILD" ;;
 571         mblaze)   TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 572         ptx)      TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 573         host) case "$llvm_cv_target_arch" in
 574             x86)         TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 575             x86_64)      TARGETS_TO_BUILD="X86 $TARGETS_TO_BUILD" ;;
 576             Sparc)       TARGETS_TO_BUILD="Sparc $TARGETS_TO_BUILD" ;;
 577             PowerPC)     TARGETS_TO_BUILD="PowerPC $TARGETS_TO_BUILD" ;;
 578             ARM)         TARGETS_TO_BUILD="ARM $TARGETS_TO_BUILD" ;;
 579             Mips)        TARGETS_TO_BUILD="Mips $TARGETS_TO_BUILD" ;;
 580             MBlaze)      TARGETS_TO_BUILD="MBlaze $TARGETS_TO_BUILD" ;;
 581             CellSPU|SPU) TARGETS_TO_BUILD="CellSPU $TARGETS_TO_BUILD" ;;
 582             XCore)       TARGETS_TO_BUILD="XCore $TARGETS_TO_BUILD" ;;
 583             MSP430)      TARGETS_TO_BUILD="MSP430 $TARGETS_TO_BUILD" ;;
 584             Hexagon)     TARGETS_TO_BUILD="Hexagon $TARGETS_TO_BUILD" ;;
 585             PTX)         TARGETS_TO_BUILD="PTX $TARGETS_TO_BUILD" ;;
 586             *)       AC_MSG_ERROR([Can not set target to build]) ;;
 587           esac ;;
 588         *) AC_MSG_ERROR([Unrecognized target $a_target]) ;;
 589       esac
 590   done
 591   ;;
 592 esac
 593 AC_SUBST(TARGETS_TO_BUILD,$TARGETS_TO_BUILD)
 594
 595 # Determine whether we are building LLVM support for the native architecture.
 596 # If so, define LLVM_NATIVE_ARCH to that LLVM target.
 597 for a_target in $TARGETS_TO_BUILD; do
 598   if test "$a_target" = "$LLVM_NATIVE_ARCH"; then
 599     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ARCH, $LLVM_NATIVE_ARCH,
 600       [LLVM architecture name for the native architecture, if available])
 601     LLVM_NATIVE_TARGET="LLVMInitialize${LLVM_NATIVE_ARCH}Target"
 602     LLVM_NATIVE_TARGETINFO="LLVMInitialize${LLVM_NATIVE_ARCH}TargetInfo"
 603     LLVM_NATIVE_TARGETMC="LLVMInitialize${LLVM_NATIVE_ARCH}TargetMC"
 604     LLVM_NATIVE_ASMPRINTER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmPrinter"
 605     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 606       LLVM_NATIVE_ASMPARSER="LLVMInitialize${LLVM_NATIVE_ARCH}AsmParser"
 607     fi
 608     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGET, $LLVM_NATIVE_TARGET,
 609       [LLVM name for the native Target init function, if available])
 610     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETINFO, $LLVM_NATIVE_TARGETINFO,
 611       [LLVM name for the native TargetInfo init function, if available])
 612     AC_DEFINE_UNQUOTED(LLVM_NATIVE_TARGETMC, $LLVM_NATIVE_TARGETMC,
 613       [LLVM name for the native target MC init function, if available])
 614     AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPRINTER, $LLVM_NATIVE_ASMPRINTER,
 615       [LLVM name for the native AsmPrinter init function, if available])
 616     if test -f ${srcdir}/lib/Target/${LLVM_NATIVE_ARCH}/AsmParser/Makefile ; then
 617       AC_DEFINE_UNQUOTED(LLVM_NATIVE_ASMPARSER, $LLVM_NATIVE_ASMPARSER,
 618        [LLVM name for the native AsmParser init function, if available])
 619     fi
 620   fi
 621 done
 622
 623 # Build the LLVM_TARGET and LLVM_... macros for Targets.def and the individual
 624 # target feature def files.
 625 LLVM_ENUM_TARGETS=""
 626 LLVM_ENUM_ASM_PRINTERS=""
 627 LLVM_ENUM_ASM_PARSERS=""
 628 LLVM_ENUM_DISASSEMBLERS=""
 629 for target_to_build in $TARGETS_TO_BUILD; do
 630   LLVM_ENUM_TARGETS="LLVM_TARGET($target_to_build) $LLVM_ENUM_TARGETS"
 631   if test -f ${srcdir}/lib/Target/${target_to_build}/*AsmPrinter.cpp ; then
 632     LLVM_ENUM_ASM_PRINTERS="LLVM_ASM_PRINTER($target_to_build) $LLVM_ENUM_ASM_PRINTERS";
 633   fi
 634   if test -f ${srcdir}/lib/Target/${target_to_build}/AsmParser/Makefile ; then
 635     LLVM_ENUM_ASM_PARSERS="LLVM_ASM_PARSER($target_to_build) $LLVM_ENUM_ASM_PARSERS";
 636   fi
 637   if test -f ${srcdir}/lib/Target/${target_to_build}/Disassembler/Makefile ; then
 638     LLVM_ENUM_DISASSEMBLERS="LLVM_DISASSEMBLER($target_to_build) $LLVM_ENUM_DISASSEMBLERS";
 639   fi
 640 done
 641 AC_SUBST(LLVM_ENUM_TARGETS)
 642 AC_SUBST(LLVM_ENUM_ASM_PRINTERS)
 643 AC_SUBST(LLVM_ENUM_ASM_PARSERS)
 644 AC_SUBST(LLVM_ENUM_DISASSEMBLERS)
 645
 646 dnl Override the option to use for optimized builds.
 647 AC_ARG_WITH(optimize-option,
 648   AS_HELP_STRING([--with-optimize-option],
 649                  [Select the compiler options to use for optimized builds]),,
 650                  withval=default)
 651 AC_MSG_CHECKING([optimization flags])
 652 case "$withval" in
 653   default)
 654     case "$llvm_cv_os_type" in
 655     FreeBSD) optimize_option=-O2 ;;
 656     MingW) optimize_option=-O2 ;;
 657     *)     optimize_option=-O3 ;;
 658     esac ;;
 659   *) optimize_option="$withval" ;;
 660 esac
 661 AC_SUBST(OPTIMIZE_OPTION,$optimize_option)
 662 AC_MSG_RESULT([$optimize_option])
 663
 664 dnl Specify extra build options
 665 AC_ARG_WITH(extra-options,
 666   AS_HELP_STRING([--with-extra-options],
 667                  [Specify additional options to compile LLVM with]),,
 668                  withval=default)
 669 case "$withval" in
 670   default) EXTRA_OPTIONS= ;;
 671   *) EXTRA_OPTIONS=$withval ;;
 672 esac
 673 AC_SUBST(EXTRA_OPTIONS,$EXTRA_OPTIONS)
 674
 675 dnl Specify extra linker build options
 676 AC_ARG_WITH(extra-ld-options,
 677   AS_HELP_STRING([--with-extra-ld-options],
 678                  [Specify additional options to link LLVM with]),,
 679                  withval=default)
 680 case "$withval" in
 681   default) EXTRA_LD_OPTIONS= ;;
 682   *) EXTRA_LD_OPTIONS=$withval ;;
 683 esac
 684 AC_SUBST(EXTRA_LD_OPTIONS,$EXTRA_LD_OPTIONS)
 685
 686 dnl Allow specific bindings to be specified for building (or not)
 687 AC_ARG_ENABLE([bindings],AS_HELP_STRING([--enable-bindings],
 688     [Build specific language bindings: all,auto,none,{binding-name} (default=auto)]),,
 689     enableval=default)
 690 BINDINGS_TO_BUILD=""
 691 case "$enableval" in
 692   yes | default | auto) BINDINGS_TO_BUILD="auto" ;;
 693   all ) BINDINGS_TO_BUILD="ocaml" ;;
 694   none | no) BINDINGS_TO_BUILD="" ;;
 695   *)for a_binding in `echo $enableval|sed -e 's/,/ /g' ` ; do
 696       case "$a_binding" in
 697         ocaml) BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD" ;;
 698         *) AC_MSG_ERROR([Unrecognized binding $a_binding]) ;;
 699       esac
 700   done
 701   ;;
 702 esac
 703
 704 dnl Allow the ocaml libdir to be overridden. This could go in a configure
 705 dnl script for bindings/ocaml/configure, except that its auto value depends on
 706 dnl OCAMLC, which is found here to support tests.
 707 AC_ARG_WITH([ocaml-libdir],
 708   [AS_HELP_STRING([--with-ocaml-libdir],
 709     [Specify install location for ocaml bindings (default is stdlib)])],
 710   [],
 711   [withval=auto])
 712 case "$withval" in
 713   auto) with_ocaml_libdir="$withval" ;;
 714   /* | [[A-Za-z]]:[[\\/]]*) with_ocaml_libdir="$withval" ;;
 715   *) AC_MSG_ERROR([Invalid path for --with-ocaml-libdir. Provide full path]) ;;
 716 esac
 717
 718 AC_ARG_WITH(clang-resource-dir,
 719   AS_HELP_STRING([--with-clang-resource-dir],
 720     [Relative directory from the Clang binary for resource files]),,
 721     withval="")
 722 AC_DEFINE_UNQUOTED(CLANG_RESOURCE_DIR,"$withval",
 723                    [Relative directory for resource files])
 724
 725 AC_ARG_WITH(c-include-dirs,
 726   AS_HELP_STRING([--with-c-include-dirs],
 727     [Colon separated list of directories clang will search for headers]),,
 728     withval="")
 729 AC_DEFINE_UNQUOTED(C_INCLUDE_DIRS,"$withval",
 730                    [Directories clang will search for headers])
 731
 732 # Clang normally uses the system c++ headers and libraries. With this option,
 733 # clang will use the ones provided by a gcc installation instead. This option should
 734 # be passed the same value that was used with --prefix when configuring gcc.
 735 AC_ARG_WITH(gcc-toolchain,
 736   AS_HELP_STRING([--with-gcc-toolchain],
 737     [Directory where gcc is installed.]),,
 738     withval="")
 739 AC_DEFINE_UNQUOTED(GCC_INSTALL_PREFIX,"$withval",
 740                    [Directory where gcc is installed.])
 741
 742 dnl Allow linking of LLVM with GPLv3 binutils code.
 743 AC_ARG_WITH(binutils-include,
 744   AS_HELP_STRING([--with-binutils-include],
 745     [Specify path to binutils/include/ containing plugin-api.h file for gold plugin.]),,
 746   withval=default)
 747 case "$withval" in
 748   default) WITH_BINUTILS_INCDIR=default ;;
 749   /* | [[A-Za-z]]:[[\\/]]*)      WITH_BINUTILS_INCDIR=$withval ;;
 750   *) AC_MSG_ERROR([Invalid path for --with-binutils-include. Provide full path]) ;;
 751 esac
 752 if test "x$WITH_BINUTILS_INCDIR" != xdefault ; then
 753   AC_SUBST(BINUTILS_INCDIR,$WITH_BINUTILS_INCDIR)
 754   if test ! -f "$WITH_BINUTILS_INCDIR/plugin-api.h"; then
 755      echo "$WITH_BINUTILS_INCDIR/plugin-api.h"
 756      AC_MSG_ERROR([Invalid path to directory containing plugin-api.h.]);
 757   fi
 758 fi
 759
 760 dnl Specify the URL where bug reports should be submitted.
 761 AC_ARG_WITH(bug-report-url,
 762   AS_HELP_STRING([--with-bug-report-url],
 763     [Specify the URL where bug reports should be submitted (default=http://llvm.org/bugs/)]),,
 764     withval="http://llvm.org/bugs/")
 765 AC_DEFINE_UNQUOTED(BUG_REPORT_URL,"$withval",
 766                    [Bug report URL.])
 767
 768 dnl --enable-libffi : check whether the user wants to turn off libffi:
 769 AC_ARG_ENABLE(libffi,AS_HELP_STRING(
 770   --enable-libffi,[Check for the presence of libffi (default is NO)]),
 771   [case "$enableval" in
 772     yes) llvm_cv_enable_libffi="yes" ;;
 773     no)  llvm_cv_enable_libffi="no"  ;;
 774     *) AC_MSG_ERROR([Invalid setting for --enable-libffi. Use "yes" or "no"]) ;;
 775   esac],
 776   llvm_cv_enable_libffi=no)
 777
 778 dnl===-----------------------------------------------------------------------===
 779 dnl===
 780 dnl=== SECTION 4: Check for programs we need and that they are the right version
 781 dnl===
 782 dnl===-----------------------------------------------------------------------===
 783
 784 AC_PROG_NM
 785 AC_SUBST(NM)
 786
 787 dnl Check for the tools that the makefiles require
 788 AC_CHECK_GNU_MAKE
 789 AC_PROG_LN_S
 790 AC_PATH_PROG(CMP, [cmp], [cmp])
 791 AC_PATH_PROG(CP, [cp], [cp])
 792 AC_PATH_PROG(DATE, [date], [date])
 793 AC_PATH_PROG(FIND, [find], [find])
 794 AC_PATH_PROG(GREP, [grep], [grep])
 795 AC_PATH_PROG(MKDIR,[mkdir],[mkdir])
 796 AC_PATH_PROG(MV,   [mv],   [mv])
 797 AC_PROG_RANLIB
 798 AC_CHECK_TOOL(AR, ar, false)
 799 AC_PATH_PROG(RM,   [rm],   [rm])
 800 AC_PATH_PROG(SED,  [sed],  [sed])
 801 AC_PATH_PROG(TAR,  [tar],  [gtar])
 802 AC_PATH_PROG(BINPWD,[pwd],  [pwd])
 803
 804 dnl Looking for misc. graph plotting software
 805 AC_PATH_PROG(GRAPHVIZ, [Graphviz], [echo Graphviz])
 806 if test "$GRAPHVIZ" != "echo Graphviz" ; then
 807   AC_DEFINE([HAVE_GRAPHVIZ],[1],[Define if the Graphviz program is available])
 808   dnl If we're targeting for mingw we should emit windows paths, not msys
 809   if test "$llvm_cv_os_type" = "MingW" ; then
 810     GRAPHVIZ=`echo $GRAPHVIZ | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 811   fi
 812   AC_DEFINE_UNQUOTED([LLVM_PATH_GRAPHVIZ],"$GRAPHVIZ${EXEEXT}",
 813    [Define to path to Graphviz program if found or 'echo Graphviz' otherwise])
 814 fi
 815 AC_PATH_PROG(DOT, [dot], [echo dot])
 816 if test "$DOT" != "echo dot" ; then
 817   AC_DEFINE([HAVE_DOT],[1],[Define if the dot program is available])
 818   dnl If we're targeting for mingw we should emit windows paths, not msys
 819   if test "$llvm_cv_os_type" = "MingW" ; then
 820     DOT=`echo $DOT | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 821   fi
 822   AC_DEFINE_UNQUOTED([LLVM_PATH_DOT],"$DOT${EXEEXT}",
 823    [Define to path to dot program if found or 'echo dot' otherwise])
 824 fi
 825 AC_PATH_PROG(FDP, [fdp], [echo fdp])
 826 if test "$FDP" != "echo fdp" ; then
 827   AC_DEFINE([HAVE_FDP],[1],[Define if the neat program is available])
 828   dnl If we're targeting for mingw we should emit windows paths, not msys
 829   if test "$llvm_cv_os_type" = "MingW" ; then
 830     FDP=`echo $FDP | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 831   fi
 832   AC_DEFINE_UNQUOTED([LLVM_PATH_FDP],"$FDP${EXEEXT}",
 833    [Define to path to fdp program if found or 'echo fdp' otherwise])
 834 fi
 835 AC_PATH_PROG(NEATO, [neato], [echo neato])
 836 if test "$NEATO" != "echo neato" ; then
 837   AC_DEFINE([HAVE_NEATO],[1],[Define if the neat program is available])
 838   dnl If we're targeting for mingw we should emit windows paths, not msys
 839   if test "$llvm_cv_os_type" = "MingW" ; then
 840     NEATO=`echo $NEATO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 841   fi
 842   AC_DEFINE_UNQUOTED([LLVM_PATH_NEATO],"$NEATO${EXEEXT}",
 843    [Define to path to neato program if found or 'echo neato' otherwise])
 844 fi
 845 AC_PATH_PROG(TWOPI, [twopi], [echo twopi])
 846 if test "$TWOPI" != "echo twopi" ; then
 847   AC_DEFINE([HAVE_TWOPI],[1],[Define if the neat program is available])
 848   dnl If we're targeting for mingw we should emit windows paths, not msys
 849   if test "$llvm_cv_os_type" = "MingW" ; then
 850     TWOPI=`echo $TWOPI | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 851   fi
 852   AC_DEFINE_UNQUOTED([LLVM_PATH_TWOPI],"$TWOPI${EXEEXT}",
 853    [Define to path to twopi program if found or 'echo twopi' otherwise])
 854 fi
 855 AC_PATH_PROG(CIRCO, [circo], [echo circo])
 856 if test "$CIRCO" != "echo circo" ; then
 857   AC_DEFINE([HAVE_CIRCO],[1],[Define if the neat program is available])
 858   dnl If we're targeting for mingw we should emit windows paths, not msys
 859   if test "$llvm_cv_os_type" = "MingW" ; then
 860     CIRCO=`echo $CIRCO | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 861   fi
 862   AC_DEFINE_UNQUOTED([LLVM_PATH_CIRCO],"$CIRCO${EXEEXT}",
 863    [Define to path to circo program if found or 'echo circo' otherwise])
 864 fi
 865 AC_PATH_PROGS(GV, [gv gsview32], [echo gv])
 866 if test "$GV" != "echo gv" ; then
 867   AC_DEFINE([HAVE_GV],[1],[Define if the gv program is available])
 868   dnl If we're targeting for mingw we should emit windows paths, not msys
 869   if test "$llvm_cv_os_type" = "MingW" ; then
 870     GV=`echo $GV | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 871   fi
 872   AC_DEFINE_UNQUOTED([LLVM_PATH_GV],"$GV${EXEEXT}",
 873    [Define to path to gv program if found or 'echo gv' otherwise])
 874 fi
 875 AC_PATH_PROG(DOTTY, [dotty], [echo dotty])
 876 if test "$DOTTY" != "echo dotty" ; then
 877   AC_DEFINE([HAVE_DOTTY],[1],[Define if the dotty program is available])
 878   dnl If we're targeting for mingw we should emit windows paths, not msys
 879   if test "$llvm_cv_os_type" = "MingW" ; then
 880     DOTTY=`echo $DOTTY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 881   fi
 882   AC_DEFINE_UNQUOTED([LLVM_PATH_DOTTY],"$DOTTY${EXEEXT}",
 883    [Define to path to dotty program if found or 'echo dotty' otherwise])
 884 fi
 885 AC_PATH_PROG(XDOT_PY, [xdot.py], [echo xdot.py])
 886 if test "$XDOT_PY" != "echo xdot.py" ; then
 887   AC_DEFINE([HAVE_XDOT_PY],[1],[Define if the xdot.py program is available])
 888   dnl If we're targeting for mingw we should emit windows paths, not msys
 889   if test "$llvm_cv_os_type" = "MingW" ; then
 890     XDOT_PY=`echo $XDOT_PY | sed 's/^\/\([[A-Za-z]]\)\//\1:\//' `
 891   fi
 892   AC_DEFINE_UNQUOTED([LLVM_PATH_XDOT_PY],"$XDOT_PY${EXEEXT}",
 893    [Define to path to xdot.py program if found or 'echo xdot.py' otherwise])
 894 fi
 895
 896 dnl Find the install program
 897 AC_PROG_INSTALL
 898 dnl Prepend src dir to install path dir if it's a relative path
 899 dnl This is a hack for installs that take place in something other
 900 dnl than the top level.
 901 case "$INSTALL" in
 902  [[\\/$]]* | ?:[[\\/]]* ) ;;
 903  *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 904 esac
 905
 906 dnl Checks for documentation and testing tools that we can do without. If these
 907 dnl are not found then they are set to "true" which always succeeds but does
 908 dnl nothing. This just lets the build output show that we could have done
 909 dnl something if the tool was available.
 910 AC_PATH_PROG(BZIP2, [bzip2])
 911 AC_PATH_PROG(CAT, [cat])
 912 AC_PATH_PROG(DOXYGEN, [doxygen])
 913 AC_PATH_PROG(GROFF, [groff])
 914 AC_PATH_PROG(GZIPBIN, [gzip])
 915 AC_PATH_PROG(POD2HTML, [pod2html])
 916 AC_PATH_PROG(POD2MAN, [pod2man])
 917 AC_PATH_PROG(PDFROFF, [pdfroff])
 918 AC_PATH_PROG(RUNTEST, [runtest])
 919 DJ_AC_PATH_TCLSH
 920 AC_PATH_PROG(ZIP, [zip])
 921 AC_PATH_PROGS(OCAMLC, [ocamlc])
 922 AC_PATH_PROGS(OCAMLOPT, [ocamlopt])
 923 AC_PATH_PROGS(OCAMLDEP, [ocamldep])
 924 AC_PATH_PROGS(OCAMLDOC, [ocamldoc])
 925 AC_PATH_PROGS(GAS, [gas as])
 926
 927 dnl Get the version of the linker in use.
 928 AC_LINK_GET_VERSION
 929
 930 dnl Determine whether the linker supports the -R option.
 931 AC_LINK_USE_R
 932
 933 dnl Determine whether the linker supports the -export-dynamic option.
 934 AC_LINK_EXPORT_DYNAMIC
 935
 936 dnl Determine whether the linker supports the --version-script option.
 937 AC_LINK_VERSION_SCRIPT
 938
 939 dnl Check for libtool and the library that has dlopen function (which must come
 940 dnl before the AC_PROG_LIBTOOL check in order to enable dlopening libraries with
 941 dnl libtool).
 942 AC_LIBTOOL_DLOPEN
 943 AC_LIB_LTDL
 944
 945 AC_MSG_CHECKING([tool compatibility])
 946
 947 dnl Ensure that compilation tools are GCC or a GNU compatible compiler such as
 948 dnl ICC; we use GCC specific options in the makefiles so the compiler needs
 949 dnl to support those options.
 950 dnl "icc" emits gcc signatures
 951 dnl "icc -no-gcc" emits no gcc signature BUT is still compatible
 952 ICC=no
 953 IXX=no
 954 case $CC in
 955   icc*|icpc*)
 956     ICC=yes
 957     IXX=yes
 958     ;;
 959    *)
 960     ;;
 961 esac
 962
 963 if test "$GCC" != "yes" && test "$ICC" != "yes"
 964 then
 965   AC_MSG_ERROR([gcc|icc required but not found])
 966 fi
 967
 968 dnl Ensure that compilation tools are compatible with GCC extensions
 969 if test "$GXX" != "yes" && test "$IXX" != "yes"
 970 then
 971   AC_MSG_ERROR([g++|clang++|icc required but not found])
 972 fi
 973
 974 dnl Verify that GCC is version 3.0 or higher
 975 if test "$GCC" = "yes"
 976 then
 977   AC_COMPILE_IFELSE([[#if !defined(__GNUC__) || __GNUC__ < 3
 978 #error Unsupported GCC version
 979 #endif
 980 ]], [], [AC_MSG_ERROR([gcc 3.x required, but you have a lower version])])
 981 fi
 982
 983 dnl Check for GNU Make.  We use its extensions, so don't build without it
 984 if test -z "$llvm_cv_gnu_make_command"
 985 then
 986   AC_MSG_ERROR([GNU Make required but not found])
 987 fi
 988
 989 dnl Tool compatibility is okay if we make it here.
 990 AC_MSG_RESULT([ok])
 991
 992 dnl Check optional compiler flags.
 993 AC_MSG_CHECKING([optional compiler flags])
 994 CXX_FLAG_CHECK(NO_VARIADIC_MACROS, [-Wno-variadic-macros])
 995 CXX_FLAG_CHECK(NO_MISSING_FIELD_INITIALIZERS, [-Wno-missing-field-initializers])
 996 CXX_FLAG_CHECK(COVERED_SWITCH_DEFAULT, [-Wcovered-switch-default])
 997 AC_MSG_RESULT([$NO_VARIADIC_MACROS $NO_MISSING_FIELD_INITIALIZERS $COVERED_SWITCH_DEFAULT])
 998
 999 dnl===-----------------------------------------------------------------------===
1000 dnl===
1001 dnl=== SECTION 5: Check for libraries
1002 dnl===
1003 dnl===-----------------------------------------------------------------------===
1004
1005 AC_CHECK_LIB(m,sin)
1006 if test "$llvm_cv_os_type" = "MingW" ; then
1007   AC_CHECK_LIB(imagehlp, main)
1008   AC_CHECK_LIB(psapi, main)
1009 fi
1010
1011 dnl dlopen() is required for plugin support.
1012 AC_SEARCH_LIBS(dlopen,dl,AC_DEFINE([HAVE_DLOPEN],[1],
1013                [Define if dlopen() is available on this platform.]),
1014                AC_MSG_WARN([dlopen() not found - disabling plugin support]))
1015
1016 dnl libffi is optional; used to call external functions from the interpreter
1017 if test "$llvm_cv_enable_libffi" = "yes" ; then
1018   AC_SEARCH_LIBS(ffi_call,ffi,AC_DEFINE([HAVE_FFI_CALL],[1],
1019                  [Define if libffi is available on this platform.]),
1020                  AC_MSG_ERROR([libffi not found - configure without --enable-libffi to compile without it]))
1021 fi
1022
1023 dnl mallinfo is optional; the code can compile (minus features) without it
1024 AC_SEARCH_LIBS(mallinfo,malloc,AC_DEFINE([HAVE_MALLINFO],[1],
1025                [Define if mallinfo() is available on this platform.]))
1026
1027 dnl pthread locking functions are optional - but llvm will not be thread-safe
1028 dnl without locks.
1029 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1030   AC_CHECK_LIB(pthread, pthread_mutex_init)
1031   AC_SEARCH_LIBS(pthread_mutex_lock,pthread,
1032                  AC_DEFINE([HAVE_PTHREAD_MUTEX_LOCK],[1],
1033                            [Have pthread_mutex_lock]))
1034   AC_SEARCH_LIBS(pthread_rwlock_init,pthread,
1035                  AC_DEFINE([HAVE_PTHREAD_RWLOCK_INIT],[1],
1036                  [Have pthread_rwlock_init]))
1037   AC_SEARCH_LIBS(pthread_getspecific,pthread,
1038                  AC_DEFINE([HAVE_PTHREAD_GETSPECIFIC],[1],
1039                  [Have pthread_getspecific]))
1040 fi
1041
1042 dnl Allow extra x86-disassembler library
1043 AC_ARG_WITH(udis86,
1044   AS_HELP_STRING([--with-udis86=<path>],
1045     [Use udis86 external x86 disassembler library]),
1046     [
1047       AC_SUBST(USE_UDIS86, [1])
1048       case "$withval" in
1049         /usr/lib|yes) ;;
1050         *) LDFLAGS="$LDFLAGS -L${withval}" ;;
1051       esac
1052       AC_CHECK_LIB(udis86, ud_init, [], [
1053         echo "Error! You need to have libudis86 around."
1054         exit -1
1055       ])
1056     ],
1057     AC_SUBST(USE_UDIS86, [0]))
1058 AC_DEFINE_UNQUOTED([USE_UDIS86],$USE_UDIS86,
1059                    [Define if use udis86 library])
1060
1061 dnl Allow OProfile support for JIT output.
1062 AC_ARG_WITH(oprofile,
1063   AS_HELP_STRING([--with-oprofile=<prefix>],
1064     [Tell OProfile >= 0.9.4 how to symbolize JIT output]),
1065     [
1066       AC_SUBST(USE_OPROFILE, [1])
1067       case "$withval" in
1068         /usr|yes) llvm_cv_oppath=/usr/lib/oprofile ;;
1069         no) llvm_cv_oppath=
1070             AC_SUBST(USE_OPROFILE, [0]) ;;
1071         *) llvm_cv_oppath="${withval}/lib/oprofile"
1072            CPPFLAGS="-I${withval}/include";;
1073       esac
1074       if test -n "$llvm_cv_oppath" ; then
1075         LIBS="$LIBS -L${llvm_cv_oppath} -Wl,-rpath,${llvm_cv_oppath}"
1076         dnl Work around http://bugs.debian.org/cgi-bin/bugreport.cgi?bug=537744:
1077         dnl libbfd is not included properly in libopagent in some Debian
1078         dnl versions.  If libbfd isn't found at all, we assume opagent works
1079         dnl anyway.
1080         AC_SEARCH_LIBS(bfd_init, bfd, [], [])
1081         AC_SEARCH_LIBS(op_open_agent, opagent, [], [
1082           echo "Error! You need to have libopagent around."
1083           exit -1
1084         ])
1085         AC_CHECK_HEADER([opagent.h], [], [
1086           echo "Error! You need to have opagent.h around."
1087           exit -1
1088           ])
1089       fi
1090     ],
1091     [
1092       AC_SUBST(USE_OPROFILE, [0])
1093     ])
1094 AC_DEFINE_UNQUOTED([USE_OPROFILE],$USE_OPROFILE,
1095                    [Define if we have the oprofile JIT-support library])
1096
1097 dnl===-----------------------------------------------------------------------===
1098 dnl===
1099 dnl=== SECTION 6: Check for header files
1100 dnl===
1101 dnl===-----------------------------------------------------------------------===
1102
1103 dnl First, use autoconf provided macros for specific headers that we need
1104 dnl We don't check for ancient stuff or things that are guaranteed to be there
1105 dnl by the C++ standard. We always use the <cfoo> versions of <foo.h> C headers.
1106 dnl Generally we're looking for POSIX headers.
1107 AC_HEADER_DIRENT
1108 AC_HEADER_MMAP_ANONYMOUS
1109 AC_HEADER_STAT
1110 AC_HEADER_SYS_WAIT
1111 AC_HEADER_TIME
1112
1113 AC_CHECK_HEADERS([dlfcn.h execinfo.h fcntl.h inttypes.h limits.h link.h])
1114 AC_CHECK_HEADERS([malloc.h setjmp.h signal.h stdint.h termios.h unistd.h])
1115 AC_CHECK_HEADERS([utime.h windows.h])
1116 AC_CHECK_HEADERS([sys/mman.h sys/param.h sys/resource.h sys/time.h sys/uio.h])
1117 AC_CHECK_HEADERS([sys/types.h sys/ioctl.h malloc/malloc.h mach/mach.h])
1118 AC_CHECK_HEADERS([valgrind/valgrind.h])
1119 AC_CHECK_HEADERS([fenv.h])
1120 if test "$ENABLE_THREADS" -eq 1 && test "$ENABLE_PTHREADS" -eq 1 ; then
1121   AC_CHECK_HEADERS(pthread.h,
1122                    AC_SUBST(HAVE_PTHREAD, 1),
1123                    AC_SUBST(HAVE_PTHREAD, 0))
1124 else
1125   AC_SUBST(HAVE_PTHREAD, 0)
1126 fi
1127
1128 dnl Try to find ffi.h.
1129 if test "$llvm_cv_enable_libffi" = "yes" ; then
1130   AC_CHECK_HEADERS([ffi.h ffi/ffi.h])
1131 fi
1132
1133 dnl Try to find Darwin specific crash reporting libraries.
1134 AC_CHECK_HEADERS([CrashReporterClient.h])
1135
1136 dnl Try to find Darwin specific crash reporting global.
1137 AC_MSG_CHECKING([__crashreporter_info__])
1138 AC_LINK_IFELSE(
1139   AC_LANG_SOURCE(
1140     [[extern const char *__crashreporter_info__;
1141       int main() {
1142         __crashreporter_info__ = "test";
1143         return 0;
1144       }
1145     ]]),
1146   AC_MSG_RESULT(yes)
1147   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 1, Can use __crashreporter_info__),
1148   AC_MSG_RESULT(no)
1149   AC_DEFINE(HAVE_CRASHREPORTER_INFO, 0,
1150             Define if __crashreporter_info__ exists.))
1151
1152 dnl===-----------------------------------------------------------------------===
1153 dnl===
1154 dnl=== SECTION 7: Check for types and structures
1155 dnl===
1156 dnl===-----------------------------------------------------------------------===
1157
1158 AC_HUGE_VAL_CHECK
1159 AC_TYPE_PID_T
1160 AC_TYPE_SIZE_T
1161 AC_DEFINE_UNQUOTED([RETSIGTYPE],[void],[Define as the return type of signal handlers (`int' or `void').])
1162 AC_STRUCT_TM
1163 AC_CHECK_TYPES([int64_t],,AC_MSG_ERROR([Type int64_t required but not found]))
1164 AC_CHECK_TYPES([uint64_t],,
1165          AC_CHECK_TYPES([u_int64_t],,
1166          AC_MSG_ERROR([Type uint64_t or u_int64_t required but not found])))
1167
1168 dnl===-----------------------------------------------------------------------===
1169 dnl===
1170 dnl=== SECTION 8: Check for specific functions needed
1171 dnl===
1172 dnl===-----------------------------------------------------------------------===
1173
1174 AC_CHECK_FUNCS([backtrace ceilf floorf roundf rintf nearbyintf getcwd ])
1175 AC_CHECK_FUNCS([powf fmodf strtof round ])
1176 AC_CHECK_FUNCS([getpagesize getrusage getrlimit setrlimit gettimeofday ])
1177 AC_CHECK_FUNCS([isatty mkdtemp mkstemp ])
1178 AC_CHECK_FUNCS([mktemp posix_spawn realpath sbrk setrlimit strdup ])
1179 AC_CHECK_FUNCS([strerror strerror_r setenv ])
1180 AC_CHECK_FUNCS([strtoll strtoq sysconf malloc_zone_statistics ])
1181 AC_CHECK_FUNCS([setjmp longjmp sigsetjmp siglongjmp writev])
1182 AC_C_PRINTF_A
1183 AC_FUNC_RAND48
1184
1185 dnl Check the declaration "Secure API" on Windows environments.
1186 AC_CHECK_DECLS([strerror_s])
1187
1188 dnl Check symbols in libgcc.a for JIT on Mingw.
1189 if test "$llvm_cv_os_type" = "MingW" ; then
1190   AC_CHECK_LIB(gcc,_alloca,AC_DEFINE([HAVE__ALLOCA],[1],[Have host's _alloca]))
1191   AC_CHECK_LIB(gcc,__alloca,AC_DEFINE([HAVE___ALLOCA],[1],[Have host's __alloca]))
1192   AC_CHECK_LIB(gcc,__chkstk,AC_DEFINE([HAVE___CHKSTK],[1],[Have host's __chkstk]))
1193   AC_CHECK_LIB(gcc,___chkstk,AC_DEFINE([HAVE____CHKSTK],[1],[Have host's ___chkstk]))
1194
1195   AC_CHECK_LIB(gcc,__ashldi3,AC_DEFINE([HAVE___ASHLDI3],[1],[Have host's __ashldi3]))
1196   AC_CHECK_LIB(gcc,__ashrdi3,AC_DEFINE([HAVE___ASHRDI3],[1],[Have host's __ashrdi3]))
1197   AC_CHECK_LIB(gcc,__divdi3,AC_DEFINE([HAVE___DIVDI3],[1],[Have host's __divdi3]))
1198   AC_CHECK_LIB(gcc,__fixdfdi,AC_DEFINE([HAVE___FIXDFDI],[1],[Have host's __fixdfdi]))
1199   AC_CHECK_LIB(gcc,__fixsfdi,AC_DEFINE([HAVE___FIXSFDI],[1],[Have host's __fixsfdi]))
1200   AC_CHECK_LIB(gcc,__floatdidf,AC_DEFINE([HAVE___FLOATDIDF],[1],[Have host's __floatdidf]))
1201   AC_CHECK_LIB(gcc,__lshrdi3,AC_DEFINE([HAVE___LSHRDI3],[1],[Have host's __lshrdi3]))
1202   AC_CHECK_LIB(gcc,__moddi3,AC_DEFINE([HAVE___MODDI3],[1],[Have host's __moddi3]))
1203   AC_CHECK_LIB(gcc,__udivdi3,AC_DEFINE([HAVE___UDIVDI3],[1],[Have host's __udivdi3]))
1204   AC_CHECK_LIB(gcc,__umoddi3,AC_DEFINE([HAVE___UMODDI3],[1],[Have host's __umoddi3]))
1205
1206   AC_CHECK_LIB(gcc,__main,AC_DEFINE([HAVE___MAIN],[1],[Have host's __main]))
1207   AC_CHECK_LIB(gcc,__cmpdi2,AC_DEFINE([HAVE___CMPDI2],[1],[Have host's __cmpdi2]))
1208 fi
1209
1210 dnl Check Win32 API EnumerateLoadedModules.
1211 if test "$llvm_cv_os_type" = "MingW" ; then
1212   AC_MSG_CHECKING([whether EnumerateLoadedModules() accepts new decl])
1213   AC_COMPILE_IFELSE([[#include <windows.h>
1214 #include <imagehlp.h>
1215 extern void foo(PENUMLOADED_MODULES_CALLBACK);
1216 extern void foo(BOOL(CALLBACK*)(PCSTR,ULONG_PTR,ULONG,PVOID));]],
1217 [
1218   AC_MSG_RESULT([yes])
1219   llvm_cv_win32_elmcb_pcstr="PCSTR"
1220 ],
1221 [
1222   AC_MSG_RESULT([no])
1223   llvm_cv_win32_elmcb_pcstr="PSTR"
1224 ])
1225   AC_DEFINE_UNQUOTED([WIN32_ELMCB_PCSTR],$llvm_cv_win32_elmcb_pcstr,[Type of 1st arg on ELM Callback])
1226 fi
1227
1228 dnl Check for variations in the Standard C++ library and STL. These macros are
1229 dnl provided by LLVM in the autoconf/m4 directory.
1230 AC_FUNC_ISNAN
1231 AC_FUNC_ISINF
1232
1233 dnl Check for mmap support.We also need to know if /dev/zero is required to
1234 dnl be opened for allocating RWX memory.
1235 dnl Make sure we aren't attempting to configure for an unknown system
1236 if test "$llvm_cv_platform_type" = "Unix" ; then
1237   AC_FUNC_MMAP
1238   AC_FUNC_MMAP_FILE
1239   AC_NEED_DEV_ZERO_FOR_MMAP
1240
1241   if test "$ac_cv_func_mmap_fixed_mapped" = "no"
1242   then
1243     AC_MSG_WARN([mmap() of a fixed address required but not supported])
1244   fi
1245   if test "$ac_cv_func_mmap_file" = "no"
1246   then
1247     AC_MSG_WARN([mmap() of files required but not found])
1248   fi
1249 fi
1250
1251 dnl atomic builtins are required for threading support.
1252 AC_MSG_CHECKING(for GCC atomic builtins)
1253 dnl Since we'll be using these atomic builtins in C++ files we should test
1254 dnl the C++ compiler.
1255 AC_LANG_PUSH([C++])
1256 AC_LINK_IFELSE(
1257   AC_LANG_SOURCE(
1258     [[int main() {
1259         volatile unsigned long val = 1;
1260         __sync_synchronize();
1261         __sync_val_compare_and_swap(&val, 1, 0);
1262         __sync_add_and_fetch(&val, 1);
1263         __sync_sub_and_fetch(&val, 1);
1264         return 0;
1265       }
1266     ]]),
1267   AC_LANG_POP([C++])
1268   AC_MSG_RESULT(yes)
1269   AC_DEFINE(LLVM_HAS_ATOMICS, 1, Has gcc/MSVC atomic intrinsics),
1270   AC_MSG_RESULT(no)
1271   AC_DEFINE(LLVM_HAS_ATOMICS, 0, Has gcc/MSVC atomic intrinsics)
1272   AC_MSG_WARN([LLVM will be built thread-unsafe because atomic builtins are missing]))
1273
1274 dnl===-----------------------------------------------------------------------===
1275 dnl===
1276 dnl=== SECTION 9: Additional checks, variables, etc.
1277 dnl===
1278 dnl===-----------------------------------------------------------------------===
1279
1280 dnl Handle 32-bit linux systems running a 64-bit kernel.
1281 dnl This has to come after section 4 because it invokes the compiler.
1282 if test "$llvm_cv_os_type" = "Linux" -a "$llvm_cv_target_arch" = "x86_64" ; then
1283   AC_IS_LINUX_MIXED
1284   if test "$llvm_cv_linux_mixed" = "yes"; then
1285     llvm_cv_target_arch="x86"
1286     ARCH="x86"
1287   fi
1288 fi
1289
1290 dnl Check whether __dso_handle is present
1291 AC_CHECK_FUNCS([__dso_handle])
1292
1293 dnl Propagate the shared library extension that the libltdl checks did to
1294 dnl the Makefiles so we can use it there too
1295 AC_SUBST(SHLIBEXT,$libltdl_cv_shlibext)
1296
1297 dnl Propagate the run-time library path variable that the libltdl
1298 dnl checks found to the Makefiles so we can use it there too
1299 AC_SUBST(SHLIBPATH_VAR,$libltdl_cv_shlibpath_var)
1300
1301 # Translate the various configuration directories and other basic
1302 # information into substitutions that will end up in Makefile.config.in
1303 # that these configured values can be used by the makefiles
1304 if test "${prefix}" = "NONE" ; then
1305   prefix="/usr/local"
1306 fi
1307 eval LLVM_PREFIX="${prefix}";
1308 eval LLVM_BINDIR="${prefix}/bin";
1309 eval LLVM_LIBDIR="${prefix}/lib";
1310 eval LLVM_DATADIR="${prefix}/share/llvm";
1311 eval LLVM_DOCSDIR="${prefix}/share/doc/llvm";
1312 eval LLVM_ETCDIR="${prefix}/etc/llvm";
1313 eval LLVM_INCLUDEDIR="${prefix}/include";
1314 eval LLVM_INFODIR="${prefix}/info";
1315 eval LLVM_MANDIR="${prefix}/man";
1316 LLVM_CONFIGTIME=`date`
1317 AC_SUBST(LLVM_PREFIX)
1318 AC_SUBST(LLVM_BINDIR)
1319 AC_SUBST(LLVM_LIBDIR)
1320 AC_SUBST(LLVM_DATADIR)
1321 AC_SUBST(LLVM_DOCSDIR)
1322 AC_SUBST(LLVM_ETCDIR)
1323 AC_SUBST(LLVM_INCLUDEDIR)
1324 AC_SUBST(LLVM_INFODIR)
1325 AC_SUBST(LLVM_MANDIR)
1326 AC_SUBST(LLVM_CONFIGTIME)
1327
1328 # Place the various directores into the config.h file as #defines so that we
1329 # can know about the installation paths within LLVM.
1330 AC_DEFINE_UNQUOTED(LLVM_PREFIX,"$LLVM_PREFIX",
1331                    [Installation prefix directory])
1332 AC_DEFINE_UNQUOTED(LLVM_BINDIR, "$LLVM_BINDIR",
1333                    [Installation directory for binary executables])
1334 AC_DEFINE_UNQUOTED(LLVM_LIBDIR, "$LLVM_LIBDIR",
1335                    [Installation directory for libraries])
1336 AC_DEFINE_UNQUOTED(LLVM_DATADIR, "$LLVM_DATADIR",
1337                    [Installation directory for data files])
1338 AC_DEFINE_UNQUOTED(LLVM_DOCSDIR, "$LLVM_DOCSDIR",
1339                    [Installation directory for documentation])
1340 AC_DEFINE_UNQUOTED(LLVM_ETCDIR, "$LLVM_ETCDIR",
1341                    [Installation directory for config files])
1342 AC_DEFINE_UNQUOTED(LLVM_INCLUDEDIR, "$LLVM_INCLUDEDIR",
1343                    [Installation directory for include files])
1344 AC_DEFINE_UNQUOTED(LLVM_INFODIR, "$LLVM_INFODIR",
1345                    [Installation directory for .info files])
1346 AC_DEFINE_UNQUOTED(LLVM_MANDIR, "$LLVM_MANDIR",
1347                    [Installation directory for man pages])
1348 AC_DEFINE_UNQUOTED(LLVM_CONFIGTIME, "$LLVM_CONFIGTIME",
1349                    [Time at which LLVM was configured])
1350 AC_DEFINE_UNQUOTED(LLVM_DEFAULT_TARGET_TRIPLE, "$target",
1351                    [Target triple LLVM will generate code for by default])
1352
1353 # Determine which bindings to build.
1354 if test "$BINDINGS_TO_BUILD" = auto ; then
1355   BINDINGS_TO_BUILD=""
1356   if test "x$OCAMLC" != x -a "x$OCAMLDEP" != x ; then
1357     BINDINGS_TO_BUILD="ocaml $BINDINGS_TO_BUILD"
1358   fi
1359 fi
1360 AC_SUBST(BINDINGS_TO_BUILD,$BINDINGS_TO_BUILD)
1361
1362 # This isn't really configurey, but it avoids having to repeat the list in
1363 # other files.
1364 AC_SUBST(ALL_BINDINGS,ocaml)
1365
1366 # Do any work necessary to ensure that bindings have what they need.
1367 binding_prereqs_failed=0
1368 for a_binding in $BINDINGS_TO_BUILD ; do
1369   case "$a_binding" in
1370   ocaml)
1371     if test "x$OCAMLC" = x ; then
1372       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlc not found. Try configure OCAMLC=/path/to/ocamlc])
1373       binding_prereqs_failed=1
1374     fi
1375     if test "x$OCAMLDEP" = x ; then
1376       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamldep not found. Try configure OCAMLDEP=/path/to/ocamldep])
1377       binding_prereqs_failed=1
1378     fi
1379     if test "x$OCAMLOPT" = x ; then
1380       AC_MSG_WARN([--enable-bindings=ocaml specified, but ocamlopt not found. Try configure OCAMLOPT=/path/to/ocamlopt])
1381       dnl ocamlopt is optional!
1382     fi
1383     if test "x$with_ocaml_libdir" != xauto ; then
1384       AC_SUBST(OCAML_LIBDIR,$with_ocaml_libdir)
1385     else
1386       ocaml_stdlib="`"$OCAMLC" -where`"
1387       if test "$LLVM_PREFIX" '<' "$ocaml_stdlib" -a "$ocaml_stdlib" '<' "$LLVM_PREFIX~"
1388       then
1389         # ocaml stdlib is beneath our prefix; use stdlib
1390         AC_SUBST(OCAML_LIBDIR,$ocaml_stdlib)
1391       else
1392         # ocaml stdlib is outside our prefix; use libdir/ocaml
1393         AC_SUBST(OCAML_LIBDIR,$LLVM_LIBDIR/ocaml)
1394       fi
1395     fi
1396     ;;
1397   esac
1398 done
1399 if test "$binding_prereqs_failed" = 1 ; then
1400   AC_MSG_ERROR([Prequisites for bindings not satisfied. Fix them or use configure --disable-bindings.])
1401 fi
1402
1403 dnl Determine whether the compiler supports -fvisibility-inlines-hidden.
1404 AC_CXX_USE_VISIBILITY_INLINES_HIDDEN
1405
1406 dnl Determine linker rpath flag
1407 if test "$llvm_cv_link_use_r" = "yes" ; then
1408   RPATH="-Wl,-R"
1409 else
1410   RPATH="-Wl,-rpath"
1411 fi
1412 AC_SUBST(RPATH)
1413
1414 dnl Determine linker rdynamic flag
1415 if test "$llvm_cv_link_use_export_dynamic" = "yes" ; then
1416   RDYNAMIC="-Wl,-export-dynamic"
1417 else
1418   RDYNAMIC=""
1419 fi
1420 AC_SUBST(RDYNAMIC)
1421
1422 dnl===-----------------------------------------------------------------------===
1423 dnl===
1424 dnl=== SECTION 10: Specify the output files and generate it
1425 dnl===
1426 dnl===-----------------------------------------------------------------------===
1427
1428 dnl **************************************************************************
1429 dnl End LLVM configure.ac Import
1430 dnl **************************************************************************
1431
1432 dnl Configure a common Makefile
1433 AC_CONFIG_FILES(Makefile.common)
1434 AC_CONFIG_FILES(Makefile.llvm.config)
1435
1436 dnl Configure project makefiles
1437 dnl List every Makefile that exists within your source tree
1438 AC_CONFIG_MAKEFILE(Makefile)
1439 AC_CONFIG_MAKEFILE(lib/Makefile)
1440 AC_CONFIG_MAKEFILE(lib/sample/Makefile)
1441 AC_CONFIG_MAKEFILE(tools/Makefile)
1442 AC_CONFIG_MAKEFILE(tools/sample/Makefile)
1443
1444 dnl This must be last
1445 AC_OUTPUT