tools/llvm-config/CMakeLists.txt

   1 include(TestBigEndian)
   2
   3 include(FindPerl)
   4 if( NOT PERL_FOUND )
   5   message(FATAL_ERROR "Perl required but not found!")
   6 endif( NOT PERL_FOUND )
   7
   8 set(PERL ${PERL_EXECUTABLE})
   9 set(VERSION PACKAGE_VERSION)
  10 set(PREFIX ${LLVM_BINARY_DIR}) # TODO: Root for `make install'.
  11 set(abs_top_srcdir ${LLVM_MAIN_SRC_DIR})
  12 set(abs_top_builddir ${LLVM_BINARY_DIR})
  13 execute_process(COMMAND date
  14   OUTPUT_VARIABLE LLVM_CONFIGTIME
  15   OUTPUT_STRIP_TRAILING_WHITESPACE)
  16 # LLVM_ON_UNIX and LLVM_ON_WIN32 already set.
  17 # those are set to blank by `autoconf' on MinGW, so it seems they are not required:
  18 #set(LLVMGCCDIR "")
  19 #set(LLVMGCC "")
  20 #set(LLVMGXX "")
  21 #set(LLVMGCC_VERSION "")
  22 #set(LLVMGCC_MAJVERS "")
  23 test_big_endian(IS_BIG_ENDIAN)
  24 if( IS_BIG_ENDIAN )
  25   set(ENDIAN "big")
  26 else( IS_BIG_ENDIAN )
  27   set(ENDIAN "little")
  28 endif( IS_BIG_ENDIAN )
  29 set(SHLIBEXT ${LTDL_SHLIB_EXT})
  30 #EXEEXT already set.
  31 set(OS "${CMAKE_SYSTEM}")
  32 set(ARCH "${LLVM_NATIVE_ARCH}")
  33
  34 get_system_libs(LLVM_SYSTEM_LIBS_LIST)
  35 foreach(l ${LLVM_SYSTEM_LIBS_LIST})
  36   set(LLVM_SYSTEM_LIBS ${LLVM_SYSTEM_LIBS} "-l${l}")
  37 endforeach()
  38
  39 foreach(c ${LLVM_TARGETS_TO_BUILD})
  40   set(TARGETS_BUILT "${TARGETS_BUILT} ${c}")
  41 endforeach(c)
  42 set(TARGETS_TO_BUILD ${TARGETS_BUILT})
  43 set(TARGET_HAS_JIT "1")  # TODO
  44
  45 # Avoids replacement at config-time:
  46 set(LLVM_CPPFLAGS "@LLVM_CPPFLAGS@")
  47 set(LLVM_CFLAGS "@LLVM_CFLAGS@")
  48 set(LLVM_CXXFLAGS "@LLVM_CXXFLAGS@")
  49 set(LLVM_LDFLAGS "@LLVM_LDFLAGS@")
  50 set(LIBS "@LIBS@")
  51 set(LLVM_BUILDMODE "@LLVM_BUILDMODE@")
  52
  53 configure_file(
  54   ${CMAKE_CURRENT_SOURCE_DIR}/llvm-config.in.in
  55   ${CMAKE_CURRENT_BINARY_DIR}/llvm-config.in
  56   @ONLY
  57 )
  58
  59 set(LIBDEPS ${CMAKE_CURRENT_BINARY_DIR}/LibDeps.txt)
  60 set(LIBDEPS_TMP ${CMAKE_CURRENT_BINARY_DIR}/LibDeps.txt.tmp)
  61 set(FINAL_LIBDEPS ${CMAKE_CURRENT_BINARY_DIR}/FinalLibDeps.txt)
  62 set(LLVM_CONFIG ${LLVM_TOOLS_BINARY_DIR}/llvm-config)
  63 set(LLVM_CONFIG_IN ${CMAKE_CURRENT_BINARY_DIR}/llvm-config.in)
  64
  65 if( CMAKE_CROSSCOMPILING )
  66   set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM ONLY)
  67 endif()
  68
  69 find_program(NM_PATH nm PATH_SUFFIXES /bin)
  70
  71 if( NOT NM_PATH )
  72   message(FATAL_ERROR "`nm' not found")
  73 endif()
  74
  75 add_custom_command(OUTPUT ${LIBDEPS_TMP}
  76   COMMAND ${PERL_EXECUTABLE} ${LLVM_MAIN_SRC_DIR}/utils/GenLibDeps.pl -flat ${CMAKE_ARCHIVE_OUTPUT_DIRECTORY}/${CMAKE_CFG_INTDIR} ${NM_PATH} > ${LIBDEPS_TMP}
  77   DEPENDS ${llvm_libs}
  78   COMMENT "Regenerating ${LIBDEPS_TMP}")
  79
  80 add_custom_command(OUTPUT ${LIBDEPS}
  81   COMMAND ${CMAKE_COMMAND} -E copy_if_different ${LIBDEPS_TMP} ${LIBDEPS}
  82   DEPENDS ${LIBDEPS_TMP}
  83   COMMENT "Updated ${LIBDEPS} because dependencies changed")
  84
  85 add_custom_command(OUTPUT ${FINAL_LIBDEPS}
  86   COMMAND ${PERL_EXECUTABLE} ${CMAKE_CURRENT_SOURCE_DIR}/find-cycles.pl < ${LIBDEPS} > ${FINAL_LIBDEPS} || ${CMAKE_COMMAND} -E remove -f ${FINAL_LIBDEPS}
  87   DEPENDS ${LIBDEPS}
  88   COMMENT "Checking for cyclic dependencies between LLVM libraries.")
  89
  90 set(C_FLGS "${CMAKE_C_FLAGS_${uppercase_CMAKE_BUILD_TYPE}} ${LLVM_DEFINITIONS}")
  91 set(CXX_FLGS "${CMAKE_CXX_FLAGS_${uppercase_CMAKE_BUILD_TYPE}} ${LLVM_DEFINITIONS}")
  92 set(CPP_FLGS "${CMAKE_CPP_FLAGS_${uppercase_CMAKE_BUILD_TYPE}} ${LLVM_DEFINITIONS}")
  93
  94 add_custom_command(OUTPUT ${LLVM_CONFIG}
  95   COMMAND echo 's!@LLVM_CPPFLAGS@!${CPP_FLGS}!' > temp.sed
  96   COMMAND echo 's!@LLVM_CFLAGS@!${C_FLGS}!' >> temp.sed
  97   COMMAND echo 's!@LLVM_CXXFLAGS@!${CXX_FLGS}!' >> temp.sed
  98   # TODO: Use general flags for linking! not just for shared libs:
  99   COMMAND echo 's!@LLVM_LDFLAGS@!${CMAKE_SHARED_LINKER_FLAGS}!' >> temp.sed
 100   COMMAND echo 's!@LIBS@!${LLVM_SYSTEM_LIBS}!' >> temp.sed
 101   COMMAND echo 's!@LLVM_BUILDMODE@!${CMAKE_BUILD_TYPE}!' >> temp.sed
 102   COMMAND sed -f temp.sed < ${LLVM_CONFIG_IN} > ${LLVM_CONFIG}
 103   COMMAND ${CMAKE_COMMAND} -E remove -f temp.sed
 104   COMMAND cat ${FINAL_LIBDEPS} >> ${LLVM_CONFIG}
 105   COMMAND chmod +x ${LLVM_CONFIG}
 106   DEPENDS ${FINAL_LIBDEPS} ${LLVM_CONFIG_IN}
 107   COMMENT "Building llvm-config script."
 108   )
 109
 110 add_custom_target(llvm-config.target ALL
 111   DEPENDS ${LLVM_CONFIG})
 112
 113 add_dependencies(llvm-config.target ${llvm_lib_targets})
 114
 115 # Make sure that llvm-config builds before the llvm tools, so we have
 116 # LibDeps.txt and can use it for updating the hard-coded library
 117 # dependencies on cmake/modules/LLVMLibDeps.cmake when the tools'
 118 # build fail due to outdated dependencies:
 119 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} llvm-config.target)
 120
 121 install(FILES ${LLVM_CONFIG}
 122   PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE
 123   WORLD_READ WORLD_EXECUTE
 124   DESTINATION bin)
 125
 126
 127 # Regeneration of library dependencies.
 128
 129 # See the comments at the end of cmake/modules/LLVMConfig.cmake for
 130 # notes and guidelines.
 131
 132 set(LLVMLibDeps ${LLVM_MAIN_SRC_DIR}/cmake/modules/LLVMLibDeps.cmake)
 133 set(LLVMLibDeps_TMP ${CMAKE_CURRENT_BINARY_DIR}/LLVMLibDeps.cmake.tmp)
 134
 135 add_custom_command(OUTPUT ${LLVMLibDeps_TMP}
 136   COMMAND sed -e s'@\\.a@@g' -e s'@\\.so@@g' -e 's@libLLVM@LLVM@g' -e 's@: @ @' -e 's@\\\(.*\\\)@set\(MSVC_LIB_DEPS_\\1\)@' ${FINAL_LIBDEPS} > ${LLVMLibDeps_TMP}
 137   COMMAND ${CMAKE_COMMAND} -E copy_if_different ${LLVMLibDeps_TMP} ${LLVMLibDeps}
 138   DEPENDS ${FINAL_LIBDEPS}
 139   COMMENT "Updating cmake library dependencies file ${LLVMLibDeps}"
 140   )
 141
 142 if( LLVM_TARGETS_TO_BUILD STREQUAL LLVM_ALL_TARGETS )
 143   add_custom_target(llvmlibdeps.target ALL DEPENDS ${LLVMLibDeps_TMP})
 144   add_dependencies(llvmlibdeps.target llvm-config.target)
 145   set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} llvmlibdeps.target)
 146 endif()
 147
 148 set(LLVM_COMMON_DEPENDS ${LLVM_COMMON_DEPENDS} PARENT_SCOPE)