test/Transforms/InstCombine/addrspacecast.ll

   1 ; RUN: opt -instcombine -S < %s | FileCheck %s
   2
   3 target datalayout = "e-p:64:64:64-p1:32:32:32-p2:16:16:16-n8:16:32:64"
   4
   5
   6 declare void @llvm.memcpy.p0i8.p0i8.i32(i8*, i8*, i32, i32, i1) nounwind
   7 declare void @llvm.memcpy.p0i8.p1i8.i32(i8*, i8 addrspace(1)*, i32, i32, i1) nounwind
   8 declare void @llvm.memcpy.p0i8.p2i8.i32(i8*, i8 addrspace(2)*, i32, i32, i1) nounwind
   9
  10
  11 define i32* @combine_redundant_addrspacecast(i32 addrspace(1)* %x) nounwind {
  12 ; CHECK-LABEL: @combine_redundant_addrspacecast(
  13 ; CHECK: addrspacecast i32 addrspace(1)* %x to i32*
  14 ; CHECK-NEXT: ret
  15   %y = addrspacecast i32 addrspace(1)* %x to i32 addrspace(3)*
  16   %z = addrspacecast i32 addrspace(3)* %y to i32*
  17   ret i32* %z
  18 }
  19
  20 define <4 x i32*> @combine_redundant_addrspacecast_vector(<4 x i32 addrspace(1)*> %x) nounwind {
  21 ; CHECK-LABEL: @combine_redundant_addrspacecast_vector(
  22 ; CHECK: addrspacecast <4 x i32 addrspace(1)*> %x to <4 x i32*>
  23 ; CHECK-NEXT: ret
  24   %y = addrspacecast <4 x i32 addrspace(1)*> %x to <4 x i32 addrspace(3)*>
  25   %z = addrspacecast <4 x i32 addrspace(3)*> %y to <4 x i32*>
  26   ret <4 x i32*> %z
  27 }
  28
  29 define float* @combine_redundant_addrspacecast_types(i32 addrspace(1)* %x) nounwind {
  30 ; CHECK-LABEL: @combine_redundant_addrspacecast_types(
  31 ; CHECK: addrspacecast i32 addrspace(1)* %x to float*
  32 ; CHECK-NEXT: ret
  33   %y = addrspacecast i32 addrspace(1)* %x to i32 addrspace(3)*
  34   %z = addrspacecast i32 addrspace(3)* %y to float*
  35   ret float* %z
  36 }
  37
  38 @const_array = addrspace(2) constant [60 x i8] [i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22,
  39                                                 i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22,
  40                                                 i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22,
  41                                                 i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22,
  42                                                 i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22, i8 2, i8 9, i8 4, i8 22 ]
  43
  44 declare void @foo(i8*) nounwind
  45
  46 ; A copy from a constant addrspacecast'ed global
  47 ; CHECK-LABEL: @memcpy_addrspacecast(
  48 ; CHECK-NOT:  call void @llvm.memcpy
  49 define i32 @memcpy_addrspacecast() nounwind {
  50 entry:
  51   %alloca = alloca i8, i32 48
  52   call void @llvm.memcpy.p0i8.p1i8.i32(i8* %alloca, i8 addrspace(1)* addrspacecast (i8 addrspace(2)* getelementptr inbounds ([60 x i8] addrspace(2)* @const_array, i16 0, i16 4) to i8 addrspace(1)*), i32 48, i32 4, i1 false) nounwind
  53   br label %loop.body
  54
  55 loop.body:
  56   %i = phi i32 [ 0, %entry ], [ %i.inc, %loop.body ]
  57   %sum = phi i32 [ 0, %entry ], [ %sum.inc, %loop.body]
  58   %ptr = getelementptr i8* %alloca, i32 %i
  59   %load = load i8* %ptr
  60   %ext = zext i8 %load to i32
  61   %sum.inc = add i32 %sum, %ext
  62   %i.inc = add i32 %i, 1
  63   %cmp = icmp ne i32 %i, 48
  64   br i1 %cmp, label %loop.body, label %end
  65
  66 end:
  67   ret i32 %sum.inc
  68 }
  69