tools/llvm-config/llvm-config.in.in

   1 #!@PERL@
   2 ##===- tools/llvm-config ---------------------------------------*- perl -*-===##
   3 #
   4 #                     The LLVM Compiler Infrastructure
   5 #
   6 # This file was developed by Eric Kidd and is distributed under
   7 # the University of Illinois Open Source License. See LICENSE.TXT for details.
   8 #
   9 ##===----------------------------------------------------------------------===##
  10 #
  11 # Synopsis: Prints out compiler options needed to build against an installed
  12 #           copy of LLVM.
  13 #
  14 # Syntax:   llvm-config OPTIONS... [COMPONENTS...]
  15 #
  16 ##===----------------------------------------------------------------------===##
  17
  18 use 5.006;
  19 use strict;
  20 use warnings;
  21
  22 #---- begin autoconf values ----
  23 my $PACKAGE_NAME        = q{@PACKAGE_NAME@};
  24 my $VERSION             = q{@PACKAGE_VERSION@};
  25 my $PREFIX              = q{@LLVM_PREFIX@};
  26 my $LLVM_CONFIGTIME     = q{@LLVM_CONFIGTIME@};
  27 my $LLVM_SRC_ROOT       = q{@abs_top_srcdir@};
  28 my $LLVM_OBJ_ROOT       = q{@abs_top_builddir@};
  29 my $LLVM_ON_WIN32       = q{@LLVM_ON_WIN32@};
  30 my $LLVM_ON_UNIX        = q{@LLVM_ON_UNIX@};
  31 my $LLVMGCCDIR          = q{@LLVMGCCDIR@};
  32 my $LLVMGCC             = q{@LLVMGCC@};
  33 my $LLVMGXX             = q{@LLVMGXX@};
  34 my $LLVMGCC_VERSION     = q{@LLVMGCC_VERSION@};
  35 my $LLVMGCC_MAJVERS     = q{@LLVMGCC_MAJVERS@};
  36 my $ENDIAN              = q{@ENDIAN@};
  37 my $SHLIBEXT            = q{@SHLIBEXT@};
  38 my $EXEEXT              = q{@EXEEXT@};
  39 my $OS                  = q{@OS@};
  40 my $ARCH                = lc(q{@ARCH@});
  41 my $TARGET_TRIPLE       = q{@target@};
  42 my $TARGETS_TO_BUILD    = q{@TARGETS_TO_BUILD@};
  43 my $TARGET_HAS_JIT      = q{@TARGET_HAS_JIT@};
  44 my @TARGETS_BUILT       = map { lc($_) } qw{@TARGETS_TO_BUILD@};
  45 #---- end autoconf values ----
  46
  47 # Must pretend x86_64 architecture is really x86, otherwise the native backend
  48 # won't get linked in.
  49 $ARCH = "x86" if $ARCH eq "x86_64";
  50
  51 #---- begin Makefile values ----
  52 my $CFLAGS              = q{@LLVM_CFLAGS@};
  53 my $CXXFLAGS            = q{@LLVM_CXXFLAGS@};
  54 my $LDFLAGS             = q{@LLVM_LDFLAGS@};
  55 my $SYSTEM_LIBS         = q{@LIBS@};
  56 my $LLVM_BUILDMODE      = q{@LLVM_BUILDMODE@};
  57 #---- end Makefile values ----
  58
  59 # Figure out where llvm-config is being run from.  Primarily, we care if it has
  60 # been installed, or is running from the build directory, which changes the
  61 # locations of some files.
  62
  63 # Convert the current executable name into its directory (e.g. ".").
  64 my ($RUN_DIR) = ($0 =~ /^(.*)\/.*$/);
  65
  66 # Turn the directory into an absolute directory on the file system, also pop up
  67 # from "bin" into the build or prefix dir.
  68 my $ABS_RUN_DIR = `cd $RUN_DIR/..; pwd`;
  69 chomp($ABS_RUN_DIR);
  70
  71 # Compute the absolute object directory build, e.g. "foo/llvm/Debug".
  72 my $ABS_OBJ_ROOT = "$LLVM_OBJ_ROOT/$LLVM_BUILDMODE";
  73 $ABS_OBJ_ROOT = `cd $ABS_OBJ_ROOT; pwd` if (-d $ABS_OBJ_ROOT);
  74 chomp($ABS_OBJ_ROOT);
  75
  76 my $INCLUDEDIR = "$ABS_RUN_DIR/include";
  77 my $LIBDIR     = "$ABS_RUN_DIR/lib";
  78 my $BINDIR     = "$ABS_RUN_DIR/bin";
  79 if ($ABS_RUN_DIR eq $ABS_OBJ_ROOT) {
  80   # If we are running out of the build directory, the include dir is in the
  81   # srcdir.
  82   $INCLUDEDIR = "$LLVM_SRC_ROOT/include";
  83 } else {
  84   # If installed, ignore the prefix the tree was configured with, use the
  85   # current prefix.
  86   $PREFIX = $ABS_RUN_DIR;
  87 }
  88
  89 sub usage;
  90 sub fix_library_names (@);
  91 sub fix_library_files (@);
  92 sub expand_dependencies (@);
  93 sub name_map_entries;
  94
  95 # Parse our command-line arguments.
  96 usage if @ARGV == 0;
  97 my @components;
  98 my $has_opt = 0;
  99 my $want_libs = 0;
 100 my $want_libnames = 0;
 101 my $want_libfiles = 0;
 102 my $want_components = 0;
 103 foreach my $arg (@ARGV) {
 104     if ($arg =~ /^-/) {
 105         if ($arg eq "--version") {
 106             $has_opt = 1; print "$VERSION\n";
 107         } elsif ($arg eq "--prefix") {
 108             $has_opt = 1; print "$PREFIX\n";
 109         } elsif ($arg eq "--bindir") {
 110             $has_opt = 1; print "$BINDIR\n";
 111         } elsif ($arg eq "--includedir") {
 112             $has_opt = 1; print "$INCLUDEDIR\n";
 113         } elsif ($arg eq "--libdir") {
 114             $has_opt = 1; print "$LIBDIR\n";
 115         } elsif ($arg eq "--cflags") {
 116             $has_opt = 1; print "-I$INCLUDEDIR $CFLAGS\n";
 117         } elsif ($arg eq "--cxxflags") {
 118             $has_opt = 1; print "-I$INCLUDEDIR $CXXFLAGS\n";
 119         } elsif ($arg eq "--ldflags") {
 120             $has_opt = 1; print "-L$LIBDIR $LDFLAGS $SYSTEM_LIBS\n";
 121         } elsif ($arg eq "--libs") {
 122             $has_opt = 1; $want_libs = 1;
 123         } elsif ($arg eq "--libnames") {
 124             $has_opt = 1; $want_libnames = 1;
 125         } elsif ($arg eq "--libfiles") {
 126             $has_opt = 1; $want_libfiles = 1;
 127         } elsif ($arg eq "--components") {
 128             $has_opt = 1; print join(' ', name_map_entries), "\n";
 129         } elsif ($arg eq "--targets-built") {
 130             $has_opt = 1; print join(' ', @TARGETS_BUILT), "\n";
 131         } elsif ($arg eq "--host-target") {
 132             $has_opt = 1; print "$TARGET_TRIPLE\n";
 133         } elsif ($arg eq "--build-mode") {
 134             $has_opt = 1; print "$LLVM_BUILDMODE\n";
 135         } elsif ($arg eq "--obj-root") {
 136             $has_opt = 1; print `cd $LLVM_OBJ_ROOT/; pwd`;
 137         } elsif ($arg eq "--src-root") {
 138             $has_opt = 1; print `cd $LLVM_SRC_ROOT/; pwd`;
 139         } else {
 140             usage();
 141         }
 142     } else {
 143         push @components, $arg;
 144     }
 145 }
 146
 147 # If no options were specified, fail.
 148 usage unless $has_opt;
 149
 150 # If no components were specified, default to 'all'.
 151 if (@components == 0) {
 152     push @components, 'all';
 153 }
 154
 155 # Force component names to lower case.
 156 @components = map lc, @components;
 157
 158 # Handle any arguments which require building our dependency graph.
 159 if ($want_libs || $want_libnames || $want_libfiles) {
 160     my @libs = expand_dependencies(@components);
 161     print join(' ', fix_library_names(@libs)), "\n" if ($want_libs);
 162     print join(' ',  @libs), "\n" if ($want_libnames);
 163     print join(' ', fix_library_files(@libs)), "\n" if ($want_libfiles);
 164 }
 165
 166 exit 0;
 167
 168 #==========================================================================
 169 #  Support Routines
 170 #==========================================================================
 171
 172 sub usage {
 173     print STDERR <<__EOD__;
 174 Usage: llvm-config <OPTION>... [<COMPONENT>...]
 175
 176 Get various configuration information needed to compile programs which use
 177 LLVM.  Typically called from 'configure' scripts.  Examples:
 178   llvm-config --cxxflags
 179   llvm-config --ldflags
 180   llvm-config --libs engine bcreader scalaropts
 181
 182 Options:
 183   --version              Print LLVM version.
 184   --prefix               Print the installation prefix.
 185   --src-root             Print the source root LLVM was built from.
 186   --obj-root             Print the object root used to build LLVM.
 187   --bindir               Directory containing LLVM executables.
 188   --includedir           Directory containing LLVM headers.
 189   --libdir               Directory containing LLVM libraries.
 190   --cflags               C compiler flags for files that include LLVM headers.
 191   --cxxflags             C++ compiler flags for files that include LLVM headers.
 192   --ldflags              Print Linker flags.
 193   --libs                 Libraries needed to link against LLVM components.
 194   --libnames             Bare library names for in-tree builds.
 195   --libfiles             Fully qualified library filenames for makefile depends.
 196   --components           List of all possible components.
 197   --targets-built        List of all targets currently built.
 198   --host-target          Target triple used to configure LLVM.
 199   --build-mode           Print build mode of LLVM tree (e.g. Debug or Release).
 200 Typical components:
 201   all                    All LLVM libraries (default).
 202   backend                Either a native backend or the C backend.
 203   engine                 Either a native JIT or a bytecode interpreter.
 204 __EOD__
 205     exit(1);
 206 }
 207
 208 # Use -lfoo instead of libfoo.a whenever possible, and add directories to
 209 # files which can't be found using -L.
 210 sub fix_library_names (@) {
 211     my @libs = @_;
 212     my @result;
 213     foreach my $lib (@libs) {
 214         # Transform the bare library name appropriately.
 215         my ($basename) = ($lib =~ /^lib([^.]*)\.a/);
 216         if (defined $basename) {
 217             push @result, "-l$basename";
 218         } else {
 219             push @result, "$LIBDIR/$lib";
 220         }
 221     }
 222     return @result;
 223 }
 224
 225 # Turn the list of libraries into a list of files.
 226 sub fix_library_files(@) {
 227     my @libs = @_;
 228     my @result;
 229     foreach my $lib (@libs) {
 230         # Transform the bare library name into a filename.
 231         push @result, "$LIBDIR/$lib";
 232     }
 233     return @result;
 234 }
 235
 236 #==========================================================================
 237 #  Library Dependency Analysis
 238 #==========================================================================
 239 #  Given a few human-readable library names, find all their dependencies
 240 #  and sort them into an order which the linker will like.  If we packed
 241 #  our libraries into fewer archives, we could make the linker do much
 242 #  of this work for us.
 243 #
 244 #  Libraries have two different types of names in this code: Human-friendly
 245 #  "component" names entered on the command-line, and the raw file names
 246 #  we use internally (and ultimately pass to the linker).
 247 #
 248 #  To understand this code, you'll need a working knowledge of Perl 5,
 249 #  and possibly some quality time with 'man perlref'.
 250
 251 sub load_dependencies;
 252 sub build_name_map;
 253 sub have_native_backend;
 254 sub find_best_engine;
 255 sub expand_names (@);
 256 sub find_all_required_sets (@);
 257 sub find_all_required_sets_helper ($$@);
 258
 259 # Each "set" contains one or more libraries which must be included as a
 260 # group (due to cyclic dependencies).  Sets are represented as a Perl array
 261 # reference pointing to a list of internal library names.
 262 my @SETS;
 263
 264 # Various mapping tables.
 265 my %LIB_TO_SET_MAP; # Maps internal library names to their sets.
 266 my %SET_DEPS;       # Maps sets to a list of libraries they depend on.
 267 my %NAME_MAP;       # Maps human-entered names to internal names.
 268
 269 # Have our dependencies been loaded yet?
 270 my $DEPENDENCIES_LOADED = 0;
 271
 272 # Given a list of human-friendly component names, translate them into a
 273 # complete set of linker arguments.
 274 sub expand_dependencies (@) {
 275     my @libs = @_;
 276     load_dependencies;
 277     my @required_sets = find_all_required_sets(expand_names(@libs));
 278     my @sorted_sets = topologically_sort_sets(@required_sets);
 279
 280     # Expand the library sets into libraries.
 281     my @result;
 282     foreach my $set (@sorted_sets) { push @result, @{$set}; }
 283     return @result;
 284 }
 285
 286 # Load in the raw dependency data stored at the end of this file.
 287 sub load_dependencies {
 288     return if $DEPENDENCIES_LOADED;
 289     $DEPENDENCIES_LOADED = 1;
 290     while (<DATA>) {
 291         # Parse our line.
 292         my ($libs, $deps) = /^\s*([^:]+):\s*(.*)\s*$/;
 293         die "Malformed dependency data" unless defined $deps;
 294         my @libs = split(' ', $libs);
 295         my @deps = split(' ', $deps);
 296
 297         # Record our dependency data.
 298         my $set = \@libs;
 299         push @SETS, $set;
 300         foreach my $lib (@libs) { $LIB_TO_SET_MAP{$lib} = $set; }
 301         $SET_DEPS{$set} = \@deps;
 302     }
 303     build_name_map;
 304 }
 305
 306 # Build a map converting human-friendly component names into internal
 307 # library names.
 308 sub build_name_map {
 309     # Add entries for all the actual libraries.
 310     foreach my $set (@SETS) {
 311         foreach my $lib (sort @$set) {
 312             my $short_name = $lib;
 313             $short_name =~ s/^(lib)?LLVM([^.]*)\..*$/$2/;
 314             $short_name =~ tr/A-Z/a-z/;
 315             $NAME_MAP{$short_name} = [$lib];
 316         }
 317     }
 318
 319     # Add virtual entries.
 320     $NAME_MAP{'native'}  = have_native_backend() ? [$ARCH] : [];
 321     $NAME_MAP{'backend'} = have_native_backend() ? ['native'] : ['cbackend'];
 322     $NAME_MAP{'engine'}  = find_best_engine;
 323     $NAME_MAP{'all'}     = [name_map_entries];   # Must be last.
 324 }
 325
 326 # Return true if we have a native backend to use.
 327 sub have_native_backend {
 328     my %BUILT;
 329     foreach my $target (@TARGETS_BUILT) { $BUILT{$target} = 1; }
 330     return defined $NAME_MAP{$ARCH} && defined $BUILT{$ARCH};
 331 }
 332
 333 # Find a working subclass of ExecutionEngine for this platform.
 334 sub find_best_engine {
 335     if (have_native_backend && $TARGET_HAS_JIT) {
 336         return ['jit', 'native'];
 337     } else {
 338         return ['interpreter'];
 339     }
 340 }
 341
 342 # Get all the human-friendly component names.
 343 sub name_map_entries {
 344     load_dependencies;
 345     return sort keys %NAME_MAP;
 346 }
 347
 348 # Map human-readable names to internal library names.
 349 sub expand_names (@) {
 350     my @names = @_;
 351     my @result;
 352     foreach my $name (@names) {
 353         if (defined $LIB_TO_SET_MAP{$name}) {
 354             # We've hit bottom: An actual library name.
 355             push @result, $name;
 356         } elsif (defined $NAME_MAP{$name}) {
 357             # We've found a short name to expand.
 358             push @result, expand_names(@{$NAME_MAP{$name}});
 359         } else {
 360             print STDERR "llvm-config: unknown component name: $name\n";
 361             exit(1);
 362         }
 363     }
 364     return @result;
 365 }
 366
 367 # Given a list of internal library names, return all sets of libraries which
 368 # will need to be included by the linker (in no particular order).
 369 sub find_all_required_sets (@) {
 370     my @libs = @_;
 371     my %sets_added;
 372     my @result;
 373     find_all_required_sets_helper(\%sets_added, \@result, @libs);
 374     return @result;
 375 }
 376
 377 # Recursive closures are pretty broken in Perl, so we're going to separate
 378 # this function from find_all_required_sets and pass in the state we need
 379 # manually, as references.  Yes, this is fairly unpleasant.
 380 sub find_all_required_sets_helper ($$@) {
 381     my ($sets_added, $result, @libs) = @_;
 382     foreach my $lib (@libs) {
 383         my $set = $LIB_TO_SET_MAP{$lib};
 384         next if defined $$sets_added{$set};
 385         $$sets_added{$set} = 1;
 386         push @$result, $set;
 387         find_all_required_sets_helper($sets_added, $result, @{$SET_DEPS{$set}});
 388     }
 389 }
 390
 391 # Print a list of sets, with a label.  Used for debugging.
 392 sub print_sets ($@) {
 393     my ($label, @sets) = @_;
 394     my @output;
 395     foreach my $set (@sets) { push @output, join(',', @$set); }
 396     print "$label: ", join(';', @output), "\n";
 397 }
 398
 399 # Returns true if $lib is a key in $added.
 400 sub has_lib_been_added ($$) {
 401     my ($added, $lib) = @_;
 402     return defined $$added{$LIB_TO_SET_MAP{$lib}};
 403 }
 404
 405 # Returns true if all the dependencies of $set appear in $added.
 406 sub have_all_deps_been_added ($$) {
 407     my ($added, $set) = @_;
 408     #print_sets("  Checking", $set);
 409     #print_sets("     Wants", $SET_DEPS{$set});
 410     foreach my $lib (@{$SET_DEPS{$set}}) {
 411         return 0 unless has_lib_been_added($added, $lib);
 412     }
 413     return 1;
 414 }
 415
 416 # Given a list of sets, topologically sort them using dependencies.
 417 sub topologically_sort_sets (@) {
 418     my @sets = @_;
 419     my %added;
 420     my @result;
 421     SCAN: while (@sets) { # We'll delete items from @sets as we go.
 422         #print_sets("So far", reverse(@result));
 423         #print_sets("Remaining", @sets);
 424         for (my $i = 0; $i < @sets; ++$i) {
 425             my $set = $sets[$i];
 426             if (have_all_deps_been_added(\%added, $set)) {
 427                 push @result, $set;
 428                 $added{$set} = 1;
 429                 #print "Removing $i.\n";
 430                 splice(@sets, $i, 1);
 431                 next SCAN; # Restart our scan.
 432             }
 433         }
 434         die "Can't find a library with no dependencies";
 435     }
 436     return reverse(@result);
 437 }
 438
 439 # Our library dependency data will be added after the '__END__' token, and will
 440 # be read through the magic <DATA> filehandle.
 441 __END__