test/Transforms/LoopUnroll/runtime-loop.ll

   1 ; RUN: opt < %s -S -loop-unroll -unroll-runtime=true | FileCheck %s
   2
   3 ; Tests for unrolling loops with run-time trip counts
   4
   5 ; CHECK: %xtraiter = and i32 %n
   6 ; CHECK:  %lcmp.mod = icmp ne i32 %xtraiter, 0
   7 ; CHECK:  br i1 %lcmp.mod, label %for.body.prol, label %for.body.preheader.split
   8
   9 ; CHECK: for.body.prol:
  10 ; CHECK: %indvars.iv.prol = phi i64 [ %indvars.iv.next.prol, %for.body.prol ], [ 0, %for.body.preheader ]
  11 ; CHECK:  %prol.iter.sub = sub i32 %prol.iter, 1
  12 ; CHECK:  %prol.iter.cmp = icmp ne i32 %prol.iter.sub, 0
  13 ; CHECK:  br i1 %prol.iter.cmp, label %for.body.prol, label %for.body.preheader.split, !llvm.loop !0
  14
  15 define i32 @test(i32* nocapture %a, i32 %n) nounwind uwtable readonly {
  16 entry:
  17   %cmp1 = icmp eq i32 %n, 0
  18   br i1 %cmp1, label %for.end, label %for.body
  19
  20 for.body:                                         ; preds = %for.body, %entry
  21   %indvars.iv = phi i64 [ %indvars.iv.next, %for.body ], [ 0, %entry ]
  22   %sum.02 = phi i32 [ %add, %for.body ], [ 0, %entry ]
  23   %arrayidx = getelementptr inbounds i32, i32* %a, i64 %indvars.iv
  24   %0 = load i32, i32* %arrayidx, align 4
  25   %add = add nsw i32 %0, %sum.02
  26   %indvars.iv.next = add i64 %indvars.iv, 1
  27   %lftr.wideiv = trunc i64 %indvars.iv.next to i32
  28   %exitcond = icmp eq i32 %lftr.wideiv, %n
  29   br i1 %exitcond, label %for.end, label %for.body
  30
  31 for.end:                                          ; preds = %for.body, %entry
  32   %sum.0.lcssa = phi i32 [ 0, %entry ], [ %add, %for.body ]
  33   ret i32 %sum.0.lcssa
  34 }
  35
  36
  37 ; Still try to completely unroll loops with compile-time trip counts
  38 ; even if the -unroll-runtime is specified
  39
  40 ; CHECK: for.body:
  41 ; CHECK-NOT: for.body.prol:
  42
  43 define i32 @test1(i32* nocapture %a) nounwind uwtable readonly {
  44 entry:
  45   br label %for.body
  46
  47 for.body:                                         ; preds = %for.body, %entry
  48   %indvars.iv = phi i64 [ 0, %entry ], [ %indvars.iv.next, %for.body ]
  49   %sum.01 = phi i32 [ 0, %entry ], [ %add, %for.body ]
  50   %arrayidx = getelementptr inbounds i32, i32* %a, i64 %indvars.iv
  51   %0 = load i32, i32* %arrayidx, align 4
  52   %add = add nsw i32 %0, %sum.01
  53   %indvars.iv.next = add i64 %indvars.iv, 1
  54   %lftr.wideiv = trunc i64 %indvars.iv.next to i32
  55   %exitcond = icmp eq i32 %lftr.wideiv, 5
  56   br i1 %exitcond, label %for.end, label %for.body
  57
  58 for.end:                                          ; preds = %for.body
  59   ret i32 %add
  60 }
  61
  62 ; This is test 2007-05-09-UnknownTripCount.ll which can be unrolled now
  63 ; if the -unroll-runtime option is turned on
  64
  65 ; CHECK: bb72.2:
  66
  67 define void @foo(i32 %trips) {
  68 entry:
  69         br label %cond_true.outer
  70
  71 cond_true.outer:
  72         %indvar1.ph = phi i32 [ 0, %entry ], [ %indvar.next2, %bb72 ]
  73         br label %bb72
  74
  75 bb72:
  76         %indvar.next2 = add i32 %indvar1.ph, 1
  77         %exitcond3 = icmp eq i32 %indvar.next2, %trips
  78         br i1 %exitcond3, label %cond_true138, label %cond_true.outer
  79
  80 cond_true138:
  81         ret void
  82 }
  83
  84
  85 ; Test run-time unrolling for a loop that counts down by -2.
  86
  87 ; CHECK: for.body.prol:
  88 ; CHECK: br i1 %prol.iter.cmp, label %for.body.prol, label %for.body.preheader.split
  89
  90 define zeroext i16 @down(i16* nocapture %p, i32 %len) nounwind uwtable readonly {
  91 entry:
  92   %cmp2 = icmp eq i32 %len, 0
  93   br i1 %cmp2, label %for.end, label %for.body
  94
  95 for.body:                                         ; preds = %for.body, %entry
  96   %p.addr.05 = phi i16* [ %incdec.ptr, %for.body ], [ %p, %entry ]
  97   %len.addr.04 = phi i32 [ %sub, %for.body ], [ %len, %entry ]
  98   %res.03 = phi i32 [ %add, %for.body ], [ 0, %entry ]
  99   %incdec.ptr = getelementptr inbounds i16, i16* %p.addr.05, i64 1
 100   %0 = load i16, i16* %p.addr.05, align 2
 101   %conv = zext i16 %0 to i32
 102   %add = add i32 %conv, %res.03
 103   %sub = add nsw i32 %len.addr.04, -2
 104   %cmp = icmp eq i32 %sub, 0
 105   br i1 %cmp, label %for.cond.for.end_crit_edge, label %for.body
 106
 107 for.cond.for.end_crit_edge:                       ; preds = %for.body
 108   %phitmp = trunc i32 %add to i16
 109   br label %for.end
 110
 111 for.end:                                          ; preds = %for.cond.for.end_crit_edge, %entry
 112   %res.0.lcssa = phi i16 [ %phitmp, %for.cond.for.end_crit_edge ], [ 0, %entry ]
 113   ret i16 %res.0.lcssa
 114 }
 115
 116 ; CHECK: !0 = distinct !{!0, !1}
 117 ; CHECK: !1 = !{!"llvm.loop.unroll.disable"}
 118