test/CodeGen/AArch64/func-calls.ll

   1
   2 ; RUN: llc -verify-machineinstrs < %s -mtriple=arm64-none-linux-gnu | FileCheck %s --check-prefix=CHECK --check-prefix=CHECK-ARM64
   3 ; RUN: llc -verify-machineinstrs < %s -mtriple=arm64-none-linux-gnu -mattr=-neon | FileCheck --check-prefix=CHECK --check-prefix=CHECK-ARM64-NONEON %s
   4 ; RUN: llc -verify-machineinstrs < %s -mtriple=arm64-none-linux-gnu -mattr=-fp-armv8 | FileCheck --check-prefix=CHECK-NOFP %s
   5 ; RUN: llc -verify-machineinstrs < %s -mtriple=arm64_be-none-linux-gnu | FileCheck --check-prefix=CHECK --check-prefix=CHECK-BE %s
   6
   7 %myStruct = type { i64 , i8, i32 }
   8
   9 @var8 = global i8 0
  10 @var8_2 = global i8 0
  11 @var32 = global i32 0
  12 @var64 = global i64 0
  13 @var128 = global i128 0
  14 @varfloat = global float 0.0
  15 @varfloat_2 = global float 0.0
  16 @vardouble = global double 0.0
  17 @varstruct = global %myStruct zeroinitializer
  18 @varsmallstruct = global [2 x i64] zeroinitializer
  19
  20 declare void @take_i8s(i8 %val1, i8 %val2)
  21 declare void @take_floats(float %val1, float %val2)
  22
  23 define void @simple_args() {
  24 ; CHECK-LABEL: simple_args:
  25   %char1 = load i8* @var8
  26   %char2 = load i8* @var8_2
  27   call void @take_i8s(i8 %char1, i8 %char2)
  28 ; CHECK-DAG: ldrb w0, [{{x[0-9]+}}, {{#?}}:lo12:var8]
  29 ; CHECK-DAG: ldrb w1, [{{x[0-9]+}}, {{#?}}:lo12:var8_2]
  30 ; CHECK: bl take_i8s
  31
  32   %float1 = load float* @varfloat
  33   %float2 = load float* @varfloat_2
  34   call void @take_floats(float %float1, float %float2)
  35 ; CHECK-DAG: ldr s1, [{{x[0-9]+}}, {{#?}}:lo12:varfloat_2]
  36 ; CHECK-DAG: ldr s0, [{{x[0-9]+}}, {{#?}}:lo12:varfloat]
  37 ; CHECK: bl take_floats
  38 ; CHECK-NOFP-NOT: ldr s1,
  39 ; CHECK-NOFP-NOT: ldr s0,
  40
  41   ret void
  42 }
  43
  44 declare i32 @return_int()
  45 declare double @return_double()
  46 declare [2 x i64] @return_smallstruct()
  47 declare void @return_large_struct(%myStruct* sret %retval)
  48
  49 define void @simple_rets() {
  50 ; CHECK-LABEL: simple_rets:
  51
  52   %int = call i32 @return_int()
  53   store i32 %int, i32* @var32
  54 ; CHECK: bl return_int
  55 ; CHECK: str w0, [{{x[0-9]+}}, {{#?}}:lo12:var32]
  56
  57   %dbl = call double @return_double()
  58   store double %dbl, double* @vardouble
  59 ; CHECK: bl return_double
  60 ; CHECK: str d0, [{{x[0-9]+}}, {{#?}}:lo12:vardouble]
  61 ; CHECK-NOFP-NOT: str d0,
  62
  63   %arr = call [2 x i64] @return_smallstruct()
  64   store [2 x i64] %arr, [2 x i64]* @varsmallstruct
  65 ; CHECK: bl return_smallstruct
  66 ; CHECK: str x1, [{{x[0-9]+}}, #8]
  67 ; CHECK: str x0, [{{x[0-9]+}}, {{#?}}:lo12:varsmallstruct]
  68
  69   call void @return_large_struct(%myStruct* sret @varstruct)
  70 ; CHECK: add x8, {{x[0-9]+}}, {{#?}}:lo12:varstruct
  71 ; CHECK: bl return_large_struct
  72
  73   ret void
  74 }
  75
  76
  77 declare i32 @struct_on_stack(i8 %var0, i16 %var1, i32 %var2, i64 %var3, i128 %var45,
  78                              i32* %var6, %myStruct* byval %struct, i32 %stacked,
  79                              double %notstacked)
  80 declare void @stacked_fpu(float %var0, double %var1, float %var2, float %var3,
  81                           float %var4, float %var5, float %var6, float %var7,
  82                           float %var8)
  83
  84 define void @check_stack_args() {
  85 ; CHECK-LABEL: check_stack_args:
  86   call i32 @struct_on_stack(i8 0, i16 12, i32 42, i64 99, i128 1,
  87                             i32* @var32, %myStruct* byval @varstruct,
  88                             i32 999, double 1.0)
  89   ; Want to check that the final double is passed in registers and
  90   ; that varstruct is passed on the stack. Rather dependent on how a
  91   ; memcpy gets created, but the following works for now.
  92
  93 ; CHECK-ARM64-DAG: str {{q[0-9]+}}, [sp]
  94 ; CHECK-ARM64-DAG: fmov d[[FINAL_DOUBLE:[0-9]+]], #1.0
  95 ; CHECK-ARM64: mov v0.16b, v[[FINAL_DOUBLE]].16b
  96
  97 ; CHECK-ARM64-NONEON-DAG: str {{q[0-9]+}}, [sp]
  98 ; CHECK-ARM64-NONEON-DAG: fmov d[[FINAL_DOUBLE:[0-9]+]], #1.0
  99 ; CHECK-ARM64-NONEON: fmov d0, d[[FINAL_DOUBLE]]
 100
 101 ; CHECK: bl struct_on_stack
 102 ; CHECK-NOFP-NOT: fmov
 103
 104   call void @stacked_fpu(float -1.0, double 1.0, float 4.0, float 2.0,
 105                          float -2.0, float -8.0, float 16.0, float 1.0,
 106                          float 64.0)
 107
 108 ; CHECK-ARM64:  movz [[SIXTY_FOUR:w[0-9]+]], #0x4280, lsl #16
 109 ; CHECK-ARM64: str [[SIXTY_FOUR]], [sp]
 110
 111 ; CHECK-ARM64-NONEON:  movz [[SIXTY_FOUR:w[0-9]+]], #0x4280, lsl #16
 112 ; CHECK-ARM64-NONEON: str [[SIXTY_FOUR]], [sp]
 113
 114 ; CHECK: bl stacked_fpu
 115   ret void
 116 }
 117
 118
 119 declare void @check_i128_stackalign(i32 %val0, i32 %val1, i32 %val2, i32 %val3,
 120                                     i32 %val4, i32 %val5, i32 %val6, i32 %val7,
 121                                     i32 %stack1, i128 %stack2)
 122
 123 declare void @check_i128_regalign(i32 %val0, i128 %val1)
 124
 125
 126 define void @check_i128_align() {
 127 ; CHECK-LABEL: check_i128_align:
 128   %val = load i128* @var128
 129   call void @check_i128_stackalign(i32 0, i32 1, i32 2, i32 3,
 130                                    i32 4, i32 5, i32 6, i32 7,
 131                                    i32 42, i128 %val)
 132 ; CHECK: ldr [[I128LO:x[0-9]+]], [{{x[0-9]+}}, {{#?}}:lo12:var128]
 133 ; CHECK: ldr [[I128HI:x[0-9]+]], [{{x[0-9]+}}, #8]
 134 ; CHECK-ARM64: stp [[I128LO]], [[I128HI]], [sp, #16]
 135 ; CHECK-ARM64-NONEON: stp [[I128LO]], [[I128HI]], [sp, #16]
 136 ; CHECK: bl check_i128_stackalign
 137
 138   call void @check_i128_regalign(i32 0, i128 42)
 139 ; CHECK-NOT: mov x1
 140 ; CHECK-LE: movz x2, #{{0x2a|42}}
 141 ; CHECK-LE: mov x3, xzr
 142 ; CHECK-BE: movz {{x|w}}3, #{{0x2a|42}}
 143 ; CHECK-BE: mov x2, xzr
 144 ; CHECK: bl check_i128_regalign
 145
 146   ret void
 147 }
 148
 149 @fptr = global void()* null
 150
 151 define void @check_indirect_call() {
 152 ; CHECK-LABEL: check_indirect_call:
 153   %func = load void()** @fptr
 154   call void %func()
 155 ; CHECK: ldr [[FPTR:x[0-9]+]], [{{x[0-9]+}}, {{#?}}:lo12:fptr]
 156 ; CHECK: blr [[FPTR]]
 157
 158   ret void
 159 }