test/Transforms/IndVarSimplify/no-iv-rewrite.ll

   1 ; RUN: opt < %s -indvars -disable-iv-rewrite -S | FileCheck %s
   2 ;
   3 ; Make sure that indvars isn't inserting canonical IVs.
   4 ; This is kinda hard to do until linear function test replacement is removed.
   5
   6 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:64:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-s0:64:64-f80:128:128-n8:16:32:64"
   7
   8 define i32 @sum(i32* %arr, i32 %n) nounwind {
   9 entry:
  10   %precond = icmp slt i32 0, %n
  11   br i1 %precond, label %ph, label %return
  12
  13 ph:
  14   br label %loop
  15
  16 ; CHECK: loop:
  17 ;
  18 ; We should only have 2 IVs.
  19 ; CHECK: phi
  20 ; CHECK: phi
  21 ; CHECK-NOT: phi
  22 ;
  23 ; sext should be eliminated while preserving gep inboundsness.
  24 ; CHECK-NOT: sext
  25 ; CHECK: getelementptr inbounds
  26 ; CHECK: exit
  27 loop:
  28   %i.02 = phi i32 [ 0, %ph ], [ %iinc, %loop ]
  29   %s.01 = phi i32 [ 0, %ph ], [ %sinc, %loop ]
  30   %ofs = sext i32 %i.02 to i64
  31   %adr = getelementptr inbounds i32* %arr, i64 %ofs
  32   %val = load i32* %adr
  33   %sinc = add nsw i32 %s.01, %val
  34   %iinc = add nsw i32 %i.02, 1
  35   %cond = icmp slt i32 %iinc, %n
  36   br i1 %cond, label %loop, label %exit
  37
  38 exit:
  39   %s.lcssa = phi i32 [ %sinc, %loop ]
  40   br label %return
  41
  42 return:
  43   %s.0.lcssa = phi i32 [ %s.lcssa, %exit ], [ 0, %entry ]
  44   ret i32 %s.0.lcssa
  45 }
  46
  47 define i64 @suml(i32* %arr, i32 %n) nounwind {
  48 entry:
  49   %precond = icmp slt i32 0, %n
  50   br i1 %precond, label %ph, label %return
  51
  52 ph:
  53   br label %loop
  54
  55 ; CHECK: loop:
  56 ;
  57 ; We should only have 2 IVs.
  58 ; CHECK: phi
  59 ; CHECK: phi
  60 ; CHECK-NOT: phi
  61 ;
  62 ; %ofs sext should be eliminated while preserving gep inboundsness.
  63 ; CHECK-NOT: sext
  64 ; CHECK: getelementptr inbounds
  65 ; %vall sext should obviously not be eliminated
  66 ; CHECK: sext
  67 ; CHECK: exit
  68 loop:
  69   %i.02 = phi i32 [ 0, %ph ], [ %iinc, %loop ]
  70   %s.01 = phi i64 [ 0, %ph ], [ %sinc, %loop ]
  71   %ofs = sext i32 %i.02 to i64
  72   %adr = getelementptr inbounds i32* %arr, i64 %ofs
  73   %val = load i32* %adr
  74   %vall = sext i32 %val to i64
  75   %sinc = add nsw i64 %s.01, %vall
  76   %iinc = add nsw i32 %i.02, 1
  77   %cond = icmp slt i32 %iinc, %n
  78   br i1 %cond, label %loop, label %exit
  79
  80 exit:
  81   %s.lcssa = phi i64 [ %sinc, %loop ]
  82   br label %return
  83
  84 return:
  85   %s.0.lcssa = phi i64 [ %s.lcssa, %exit ], [ 0, %entry ]
  86   ret i64 %s.0.lcssa
  87 }
  88
  89 define void @outofbounds(i32* %first, i32* %last, i32 %idx) nounwind {
  90   %precond = icmp ne i32* %first, %last
  91   br i1 %precond, label %ph, label %return
  92
  93 ; CHECK: ph:
  94 ; It's not indvars' job to perform LICM on %ofs
  95 ; CHECK-NOT: sext
  96 ph:
  97   br label %loop
  98
  99 ; CHECK: loop:
 100 ;
 101 ; Preserve exactly one pointer type IV.
 102 ; CHECK: phi i32*
 103 ; CHECK-NOT: phi
 104 ;
 105 ; Don't create any extra adds.
 106 ; CHECK-NOT: add
 107 ;
 108 ; Preserve gep inboundsness, and don't factor it.
 109 ; CHECK: getelementptr inbounds i32* %ptriv, i32 1
 110 ; CHECK-NOT: add
 111 ; CHECK: exit
 112 loop:
 113   %ptriv = phi i32* [ %first, %ph ], [ %ptrpost, %loop ]
 114   %ofs = sext i32 %idx to i64
 115   %adr = getelementptr inbounds i32* %ptriv, i64 %ofs
 116   store i32 3, i32* %adr
 117   %ptrpost = getelementptr inbounds i32* %ptriv, i32 1
 118   %cond = icmp ne i32* %ptrpost, %last
 119   br i1 %cond, label %loop, label %exit
 120
 121 exit:
 122   br label %return
 123
 124 return:
 125   ret void
 126 }
 127
 128 %struct = type { i32 }
 129
 130 define void @bitcastiv(i32 %start, i32 %limit, i32 %step, %struct* %base)
 131 nounwind
 132 {
 133 entry:
 134   br label %loop
 135
 136 ; CHECK: loop:
 137 ;
 138 ; Preserve casts
 139 ; CHECK: phi i32
 140 ; CHECK: bitcast
 141 ; CHECK: getelementptr
 142 ; CHECK: exit
 143 loop:
 144   %iv = phi i32 [%start, %entry], [%next, %loop]
 145   %p = phi %struct* [%base, %entry], [%pinc, %loop]
 146   %adr = getelementptr %struct* %p, i32 0, i32 0
 147   store i32 3, i32* %adr
 148   %pp = bitcast %struct* %p to i32*
 149   store i32 4, i32* %pp
 150   %pinc = getelementptr %struct* %p, i32 1
 151   %next = add i32 %iv, 1
 152   %cond = icmp ne i32 %next, %limit
 153   br i1 %cond, label %loop, label %exit
 154
 155 exit:
 156   br label %return
 157
 158 return:
 159   ret void
 160 }