test/CodeGen/AArch64/func-argpassing.ll

   1 ; RUN: llc -verify-machineinstrs < %s -mtriple=aarch64-none-linux-gnu | FileCheck --check-prefix=CHECK --check-prefix=CHECK-AARCH64 --check-prefix=CHECK-LE %s
   2 ; RUN: llc -verify-machineinstrs < %s -mtriple=aarch64-none-linux-gnu -mattr=-fp-armv8 | FileCheck --check-prefix=CHECK-NOFP %s
   3 ; RUN: llc -verify-machineinstrs < %s -mtriple=aarch64_be-none-linux-gnu | FileCheck --check-prefix=CHECK --check-prefix=CHECK-BE %s
   4 ; RUN: llc -verify-machineinstrs < %s -mtriple=aarch64_be-none-linux-gnu -mattr=-fp-armv8 | FileCheck --check-prefix=CHECK-NOFP %s
   5 ; RUN: llc -verify-machineinstrs < %s -mtriple=arm64-none-linux-gnu | FileCheck --check-prefix=CHECK --check-prefix=CHECK-ARM64 %s
   6
   7 %myStruct = type { i64 , i8, i32 }
   8
   9 @var8 = global i8 0
  10 @var32 = global i32 0
  11 @var64 = global i64 0
  12 @var128 = global i128 0
  13 @varfloat = global float 0.0
  14 @vardouble = global double 0.0
  15 @varstruct = global %myStruct zeroinitializer
  16
  17 define void @take_i8s(i8 %val1, i8 %val2) {
  18 ; CHECK-LABEL: take_i8s:
  19     store i8 %val2, i8* @var8
  20     ; Not using w1 may be technically allowed, but it would indicate a
  21     ; problem in itself.
  22 ;  CHECK: strb w1, [{{x[0-9]+}}, {{#?}}:lo12:var8]
  23     ret void
  24 }
  25
  26 define void @add_floats(float %val1, float %val2) {
  27 ; CHECK-LABEL: add_floats:
  28     %newval = fadd float %val1, %val2
  29 ; CHECK: fadd [[ADDRES:s[0-9]+]], s0, s1
  30 ; CHECK-NOFP-NOT: fadd
  31     store float %newval, float* @varfloat
  32 ; CHECK: str [[ADDRES]], [{{x[0-9]+}}, {{#?}}:lo12:varfloat]
  33     ret void
  34 }
  35
  36 ; byval pointers should be allocated to the stack and copied as if
  37 ; with memcpy.
  38 define void @take_struct(%myStruct* byval %structval) {
  39 ; CHECK-LABEL: take_struct:
  40     %addr0 = getelementptr %myStruct* %structval, i64 0, i32 2
  41     %addr1 = getelementptr %myStruct* %structval, i64 0, i32 0
  42
  43     %val0 = load volatile i32* %addr0
  44     ; Some weird move means x0 is used for one access
  45 ; CHECK: ldr [[REG32:w[0-9]+]], [{{x[0-9]+|sp}}, #12]
  46     store volatile i32 %val0, i32* @var32
  47 ; CHECK: str [[REG32]], [{{x[0-9]+}}, {{#?}}:lo12:var32]
  48
  49     %val1 = load volatile i64* %addr1
  50 ; CHECK: ldr [[REG64:x[0-9]+]], [{{x[0-9]+|sp}}]
  51     store volatile i64 %val1, i64* @var64
  52 ; CHECK: str [[REG64]], [{{x[0-9]+}}, {{#?}}:lo12:var64]
  53
  54     ret void
  55 }
  56
  57 ; %structval should be at sp + 16
  58 define void @check_byval_align(i32* byval %ignore, %myStruct* byval align 16 %structval) {
  59 ; CHECK-LABEL: check_byval_align:
  60
  61     %addr0 = getelementptr %myStruct* %structval, i64 0, i32 2
  62     %addr1 = getelementptr %myStruct* %structval, i64 0, i32 0
  63
  64     %val0 = load volatile i32* %addr0
  65     ; Some weird move means x0 is used for one access
  66 ; CHECK-AARCH64: add x[[STRUCTVAL_ADDR:[0-9]+]], sp, #16
  67 ; CHECK-AARCH64: ldr [[REG32:w[0-9]+]], [x[[STRUCTVAL_ADDR]], #12]
  68 ; CHECK-ARM64: ldr [[REG32:w[0-9]+]], [sp, #28]
  69     store i32 %val0, i32* @var32
  70 ; CHECK: str [[REG32]], [{{x[0-9]+}}, {{#?}}:lo12:var32]
  71
  72     %val1 = load volatile i64* %addr1
  73 ; CHECK: ldr [[REG64:x[0-9]+]], [sp, #16]
  74     store i64 %val1, i64* @var64
  75 ; CHECK: str [[REG64]], [{{x[0-9]+}}, {{#?}}:lo12:var64]
  76
  77     ret void
  78 }
  79
  80 define i32 @return_int() {
  81 ; CHECK-LABEL: return_int:
  82     %val = load i32* @var32
  83     ret i32 %val
  84 ; CHECK: ldr w0, [{{x[0-9]+}}, {{#?}}:lo12:var32]
  85     ; Make sure epilogue follows
  86 ; CHECK-NEXT: ret
  87 }
  88
  89 define double @return_double() {
  90 ; CHECK-LABEL: return_double:
  91     ret double 3.14
  92 ; CHECK: ldr d0, [{{x[0-9]+}}, {{#?}}:lo12:.LCPI
  93 ; CHECK-NOFP-NOT: ldr d0,
  94 }
  95
  96 ; This is the kind of IR clang will produce for returning a struct
  97 ; small enough to go into registers. Not all that pretty, but it
  98 ; works.
  99 define [2 x i64] @return_struct() {
 100 ; CHECK-LABEL: return_struct:
 101     %addr = bitcast %myStruct* @varstruct to [2 x i64]*
 102     %val = load [2 x i64]* %addr
 103     ret [2 x i64] %val
 104 ; CHECK-DAG: ldr x0, [{{x[0-9]+}}, {{#?}}:lo12:varstruct]
 105     ; Odd register regex below disallows x0 which we want to be live now.
 106 ; CHECK-DAG: add {{x[1-9][0-9]*}}, {{x[1-9][0-9]*}}, {{#?}}:lo12:varstruct
 107 ; CHECK: ldr x1, [{{x[1-9][0-9]*}}, #8]
 108     ; Make sure epilogue immediately follows
 109 ; CHECK-NEXT: ret
 110 }
 111
 112 ; Large structs are passed by reference (storage allocated by caller
 113 ; to preserve value semantics) in x8. Strictly this only applies to
 114 ; structs larger than 16 bytes, but C semantics can still be provided
 115 ; if LLVM does it to %myStruct too. So this is the simplest check
 116 define void @return_large_struct(%myStruct* sret %retval) {
 117 ; CHECK-LABEL: return_large_struct:
 118     %addr0 = getelementptr %myStruct* %retval, i64 0, i32 0
 119     %addr1 = getelementptr %myStruct* %retval, i64 0, i32 1
 120     %addr2 = getelementptr %myStruct* %retval, i64 0, i32 2
 121
 122     store i64 42, i64* %addr0
 123     store i8 2, i8* %addr1
 124     store i32 9, i32* %addr2
 125 ; CHECK: str {{x[0-9]+}}, [x8]
 126 ; CHECK: strb {{w[0-9]+}}, [x8, #8]
 127 ; CHECK: str {{w[0-9]+}}, [x8, #12]
 128
 129     ret void
 130 }
 131
 132 ; This struct is just too far along to go into registers: (only x7 is
 133 ; available, but it needs two). Also make sure that %stacked doesn't
 134 ; sneak into x7 behind.
 135 define i32 @struct_on_stack(i8 %var0, i16 %var1, i32 %var2, i64 %var3, i128 %var45,
 136                           i32* %var6, %myStruct* byval %struct, i32* byval %stacked,
 137                           double %notstacked) {
 138 ; CHECK-LABEL: struct_on_stack:
 139     %addr = getelementptr %myStruct* %struct, i64 0, i32 0
 140     %val64 = load volatile i64* %addr
 141     store volatile i64 %val64, i64* @var64
 142     ; Currently nothing on local stack, so struct should be at sp
 143 ; CHECK: ldr [[VAL64:x[0-9]+]], [sp]
 144 ; CHECK: str [[VAL64]], [{{x[0-9]+}}, {{#?}}:lo12:var64]
 145
 146     store volatile double %notstacked, double* @vardouble
 147 ; CHECK-NOT: ldr d0
 148 ; CHECK: str d0, [{{x[0-9]+}}, {{#?}}:lo12:vardouble
 149 ; CHECK-NOFP-NOT: str d0,
 150
 151     %retval = load volatile i32* %stacked
 152     ret i32 %retval
 153 ; CHECK-LE: ldr w0, [sp, #16]
 154 ; CHECK-BE: ldr w0, [sp, #20]
 155 }
 156
 157 define void @stacked_fpu(float %var0, double %var1, float %var2, float %var3,
 158                          float %var4, float %var5, float %var6, float %var7,
 159                          float %var8) {
 160 ; CHECK-LABEL: stacked_fpu:
 161     store float %var8, float* @varfloat
 162     ; Beware as above: the offset would be different on big-endian
 163     ; machines if the first ldr were changed to use s-registers.
 164 ; CHECK: ldr {{[ds]}}[[VALFLOAT:[0-9]+]], [sp]
 165 ; CHECK: str s[[VALFLOAT]], [{{x[0-9]+}}, {{#?}}:lo12:varfloat]
 166
 167     ret void
 168 }
 169
 170 ; 128-bit integer types should be passed in xEVEN, xODD rather than
 171 ; the reverse. In this case x2 and x3. Nothing should use x1.
 172 define i64 @check_i128_regalign(i32 %val0, i128 %val1, i64 %val2) {
 173 ; CHECK-LABEL: check_i128_regalign
 174     store i128 %val1, i128* @var128
 175 ; CHECK-DAG: str x2, [{{x[0-9]+}}, {{#?}}:lo12:var128]
 176 ; CHECK-DAG: str x3, [{{x[0-9]+}}, #8]
 177
 178     ret i64 %val2
 179 ; CHECK: mov x0, x4
 180 }
 181
 182 define void @check_i128_stackalign(i32 %val0, i32 %val1, i32 %val2, i32 %val3,
 183                                    i32 %val4, i32 %val5, i32 %val6, i32 %val7,
 184                                    i32 %stack1, i128 %stack2) {
 185 ; CHECK-LABEL: check_i128_stackalign
 186     store i128 %stack2, i128* @var128
 187     ; Nothing local on stack in current codegen, so first stack is 16 away
 188 ; CHECK-LE: add     x[[REG:[0-9]+]], sp, #16
 189 ; CHECK-LE: ldr {{x[0-9]+}}, [x[[REG]], #8]
 190 ; CHECK-BE: ldr {{x[0-9]+}}, [sp, #24]
 191
 192     ; Important point is that we address sp+24 for second dword
 193 ; CHECK-AARCH64: ldr     {{x[0-9]+}}, [sp, #16]
 194
 195 ; CHECK-ARM64: ldp {{x[0-9]+}}, {{x[0-9]+}}, [sp, #16]
 196     ret void
 197 }
 198
 199 declare void @llvm.memcpy.p0i8.p0i8.i32(i8*, i8*, i32, i32, i1)
 200
 201 define i32 @test_extern() {
 202 ; CHECK-LABEL: test_extern:
 203   call void @llvm.memcpy.p0i8.p0i8.i32(i8* undef, i8* undef, i32 undef, i32 4, i1 0)
 204 ; CHECK: bl memcpy
 205   ret i32 0
 206 }