test/Transforms/SROA/alignment.ll

   1 ; RUN: opt < %s -sroa -S | FileCheck %s
   2 target datalayout = "e-p:64:64:64-i1:8:8-i8:8:8-i16:16:16-i32:32:32-i64:32:64-f32:32:32-f64:64:64-v64:64:64-v128:128:128-a0:0:64-n8:16:32:64"
   3
   4 declare void @llvm.memcpy.p0i8.p0i8.i32(i8*, i8*, i32, i32, i1)
   5
   6 define void @test1({ i8, i8 }* %a, { i8, i8 }* %b) {
   7 ; CHECK: @test1
   8 ; CHECK: %[[gep_a0:.*]] = getelementptr inbounds { i8, i8 }* %a, i64 0, i32 0
   9 ; CHECK: %[[a0:.*]] = load i8* %[[gep_a0]], align 16
  10 ; CHECK: %[[gep_a1:.*]] = getelementptr inbounds { i8, i8 }* %a, i64 0, i32 1
  11 ; CHECK: %[[a1:.*]] = load i8* %[[gep_a1]], align 1
  12 ; CHECK: %[[gep_b0:.*]] = getelementptr inbounds { i8, i8 }* %b, i64 0, i32 0
  13 ; CHECK: store i8 %[[a0]], i8* %[[gep_b0]], align 16
  14 ; CHECK: %[[gep_b1:.*]] = getelementptr inbounds { i8, i8 }* %b, i64 0, i32 1
  15 ; CHECK: store i8 %[[a1]], i8* %[[gep_b1]], align 1
  16 ; CHECK: ret void
  17
  18 entry:
  19   %alloca = alloca { i8, i8 }, align 16
  20   %gep_a = getelementptr { i8, i8 }* %a, i32 0, i32 0
  21   %gep_alloca = getelementptr { i8, i8 }* %alloca, i32 0, i32 0
  22   %gep_b = getelementptr { i8, i8 }* %b, i32 0, i32 0
  23
  24   store i8 420, i8* %gep_alloca, align 16
  25
  26   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %gep_alloca, i8* %gep_a, i32 2, i32 16, i1 false)
  27   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %gep_b, i8* %gep_alloca, i32 2, i32 16, i1 false)
  28   ret void
  29 }
  30
  31 define void @test2() {
  32 ; CHECK: @test2
  33 ; CHECK: alloca i16
  34 ; CHECK: load i8* %{{.*}}
  35 ; CHECK: store i8 42, i8* %{{.*}}
  36 ; CHECK: ret void
  37
  38 entry:
  39   %a = alloca { i8, i8, i8, i8 }, align 2
  40   %gep1 = getelementptr { i8, i8, i8, i8 }* %a, i32 0, i32 1
  41   %cast1 = bitcast i8* %gep1 to i16*
  42   store volatile i16 0, i16* %cast1
  43   %gep2 = getelementptr { i8, i8, i8, i8 }* %a, i32 0, i32 2
  44   %result = load i8* %gep2
  45   store i8 42, i8* %gep2
  46   ret void
  47 }
  48
  49 define void @PR13920(<2 x i64>* %a, i16* %b) {
  50 ; Test that alignments on memcpy intrinsics get propagated to loads and stores.
  51 ; CHECK: @PR13920
  52 ; CHECK: load <2 x i64>* %a, align 2
  53 ; CHECK: store <2 x i64> {{.*}}, <2 x i64>* {{.*}}, align 2
  54 ; CHECK: ret void
  55
  56 entry:
  57   %aa = alloca <2 x i64>, align 16
  58   %aptr = bitcast <2 x i64>* %a to i8*
  59   %aaptr = bitcast <2 x i64>* %aa to i8*
  60   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %aaptr, i8* %aptr, i32 16, i32 2, i1 false)
  61   %bptr = bitcast i16* %b to i8*
  62   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %bptr, i8* %aaptr, i32 16, i32 2, i1 false)
  63   ret void
  64 }
  65
  66 define void @test3(i8* %x) {
  67 ; Test that when we promote an alloca to a type with lower ABI alignment, we
  68 ; provide the needed explicit alignment that code using the alloca may be
  69 ; expecting. However, also check that any offset within an alloca can in turn
  70 ; reduce the alignment.
  71 ; CHECK: @test3
  72 ; CHECK: alloca [22 x i8], align 8
  73 ; CHECK: alloca [18 x i8], align 2
  74 ; CHECK: ret void
  75
  76 entry:
  77   %a = alloca { i8*, i8*, i8* }
  78   %b = alloca { i8*, i8*, i8* }
  79   %a_raw = bitcast { i8*, i8*, i8* }* %a to i8*
  80   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %a_raw, i8* %x, i32 22, i32 8, i1 false)
  81   %b_raw = bitcast { i8*, i8*, i8* }* %b to i8*
  82   %b_gep = getelementptr i8* %b_raw, i32 6
  83   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %b_gep, i8* %x, i32 18, i32 2, i1 false)
  84   ret void
  85 }
  86
  87 %struct.S = type { i8, { i64 } }
  88
  89 define void @test4() {
  90 ; This test case triggered very strange alignment behavior with memcpy due to
  91 ; strange splitting. Reported by Duncan.
  92 ; CHECK: @test4
  93
  94 entry:
  95   %D.2113 = alloca %struct.S
  96   %Op = alloca %struct.S
  97   %D.2114 = alloca %struct.S
  98   %gep1 = getelementptr inbounds %struct.S* %Op, i32 0, i32 0
  99   store i8 0, i8* %gep1, align 8
 100   %gep2 = getelementptr inbounds %struct.S* %Op, i32 0, i32 1, i32 0
 101   %cast = bitcast i64* %gep2 to double*
 102   store double 0.000000e+00, double* %cast, align 8
 103   store i64 0, i64* %gep2, align 8
 104   %dst1 = bitcast %struct.S* %D.2114 to i8*
 105   %src1 = bitcast %struct.S* %Op to i8*
 106   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst1, i8* %src1, i32 16, i32 8, i1 false)
 107   %dst2 = bitcast %struct.S* %D.2113 to i8*
 108   %src2 = bitcast %struct.S* %D.2114 to i8*
 109   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %dst2, i8* %src2, i32 16, i32 8, i1 false)
 110 ; We get 3 memcpy calls with various reasons to shrink their alignment to 1.
 111 ; CHECK: @llvm.memcpy.p0i8.p0i8.i32(i8* %{{.*}}, i8* %{{.*}}, i32 3, i32 1, i1 false)
 112 ; CHECK: @llvm.memcpy.p0i8.p0i8.i32(i8* %{{.*}}, i8* %{{.*}}, i32 8, i32 1, i1 false)
 113 ; CHECK: @llvm.memcpy.p0i8.p0i8.i32(i8* %{{.*}}, i8* %{{.*}}, i32 11, i32 1, i1 false)
 114
 115   ret void
 116 }
 117
 118 define void @test5() {
 119 ; Test that we preserve underaligned loads and stores when splitting.
 120 ; CHECK: @test5
 121 ; CHECK: alloca [9 x i8]
 122 ; CHECK: alloca [9 x i8]
 123 ; CHECK: store volatile double 0.0{{.*}}, double* %{{.*}}, align 1
 124 ; CHECK: load i16* %{{.*}}, align 1
 125 ; CHECK: load double* %{{.*}}, align 1
 126 ; CHECK: store volatile double %{{.*}}, double* %{{.*}}, align 1
 127 ; CHECK: load i16* %{{.*}}, align 1
 128 ; CHECK: ret void
 129
 130 entry:
 131   %a = alloca [18 x i8]
 132   %raw1 = getelementptr inbounds [18 x i8]* %a, i32 0, i32 0
 133   %ptr1 = bitcast i8* %raw1 to double*
 134   store volatile double 0.0, double* %ptr1, align 1
 135   %weird_gep1 = getelementptr inbounds [18 x i8]* %a, i32 0, i32 7
 136   %weird_cast1 = bitcast i8* %weird_gep1 to i16*
 137   %weird_load1 = load i16* %weird_cast1, align 1
 138
 139   %raw2 = getelementptr inbounds [18 x i8]* %a, i32 0, i32 9
 140   %ptr2 = bitcast i8* %raw2 to double*
 141   %d1 = load double* %ptr1, align 1
 142   store volatile double %d1, double* %ptr2, align 1
 143   %weird_gep2 = getelementptr inbounds [18 x i8]* %a, i32 0, i32 16
 144   %weird_cast2 = bitcast i8* %weird_gep2 to i16*
 145   %weird_load2 = load i16* %weird_cast2, align 1
 146
 147   ret void
 148 }
 149
 150 define void @test6() {
 151 ; Test that we promote alignment when the underlying alloca switches to one
 152 ; that innately provides it.
 153 ; CHECK: @test6
 154 ; CHECK: alloca double
 155 ; CHECK: alloca double
 156 ; CHECK-NOT: align
 157 ; CHECK: ret void
 158
 159 entry:
 160   %a = alloca [16 x i8]
 161   %raw1 = getelementptr inbounds [16 x i8]* %a, i32 0, i32 0
 162   %ptr1 = bitcast i8* %raw1 to double*
 163   store volatile double 0.0, double* %ptr1, align 1
 164
 165   %raw2 = getelementptr inbounds [16 x i8]* %a, i32 0, i32 8
 166   %ptr2 = bitcast i8* %raw2 to double*
 167   %val = load double* %ptr1, align 1
 168   store volatile double %val, double* %ptr2, align 1
 169
 170   ret void
 171 }
 172
 173 define void @test7(i8* %out) {
 174 ; Test that we properly compute the destination alignment when rewriting
 175 ; memcpys as direct loads or stores.
 176 ; CHECK: @test7
 177 ; CHECK-NOT: alloca
 178
 179 entry:
 180   %a = alloca [16 x i8]
 181   %raw1 = getelementptr inbounds [16 x i8]* %a, i32 0, i32 0
 182   %ptr1 = bitcast i8* %raw1 to double*
 183   %raw2 = getelementptr inbounds [16 x i8]* %a, i32 0, i32 8
 184   %ptr2 = bitcast i8* %raw2 to double*
 185
 186   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %raw1, i8* %out, i32 16, i32 0, i1 false)
 187 ; CHECK: %[[val2:.*]] = load double* %{{.*}}, align 1
 188 ; CHECK: %[[val1:.*]] = load double* %{{.*}}, align 1
 189
 190   %val1 = load double* %ptr2, align 1
 191   %val2 = load double* %ptr1, align 1
 192
 193   store double %val1, double* %ptr1, align 1
 194   store double %val2, double* %ptr2, align 1
 195
 196   call void @llvm.memcpy.p0i8.p0i8.i32(i8* %out, i8* %raw1, i32 16, i32 0, i1 false)
 197 ; CHECK: store double %[[val1]], double* %{{.*}}, align 1
 198 ; CHECK: store double %[[val2]], double* %{{.*}}, align 1
 199
 200   ret void
 201 ; CHECK: ret void
 202 }