test/Analysis/Delinearization/multidim_ivs_and_parameteric_offsets_3d.ll

   1 ; RUN: opt < %s -analyze -delinearize | FileCheck %s
   2
   3 ; void foo(long n, long m, long o, double A[n][m][o], long p, long q, long r) {
   4 ;
   5 ;   for (long i = 0; i < n; i++)
   6 ;     for (long j = 0; j < m; j++)
   7 ;       for (long k = 0; k < o; k++)
   8 ;         A[i+p][j+q][k+r] = 1.0;
   9 ; }
  10
  11 ; AddRec: {{{((8 * ((((%m * %p) + %q) * %o) + %r)) + %A),+,(8 * %m * %o)}<%for.i>,+,(8 * %o)}<%for.j>,+,8}<%for.k>
  12 ; CHECK: Base offset: %A
  13 ; CHECK: ArrayDecl[UnknownSize][%m][%o] with elements of sizeof(double) bytes.
  14 ; CHECK: ArrayRef[{%p,+,1}<nw><%for.i>][{%q,+,1}<nw><%for.j>][{%r,+,1}<nw><%for.k>]
  15
  16 ; AddRec: {{(-8 + (8 * ((((%m * %p) + %q) * %o) + %r)) + (8 * %o) + %A),+,(8 * %m * %o)}<%for.i>,+,(8 * %o)}<%for.j>
  17 ; CHECK: Base offset: %A
  18 ; CHECK: ArrayDecl[UnknownSize][%o] with elements of sizeof(double) bytes.
  19 ; CHECK: ArrayRef[{(1 + (%m * %p) + %q),+,%m}<%for.i>][{(-1 + %r),+,%o}<%for.j>]
  20
  21 ; AddRec: {(-8 + (8 * ((((%m * %p) + %q) * %o) + %r)) + (8 * %m * %o) + %A),+,(8 * %m * %o)}<%for.i>
  22 ; CHECK: Base offset: %A
  23 ; CHECK: ArrayDecl[UnknownSize] with elements of sizeof(double) bytes.
  24 ; CHECK: ArrayRef[{(-1 + ((((1 + %p) * %m) + %q) * %o) + %r),+,(%m * %o)}<%for.i>]
  25
  26 define void @foo(i64 %n, i64 %m, i64 %o, double* %A, i64 %p, i64 %q, i64 %r) {
  27 entry:
  28   br label %for.i
  29
  30 for.i:
  31   %i = phi i64 [ 0, %entry ], [ %i.inc, %for.i.inc ]
  32   br label %for.j
  33
  34 for.j:
  35   %j = phi i64 [ 0, %for.i ], [ %j.inc, %for.j.inc ]
  36   br label %for.k
  37
  38 for.k:
  39   %k = phi i64 [ 0, %for.j ], [ %k.inc, %for.k.inc ]
  40   %offset0 = add nsw i64 %i, %p
  41   %subscript0 = mul i64 %offset0, %m
  42   %offset1 = add nsw i64 %j, %q
  43   %subscript1 = add i64 %offset1, %subscript0
  44   %subscript2 = mul i64 %subscript1, %o
  45   %offset2 = add nsw i64 %k, %r
  46   %subscript = add i64 %subscript2, %offset2
  47   %idx = getelementptr inbounds double* %A, i64 %subscript
  48   store double 1.0, double* %idx
  49   br label %for.k.inc
  50
  51 for.k.inc:
  52   %k.inc = add nsw i64 %k, 1
  53   %k.exitcond = icmp eq i64 %k.inc, %o
  54   br i1 %k.exitcond, label %for.j.inc, label %for.k
  55
  56 for.j.inc:
  57   %j.inc = add nsw i64 %j, 1
  58   %j.exitcond = icmp eq i64 %j.inc, %m
  59   br i1 %j.exitcond, label %for.i.inc, label %for.j
  60
  61 for.i.inc:
  62   %i.inc = add nsw i64 %i, 1
  63   %i.exitcond = icmp eq i64 %i.inc, %n
  64   br i1 %i.exitcond, label %end, label %for.i
  65
  66 end:
  67   ret void
  68 }